DrawFrame - animation sub using DRAW

[bplus]

@bplus: I see you actualy even did not use the original DRAW there, instead you invented completely new language and treated all graphics by yourself. That is quite an advantage over using DRAW, where some limitations I cannot bypass - e.g.  I can't turn the direction in decimals (TA10.25 doesn't work), which makes turning large object choppy.

Yes very perceptive! Only one who has tried this can appreciate it, it may work to your advantage too but I am afraid we will run out of single letter commands and have to move to 2 letters or better yet whole words of variable length, specially if want mouse or rnd functions added and keep frames control pen size and, of course, way more variables! :-))

[TempodiBasic]

following your post I met this

  I can't turn the direction in decimals (TA10.25 doesn't work), which makes turning large object choppy.

what do you mean in specific? I find your ideas very interesting!

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. CONST Black = _RGBA32(0, 0, 0, 255), White = _RGBA32(255, 255, 255, 255), Red = _RGBA32(200, 0, 0, 255), Blu = _RGBA32(0, 255, 255, 255), Green = _RGBA32(0, 255, 0, 255)
3. FOR b = 1 TO 4 STEP 1
4.     IF b = 1 THEN
5.         DRAW "c" + STR$(White) + "BM-200,-100"
6.     ELSEIF b = 2 THEN
7.         DRAW "c" + STR$(Red) + "BM+400,+300"
8.     ELSEIF b = 3 THEN
9.         DRAW "c" + STR$(Blu) + "BM-200,+0"
10.     ELSEIF b = 4 THEN
11.         DRAW "c" + STR$(Green) + "BM-200,-100"
12.     END IF
13.     FOR a = 0 TO 360 STEP .25 '.5
14.         LOCATE 1, 1: PRINT a; "    "
15.         DRAW "TA" + STR$(a) + "M+50,+50BM-50,-50"
16.         _DELAY .02
17.     NEXT
18. NEXT/code]
19.  

[TempodiBasic]

@Bplus
your tt is very fine duplicate of DRAW (?) or  very fine alternative to DRAW (?).
Thanks to share.

[SMcNeill]

You guys might want to add a simple SCALE command to your work.

“U1R1D1L1” — this would draw a simple 1 unit box...
Add a Scale command in front of it “^100” + “U1R1D1L” would draw a 100x100 box on the screen, as the “^” represents a scale amount for all commands after.

[bplus]

You guys might want to add a simple SCALE command to your work.

“U1R1D1L1” — this would draw a simple 1 unit box...
Add a Scale command in front of it “^100” + “U1R1D1L” would draw a 100x100 box on the screen, as the “^” represents a scale amount for all commands after.

Well I did use scale outside of the drawstrings commands so that I could use same strings at different scales, see reply #11 code lines 90-100.

@ TempodiBasic, Thanks, yes, I would say alternate to DRAW since it is not being used in tt SUB.

[dajan]

what do you mean in specific?

TempodiBasic, bingo! Of course TA works with decimals, thanks a lot for pointing that out.  I tried and gave up, but now I realize I have probbably tried with such small numbers, that I have been feeding TA parameter with exponential number format and the DRAW went crazy.
I have fix that now, and the tree limbs swinging is WAY smoother, it is especially noticable in slow motion speeds.

And as a bonus, here's a new short clip with dog, I'll be teaching him new tricks, eventually:

Code: QB64: [Select]

1.  
2. '----------------------------------------------------------------------------------------------------------------------------------------------------
3. ' The Tree string
4. '----------------------------------------------------------------------------------------------------------------------------------------------------
5. leaf1$ = "Q1:17;* (V30 K11:17;17.5 S1%;!40% K11:17.5;19 S!40%;50% V-90 K12 V-10;10 U50 V-800U20 V30U20 V30U20 V20U40 V20U40 V20U50 V100U50 V20U40 V20U40 V20U20 V30U20 V30U20 V-800 K12 U50;47 V180 K12 V10;-10 V90 V-30 S100%)"
6. smallimb2$ = "Q2:7;* (V-90 K22:7;14 S1%;100% U100 K23:40;44 BM+0,+0;-4000,-100 K12:22;22.2# Q1 K23 BM+0,+0;+4000,+100 K22 S1%;100% U200 K23:47;49 BM+0,+0;-4000,-100 K12:22.1;22.3# Q1 K23 BM+0,+0;+4000,+100 K22 S1%;100% U100 V90 U10 V90 V-90 K23:49;51 BM+0,+0;-4000,-100 K12:22.2;22.4# Q1 K23 BM+0,+0;+4000,+100 K22 S1%;100% V90 U200 V-60 K23:49.5;51.5 BM+0,+0;-4000,-100 K12:22.3;22.5# Q1 K23 BM+0,+0;+4000,+100 K22 S1%;100% V60 U200 V-90 S100%)"
7. biglimb3$ = "Q3:4;* (V-88 K31:4.0;11 S1%;100% U250 K32:25;25.4# V30;50 Q2 K32 V-30;-50 K31 S1%;100% U200 V88 K33:25.1;25.5# V-35;-15 Q2 K33 V35;15 V88 K34:25.2;25.6# V-40;-20 Q2 K34 V40;20 K31 S1%;100% U450 V92 V-180 S100%)"
8. trunk4$ = "Q4 (K41:0;10 S1%;100% U500 K42:28.9;29.3# V30;40 Q3 K42 V-30;-40 K41 S1%;100% U400 V88 K43:29;29.4# V0;5 Q3 K43 V0;-5 V88 K41 S1%;100% U200 K44:29.1;29.5# V-30;-20 Q3 K44 V30;20 K41 S1%;100% M+0,+0;-10,-10 K45:17;17.6 M+0,+0;-25,-20 U700 V92 V92 S100%)"
9. cloud5$ = "Q51:17; (Q5*8(U30-V30) S150% V200 Q5*6 S130% V230 Q5*6 S120% V210 Q5*8 S160% V220 Q5*6 S160% V235 Q5*6) S2"
10. clip$ = "S2 BM1200,1000" + leaf1$ + smallimb2$ + biglimb3$ + "K1:0;10#C35;52 L400 K101:24.9;25.3# M-3,-0;+3,+0 " + trunk4$ + " K101 M+3,+0;-3,-0 M910,1000 L400 K102:17;23 BM2500,50;1400,100 TA90 K51:0;0.3# S2;2.05 " + cloud5$ + " TA0 K103:20;30 BM0,0 BM-800,+100;+500,+300 TA90 K51:0;0.3# S3;3.05 Q51"
11.  
12. '----------------------------------------------------------------------------------------------------------------------------------------------------
13. ' Examples of clip strings
14. '----------------------------------------------------------------------------------------------------------------------------------------------------
15. 'clip$ = "BM500,300 Q1*12( U20 V30 )" '1 circle
16. 'clip$ = "B M500,300 Q2*6( BU100 Q1*12( U20 V30 ) BD100 V60 )" '6 circles queued in round
17. 'clip$ = "B M500,300 K1:0;3# V0;360 Q2*6( BU50 Q1*12( U10 V30 ) BD50 V60 )" '6 circles queued in round rotating
18. 'clip$ = "B M500,300 K1:0;3* V0;360 Q2*6( K2:0;2# BU50;200 Q1*12( U10 V30 ) BD50;200 V60 )" '6 circles queued in round rotating and swingigng towards centre
19. 'clip$ = "B M500,300 K2:0;2# K1:0;3* V0;360 Q2*6( K2_2:+0.2;+0.2# BU50;200 Q1*12( U10 V30 ) BD50;200 V60 )" '6 circles queued in round rotating and swingigng towards centre in different phase
20. 'clip$ = "B M500,300 K2:0;1# K1:0;3* V0;360 Q2*6( K2_2:+0.2;+0.2# BU50;200 S100%;300% Q1*12( U10 V30 ) S100% BD50;200 V60 )" '6 circles queued in round rotating and swingigng towards centre in different phase changing size
21.  
22. '----------------------------------------------------------------------------------------------------------------------------------------------------
23. ' The Dog string
24. '----------------------------------------------------------------------------------------------------------------------------------------------------
25. ' Q0 - dog positioning
26. ' Q2 - dog walking
27. ' Q3 - dog head shape, Q31 - head running
28. ' Q4 - dog ear shape, Q41 - ear running
29. ' Q5 - dog tail shape, Q51 - tail running
30. ' Q7 - dog foot shape, Q71 - foot running
31.  
32. clip$ = "S2 BM1900,518 L3500 Q0*(K0:0;10 BM1800,400;300,400 TA0)  Q7*(L40 D20 R40 U20)  Q71*(BM+20,+180 K71_71:-0.5;-0.5* K72_71:+0;-0.5# K71 V0;360 BD40 V360;0 K72 V-10;30 Q7) K41:0;0.25#"+_
33.         "Q4*(L40M+20,-40M+20,40) Q41*(K41_41:+0.05;+0.05# V-35;15 Q4 V35;-15) " + _
34.         "Q5*(R50 U40 L50 D40) Q51*(K51:0;0.25#  V10;30 BM+100,-40 Q5)" + _
35.         "Q3*(BM-20,-110 L200D120R200U120 BM-70,+30 R20D20L20U20 BM-120,-20 R30D30L30U30)  Q31*(K32:4;4.5 V0;50 K33_32:+3;+2.8 V!0;-50 K32 BM+0,0;-50,20 K33 BM+0,0;+50,-20 K31:0;0.25# BD-20;10 Q3 BM+140,-30 Q41 BR60 Q41) "+ _
36.         "Q2(Q0 K21:-0.125;0.125# BU0;40 D150R250U150L250 BM+200,+70 Q51 K71:0;1* Q0 Q71 Q0 Q71 Q0BM+250,0 Q71 Q0BM+250,+0 Q71 Q0 Q31)"
37.  
38. '----------------------------------------------------------------------------------------------------------------------------------------------------
39. SCREEN _NEWIMAGE(1920, 1080, 256)
40. _SCREENMOVE (_DESKTOPWIDTH - _WIDTH) / 2, (_DESKTOPHEIGHT - _HEIGHT) / 2
41.  
42. DrawPlayer clip$, 0, 60, 30, _WIDTH / 1920, 1
43.  
44. '----------------------------------------------------------------------------------------------------------------------------------------------------
45. 'Player demonstration
46. '----------------------------------------------------------------------------------------------------------------------------------------------------
47. SUB DrawPlayer (movie$, playfromtime, playtotime, fps, size, speed)
48.     t = playfromtime * fps
49.     dir = 1
50.     DO
51.         CLS
52.         _PRINTSTRING (0, 5), "size:" + STR$(RoundDec(size, 2)) + "   speed:" + STR$(dir * speed) + "x  time:" + STR$(RoundDec(t / fps * speed, 2))
53.         DrawFrame movie$, t / fps * speed, size
54.         IF k = 32 THEN SLEEP: k = _KEYHIT: k = _KEYHIT
55.         IF k = 20480 AND speed > 0.1 THEN speed = speed / 2: t = t * 2
56.         IF k = 18432 AND speed < 100 THEN speed = speed * 2: t = t / 2
57.         IF k = 19200 THEN t = t - 2 * fps
58.         IF k = 19712 THEN t = t + 2 * fps
59.         IF k = 43 THEN size = size + 0.01
60.         IF k = 45 THEN size = size - 0.01
61.         IF k = 114 THEN dir = -dir
62.         t = t + dir
63.         IF size > 10 THEN size = 10
64.         IF size < 0.01 THEN size = 0.01
65.         IF t > playtotime * fps / speed THEN t = playtotime * fps / speed
66.         IF t < 0 THEN t = 0
67.         k = _KEYHIT
68.         _DISPLAY
69.         _LIMIT fps
70.     LOOP UNTIL _KEYDOWN(27)
71. END SUB
72.  
73. '----------------------------------------------------------------------------------------------------------------------------------------------------
74. 'Sub & Function definitions
75. '----------------------------------------------------------------------------------------------------------------------------------------------------
76. SUB DrawFrame (SrcStrOrig AS STRING, frametime AS SINGLE, size AS SINGLE)
77.  
78.     CONST CMD_LEN_MAX = 1000 'max. command sequence length definable using statement Q()
79.  
80.     TYPE TKFset 'Key frame set type
81.         id AS INTEGER
82.         defined AS _BYTE
83.         timestart AS SINGLE
84.         timeend AS SINGLE
85.         repeat AS STRING * 1
86.         repeatcount AS INTEGER
87.     END TYPE
88.  
89.     TYPE TCmdSeq 'Command Sequence
90.         id AS INTEGER
91.         CmdStr AS STRING * CMD_LEN_MAX
92.         defined AS _BYTE
93.         startpos AS LONG
94.         endpos AS LONG
95.         timestart AS SINGLE
96.         timeend AS SINGLE
97.         repeatcount AS INTEGER
98.     END TYPE
99.  
100.     TYPE TDrawState 'global Draw state
101.         SrcLen AS LONG 'Source string length
102.         SrcPos AS LONG 'Source string last read char position
103.         ActKFSetIdx AS INTEGER 'KFset index applied to actual statement if KF enabled
104.         ActTA AS SINGLE 'Actual parameter value of previous TA statement (in degrees)
105.         ActS AS SINGLE 'Actual parameter value of previous "S" statement usage
106.         ErrDsc AS STRING * 50 'Error description
107.     END TYPE
108.  
109.     DIM KFset(0 TO 999) AS TKFset
110.     DIM CmdSeq(0 TO 99) AS TCmdSeq
111.     DIM DS AS TDrawState
112.     DIM char AS STRING * 1
113.     DIM prevchar AS STRING * 1
114.     DIM TrgStr AS STRING
115.     DIM c$, code$, label$, x1$, y1$, x2$, y2$, sgnx1$, sgny1$, rep$, repcnt$, par$, exclfrom$, exclto$, csstart$, percx1$, percx2$
116.     DIM x AS SINGLE, y AS SINGLE, x1 AS SINGLE, y1 AS SINGLE, x2 AS SINGLE, y2 AS SINGLE, kid AS INTEGER, csid AS INTEGER
117.     DIM readstate AS _BYTE
118.     DIM stat$, ParseStatement$ ' Actual statement being read from source draw string
119.     DIM SrcStr AS STRING
120.  
121.     SrcStr = SrcStrOrig
122.     TrgStr = ""
123.     stat$ = ""
124.     prevchar = ""
125.     SrcStr = SrcStr + "&"
126.     DS.SrcLen = LEN(SrcStr)
127.     DS.SrcPos = 0
128.     DS.ActKFSetIdx = 0
129.     DS.ActTA = 0
130.     DS.ActS = 4
131.  
132.     DO 'read statement
133.         DS.SrcPos = DS.SrcPos + 1
134.         char = MID$(SrcStr, DS.SrcPos, 1)
135.         IF (ASC(char) >= 64 AND ASC(char) <= 90 AND NOT (char = "A" AND prevchar = "T")) OR char = "&" THEN
136.             '-------------------------------------------Parser begin-----------------------------------------------------------
137.             stat$ = stat$ + "&"
138.             ParseStatement$ = ""
139.             readstate = 0
140.             KFenabled = 0
141.             omitstate = 0
142.             par$ = "": code$ = "": label$ = "": x1$ = "": y1$ = "": x2$ = "": y2$ = "": sgnx1$ = "": sgny1$ = "": sgnx2$ = ""
143.             rep$ = "": repcnt$ = "": par$ = "": exclfrom$ = "": exclto$ = "": csstart$ = "": percx1$ = "": percx2$ = "": rel$ = "": krel$ = ""
144.             x = 0: y = 0: x1 = 0: y1 = 0: x2 = 0: y2 = 0: kid = 0: csid = 0
145.  
146.             FOR i = 1 TO LEN(stat$)
147.                 c$ = MID$(stat$, i, 1)
148.                 SELECT CASE readstate
149.                     CASE 0:
150.                         SELECT CASE c$
151.                             CASE "A" TO "Z":
152.                                 code$ = code$ + c$
153.                             CASE "_":
154.                                 label$ = par$: par$ = "": rel$ = c$: readstate = 11
155.                             CASE ":":
156.                                 label$ = par$: par$ = "": readstate = 1
157.                             CASE ",":
158.                                 x1$ = par$: par$ = "": readstate = 2
159.                             CASE ";":
160.                                 x1$ = par$: par$ = "": readstate = 3
161.                                 KFenabled = 1
162.                             CASE "!":
163.                                 exclfrom$ = c$
164.                             CASE "+", "-":
165.                                 par$ = par$ + c$
166.                                 sgnx1$ = c$
167.                             CASE "0" TO "9", ".":
168.                                 par$ = par$ + c$
169.                             CASE "%":
170.                                 percx1$ = percx1$ + c$
171.                             CASE "*":
172.                                 label$ = par$: par$ = "": rep$ = c$: readstate = 5
173.                             CASE "(":
174.                                 label$ = par$: csstart$ = c$: readstate = 10
175.                             CASE "&", ")":
176.                                 x1$ = par$: par$ = "": readstate = 10
177.                             CASE ELSE: readstate = 99
178.                         END SELECT
179.                     CASE 11:
180.                         SELECT CASE c$
181.                             CASE "0" TO "9":
182.                                 par$ = par$ + c$
183.                             CASE ":":
184.                                 krel$ = par$: par$ = "": readstate = 1
185.                             CASE ELSE: readstate = 99
186.                         END SELECT
187.                     CASE 1:
188.                         SELECT CASE c$
189.                             CASE ",":
190.                                 x1$ = par$: par$ = "": readstate = 2
191.                             CASE ";":
192.                                 x1$ = par$: par$ = "": readstate = 3
193.                                 KFenabled = 1
194.                             CASE "!":
195.                                 exclfrom$ = c$
196.                             CASE "+", "-":
197.                                 par$ = par$ + c$
198.                                 sgnx1$ = c$
199.                             CASE "0" TO "9", ".":
200.                                 par$ = par$ + c$
201.                             CASE "%":
202.                                 percx1$ = percx1$ + c$
203.                             CASE "(":
204.                                 x1$ = par$: csstart$ = c$: readstate = 10
205.                             CASE "&", ")":
206.                                 x1$ = par$: par$ = "": readstate = 10
207.                             CASE ELSE: readstate = 99
208.                         END SELECT
209.                     CASE 2:
210.                         SELECT CASE c$
211.                             CASE ";":
212.                                 y1$ = par$: par$ = "": readstate = 3
213.                                 KFenabled = 1
214.                             CASE "+", "-":
215.                                 par$ = par$ + c$
216.                                 sgny1$ = c$
217.                             CASE "0" TO "9", ".":
218.                                 par$ = par$ + c$
219.                             CASE "&", ")":
220.                                 y1$ = par$: par$ = "": readstate = 10
221.                             CASE ELSE: readstate = 99
222.                         END SELECT
223.                     CASE 3:
224.                         SELECT CASE c$
225.                             CASE ",":
226.                                 x2$ = par$: par$ = "": readstate = 4
227.                             CASE "#":
228.                                 x2$ = par$: par$ = "": rep$ = c$: readstate = 5
229.                             CASE "*":
230.                                 x2$ = par$: par$ = "": rep$ = c$: readstate = 5
231.                             CASE "!":
232.                                 exclto$ = c$
233.                             CASE "+", "-":
234.                                 par$ = par$ + c$
235.                                 sgnx2$ = c$
236.                             CASE "0" TO "9", ".":
237.                                 par$ = par$ + c$
238.                             CASE "%":
239.                                 percx2$ = percx2$ + c$
240.                             CASE "(":
241.                                 x2$ = par$: csstart$ = c$: readstate = 10
242.                             CASE "&", ")":
243.                                 x2$ = par$: par$ = "": readstate = 10
244.                             CASE ELSE: readstate = 99
245.                         END SELECT
246.                     CASE 4:
247.                         SELECT CASE c$
248.                             CASE "#":
249.                                 y2$ = par$: par$ = "": rep$ = c$: readstate = 5
250.                             CASE "*":
251.                                 y2$ = par$: par$ = "": rep$ = c$: readstate = 5
252.                             CASE "0" TO "9", "+", "-", ".":
253.                                 par$ = par$ + c$
254.                             CASE "&", ")":
255.                                 y2$ = par$: par$ = "": readstate = 10
256.                             CASE ELSE: readstate = 99
257.                         END SELECT
258.                     CASE 5:
259.                         SELECT CASE c$
260.                             CASE "0" TO "9", "+", "-", ".":
261.                                 par$ = par$ + c$
262.                             CASE "(":
263.                                 repcnt$ = par$: par$ = "": csstart$ = c$: readstate = 10
264.                             CASE "&", ")":
265.                                 repcnt$ = par$: par$ = "": readstate = 10
266.                             CASE ELSE: readstate = 99
267.                         END SELECT
268.                 END SELECT
269.             NEXT i
270.  
271.             IF readstate = 99 THEN DS.ErrDsc = "Error in statement: " + LEFT$(stat$, LEN(stat$) - 1) ELSE DS.ErrDsc = ""
272.             IF code$ = "K" THEN
273.                 IF x2$ <> "" THEN ' defining KFset
274.                     tsdelta = 0: tedelta = 0
275.                     kid = VAL(label$)
276.                     KFset(kid).id = kid
277.                     KFset(kid).defined = 1
278.                     IF krel$ <> "" THEN
279.                         krel = VAL(krel$)
280.                         IF sgnx1$ <> "" THEN tsdelta = KFset(krel).timestart
281.                         IF sgnx2$ <> "" THEN tedelta = KFset(krel).timeend
282.                     END IF
283.                     KFset(kid).timestart = VAL(x1$) + tsdelta
284.                     KFset(kid).timeend = VAL(x2$) + tedelta
285.                     KFset(kid).repeat = rep$
286.                     KFset(kid).repeatcount = VAL(repcnt$)
287.                     DS.ActKFSetIdx = kid
288.                 ELSE ' referencing KFset
289.                     IF label$ = "" AND x1$ <> "" THEN label$ = x1$
290.                     kid = VAL(label$)
291.                     DS.ActKFSetIdx = kid
292.                 END IF
293.  
294.             ELSEIF code$ = "Q" THEN
295.                 IF x1$ <> "" OR x2$ <> "" AND label$ <> "" THEN
296.                     csid = VAL(label$)
297.                     CmdSeq(csid).timestart = VAL(x1$)
298.                     CmdSeq(csid).timeend = VAL(x2$)
299.                 END IF
300.                 IF label$ = "" AND x1$ <> "" AND x2$ = "" THEN label$ = x1$
301.                 csid = VAL(label$)
302.                 CmdSeq(csid).id = csid
303.                 IF repcnt$ <> "" THEN CmdSeq(csid).repeatcount = VAL(repcnt$)
304.  
305.                 ipos = 0
306.                 IF csstart$ = "(" THEN ' defining command sequence
307.                     parcnt = 1: c$ = ""
308.                     DO ' Find corresponding right parenthes in the source string
309.                         ipos = ipos + 1
310.                         c$ = MID$(SrcStr$, DS.SrcPos + ipos, 1)
311.                         IF c$ = "(" THEN parcnt = parcnt + 1
312.                         IF c$ = ")" THEN parcnt = parcnt - 1
313.                     LOOP UNTIL (c$ = ")" AND parcnt = 0) OR DS.SrcPos + ipos >= DS.SrcLen OR ipos >= CMD_LEN_MAX
314.                     IF (c$ = ")" AND parcnt = 0) THEN
315.                         CmdSeq(csid).CmdStr = MID$(SrcStr, DS.SrcPos, ipos)
316.                         CmdSeq(csid).defined = 1
317.                     ELSE
318.                         CmdSeq(csid).defined = 0
319.                     END IF
320.                 ELSE 'Referencing command sequence
321.                 END IF
322.  
323.                 IF CmdSeq(csid).defined = 1 THEN 'modify source string if command sequence defined
324.                     IF CmdSeq(csid).repeatcount > 0 THEN
325.                         rpt = CmdSeq(csid).repeatcount
326.                     ELSEIF rep$ = "*" THEN
327.                         rpt = 0
328.                     ELSE
329.                         rpt = 1
330.                     END IF
331.                     IF CmdSeq(csid).timeend <> 0 AND (frametime < CmdSeq(csid).timestart OR frametime > CmdSeq(csid).timeend) THEN rpt = 0
332.                     IF frametime < CmdSeq(csid).timestart THEN rpt = 0
333.                     cmdrpt$ = ""
334.                     FOR i = 1 TO rpt: cmdrpt$ = cmdrpt$ + RTRIM$(CmdSeq(csid).CmdStr): NEXT i
335.                     SrcStr = RTRIM$(cmdrpt$) + RIGHT$(SrcStr, DS.SrcLen - DS.SrcPos - ipos + 1)
336.                     DS.SrcLen = LEN(SrcStr)
337.                     DS.SrcPos = 0
338.                     char = ""
339.                 END IF
340.  
341.             ELSE 'do for other graphics statements
342.                 x1 = VAL(x1$): y1 = VAL(y1$): x2 = VAL(x2$): y2 = VAL(y2$)
343.                 kid = DS.ActKFSetIdx
344.                 IF KFenabled = 1 AND KFset(kid).defined = 1 THEN 'change parameters if statement is keyframed
345.                     fk = (frametime - KFset(kid).timestart) / (KFset(kid).timeend - KFset(kid).timestart)
346.                     IF (frametime >= KFset(kid).timestart AND frametime <= KFset(kid).timeend) THEN
347.                         IF x1$ <> "" THEN x1 = x1 + (x2 - x1) * fk
348.                         IF y1$ <> "" THEN y1 = y1 + (y2 - y1) * fk
349.                     ELSEIF (frametime > KFset(kid).timeend AND exclto$ <> "!") THEN
350.                         period = INT((frametime - KFset(kid).timestart) / (KFset(kid).timeend - KFset(kid).timestart))
351.                         IF (KFset(kid).repeat = "*" OR KFset(kid).repeat = "#") AND (period < KFset(kid).repeatcount OR KFset(kid).repeatcount = 0) THEN
352.                             IF KFset(kid).repeat = "#" AND period MOD 2 = 1 THEN
353.                                 fk = (KFset(kid).timeend - frametime + period * (KFset(kid).timeend - KFset(kid).timestart)) / (KFset(kid).timeend - KFset(kid).timestart)
354.                             ELSE
355.                                 fk = (frametime - KFset(kid).timestart - period * (KFset(kid).timeend - KFset(kid).timestart)) / (KFset(kid).timeend - KFset(kid).timestart)
356.                             END IF
357.                             IF x1$ <> "" THEN x1 = x1 + (x2 - x1) * fk
358.                             IF y1$ <> "" THEN y1 = y1 + (y2 - y1) * fk
359.                         ELSE
360.                             IF KFset(kid).repeat = "#" AND KFset(kid).repeatcount MOD 2 = 0 THEN
361.                                 IF x1$ <> "" THEN x1 = x1
362.                                 IF y1$ <> "" THEN y1 = y1
363.                             ELSE
364.                                 IF x1$ <> "" THEN x1 = x2
365.                                 IF y1$ <> "" THEN y1 = y2
366.                             END IF
367.                         END IF
368.                     ELSEIF (frametime < KFset(kid).timestart AND exclfrom$ <> "!") THEN
369.                         omitstate = 0
370.                     ELSE
371.                         omitstate = 1
372.                     END IF
373.                 END IF
374.                 IF omitstate = 0 THEN
375.                     SELECT CASE code$
376.                         CASE "T", "TA":
377.                             x1 = RoundDec(x1, 6)
378.                             DS.ActTA = x1
379.                             IF (DS.ActTA > 360) OR (DS.ActTA < -360) THEN DS.ActTA = DS.ActTA + (DS.ActTA > 0) * 360
380.                         CASE "V":
381.                             DS.ActTA = DS.ActTA + RoundDec(x1, 6)
382.                             IF (DS.ActTA > 360) OR (DS.ActTA < -360) THEN DS.ActTA = DS.ActTA + (DS.ActTA > 0) * 360
383.                             code$ = "TA"
384.                             x1 = RoundDec(DS.ActTA, 6)
385.                         CASE "C":
386.                             x1 = _ROUND(x1)
387.                         CASE "M", "D", "E", "F", "G", "H", "L", "R", "U":
388.                             x1 = RoundDec(x1 * size, 4)
389.                             y1 = RoundDec(y1 * size, 4)
390.                         CASE "S":
391.                             IF percx1$ <> "" OR percx2$ <> "" THEN
392.                                 x1 = RoundDec(x1 * DS.ActS / 100, 5)
393.                                 IF x1 > 8 THEN x1 = 8
394.                             ELSE
395.                                 DS.ActS = x1
396.                             END IF
397.                     END SELECT
398.                     IF sgnx1$ <> "" AND x1 < 0 THEN sgnx1$ = ""
399.                     IF sgnx1$ <> "" AND x1 > 0 THEN sgnx1$ = "+"
400.                     IF sgny1$ <> "" AND y1 < 0 THEN sgny1$ = ""
401.                     IF sgny1$ <> "" AND y1 > 0 THEN sgny1$ = "+"
402.                     ParseStatement$ = code$
403.                     IF x1$ <> "" THEN
404.                         ParseStatement$ = ParseStatement$ + sgnx1$ + LTRIM$(STR$(x1))
405.                         IF y1$ <> "" THEN ParseStatement$ = ParseStatement$ + "," + sgny1$ + LTRIM$(STR$(y1))
406.                     END IF
407.                 ELSE
408.                     ParseStatement$ = ""
409.                 END IF
410.             END IF
411.  
412.             ''---DEBUG BEGIN-----------
413.             'IF CmdSeq(csid).defined = 1 THEN cmd$ = RTRIM$(CmdSeq(csid).CmdStr) ELSE cmd$ = ""
414.             'PRINT
415.             'PRINT stat$ + " > ", , code$ + "/" + label$ + "/" + x1$ + "/" + y1$ + "/" + x2$ + "/" + y2$ + "/" + exclfrom$ + "/" + exclto$ + "/" + rep$ + "/" + repcnt$
416.             'PRINT "TrgStr: "; TrgStr
417.             'PRINT "SrcStr: "; SrcStr
418.             'PRINT "cmd$: ", cmd$
419.             'PRINT "DS.Srcpos", DS.SrcPos
420.             'PRINT "ParseStatement$: ", ParseStatement$
421.             'IF stat$ = "Q1*(&" OR stat$ = "Q1(&" THEN stopable = 1
422.             'IF stopable THEN
423.             '    DO
424.             '    LOOP UNTIL _KEYHIT = 32
425.             'END IF
426.             ''---DEBUG END-------------
427.  
428.             '-------------------------------------------Parser end-----------------------------------------------------------
429.             TrgStr = TrgStr + ParseStatement$
430.             IF LTRIM$(DS.ErrDsc) <> "" THEN PRINT RTRIM$(DS.ErrDsc) + " at position:" + STR$(DS.SrcPos - LEN(stat$))
431.             stat$ = ""
432.         END IF
433.         IF char <> " " THEN
434.             stat$ = stat$ + char
435.         END IF
436.         prevchar = char
437.     LOOP WHILE DS.SrcPos < DS.SrcLen
438.  
439.     DRAW TrgStr
440.  
441.     'PRINT SrcStr '---DEBUG code----
442.     'PRINT TrgStr '---DEBUG code----
443. END SUB
444.  
445. '----------------------------------------------------------------------------------------------------------------------------------------------------
446. FUNCTION RoundDec (x AS SINGLE, n AS INTEGER)
447.     RoundDec = _ROUND(x * 10 ^ n) / (10 ^ n)
448. END FUNCTION
449.  
450. '----------------------------------------------------------------------------------------------------------------------------------------------------
451.