Cave Fighter - Side Scrolling Action Game

[SierraKen]

For almost a week I've been working hard on this game. I wanted to see if I could use the new scrolling map method that Felippe told us about recently and turn it into a spaceship game. In this game you control your tiny red ship with the arrow keys or WASD keys and press the space bar to fire. The object is to get to the end of each cave level. There's 3 cave levels included here that I made using my graphics program Paint.Net. I'm no artist but I tried my best :). One trick you will probably need to do is shoot your laser through the mountains to hit some of the shooting cannons. You don't destroy rocks but the laser goes straight through anything and you can shoot it in the 4 directions you can move with. I hope you all enjoy this game, it's one of the biggest games I've ever made. I realize that most likely the lines of code could be reduced dramatically (it has around 1000 lines) but I don't know how to reduce the number of variables yet like many of you guys do. The player.x, player.y, camera.x, camera.y variables I got directly from Felippe's original code. Which was a trick in itself to figure out what used 800 x 600 and what used the 4000 x 600 level picture files when adding more graphics to it with the game. I still don't understand it completely but I figured it out enough to use. Enjoy the game and please leave comments, thanks. All the files are in the zip file in attachments as well as a picture I will add. Oh also, I'm sure you all will laugh at the look of the ship, but like I said I'm no artist and I think it goes good with the laser sound. lol Oh one more thing, I added a lot of comments in the code on how it's very easy to add more levels. I used a separate program I made to detect coordinates with the mouse on the picture files so I could plot and display each cannon and their cannonballs.

Edit: I forgot to mention that to Pause the game, press P. I just used the SLEEP command for that. So you can press any other key to turn Pause off.

Edit Again: The zip file is updated to now have 5 levels of caves and a new looking spaceship that B+ let me use. :)

Edit Again: This zip file has been updated again to fix a problem that slows down the game if you sit in one place for a long time.

[johnno56]

Cool game. Took me a few lives to figure out the timing of enemy bullets... Perhaps, to make it a little harder - after a few levels, placing some enemies on the cave ceiling firing down to the right or perhaps increasing bullet speed based on level number? But still a cool game!

[Petr]

Hi, nice game. It is a pity that the SOUND command suspends the execution of the program, unlike QBasic 4.5. I sent you something in a private message, maybe it's not too hard. You inspired me with this game for it :)

[SierraKen]

Thanks guys! :) Johnno, adding more cannons would make it a lot harder, I probably won't.
Thanks Petr, I'll check and see what you gave me.
B+ is probably having a hard time with the keys again. I might try to make a mouse version for him if I can.

[bplus]

It's OK Ken, WASD is actually better than arrow keys specially with practice.

Since you are a friend I will lend you my ship you can use. I am sure the explosions and crashes will buff out ;-))

Here is SUB drawShip demo with 2 handy helper subs specially fcirc for fast draw of circle fills:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(1024, 700, 32)
2. _DELAY .25
3. _SCREENMOVE _MIDDLE
4.  
5. DIM sc AS _UNSIGNED LONG ' ship color
6. sc = _RGB32(RND * 215 + 40, RND * 255, RND * 255)
7. _MOUSEHIDE
8. DO
9.     CLS
10.     lc = lc + 1 'loop counter
11.     IF lc > 3 * 60 THEN sc = _RGB32(RND * 215 + 40, RND * 255, RND * 255): lc = 0 'every 3 secs change ship color
12.     WHILE _MOUSEINPUT: WEND
13.     drawShip _MOUSEX, _MOUSEY, sc ' here is how to call drawShip   easier than using circle
14.     _DISPLAY
15.     _LIMIT 60
16. LOOP UNTIL _KEYDOWN(27)
17.  
18. SUB drawShip (x, y, colr AS _UNSIGNED LONG) 'shipType     collisions same as circle x, y radius = 30
19.     STATIC ls
20.     DIM light AS LONG, r AS LONG, g AS LONG, b AS LONG
21.     r = _RED32(colr): g = _GREEN32(colr): b = _BLUE32(colr)
22.     fellipse x, y, 6, 15, _RGB32(r, g - 120, b - 100)
23.     fellipse x, y, 18, 11, _RGB32(r, g - 60, b - 50)
24.     fellipse x, y, 30, 7, _RGB32(r, g, b)
25.     FOR light = 0 TO 5
26.         fcirc x - 30 + 11 * light + ls, y, 1, _RGB32(ls * 50, ls * 50, ls * 50)
27.     NEXT
28.     ls = ls + 1
29.     IF ls > 5 THEN ls = 0
30. END SUB
31.  
32.  
33. ' ======== helper subs for drawShip that you can use for other things specially fcirc = fill_circle  x, y, radius, color
34.  
35. SUB fellipse (CX AS LONG, CY AS LONG, xr AS LONG, yr AS LONG, C AS _UNSIGNED LONG)
36.     IF xr = 0 OR yr = 0 THEN EXIT SUB
37.     DIM h2 AS _INTEGER64, w2 AS _INTEGER64, h2w2 AS _INTEGER64
38.     DIM x AS LONG, y AS LONG
39.     w2 = xr * xr: h2 = yr * yr: h2w2 = h2 * w2
40.     LINE (CX - xr, CY)-(CX + xr, CY), C, BF
41.     DO WHILE y < yr
42.         y = y + 1
43.         x = SQR((h2w2 - y * y * w2) \ h2)
44.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
45.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
46.     LOOP
47. END SUB
48.  
49. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version  fill circle x, y, radius, color
50.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
51.     x0 = R: y0 = 0: e = 0
52.     DO WHILE y0 < x0
53.         IF e <= 0 THEN
54.             y0 = y0 + 1
55.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
56.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
57.             e = e + 2 * y0
58.         ELSE
59.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
60.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
61.             x0 = x0 - 1: e = e - 2 * x0
62.         END IF
63.     LOOP
64.     LINE (x - R, y)-(x + R, y), C, BF
65. END SUB
66.  
67.  

Maybe 30 Radius too big, we can shrink down?

[SierraKen]

THANKS B+! Your spaceship really livens up my game a lot. I had to shrink it by 1/3 to fly easier in the caves but it works great now. I also widened the tops of the caves some. I also added 2 more levels making 5 total (70 cannons total!) Plus I shrank the cannonballs from 5 pixels to 2 pixels to make it easier as well. I moved the laser to fit the ship better too.
Petr gave me code on how to make a 360 degree turning cannon and I added code to his making the tank (or ship) move toward where it was pointing. I tried adding that to this game but using a mouse with a scrolling map is very hard and I know it wouldn't work well with that. So I'll use Petr's code on another game sometime.

Tell me what you all think, I'll replace the last zip with this one too and also it will be below on this post.

[bplus]

Hey I like what you've done with the ship!

"Mark what's that noise?" (as the dog is running upstairs WTH?)

Just playing a game, mom! ;-))

[SierraKen]

LOL Thanks B+!. :)) I just added a picture to my last post and also an updated picture on the first post.

[SierraKen]

I came across a small problem that slows the game down tremendously if you let it sit for around 10 minutes. I believe it was because I put the limit on cannonballs way too high, it was at around 4000 for each cannon, so I reduced each one to 100 (dimmed at 200) and I added code to erase them all once it gets to 100 and then it starts over. It looks like I fixed it mostly. I haven't done a big test on it but it's better than it was at least.

Here is the updated attachment zip file. I'll update the other ones as well.

[johnno56]

Cool... Much improved. I got through all 5 levels but still lost a life....

I don't know if this feature was deliberate, to make it easier, but some of the 'shots' could pass through the cavern and hit the target. I'm not complaining... Got me out of some tricky spots at times... nudge, nudge, wink, wink... The 'ship' looks 'very' familiar... Any ideas bplus? lol

[bplus]

The 'ship' looks 'very' familiar... Any ideas bplus? lol

SmallBASIC Space Shooter Game - target practice with plasma laser cannon! I believe it was translated SdlBasic as well. Aurel requested a space shooter game, the ship got created then, so with Asteroids this is 4th appearance at least. When you find a good thing stick with it!

Speaking of plasma laser cannon... if you fly the ship with WASD you have mouse hand free to aim the plasma laser cannon. :)

@SierraKen are you using the the fcirc SUB to make solid circles, it is fastest method, faster than paint or drawing circles in a loop. Oh speaking of cannon balls... ;-))

[SierraKen]

Johno, yes that's the trick I left in so people can shoot the cannons easier. :)

B+, yes but only on the saucer, the rest I just kept as my usual sz loops. :)

[bplus]

B+, yes but only on the saucer, the rest I just kept as my usual sz loops. :)

Yes there is an opportunity to speed things up! Whenever you need a filled in circle use: fcirc x, y, r, color
You can cut some time of drawing.


Here is Plasma Laser Cannon demo with some balls for targets:

Code: QB64: [Select]

1. _TITLE "Plasma Laser Cannon demo" 'b+ 2020-11-11
2. SCREEN _NEWIMAGE(1024, 700, 32)
3. _DELAY .25
4. _SCREENMOVE _MIDDLE
5. RANDOMIZE TIMER
6.  
7. DIM SHARED tx, ty, tr, tc AS _UNSIGNED LONG
8. newTarget
9. DO
10.     CLS
11.     PRINT tx, ty, tr, tc
12.     drawBall tx, ty, tr, tc
13.     WHILE _MOUSEINPUT: WEND 'aim with mouse
14.     mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1)
15.     IF mb THEN
16.         PLC _WIDTH / 2, _HEIGHT / 2, _MOUSEX, _MOUSEY, tr
17.         drawShip _WIDTH / 2, _HEIGHT / 2, &HFF66FF88
18.         _DISPLAY
19.     ELSE
20.         drawShip _WIDTH / 2, _HEIGHT / 2, &HFF66FF88
21.     END IF
22.     IF _HYPOT(mx - tx, my - ty) < tr AND mb THEN
23.         FOR r = 0 TO 255
24.             fcirc tx, ty, r, _RGBA32(255, 255 - r, 0, 10)
25.             _DISPLAY
26.             _LIMIT 400
27.         NEXT
28.         newTarget
29.     END IF
30.     IF INKEY$ = " " THEN newTarget
31.     _DISPLAY
32.     _LIMIT 60
33. LOOP UNTIL _KEYDOWN(27)
34.  
35. SUB newTarget
36.     IF RND < .5 THEN
37.         IF RND < .5 THEN tx = RND * 200 + 50 ELSE tx = _WIDTH - 250 + RND * 200
38.         ty = RND * (_HEIGHT - 100) + 50
39.     ELSE
40.         IF RND < .5 THEN ty = RND * 200 + 50 ELSE ty = _HEIGHT - 250 + RND * 100
41.         tx = RND * (_WIDTH - 100) + 50
42.     END IF
43.     tr = RND * 50 + 20
44.     tc = _RGB32(60 + RND * 195, RND * 255, RND * 255)
45. END SUB
46.  
47. SUB PLC (baseX, baseY, targetX, targetY, targetR) ' PLC for PlasmaLaserCannon
48.     r = RND ^ 2 * RND: g = RND ^ 2 * RND: b = RND ^ 2 * RND: hp = _PI(.5) ' red, green, blue, half pi
49.     ta = _ATAN2(targetY - baseY, targetX - baseX) ' angle of target to cannon base
50.     dist = _HYPOT(targetY - baseY, targetX - baseX) ' distance cannon to target
51.     dr = targetR / dist
52.     FOR r = 0 TO dist STEP .25
53.         x = baseX + r * COS(ta)
54.         y = baseY + r * SIN(ta)
55.         c = c + .3
56.         fcirc x, y, dr * r, _RGB32(128 + 127 * SIN(r * c), 128 + 127 * SIN(g * c), 128 + 127 * SIN(b * c))
57.     NEXT
58.     FOR rr = dr * r TO 0 STEP -.5
59.         c = c + 1
60.         fcirc x, y, rr, _RGB32(128 + 127 * SIN(r * c), 128 + 127 * SIN(g * c), 128 + 127 * SIN(b * c))
61.     NEXT
62. END SUB
63.  
64. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version  fill circle x, y, radius, color
65.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
66.     x0 = R: y0 = 0: e = 0
67.     DO WHILE y0 < x0
68.         IF e <= 0 THEN
69.             y0 = y0 + 1
70.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
71.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
72.             e = e + 2 * y0
73.         ELSE
74.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
75.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
76.             x0 = x0 - 1: e = e - 2 * x0
77.         END IF
78.     LOOP
79.     LINE (x - R, y)-(x + R, y), C, BF
80. END SUB
81.  
82. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
83.     DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
84.     rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
85.     FOR rr = r TO 0 STEP -1
86.         f = 1 - rr / r
87.         fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
88.     NEXT
89. END SUB
90.  
91. SUB drawShip (x, y, colr AS _UNSIGNED LONG) 'shipType     collisions same as circle x, y radius = 30
92.     STATIC ls
93.     DIM light AS LONG, r AS LONG, g AS LONG, b AS LONG
94.     r = _RED32(colr): g = _GREEN32(colr): b = _BLUE32(colr)
95.     fellipse x, y, 6, 15, _RGB32(r, g - 120, b - 100)
96.     fellipse x, y, 18, 11, _RGB32(r, g - 60, b - 50)
97.     fellipse x, y, 30, 7, _RGB32(r, g, b)
98.     FOR light = 0 TO 5
99.         fcirc x - 30 + 11 * light + ls, y, 1, _RGB32(ls * 50, ls * 50, ls * 50)
100.     NEXT
101.     ls = ls + 1
102.     IF ls > 5 THEN ls = 0
103. END SUB
104.  
105. SUB fellipse (CX AS LONG, CY AS LONG, xr AS LONG, yr AS LONG, C AS _UNSIGNED LONG)
106.     IF xr = 0 OR yr = 0 THEN EXIT SUB
107.     DIM h2 AS _INTEGER64, w2 AS _INTEGER64, h2w2 AS _INTEGER64
108.     DIM x AS LONG, y AS LONG
109.     w2 = xr * xr: h2 = yr * yr: h2w2 = h2 * w2
110.     LINE (CX - xr, CY)-(CX + xr, CY), C, BF
111.     DO WHILE y < yr
112.         y = y + 1
113.         x = SQR((h2w2 - y * y * w2) \ h2)
114.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
115.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
116.     LOOP
117. END SUB
118.  
119.  

EDIT: forgot I switched to circles instead of lines so removed x1, y1, x2, y2 calcs for PLC

[SierraKen]

Wow incredible... so Subs don't always run at the same time as the program, but they keep it in memory to be used as many times as needed for the main program. I finally get it! LOL Thanks B+.

[bplus]

Wow incredible... so Subs don't always run at the same time as the program, but they keep it in memory to be used as many times as needed for the main program. I finally get it! LOL Thanks B+.

Yes they are just like PRINT, INPUT, CIRCLE, LINE only you put the code for them in your program.

Just imagine them as extensions to QB64 command keywords. They are meant to be used over and over just like command keywords of QB64.