Cave Fighter - Side Scrolling Action Game

[SierraKen]

Awesome, I will have to experiment with them. :)

[bplus]

The most obvious one to start using is fcirc which you can rename FillCircle or CircleFill.... that's an advantage to these SUBs and FUNCTIONs because you load them in yourself or create them, you can name them as you please.

[SierraKen]

That was SO COOL! I just used your FillCircle Sub and made a large bright green circle. It feels almost like learning BASIC again back in the 80's. LOL
I also made a new folder called - SUB EXAMPLES that I can go to easily from now on. :))

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. x = 400: y = 300: r = 100
3. c = _RGB32(0, 255, 0)
4.  
5. fillcircle x, y, r, c
6.  
7.  
8. SUB fillcircle (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG) 'vince version  fill circle x, y, radius, color
9.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
10.     x0 = R: y0 = 0: e = 0
11.     DO WHILE y0 < x0
12.         IF e <= 0 THEN
13.             y0 = y0 + 1
14.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
15.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
16.             e = e + 2 * y0
17.         ELSE
18.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
19.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
20.             x0 = x0 - 1: e = e - 2 * x0
21.         END IF
22.     LOOP
23.     LINE (x - R, y)-(x + R, y), C, BF
24. END SUB
25.  

[FellippeHeitor]

Very good idea for a game using the map technique, Ken!

[SierraKen]

Thanks Felippe!

[bplus]

I noticed something odd using _vince version of circle fill, tiny white crosses were appearing on spheres whereas the Steve Gold Standard does not have them.

Check it out: I put an s before the Steve Gold Standard circle to test the vince version result: little white crosses on the spheres whereas put a v on vince version and remove the s on the Steve Gold Standard version result: no crosses.

Code: QB64: [Select]

1. _TITLE "Plasma Laser Cannon demo" 'b+ 2020-11-11
2. SCREEN _NEWIMAGE(1024, 700, 32)
3. _DELAY .25
4. _SCREENMOVE _MIDDLE
5. RANDOMIZE TIMER
6.  
7. DIM SHARED tx, ty, tr, tc AS _UNSIGNED LONG
8. newTarget
9. DO
10.     CLS
11.     PRINT tx, ty, tr, tc
12.     drawBall tx, ty, tr, tc
13.     WHILE _MOUSEINPUT: WEND 'aim with mouse
14.     mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1)
15.     IF mb THEN
16.         PLC _WIDTH / 2, _HEIGHT / 2, _MOUSEX, _MOUSEY, tr
17.         drawShip _WIDTH / 2, _HEIGHT / 2, &HFF66FF88
18.         _DISPLAY
19.     ELSE
20.         drawShip _WIDTH / 2, _HEIGHT / 2, &HFF66FF88
21.     END IF
22.     IF _HYPOT(mx - tx, my - ty) < tr AND mb THEN
23.         FOR r = 0 TO 255
24.             fcirc tx, ty, r, _RGBA32(255, 255 - r, 0, 10)
25.             _DISPLAY
26.             _LIMIT 400
27.         NEXT
28.         newTarget
29.     END IF
30.     IF INKEY$ = " " THEN newTarget
31.     _DISPLAY
32.     _LIMIT 60
33. LOOP UNTIL _KEYDOWN(27)
34.  
35. SUB newTarget
36.     IF RND < .5 THEN
37.         IF RND < .5 THEN tx = RND * 200 + 50 ELSE tx = _WIDTH - 250 + RND * 200
38.         ty = RND * (_HEIGHT - 100) + 50
39.     ELSE
40.         IF RND < .5 THEN ty = RND * 200 + 50 ELSE ty = _HEIGHT - 250 + RND * 100
41.         tx = RND * (_WIDTH - 100) + 50
42.     END IF
43.     tr = RND * 50 + 20
44.     tc = _RGB32(60 + RND * 195, RND * 255, RND * 255)
45. END SUB
46.  
47. SUB PLC (baseX, baseY, targetX, targetY, targetR) ' PLC for PlasmaLaserCannon
48.     r = RND ^ 2 * RND: g = RND ^ 2 * RND: b = RND ^ 2 * RND: hp = _PI(.5) ' red, green, blue, half pi
49.     ta = _ATAN2(targetY - baseY, targetX - baseX) ' angle of target to cannon base
50.     dist = _HYPOT(targetY - baseY, targetX - baseX) ' distance cannon to target
51.     dr = targetR / dist
52.     FOR r = 0 TO dist STEP .25
53.         x = baseX + r * COS(ta)
54.         y = baseY + r * SIN(ta)
55.         c = c + .3
56.         fcirc x, y, dr * r, _RGB32(128 + 127 * SIN(r * c), 128 + 127 * SIN(g * c), 128 + 127 * SIN(b * c))
57.     NEXT
58.     FOR rr = dr * r TO 0 STEP -.5
59.         c = c + 1
60.         fcirc x, y, rr, _RGB32(128 + 127 * SIN(r * c), 128 + 127 * SIN(g * c), 128 + 127 * SIN(b * c))
61.     NEXT
62. END SUB
63.  
64. SUB drawBall (x, y, r, c AS _UNSIGNED LONG)
65.     DIM rred AS LONG, grn AS LONG, blu AS LONG, rr AS LONG, f
66.     rred = _RED32(c): grn = _GREEN32(c): blu = _BLUE32(c)
67.     FOR rr = r TO 0 STEP -1
68.         f = 1 - rr / r
69.         fcirc x, y, rr, _RGB32(rred * f, grn * f, blu * f)
70.     NEXT
71. END SUB
72.  
73. SUB drawShip (x, y, colr AS _UNSIGNED LONG) 'shipType     collisions same as circle x, y radius = 30
74.     STATIC ls
75.     DIM light AS LONG, r AS LONG, g AS LONG, b AS LONG
76.     r = _RED32(colr): g = _GREEN32(colr): b = _BLUE32(colr)
77.     fellipse x, y, 6, 15, _RGB32(r, g - 120, b - 100)
78.     fellipse x, y, 18, 11, _RGB32(r, g - 60, b - 50)
79.     fellipse x, y, 30, 7, _RGB32(r, g, b)
80.     FOR light = 0 TO 5
81.         fcirc x - 30 + 11 * light + ls, y, 1, _RGB32(ls * 50, ls * 50, ls * 50)
82.     NEXT
83.     ls = ls + 1
84.     IF ls > 5 THEN ls = 0
85. END SUB
86.  
87. SUB fellipse (CX AS LONG, CY AS LONG, xr AS LONG, yr AS LONG, C AS _UNSIGNED LONG)
88.     IF xr = 0 OR yr = 0 THEN EXIT SUB
89.     DIM h2 AS _INTEGER64, w2 AS _INTEGER64, h2w2 AS _INTEGER64
90.     DIM x AS LONG, y AS LONG
91.     w2 = xr * xr: h2 = yr * yr: h2w2 = h2 * w2
92.     LINE (CX - xr, CY)-(CX + xr, CY), C, BF
93.     DO WHILE y < yr
94.         y = y + 1
95.         x = SQR((h2w2 - y * y * w2) \ h2)
96.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
97.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
98.     LOOP
99. END SUB
100.  
101. 'vince version  fill circle x, y, radius, color
102. SUB fcirc (x AS LONG, y AS LONG, R AS LONG, C AS _UNSIGNED LONG)
103.     DIM x0 AS LONG, y0 AS LONG, e AS LONG
104.     x0 = R: y0 = 0: e = 0
105.     DO WHILE y0 < x0
106.         IF e <= 0 THEN
107.             y0 = y0 + 1
108.             LINE (x - x0, y + y0)-(x + x0, y + y0), C, BF
109.             LINE (x - x0, y - y0)-(x + x0, y - y0), C, BF
110.             e = e + 2 * y0
111.         ELSE
112.             LINE (x - y0, y - x0)-(x + y0, y - x0), C, BF
113.             LINE (x - y0, y + x0)-(x + y0, y + x0), C, BF
114.             x0 = x0 - 1: e = e - 2 * x0
115.         END IF
116.     LOOP
117.     LINE (x - R, y)-(x + R, y), C, BF
118. END SUB
119.  
120. 'from Steve Gold standard
121. SUB sfcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
122.     DIM Radius AS INTEGER, RadiusError AS INTEGER
123.     DIM X AS INTEGER, Y AS INTEGER
124.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
125.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
126.     LINE (CX - X, CY)-(CX + X, CY), C, BF
127.     WHILE X > Y
128.         RadiusError = RadiusError + Y * 2 + 1
129.         IF RadiusError >= 0 THEN
130.             IF X <> Y + 1 THEN
131.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
132.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
133.             END IF
134.             X = X - 1
135.             RadiusError = RadiusError - X * 2
136.         END IF
137.         Y = Y + 1
138.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
139.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
140.     WEND
141. END SUB
142.  
143.  
144.  

Smaller green spheres easiest to see:
 

[bplus]

@SierraKen  just saying if you are going to use Fill Circle SUB to use the Steve Gold Standard (I think the name came from vince.) I am wondering how vince version got into my code but at least now I know now why Steves is slightly better.

BTW I did a time test between Steve's version doing INTEGERs and then doing LONG. He mentioned earlier when we were discussing DIM versus REDIM that LONG were faster than INTEGERs. I did not find much difference with INTEGERs edging out LONGs more significantly when x, y were integers too; the reverse case not so much.

To be perfectly explicit use this for FILL CIRCLE:

Code: QB64: [Select]

1. 'from Steve Gold standard
2. SUB fillCircle (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
3.     DIM Radius AS INTEGER, RadiusError AS INTEGER
4.     DIM X AS INTEGER, Y AS INTEGER
5.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
6.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
7.     LINE (CX - X, CY)-(CX + X, CY), C, BF
8.     WHILE X > Y
9.         RadiusError = RadiusError + Y * 2 + 1
10.         IF RadiusError >= 0 THEN
11.             IF X <> Y + 1 THEN
12.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
13.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
14.             END IF
15.             X = X - 1
16.             RadiusError = RadiusError - X * 2
17.         END IF
18.         Y = Y + 1
19.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
20.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
21.     WEND
22. END SUB
23.  
24.  

[SierraKen]

Thanks B+, I deleted the old one and put this one in its place.

[Aurel]

Uff i cannot compile this one with my 1.3qb64_32bit win7

[FellippeHeitor]

Time to update, Aurel.

[johnno56]

bplus,

Just for "the fun of it"... I removed the boxfill from all the line() statements... and it still drew a complete disc....
Does it do it on 'your' screen? If it still draws a disc then is there a purpose for the boxfill? Just curious...

[SMcNeill]

bplus,

Just for "the fun of it"... I removed the boxfill from all the line() statements... and it still drew a complete disc....
Does it do it on 'your' screen? If it still draws a disc then is there a purpose for the boxfill? Just curious...

Run some speed tests sometime: BF is faster than just drawing a line without it.  (It’s from the way BF is optimized in our c-translated code, and a line, by itself, isn’t.)

[Aurel]

Time to update, Aurel.

yes that is ok,,but i suspect that is something else too
well other programs by Sierra worked?

[bplus]

yes that is ok,,but i suspect that is something else too
well other programs by Sierra worked?

@Aurel What is the error message?

Are you Saving EXE in same folder as Source in your IDE Run Menu?

[SierraKen]

Aurel, also make sure all of the files are in the same directory, I suggest its own directory.