Spotify API with OAuth2 (WIP) Windows Only

[SpriggsySpriggs]

I'm currently working on a project for the Spotify API. The project is still in its infancy. Right now, you can see the album art, song info, and playback timestamp in real-time. This program will eventually have buttons and a trackbar to control playback. I'll track the progress for the project here. The main reason why I wanted to do this project was because I had never been able to do OAuth2 before in QB64. I had no idea how to do it. The most I had done with online API was just simple GETs and POSTs. Now I have figured out the proper way to do OAuth2 and authorize a QB64 program for more advanced API like this Spotify API. I accomplished the OAuth2 authorization using a slightly edited version of Luke's HTTP server code. Obviously, you will need a Spotify account in order to use this program. It is also designed to run while you are playing music on Spotify. You can play Spotify from anywhere and this will track it. You don't have to use your computer to play the music.

Here is a short video showing how it works:

Code: QB64 $NOPREFIX: [Select]

1. Option Explicit
2. $NoPrefix
3. '$Console:Only
4.  
5. On Error GoTo errorhandler
6.  
7. Const INTERNET_OPEN_TYPE_DIRECT = 1
8.  
9. Const INTERNET_DEFAULT_HTTP_PORT = 80
10. Const INTERNET_DEFAULT_HTTPS_PORT = 443
11.  
12. Const INTERNET_SERVICE_HTTP = 3
13.  
14. Const INTERNET_FLAG_SECURE = &H00800000
15. Const INTERNET_FLAG_RELOAD = &H80000000
16.  
17. Const HTTP_QUERY_CONTENT_LENGTH = 5
18.  
19. Const TRUE = 1
20. Const FALSE = 0
21.  
22. Const CLIENT_ID = "43b28a744c8947babd5766c3674e0a13"
23. Const CLIENT_SECRET = "965f8e02e48a48ad9063e89bf5b0995f"
24. Const REDIRECT_URI = "http://localhost:8888/"
25.  
26. Const SW_SHOWNORMAL = 1
27.  
28. Declare Dynamic Library "Wininet"
29.     Function InternetOpen%& Alias "InternetOpenA" (ByVal lpszAgent As Offset, Byval dwAccessType As Unsigned Long, Byval lpszProxy As Offset, Byval lpszProxyBypass As Offset, Byval dwFlags As Unsigned Long)
30.     Function InternetConnect%& Alias "InternetConnectA" (ByVal hInternet As Offset, Byval lpszServerName As Offset, Byval nServerPort As Unsigned Long, Byval lpszUserName As Offset, Byval lpszPassword As Offset, Byval dwService As Unsigned Long, Byval dwFlags As Unsigned Long, Byval dwContext As Unsigned Long)
31.     Function HttpOpenRequest%& Alias "HttpOpenRequestA" (ByVal hConnect As Offset, Byval lpszVerb As Offset, Byval lpszObjectName As Offset, Byval lpszVersion As Offset, Byval lpszReferer As Offset, Byval lplpszAcceptTypes As Offset, Byval dwFlags As Unsigned Long, Byval dwContext As Unsigned Offset)
32.     Function HttpSendRequest& Alias "HttpSendRequestA" (ByVal hRequest As Offset, Byval lpszHeaders As Offset, Byval dwHeadersLength As Unsigned Long, Byval lpOptional As Offset, Byval dwOptionalLength As Unsigned Long)
33.     Function HttpQueryInfo& Alias "HttpQueryInfoA" (ByVal hRequest As Offset, Byval dwInfoLevel As Unsigned Long, Byval lpBuffer As Offset, Byval lpdwBufferLength As Offset, Byval lpdwIndex As Offset)
34.     Sub InternetReadFile (ByVal hFile As Offset, Byval lpBuffer As Offset, Byval dwNumberOfBytesToRead As Unsigned Long, Byval lpdwNumberOfBytesRead As Offset)
35.     Sub InternetCloseHandle (ByVal hInternet As Offset)
36. End Declare
37.  
38. '$Include:'httpserv.BI'
39.  
40. $ExeIcon:'Spotify_icon.ico'
41. Icon
42.  
43. Dim Shared As String code, refreshtoken
44.  
45. Login
46. If code <> "" Then
47.     Screen NewImage(640, 640, 32)
48.     'Print code
49.     'ReDim As Long albumart(1 To 3)
50.     'ReDim As String albumarturl(0)
51.     Dim As Long albumart
52.     Dim As String albumartstring, oldart, oldsong
53.     Dim As String token
54.     Dim As String playbackstate
55.     Dim As String playing
56.     Dim As Long songlength, position, cseconds, cminutes, chours, dseconds, dminutes, dhours
57.     token = GetToken
58.     'Print token
59.     'Print "refresh_token:"; refreshtoken
60.     Do
61.  
62.         'Dim As String current: current = SpotifyAPI("https://api.spotify.com/v1/me/player/currently-playing?market=US", token)
63.         playbackstate = SpotifyAPI("https://api.spotify.com/v1/me/player?market=US", token)
64.         albumartstring = GetKey(playbackstate, "url")
65.         'albumart(1) = OnlineImage(albumarturl(1))
66.         'albumart(2) = OnlineImage(albumarturl(2))
67.         'albumart(3) = OnlineImage(albumarturl(3))
68.         If GetKey2(playbackstate, "is_playing") = "true" Then playing = "Playing" Else playing = "Paused"
69.         ReDim As String names(0)
70.         GetAllKey playbackstate, "name", names()
71.         If oldart <> albumartstring Or oldsong <> names((UBound(names))) Then
72.             token = GetRefreshedToken
73.             FreeImage albumart
74.             oldart = albumartstring
75.             oldsong = names((UBound(names)))
76.             albumart = OnlineImage(albumartstring)
77.             Title "Playing - " + names(UBound(names)) + " by " + names(2)
78.             songlength = Val(GetKey(playbackstate, "duration_ms"))
79.             dseconds = Int(songlength \ 1000) Mod 60
80.             dminutes = Int((songlength \ (1000 * 60)) Mod 60)
81.             dhours = Int((songlength \ (1000 * 60 * 60)) Mod 24)
82.         End If
83.         Cls
84.         PutImage , albumart, 0
85.         Print "Artist: "; names(2)
86.         Print "Album : "; names(3)
87.         Print "Song  : "; names((UBound(names)))
88.         Print playing
89.         position = Val(GetKey(playbackstate, "progress_ms"))
90.         cseconds = Int(position \ 1000) Mod 60
91.         cminutes = Int((position \ (1000 * 60)) Mod 60)
92.         chours = Int((position \ (1000 * 60 * 60)) Mod 24)
93.         If chours < 10 Then
94.             Print "0"; LTrim$(Str$(chours)); ":";
95.         Else
96.             Print LTrim$(Str$(chours)); ":";
97.         End If
98.         If cminutes < 10 Then
99.             Print "0"; LTrim$(Str$(cminutes)); ":";
100.         Else
101.             Print LTrim$(Str$(cminutes)); ":";
102.         End If
103.         If cseconds < 10 Then
104.             Print "0"; LTrim$(Str$(cseconds)); "/";
105.         Else
106.             Print LTrim$(Str$(cseconds)); "/";
107.         End If
108.         If dhours < 10 Then
109.             Print "0"; LTrim$(Str$(dhours)); ":";
110.         Else
111.             Print LTrim$(Str$(dhours)); ":";
112.         End If
113.         If dminutes < 10 Then
114.             Print "0"; LTrim$(Str$(dminutes)); ":";
115.         Else
116.             Print LTrim$(Str$(dminutes)); ":";
117.         End If
118.         If dseconds < 10 Then
119.             Print "0"; LTrim$(Str$(dseconds))
120.         Else
121.             Print LTrim$(Str$(dseconds))
122.         End If
123.  
124.         Display
125.         Limit 60
126.     Loop
127. End If
128.  
129. errorhandler:
130. Resume Next
131.  
132. Sub Login ()
133.     Declare Dynamic Library "Shell32"
134.         Sub ShellExecute Alias "ShellExecuteA" (ByVal hwnd As Offset, lpOperation As String, lpFile As String, Byval lpParameters As Offset, Byval lpDirectory As Offset, Byval nShowCmd As Long)
135.     End Declare
136.     Dim As String URL: URL = "https://accounts.spotify.com/authorize?response_type=code&client_id=" + CLIENT_ID + "&scope=user-modify-playback-state%20user-read-playback-state%20user-read-currently-playing%20user-read-recently-played&state=cAzgzTDzXnVYqbAM&show_dialog=true&redirect_uri=" + REDIRECT_URI
137.     ShellExecute 0, "open" + Chr$(0), URL + Chr$(0), 0, 0, SW_SHOWNORMAL
138.     OAuth2ServerStart
139. End Sub
140.  
141. Function GetKey2$ (JSON As String, jkey As String)
142.     Dim As String outj
143.     outj = Mid$(JSON, InStr(JSON, Chr$(34) + jkey + Chr$(34) + " : ") + Len(Chr$(34) + jkey + Chr$(34) + " : "))
144.     If Mid$(outj, 1, 1) = Chr$(34) Then outj = Mid$(outj, 2)
145.     If Mid$(outj, Len(outj), 1) = Chr$(34) Then outj = Mid$(outj, Len(outj) - 1)
146.     outj = Mid$(outj, 1, Len(outj) - 2)
147.     GetKey2 = outj
148. End Function
149.  
150. Function GetRefreshedToken$ ()
151.     Dim As String URL: URL = "https://accounts.spotify.com/api/token"
152.     Dim As String server, apipath
153.     server = Mid$(URL, InStr(URL, "/") + 2)
154.     server = Mid$(server, 1, InStr(server, "/") - 1)
155.     apipath = Mid$(URL, InStr(URL, server) + Len(server)) + Chr$(0)
156.     server = server + Chr$(0)
157.     Dim As Offset hInternet: hInternet = InternetOpen(0, INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
158.     If hInternet = 0 Then
159.         Exit Function
160.     End If
161.     Dim As Offset hConnect: hConnect = InternetConnect(hInternet, Offset(server), INTERNET_DEFAULT_HTTPS_PORT, 0, 0, INTERNET_SERVICE_HTTP, 0, 0)
162.     If hConnect = 0 Then
163.         InternetCloseHandle hInternet
164.         Exit Function
165.     End If
166.     Dim As String sessiontype, accepttypes
167.     sessiontype = "POST" + Chr$(0)
168.     accepttypes = "application/json" + Chr$(0)
169.     Dim As Offset hRequest: hRequest = HttpOpenRequest(hConnect, Offset(sessiontype), Offset(apipath), 0, 0, Offset(accepttypes), INTERNET_FLAG_RELOAD Or INTERNET_FLAG_SECURE, 0)
170.     If hRequest = 0 Then
171.         InternetCloseHandle hConnect
172.         InternetCloseHandle hInternet
173.         Exit Function
174.     End If
175.     Dim As String opt: opt = "grant_type=refresh_token&refresh_token=" + refreshtoken
176.     Dim As String headers: headers = "Authorization: Basic " + encodeBase64(CLIENT_ID + ":" + CLIENT_SECRET) + Chr$(13) + Chr$(10) + "Content-Type: application/x-www-form-urlencoded" + Chr$(0)
177.     If HttpSendRequest(hRequest, Offset(headers), -1, Offset(opt), Len(opt)) <> TRUE Then
178.         InternetCloseHandle hRequest
179.         InternetCloseHandle hConnect
180.         InternetCloseHandle hInternet
181.         Exit Function
182.     End If
183.     Dim As String queryinfo: queryinfo = Space$(1024)
184.     Dim As Unsigned Long querylen: querylen = Len(queryinfo) - 1
185.  
186.     If HttpQueryInfo(hRequest, HTTP_QUERY_CONTENT_LENGTH, Offset(queryinfo), Offset(querylen), 0) <> TRUE Then
187.         InternetCloseHandle hRequest
188.         InternetCloseHandle hConnect
189.         InternetCloseHandle hInternet
190.         Exit Function
191.     End If
192.  
193.     Dim As String szBuffer: szBuffer = Space$(4097)
194.     Dim As String response
195.     Dim As Unsigned Long dwRead
196.     Do
197.         InternetReadFile hRequest, Offset(szBuffer), Len(szBuffer) - 1, Offset(dwRead)
198.         If dwRead > 0 Then response = response + Mid$(szBuffer, 1, dwRead)
199.     Loop While dwRead
200.     InternetCloseHandle hRequest
201.     InternetCloseHandle hConnect
202.     InternetCloseHandle hInternet
203.     'refreshtoken = GetKey(response, "refresh_token")
204.     GetRefreshedToken = GetKey(response, "access_token")
205. End Function
206.  
207. Function GetToken$ ()
208.     Dim As String URL: URL = "https://accounts.spotify.com/api/token"
209.     Dim As String server, apipath
210.     server = Mid$(URL, InStr(URL, "/") + 2)
211.     server = Mid$(server, 1, InStr(server, "/") - 1)
212.     apipath = Mid$(URL, InStr(URL, server) + Len(server)) + Chr$(0)
213.     server = server + Chr$(0)
214.     Dim As Offset hInternet: hInternet = InternetOpen(0, INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
215.     If hInternet = 0 Then
216.         Exit Function
217.     End If
218.     Dim As Offset hConnect: hConnect = InternetConnect(hInternet, Offset(server), INTERNET_DEFAULT_HTTPS_PORT, 0, 0, INTERNET_SERVICE_HTTP, 0, 0)
219.     If hConnect = 0 Then
220.         InternetCloseHandle hInternet
221.         Exit Function
222.     End If
223.     Dim As String sessiontype, accepttypes
224.     sessiontype = "POST" + Chr$(0)
225.     accepttypes = "application/json" + Chr$(0)
226.     Dim As Offset hRequest: hRequest = HttpOpenRequest(hConnect, Offset(sessiontype), Offset(apipath), 0, 0, Offset(accepttypes), INTERNET_FLAG_RELOAD Or INTERNET_FLAG_SECURE, 0)
227.     If hRequest = 0 Then
228.         InternetCloseHandle hConnect
229.         InternetCloseHandle hInternet
230.         Exit Function
231.     End If
232.     Dim As String opt: opt = "grant_type=authorization_code&code=" + code + "&redirect_uri=http://localhost:8888/"
233.     Dim As String headers: headers = "Authorization: Basic " + encodeBase64(CLIENT_ID + ":" + CLIENT_SECRET) + Chr$(13) + Chr$(10) + "Content-Type: application/x-www-form-urlencoded" + Chr$(0)
234.     If HttpSendRequest(hRequest, Offset(headers), -1, Offset(opt), Len(opt)) <> TRUE Then
235.         InternetCloseHandle hRequest
236.         InternetCloseHandle hConnect
237.         InternetCloseHandle hInternet
238.         Exit Function
239.     End If
240.     Dim As String queryinfo: queryinfo = Space$(1024)
241.     Dim As Unsigned Long querylen: querylen = Len(queryinfo) - 1
242.  
243.     If HttpQueryInfo(hRequest, HTTP_QUERY_CONTENT_LENGTH, Offset(queryinfo), Offset(querylen), 0) <> TRUE Then
244.         InternetCloseHandle hRequest
245.         InternetCloseHandle hConnect
246.         InternetCloseHandle hInternet
247.         Exit Function
248.     End If
249.  
250.     Dim As String szBuffer: szBuffer = Space$(4097)
251.     Dim As String response
252.     Dim As Unsigned Long dwRead
253.     Do
254.         InternetReadFile hRequest, Offset(szBuffer), Len(szBuffer) - 1, Offset(dwRead)
255.         If dwRead > 0 Then response = response + Mid$(szBuffer, 1, dwRead)
256.     Loop While dwRead
257.     InternetCloseHandle hRequest
258.     InternetCloseHandle hConnect
259.     InternetCloseHandle hInternet
260.     refreshtoken = GetKey(response, "refresh_token")
261.     GetToken = GetKey(response, "access_token")
262. End Function
263.  
264. Function SpotifyAPI$ (URL As String, token As String)
265.     Dim As String server, apipath
266.     server = Mid$(URL, InStr(URL, "/") + 2)
267.     server = Mid$(server, 1, InStr(server, "/") - 1)
268.     apipath = Mid$(URL, InStr(URL, server) + Len(server)) + Chr$(0)
269.     server = server + Chr$(0)
270.     Dim As Offset hInternet: hInternet = InternetOpen(0, INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
271.     If hInternet = 0 Then
272.         Exit Function
273.     End If
274.     Dim As Offset hConnect: hConnect = InternetConnect(hInternet, Offset(server), INTERNET_DEFAULT_HTTPS_PORT, 0, 0, INTERNET_SERVICE_HTTP, 0, 0)
275.     If hConnect = 0 Then
276.         InternetCloseHandle hInternet
277.         Exit Function
278.     End If
279.     Dim As String sessiontype, accepttypes
280.     sessiontype = "GET" + Chr$(0)
281.     accepttypes = "application/json" + Chr$(0)
282.     Dim As Offset hRequest: hRequest = HttpOpenRequest(hConnect, Offset(sessiontype), Offset(apipath), 0, 0, Offset(accepttypes), INTERNET_FLAG_RELOAD Or INTERNET_FLAG_SECURE, 0)
283.     If hRequest = 0 Then
284.         InternetCloseHandle hConnect
285.         InternetCloseHandle hInternet
286.         Exit Function
287.     End If
288.     Dim As String headers: headers = "Authorization: Bearer " + token + Chr$(0)
289.     If HttpSendRequest(hRequest, Offset(headers), -1, 0, 0) <> TRUE Then
290.         InternetCloseHandle hRequest
291.         InternetCloseHandle hConnect
292.         InternetCloseHandle hInternet
293.         Exit Function
294.     End If
295.     Dim As String queryinfo: queryinfo = Space$(1024)
296.     Dim As Unsigned Long querylen: querylen = Len(queryinfo) - 1
297.  
298.     If HttpQueryInfo(hRequest, HTTP_QUERY_CONTENT_LENGTH, Offset(queryinfo), Offset(querylen), 0) <> TRUE Then
299.         InternetCloseHandle hRequest
300.         InternetCloseHandle hConnect
301.         InternetCloseHandle hInternet
302.         Exit Function
303.     End If
304.  
305.     Dim As String szBuffer: szBuffer = Space$(4097)
306.     Dim As String response
307.     Dim As Unsigned Long dwRead
308.     Do
309.         InternetReadFile hRequest, Offset(szBuffer), Len(szBuffer) - 1, Offset(dwRead)
310.         If dwRead > 0 Then response = response + Mid$(szBuffer, 1, dwRead)
311.     Loop While dwRead
312.     InternetCloseHandle hRequest
313.     InternetCloseHandle hConnect
314.     InternetCloseHandle hInternet
315.     SpotifyAPI = response
316. End Function
317.  
318. Function GetKey$ (JSON As String, keyname As String)
319.     Dim jkey As String
320.     jkey = JSON
321.     If InStr(jkey, Chr$(34) + keyname + Chr$(34)) Then
322.         jkey = Mid$(jkey, InStr(jkey, Chr$(34) + keyname + Chr$(34)) + Len(keyname))
323.         jkey = Mid$(jkey, InStr(jkey, ":") + 2)
324.         jkey = String.Replace(jkey, "\" + Chr$(34), "'")
325.         If Mid$(jkey, 1, 1) = Chr$(34) Then
326.             jkey = Mid$(jkey, 2)
327.         End If
328.         jkey = Mid$(jkey, 1, InStr(jkey, Chr$(34)) - 1)
329.         If Right$(jkey, 1) = "," Then
330.             jkey = Mid$(jkey, 1, Len(jkey) - 1)
331.         End If
332.     Else
333.         GetKey = ""
334.     End If
335.     GetKey = jkey
336. End Function
337.  
338. Sub GetAllKey (JSON As String, keyname As String, ParseKey() As String)
339.     Dim unchangejson As String
340.     Dim jkey As String
341.     Dim x
342.     unchangejson = JSON
343.     Do
344.         If InStr(unchangejson, Chr$(34) + keyname + Chr$(34)) Then
345.             x = x + 1
346.             ReDim _Preserve ParseKey(x) As String
347.             unchangejson = Mid$(unchangejson, InStr(unchangejson, Chr$(34) + keyname + Chr$(34)) + Len(keyname))
348.             jkey = unchangejson
349.             jkey = Mid$(jkey, InStr(jkey, ":") + 2)
350.             jkey = String.Replace(jkey, "\" + Chr$(34), "'")
351.             If Mid$(jkey, 1, 1) = Chr$(34) Then
352.                 jkey = Mid$(jkey, 2)
353.             End If
354.             jkey = Mid$(jkey, 1, InStr(jkey, Chr$(34)) - 1)
355.             If Right$(jkey, 1) = "," Then
356.                 jkey = Mid$(jkey, 1, Len(jkey) - 1)
357.             End If
358.             ParseKey(x) = jkey
359.         End If
360.     Loop Until InStr(unchangejson, Chr$(34) + keyname + Chr$(34)) = 0
361. End Sub
362.  
363. Function String.Replace$ (a As String, b As String, c As String)
364.     Dim j
365.     Dim r
366.     Dim r$
367.     j = InStr(a, b)
368.     If j > 0 Then
369.         r$ = Left$(a, j - 1) + c + String.Replace(Right$(a, Len(a) - j + 1 - Len(b)), b, c)
370.     Else
371.         r$ = a
372.     End If
373.     String.Replace = r$
374. End Function
375.  
376. Function encodeBase64$ (encode As String)
377.     Declare Dynamic Library "Crypt32"
378.         Function CryptBinaryToString& Alias "CryptBinaryToStringA" (ByVal pbBinary As Offset, Byval cbBinary As Unsigned Long, Byval dwFlags As Unsigned Long, Byval pszString As Offset, Byval pcchString As Offset)
379.     End Declare
380.     Const CRYPT_STRING_NOCRLF = &H40000000
381.     Const CRYPT_STRING_BASE64 = &H00000001
382.     Dim As String encoded
383.     Dim As Unsigned Long lenEncoded
384.     If CryptBinaryToString(Offset(encode), Len(encode), CRYPT_STRING_BASE64 Or CRYPT_STRING_NOCRLF, 0, Offset(lenEncoded)) <> FALSE Then
385.         encoded = Space$(lenEncoded)
386.     Else
387.         encodeBase64 = ""
388.         Exit Function
389.     End If
390.     If CryptBinaryToString(Offset(encode), Len(encode), CRYPT_STRING_BASE64 Or CRYPT_STRING_NOCRLF, Offset(encoded), Offset(lenEncoded)) <> FALSE Then
391.         encodeBase64 = Mid$(encoded, 1, lenEncoded)
392.     Else
393.         encodeBase64 = ""
394.     End If
395. End Function
396.  
397. Sub OAuth2ServerStart
398.     Dim i
399.     Dim num_active_connections
400.     Dim server_handle
401.     server_handle = _OpenHost("TCP/IP:" + LTrim$(Str$(PORT)))
402.     Do
403.         If num_active_connections < MAX_CONNECTIONS Then
404.             Dim new_connection
405.             new_connection = _OpenConnection(server_handle)
406.             If new_connection Then
407.                 num_active_connections = num_active_connections + 1
408.                 For i = 1 To MAX_CONNECTIONS
409.                     If Connections(i).handle = 0 Then
410.                         Dim empty_connection As connection_t
411.                         Connections(i) = empty_connection
412.                         Connections(i).handle = new_connection
413.                         Exit For
414.                     End If
415.                 Next i
416.             End If
417.         End If
418.  
419.         For i = 1 To MAX_CONNECTIONS
420.             If Connections(i).handle Then
421.                 Dim buf$
422.                 Get #Connections(i).handle, , buf$
423.                 If buf$ <> "" Then
424.                     Connections(i).read_buf = Connections(i).read_buf + buf$
425.                     process_request i
426.                     http_error_complete:
427.                 End If
428.             End If
429.         Next i
430.         _Limit 240
431.     Loop Until InStr(code, "code=") Or InStr(code, "error=")
432.     If InStr(code, "code=") Then
433.         code = Mid$(code, Len("?/code=") + 1)
434.         code = Mid$(code, 1, InStr(code, "&state") - 1)
435.     Else
436.         code = ""
437.     End If
438. End Sub
439.  
440. '$Include:'httpserv.BM'
441. Function OnlineImage& (URL As String)
442.     Declare CustomType Library
443.         Function GetTempFileName~& (ByVal lpPathName As Offset, Byval lpPrefixString As Offset, Byval uUnique As Unsigned Long, Byval lpTempFileName As Offset)
444.         Function GetTempPath~& (ByVal nBufferLength As Unsigned Long, Byval lpBuffer As Offset)
445.     End Declare
446.     Dim getpath As Long
447.     Dim getfile As _Unsigned Long
448.  
449.     Dim path As String
450.     path = Space$(260 + 1)
451.     getpath = GetTempPath(Len(path), _Offset(path))
452.  
453.     path = _Trim$(path)
454.  
455.     Dim file As String
456.     Dim prefix As String
457.     Dim unique As _Unsigned Integer
458.     Randomize Timer
459.     unique = Int(Rnd * 999) + 1
460.     prefix = "spr" + Chr$(0)
461.     Dim tempfile As String
462.     tempfile = Space$(260 + 1)
463.  
464.     getfile = GetTempFileName(_Offset(path), _Offset(prefix), unique, _Offset(tempfile))
465.  
466.     tempfile = _Trim$(tempfile)
467.  
468.     URL = Mid$(URL, InStr(URL, "https://") + 8)
469.     Dim location As String
470.     location = Mid$(URL, InStr(URL, "/")) + Chr$(0)
471.     URL = Mid$(URL, 1, InStr(URL, "/") - 1) + Chr$(0)
472.     Dim As _Offset hsession, httpsession, httprequest
473.     hsession = InternetOpen(0, INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
474.  
475.     httpsession = InternetConnect(hsession, _Offset(URL), INTERNET_DEFAULT_HTTPS_PORT, 0, 0, INTERNET_SERVICE_HTTP, 0, 0)
476.  
477.     Dim sessiontype As String
478.     sessiontype = "GET" + Chr$(0)
479.     httprequest = HttpOpenRequest(httpsession, _Offset(sessiontype), _Offset(location), 0, 0, 0, INTERNET_FLAG_RELOAD Or INTERNET_FLAG_SECURE, 0)
480.  
481.     Dim sendrequest As Long
482.     sendrequest = HttpSendRequest(httprequest, 0, 0, 0, 0)
483.     Dim szBuffer As String
484.     szBuffer = Space$(2048)
485.     Dim dwRead As _Unsigned Long
486.     Dim picfile As String
487.     Open tempfile For Binary As #1
488.     Do
489.         InternetReadFile httprequest, _Offset(szBuffer), Len(szBuffer), _Offset(dwRead)
490.         If dwRead > 0 Then picfile = picfile + Mid$(szBuffer, 1, dwRead)
491.     Loop While dwRead
492.     Put #1, , picfile
493.     Close #1
494.     InternetCloseHandle hsession
495.     OnlineImage = _LoadImage(tempfile, 32)
496.     Kill tempfile
497. End Function

[Pete]

Hi Indy,

I see your avatar has changed, or did you just get a haircut? :D Anyway, nice work! One question about the error handler. I had to trap time out errors in the past, with website apps, where a resume 0 was needed instead of a resume next. I would time the trap so if the internet connection was lost or the site was unavailable, the program would then break out of the trap and issue a report. It could be started again or exited with user response. I'm not sure if your app would need or could benefit from such a routine.

Pete

[SpriggsySpriggs]

@Pete I'm intentionally ignoring errors in this iteration while it is still in this phase of testing. Sometimes the API doesn't respond as fast as QB64 would like and would cause it to have invalid handles. It seems better to just ignore and keep working. It's been rather stable so far but I won't keep it with the errors turned off like that when I get closer to the final product. I do trap whether or not authentication was successful, however.

[Pete]

Nice! almost makes me want to jump back into programming again.

Pete