Spriggsy's API Collection

[SpriggsySpriggs]

There is a public API for one of the well-known encyclopedias/dictionaries. I might look into that. It could be an interesting project.

[Dav]

Lol at "If you're API and you know it clap your hands". :)

- Dav

[SpriggsySpriggs]

Updated collection with Owlbot Dictionary API on 08/19/2020 at 6:37 PM. The API works very similar to the OMDB API in that I have a console window to display some info from the JSON response and a regular screen to show the image from the response. Below is a screenshot of the new API working:

 

[bplus]

Now that I can get a pic from NASA, I worked on a better display of the description and image:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "NASA Pic of the Day, spacebar to toggle between image and description" ' b+ mod of Spriggsy's code
3. DIM fl&, fr&, i&, d&, picTitle$, description$, toggle, k$, lp, scalePic
4. DIM nlines, lineLength, yStart, startPlace, endPlace, markPlace, xoff, yoff, poff
5. SCREEN _NEWIMAGE(_DESKTOPWIDTH - 180, _DESKTOPHEIGHT - 60, 32)
6. _DELAY .25
7. _SCREENMOVE _MIDDLE
8. PRINT "One moment please, accessing and assembling data for NASA picture of the day."
9. i& = NASApod
10. IF i& <> 0 THEN
11.     fl& = _LOADFONT(ENVIRON$("SYSTEMROOT") + "\Fonts\bahnschrift.ttf", 40)
12.     fr& = _LOADFONT(ENVIRON$("SYSTEMROOT") + "\Fonts\bahnschrift.ttf", 20)
13.     _ICON i&
14.     d& = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
15.     _DEST d&
16.     COLOR , &H00000000 ' clear background
17.     _FONT fr&
18.     lineLength = _WIDTH - 2 * .1 * _WIDTH
19.     nlines = _PRINTWIDTH(description$) / lineLength + 2
20.     yStart = (_HEIGHT - _FONTHEIGHT(fr&) * nlines) / 2
21.     startPlace = 1: endPlace = startPlace + 1
22.     FOR lp = 0 TO nlines
23.         WHILE _PRINTWIDTH(MID$(description$, startPlace, endPlace - startPlace + 1)) < lineLength
24.             endPlace = endPlace + 1
25.             IF endPlace > LEN(description$) THEN endPlace = LEN(description$): EXIT WHILE
26.         WEND
27.         markPlace = endPlace
28.         WHILE MID$(description$, endPlace, 1) <> " "
29.             endPlace = endPlace - 1
30.             IF endPlace <= startPlace THEN endPlace = markPlace: EXIT WHILE
31.         WEND
32.         poff = .1 * _WIDTH + (lineLength - _PRINTWIDTH(MID$(description$, startPlace, endPlace - startPlace + 1))) / 2
33.         _PRINTSTRING (poff, yStart + _FONTHEIGHT(fr&) * lp), MID$(description$, startPlace, endPlace - startPlace + 1)
34.         startPlace = endPlace + 1
35.         endPlace = startPlace + 2
36.         IF endPlace > LEN(description$) THEN EXIT FOR
37.     NEXT
38.     _FONT fl&
39.     _PRINTSTRING ((_WIDTH - _PRINTWIDTH(picTitle$)) / 2, 50), picTitle$
40.  
41.     _DEST 0 ' OK show time
42.     IF _WIDTH / _WIDTH(i&) < _HEIGHT / _HEIGHT(i&) THEN
43.         scalePic = _WIDTH / _WIDTH(i&)
44.         yoff = (_HEIGHT - scalePic * _HEIGHT(i&)) / 2
45.     ELSE
46.         scalePic = _HEIGHT / _HEIGHT(i&)
47.         xoff = (_WIDTH - scalePic * _WIDTH(i&)) / 2
48.     END IF
49.     DO
50.         COLOR , &HFF000000: CLS
51.         k$ = INKEY$
52.         IF k$ = " " THEN toggle = 1 - toggle
53.         IF toggle THEN
54.             _PUTIMAGE (xoff, yoff)-STEP(scalePic * _WIDTH(i&), scalePic * _HEIGHT(i&)), i&, 0
55.         ELSE
56.             _PUTIMAGE , d&, 0
57.         END IF
58.         _DISPLAY
59.         _LIMIT 60
60.     LOOP UNTIL _KEYDOWN(27)
61. ELSE
62.     PRINT "Sorry no pic available now. Press any..."
63.     SLEEP: END
64. END IF
65.  
66. FUNCTION NASApod&
67.     DIM URL AS STRING
68.     DIM URLFile AS STRING
69.     DIM nasapic AS STRING
70.     DIM nasarequest AS STRING
71.     SHARED picTitle AS STRING
72.     SHARED description AS STRING
73.     DIM a%
74.     URLFile = "nasapod.json"
75.     URL = "https://api.nasa.gov/planetary/apod?api_key=w8uuw4gfVqpcnaTI3g02zJizTgtOaXJtaAmASebV"
76.     a% = API_request(URL, URLFile)
77.     DIM U AS INTEGER
78.     U = FREEFILE
79.     OPEN URLFile FOR BINARY AS #U
80.     IF LOF(U) <> 0 THEN
81.         nasarequest = SPACE$(LOF(U))
82.         GET #U, , nasarequest
83.     ELSE
84.         CLOSE #U
85.         KILL URLFile
86.         NASApod = 0
87.         EXIT FUNCTION
88.     END IF
89.     CLOSE #U
90.     KILL URLFile
91.     picTitle = GetKey("title", nasarequest)
92.     description = GetKey("explanation", nasarequest)
93.     nasapic = GetKey("hdurl", nasarequest)
94.     URLFile = "nasapod.jpg"
95.     URL = nasapic
96.     a% = API_request(URL, URLFile)
97.     OPEN URLFile FOR BINARY AS #U
98.     IF LOF(U) <> 0 THEN
99.         NASApod = _LOADIMAGE(URLFile, 32)
100.     ELSE
101.         CLOSE #U
102.         KILL URLFile
103.         NASApod = 0
104.     END IF
105.     CLOSE #U
106.     KILL URLFile
107. END FUNCTION
108. DECLARE DYNAMIC LIBRARY "urlmon"
109.     FUNCTION URLDownloadToFileA (BYVAL pCaller AS LONG, szURL AS STRING, szFileName AS STRING, BYVAL dwReserved AS LONG, BYVAL lpfnCB AS LONG)
110. END DECLARE
111. FUNCTION API_request (URL AS STRING, File AS STRING)
112.     API_request = URLDownloadToFileA(0, URL + CHR$(0), File + CHR$(0), 0, 0)
113. END FUNCTION
114. FUNCTION GetKey$ (keyname AS STRING, JSON AS STRING)
115.     DIM jkey AS STRING
116.     jkey = JSON
117.     IF INSTR(jkey, CHR$(34) + keyname + CHR$(34)) THEN
118.         jkey = MID$(jkey, INSTR(jkey, CHR$(34) + keyname + CHR$(34)) + LEN(keyname))
119.         jkey = MID$(jkey, INSTR(jkey, ":") + 1)
120.         jkey = String.Replace(jkey, "\" + CHR$(34), "'")
121.         IF MID$(jkey, 1, 1) = CHR$(34) THEN
122.             jkey = MID$(jkey, 2)
123.         END IF
124.         jkey = MID$(jkey, 1, INSTR(jkey, CHR$(34)) - 1)
125.         IF RIGHT$(jkey, 1) = "," THEN
126.             jkey = MID$(jkey, 1, LEN(jkey) - 1)
127.         END IF
128.     ELSE
129.         GetKey = ""
130.     END IF
131.     GetKey = jkey
132. END FUNCTION
133. SUB GetAllKey (keyname AS STRING, JSON AS STRING, ParseKey() AS STRING)
134.     DIM unchangejson AS STRING
135.     DIM jkey AS STRING
136.     DIM x
137.     unchangejson = JSON
138.     DO
139.         IF INSTR(unchangejson, CHR$(34) + keyname + CHR$(34)) THEN
140.             x = x + 1
141.             REDIM _PRESERVE ParseKey(x) AS STRING
142.             unchangejson = MID$(unchangejson, INSTR(unchangejson, CHR$(34) + keyname + CHR$(34)) + LEN(keyname))
143.             jkey = unchangejson
144.             jkey = MID$(jkey, INSTR(jkey, ":") + 1)
145.             jkey = String.Replace(jkey, "\" + CHR$(34), "'")
146.             IF MID$(jkey, 1, 1) = CHR$(34) THEN
147.                 jkey = MID$(jkey, 2)
148.             END IF
149.             jkey = MID$(jkey, 1, INSTR(jkey, CHR$(34)) - 1)
150.             IF RIGHT$(jkey, 1) = "," THEN
151.                 jkey = MID$(jkey, 1, LEN(jkey) - 1)
152.             END IF
153.             ParseKey(x) = jkey
154.         END IF
155.     LOOP UNTIL INSTR(unchangejson, CHR$(34) + keyname + CHR$(34)) = 0
156. END SUB
157. FUNCTION String.Replace$ (a AS STRING, b AS STRING, c AS STRING)
158.     DIM j
159.     DIM r$
160.     j = INSTR(a, b)
161.     IF j > 0 THEN
162.         r$ = LEFT$(a, j - 1) + c + String.Replace(RIGHT$(a, LEN(a) - j + 1 - LEN(b)), b, c)
163.     ELSE
164.         r$ = a
165.     END IF
166.     String.Replace = r$
167. END FUNCTION
168.  

Only one sample to work with, tomorrow this code could be rubbish ;-))

[SpriggsySpriggs]

That's pretty neat, @bplus ! I like the formatting of the text! What an excellent picture for today, too!

[SpriggsySpriggs]

Updated NASA Picture of the Day API with source code I had posted elsewhere in the forum. Much better code. Uses the date to get the day's picture so you don't have to worry about the picture possibly being not there yet (but doesn't fix the issue of if they don't even put a picture link in the JSON response). Can be used as a screensaver by building the EXE and changing the extension to SCR, right-clicking it, and pressing install. Works pretty well. If left running, it updates automatically at 5 AM local. (I used it myself on my work computer as my screensaver. Was pretty neat. I could come in every day and see a new image on my desktop.) @bplus , I think your modification would be good to merge with this different version of my NASA Pic of the day. I will look at your code and mine and modify them to make one source and then update the source in the zip folder.

[loudar]

I have just now realized how beautiful bahnschrift can look! Really cool stuff.

[bplus]

"The Valley of Orion" really cool today!

[SpriggsySpriggs]

@bplus Yes, very beautiful! Today's is quite nice as well!
@loudar Yeah, I was just browsing the Fonts folder and happened upon it. Was wanting something that looked nice and smooth.

[SpriggsySpriggs]

Will try to update this soon. Been busy with looking for a job and other things.

[SpriggsySpriggs]

Updated 09:11 PM 09/20/2020. Added Genderize API which checks probability of gender of name based on two letter country ID entered. The test code I have only returns back either male or female. You can comment out the KILL command in the API_request function to see the full JSON response which has also the probability either way.

bUt iT's 2020!1!111!!!!!

[SpriggsySpriggs]

Updated 09:31 PM with QR Tag API which takes a URL and generates a QR code that will take you to the website you provide.

 

[SpriggsySpriggs]

09/22/2020 Added SHFileOperationA functions from WinAPI. The example program allows to delete a file to recycle bin rather than permanently.

[SpriggsySpriggs]

11:00 PM 09/22/2020 Updated my source for the SHFileOperationA WinAPI with the rest of the functionality in that set. It can now Copy, Move, Rename, and Recycle (all with confirmation dialogs, if the criteria is met).

[SpriggsySpriggs]

11:06 09/22/2020 Added Kernel32 and Advapi32 WinAPI usage for getting computer name and username. Works in 32 bit AND 64 bit.

11:33 PM 09/22/2020 Added Shell32 function to SHFileOperation WinAPI code which allows you to empty the recycle bin with confirmation. Even though it isn't SHFileOperation, it is still part of the same DLL and since it has something to do with the recycle bin I felt it was appropriate to add it to that one in particular.

1:33 AM 09/23/2020 Added Shell32 function SHQueryRecycleBin to the SHFileOperation WinAPI code which queries the Recycle Bin and shows how many files are contained in it and how much space the bin is currently occupying on disk.