QB64 Wiki Keyword Generator

[SMcNeill]

This is a little tool of mine which Dav might like for his IDE (or, for other folks who want to keep a list of keywords in our wiki, for whatever reason.)

Code: QB64: [Select]

1. CONST SleepSet = 0 'to sleep between each keyword so we can see them and read them
2. CONST SaveTo = "wiki.txt" '"SCRN:" to display to the screen, or insert a filename to save the list to disk
3.  
4. SCREEN _NEWIMAGE(1024, 720, 256)
5. PRINT "DOWNLOAD STARTING"
6. file$ = "QB64WikiList.txt"
7. 'Increase the 2-second time limit here if you need to.
8. DownloadRSS "http://qb64.org/wiki/Keyword_Reference_-_Alphabetical", file$, 2
9. PRINT "DOWNLOAD FINISHED"
10. PRINT
11.  
12.  
13. OPEN file$ FOR BINARY AS #1
14. temp$ = SPACE$(LOF(1))
15. GET #1, , temp$
16. CLOSE #1
17. l = 0
18. finish$ = "<div id=" + CHR$(34) + "symbols" + CHR$(34) + "></div>"
19. finish = INSTR(temp$, finish$) 'No need to parse anything after we get down to the symbol section of the wiki page
20.  
21. OPEN SaveTo FOR OUTPUT AS #1
22.  
23.  
24. DO
25.     l = INSTR(l, temp$, "<li>")
26.     IF l >= finish THEN EXIT DO
27.     IF l THEN
28.         l2 = INSTR(l + 5, temp$, "</li>"): IF l2 = 0 THEN l2 = LEN(temp$)
29.         work$ = MID$(temp$, l + 4, l2 - l - 5)
30.         li1 = INSTR(work$, CHR$(34)): li2 = INSTR(li1 + 1, work$, CHR$(34))
31.         link$ = MID$(work$, li1 + 1, li2 - li1 - 1)
32.         IF INSTR(link$, "&amp") THEN link$ = "Page does not exist yet."
33.         link$ = StripCRLF(link$)
34.         k1 = INSTR(li2 + 1, work$, ">"): k2 = INSTR(k1 + 1, work$, "<")
35.         keyword$ = MID$(work$, k1 + 1, k2 - k1 - 1)
36.         keyword$ = StripCRLF(keyword$)
37.         d = INSTR(k2 + 1, work$, "<span"): d1 = INSTR(d + 1, work$, ">"): d2 = INSTR(d1 + 1, work$, "</span")
38.         desc$ = MID$(work$, d1 + 1, d2 - d1 - 1)
39.         desc$ = StripCRLF(desc$)
40.         PRINT #1, keyword$
41.         PRINT #1, "         http://qb64.org"; link$
42.         PRINT #1, "         "; desc$
43.         IF SleepSet THEN SLEEP
44.         l = l2 + 1
45.     END IF
46. LOOP UNTIL l = 0
47. CLOSE
48.  
49. SLEEP
50. SYSTEM
51.  
52.  
53. SUB DownloadRSS (url$, file$, timelimit)
54.     link$ = url$
55.     DIM l AS _INTEGER64, lod AS _INTEGER64
56.  
57.     url2$ = RTRIM$(LTRIM$(link$))
58.     url4$ = RTRIM$(LTRIM$(link$))
59.     IF LEFT$(UCASE$(url2$), 7) = "HTTP://" THEN url4$ = MID$(url2$, 8)
60.     x = INSTR(url4$, "/")
61.     IF x THEN url2$ = LEFT$(url4$, x - 1)
62.     NewsClient = _OPENCLIENT("TCP/IP:80:" + url2$)
63.     IF NewsClient = 0 THEN EXIT FUNCTION
64.     e$ = CHR$(13) + CHR$(10) ' end of line characters
65.     url3$ = RIGHT$(url4$, LEN(url4$) - x + 1)
66.     x$ = "GET " + url3$ + " HTTP/1.1" + e$
67.     x$ = x$ + "Host: " + url2$ + e$ + e$
68.     PUT #NewsClient, , x$
69.  
70.     OPEN file$ FOR OUTPUT AS #1: CLOSE #1
71.     OPEN file$ FOR BINARY AS #1
72.  
73.     t! = TIMER ' start time
74.     head$ = ""
75.     cont_type$ = ""
76.     DO
77.         _LIMIT 20
78.         GET #NewsClient, , a$
79.         IF LTRIM$(a$) > "" THEN PUT #1, , a$
80.     LOOP UNTIL TIMER > t! + timelimit AND timelimit > 0 ' (in seconds)
81.     CLOSE #NewsClient
82.     CLOSE #1
83. END SUB
84.  
85. FUNCTION StripCRLF$ (text$)
86.     'The wiki seems to contain stray CRLF characters at the dangest spots.
87.     'Why it has them, I don't know, but we need to filter them out so our information will load and display properly.
88.     li1 = 0
89.     DO
90.         li1 = INSTR(li1 + 1, text$, CHR$(13) + CHR$(10))
91.         IF li1 THEN
92.             l$ = LEFT$(text$, li1 - 1)
93.             r$ = MID$(text$, li1 + 2)
94.             text$ = l$ + r$
95.         END IF
96.     LOOP UNTIL li1 = 0
97.  
98.     'Also some of the descriptions and such contain links to different keywords.
99.     'We want to just strip those links and use a normal word replacement for ease of display, since we're not going to be displaying in
100.     'an html editor/viewer.
101.  
102.     li1 = 0
103.     DO
104.         li1 = INSTR(li1 + 1, text$, "<a href")
105.         IF li1 THEN
106.             li2 = INSTR(li1 + 1, text$, "</a>")
107.             li3 = INSTR(li1 + 1, text$, ">")
108.             l$ = LEFT$(text$, li1 - 1)
109.             m$ = MID$(text$, li3 + 1, li2 - li3 - 1)
110.             r$ = MID$(text$, li2 + 4)
111.             text$ = l$ + m$ + r$
112.         END IF
113.     LOOP UNTIL li1 = 0
114.  
115.     StripCRLF$ = text$
116. END FUNCTION
117.  

Change SleepSet to 0 if you don't want to be bothered with the need to press a key between keywords.
Change SaveTo to a filename (like "wiki.txt") if you want to save the list to an external file on your hard drive.

This gives us 3 pieces of information for each entry in the wiki:

Keyword name.
Link to the wiki page where we can go to get detailed information about that keyword.
And a brief summery of what the keyword does.

[FellippeHeitor]

Does it work with no changes with the new wiki? I've had to do some reworking with the IDE's parsing routines for the wiki because we use a newer version of MediaWiki than Galleon had installed and some new formatting/tagging got in the way.

[SMcNeill]

Here's a small sample of how it outputs information for us -- as far as I can tell, it processes everything fine, without glitching out anywhere.

_ACOS
         http://qb64.org/wiki/ACOS
         arccosine function returns the angle in radians based on an input COSine value range from -1 to 1.
_ACOSH
         http://qb64.org/wiki/ACOSH
         Returns the nonnegative arc hyperbolic cosine of x, expressed in radians.
_ALPHA
         http://qb64.org/wiki/ALPHA
         returns the alpha channel transparency level of a color value used on a screen page or image.
_ALPHA32
         http://qb64.org/wiki/ALPHA32
         returns the alpha channel transparency level of a color value used on a 32 bit screen page or image.
_ARCCOT
         http://qb64.org/wiki/Mathematical_Operations
         is the inverse function of the cotangent. .  <a rel="nofollow" class="external free" href="http://mathworld.wolfram.com/InverseCosecant.html">http://mathworld.wolfram.com/InverseCosecant.html[/url]
_ARCCSC
         http://qb64.org/wiki/Mathematical_Operations
         is the inverse function of the cosecant.  <a rel="nofollow" class="external free" href="http://mathworld.wolfram.com/InverseCosecant.html">http://mathworld.wolfram.com/InverseCosecant.html[/url]
_ARCSEC
         http://qb64.org/wiki/Mathematical_Operations
         is the inverse function of the secant.  <a rel="nofollow" class="external free" href="http://mathworld.wolfram.com/InverseSecant.html">http://mathworld.wolfram.com/InverseSecant.html[/url]
_ASIN
         http://qb64.org/wiki/ASIN
         Returns the principal value of the arc sine of x, expressed in radians.
_ASINH
         http://qb64.org/wiki/ASINH
         Returns the arc hyperbolic sine of x, expressed in radians.
_ATAN2
         http://qb64.org/wiki/ATAN2
         Returns the principal value of the arc tangent of y/x, expressed in radians.
_ATANH
         http://qb64.org/wiki/ATANH
         Returns the arc hyperbolic tangent of x, expressed in radians.
_AUTODISPLAY
         http://qb64.org/wiki/AUTODISPLAY
         enables the automatic display of the screen image changes previously disabled by _DISPLAY.
_AUTODISPLAY (function)
         http://qb64.org/wiki/AUTODISPLAY_(function)
         returns the current display mode as true (-1) if automatic or false (0) if per request using _DISPLAY.
_AXIS
         http://qb64.org/wiki/AXIS
         returns a SINGLE value between -1 and 1 indicating the maximum distance from the device axis center, 0.

Edit: You were right; it required some changing to the links to each keyword.  They're no longer in the "Keyword_Reference_-_Alphabetical" subfolder, as each now falls directly into "http://qb64.org/wiki/". 

Changed and links should now be valid again.