Author Topic: Simple File Selection box for graphical modes (Now works in Linux too) (Read 2892 times)

Dav · « **on:** November 19, 2021, 01:19:41 pm »

This is an update to a simple file section box FUNCTION I made a while back. The old one wouldn't work in Linux at all - this one does. Not trying to replace the great direntry.h method, but just throwing in a single FUNCTION alternative easy to stick in a program. Tested this in Windows and Linux Mint (new fan) and it seems to work correctly and the same in both (can't test it in Mac).

(Special thanks to the Linux guys in this thread).

- Dav

EDIT: 11/23/2021 - Fixed file list bug under Linux to show all files when *.* used.

Code: QB64: [Select]

'==============
'FILESELECT.BAS  v1.1
'==============
'Simple file selector box for graphical screen modes.
'Coded by Dav, NOV/2021 (with the kind help of the QB64.org forum gurus!)
 
'* NOW WORKS UNDER LINUX!
 
'Navigate through directories and select a file.
'Use ARROWS, PAGE Up/Down, HOME, END to scroll list.
'Press ENTER to select highlighted file or enter highlighted dir.
'ESC will cancel and close box
 
'things to do: auto center box on screen, and ditch x/y input?
'              ...will need to adjust box size based on file/dir chr length
'              Add user defined colors instead...?
 
 
SCREEN _NEWIMAGE(700, 500, 32)
_SCREENMOVE _MIDDLE
 
'=== draw a background
CLS , _RGB(32, 32, 32)
FOR x = 1 TO _WIDTH STEP 3
    FOR y = 1 TO _HEIGHT STEP 3
        PSET (x, y), _RGB(RND * 255, RND * 255, RND * 255)
    NEXT
NEXT
 
'=== Ask user to select a file
a$ = FileSelect$(5, 15, 20, 55, "*.*")
 
IF a$ <> "" THEN
    PRINT "You selected: "; a$
END IF
 
END
 
 
FUNCTION FileSelect$ (y, x, y2, x2, Filespec$)
 
    '=== save original place of cursor
    origy = CSRLIN
    origx = POS(1)
 
    '=== save colors
    fg& = _DEFAULTCOLOR
    bg& = _BACKGROUNDCOLOR
 
    '=== Save whole screen
    DIM scr1 AS _MEM, scr2 AS _MEM
    scr1 = _MEMIMAGE(0): scr2 = _MEMNEW(scr1.SIZE)
    _MEMCOPY scr1, scr1.OFFSET, scr1.SIZE TO scr2, scr2.OFFSET
 
    '=== Generate a unique temp filename to use based on date + timer
    tmp$ = "_qb64_" + DATE$ + "_" + LTRIM$(STR$(INT(TIMER))) + ".tmp"
    IF INSTR(_OS$, "LINUX") THEN tmp$ = "/tmp/" + tmp$
 
    loadagain:
 
    top = 0
    selection = 0
 
    '=== list directories
    IF INSTR(_OS$, "LINUX") THEN
        SHELL _HIDE "find . -maxdepth 1 -type d > " + tmp$
    ELSE
        SHELL _HIDE "dir /b /A:D > " + tmp$
    END IF
 
    '=== make room for names
    REDIM FileNames$(10000) 'space for 10000 filenames
 
    '=== only show the ".." when not at root dir
    IF LEN(_CWD$) <> 3 THEN
        FileNames$(0) = ".."
        LineCount = 1
    ELSE
        LineCount = 0
    END IF
 
    '=== Open temp file
    FF = FREEFILE
    OPEN tmp$ FOR INPUT AS #FF
 
    WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
        LINE INPUT #FF, rl$
 
        '=== load, ignoring the . entry added under Linux
        IF rl$ <> "." THEN
 
            'also remove the ./ added at the beginning when under linux
            IF INSTR(_OS$, "LINUX") THEN
                IF LEFT$(rl$, 2) = "./" THEN
                    rl$ = RIGHT$(rl$, LEN(rl$) - 2)
                END IF
            END IF
 
            FileNames$(LineCount) = "[" + rl$ + "]"
            LineCount = LineCount + 1
 
        END IF
    WEND
 
    CLOSE #FF
 
    '=== now grab list of files...
    IF INSTR(_OS$, "LINUX") THEN
        SHELL _HIDE "rm " + tmp$
        IF Filespec$ = "*.*" THEN Filespec$ = ""
        SHELL _HIDE "find -maxdepth 1 -type f -name '" + Filespec$ + "*' > " + tmp$
    ELSE
        SHELL _HIDE "del " + tmp$
        SHELL _HIDE "dir /b /A:-D " + Filespec$ + " > " + tmp$
    END IF
 
    '=== open temp file
    FF = FREEFILE
    OPEN tmp$ FOR INPUT AS #FF
 
    WHILE ((LineCount < UBOUND(FileNames$)) AND (NOT EOF(FF)))
 
        LINE INPUT #FF, rl$
 
        '=== load, ignoring the generated temp file...
        IF rl$ <> tmp$ THEN
 
            'also remove the ./ added at the beginning when under linux
            IF INSTR(_OS$, "LINUX") THEN
                IF LEFT$(rl$, 2) = "./" THEN
                    rl$ = RIGHT$(rl$, LEN(rl$) - 2)
                END IF
            END IF
 
            FileNames$(LineCount) = rl$
            LineCount = LineCount + 1
        END IF
 
    WEND
    CLOSE #FF
 
    '=== Remove the temp file created
    IF INSTR(_OS$, "LINUX") THEN
        SHELL _HIDE "rm " + tmp$
    ELSE
        SHELL _HIDE "del " + tmp$
    END IF
 
 
    '=== draw a box
    COLOR _RGB(100, 100, 255)
    FOR l = 0 TO y2 + 1
        LOCATE y + l, x: PRINT STRING$(x2 + 4, CHR$(219));
    NEXT
 
    '=== show current working dir at top
    COLOR _RGB(255, 255, 255), _RGB(100, 100, 255)
    CurDir$ = _CWD$
    '=== Shorten it is too long, for display purposes
    IF LEN(CurDir$) > x2 - x THEN
        CurDir$ = MID$(CurDir$, 1, x2 - x - 3) + "..."
    END IF
    LOCATE y, x + 2: PRINT CurDir$;
 
    '=== scroll through list...
    DO
 
        FOR l = 0 TO (y2 - 1)
 
            LOCATE (y + 1) + l, (x + 2)
            IF l + top = selection THEN
                COLOR _RGB(0, 0, 64), _RGB(255, 255, 255) 'selected line
            ELSE
                COLOR _RGB(255, 255, 255), _RGB(0, 0, 64) 'regular
                '=== directories get a different color...
                IF MID$(FileNames$(top + l), 1, 1) = "[" THEN
                    COLOR _RGB(255, 255, 0), _RGB(0, 0, 64)
                END IF
            END IF
 
            PRINT LEFT$(FileNames$(top + l) + STRING$(x2, " "), x2);
 
        NEXT
 
        '=== Get user input
 
        k$ = INKEY$
        SELECT CASE k$
 
            CASE IS = CHR$(0) + CHR$(72) 'Up arrow
                IF selection > 0 THEN selection = selection - 1
                IF selection < top THEN top = selection
 
            CASE IS = CHR$(0) + CHR$(80) 'Down Arrow
                IF selection < (LineCount - 1) THEN selection = selection + 1
                IF selection > (top + (y2 - 2)) THEN top = selection - y2 + 1
 
            CASE IS = CHR$(0) + CHR$(73) 'Page up
                top = top - y2
                selection = selection - y2
                IF top < 0 THEN top = 0
                IF selection < 0 THEN selection = 0
 
            CASE IS = CHR$(0) + CHR$(81) 'Page Down
                top = top + y2
                selection = selection + y2
                IF top >= LineCount - y2 THEN top = LineCount - y2
                IF top < 0 THEN top = 0
                IF selection >= LineCount THEN selection = LineCount - 1
 
            CASE IS = CHR$(0) + CHR$(71) 'Home
                top = 0: selection = 0
 
            CASE IS = CHR$(0) + CHR$(79) 'End
                selection = LineCount - 1
                top = selection - y2 + 1
                IF top < 0 THEN top = 0
 
            CASE IS = CHR$(27) ' ESC cancels
                FileSelect$ = ""
                EXIT DO
 
            CASE IS = CHR$(13) 'Enter
                '=== if .. then go up one dir
                IF RTRIM$(FileNames$(selection)) = ".." THEN
                    cd$ = _CWD$
                    IF INSTR(_OS$, "LINUX") THEN
                        cd$ = LEFT$(cd$, _INSTRREV(cd$, "/"))
                    ELSE
                        cd$ = LEFT$(cd$, _INSTRREV(cd$, "\"))
                    END IF
                    CHDIR cd$
                    ERASE FileNames$
                    GOTO loadagain
                END IF
 
                'see if directory
                test$ = RTRIM$(FileNames$(selection))
                IF LEFT$(test$, 1) = "[" THEN
                    test$ = MID$(test$, 2, LEN(test$) - 2)
                    CHDIR test$
                    ERASE FileNames$
                    GOTO loadagain
                ELSE
                    IF INSTR(_OS$, "LINUX") THEN
                        IF RIGHT$(_CWD$, 1) = "/" THEN
                            C$ = _CWD$
                        ELSE
                            C$ = _CWD$ + "/"
                        END IF
                    ELSE
                        IF RIGHT$(_CWD$, 1) = "\" THEN
                            C$ = _CWD$
                        ELSE
                            C$ = _CWD$ + "\"
                        END IF
                    END IF
 
                    FileSelect$ = C$ + RTRIM$(FileNames$(selection))
                    EXIT DO
 
                END IF
 
        END SELECT
 
    LOOP
 
    _KEYCLEAR
 
    '=== Restore the whole screen
    _MEMCOPY scr2, scr2.OFFSET, scr2.SIZE TO scr1, scr1.OFFSET
    _MEMFREE scr1: _MEMFREE scr2
 
    '=== restore original y,x and color
    LOCATE origy, origx
 
    COLOR fg&, bg&
 
END FUNCTION
 
 
 

johnno56 · « **Reply #1 on:** November 19, 2021, 02:30:02 pm »

Well, I for one, think this application is quite impressive. My first instinct was to use the mouse, but keyboard, works for me as well. Very nicely done indeed...

J

Dav · « **Reply #2 on:** November 23, 2021, 07:39:49 am »

Thanks, @johnno56. I'm missing something under linux it appears - no executable files are being displayed in the list. I'm going have to study the linux file system and commands.

EDIT: I made a quick fix under Linux that seems to work for now. Not the best solution, but I need to uderstand more the way Linux uses wildcards to update further. I Added this to the Linux area when getting a file list. Now all files are listed:

Code: QB64: [Select]

IF Filespec$ = "*.*" THEN Filespec$ = ""

- Dav

News:

Author Topic: Simple File Selection box for graphical modes (Now works in Linux too) (Read 2892 times)

Dav

Simple File Selection box for graphical modes (Now works in Linux too)

johnno56

Re: Simple File Selection box for graphical modes (Now works in Linux too)

Dav

Re: Simple File Selection box for graphical modes (Now works in Linux too)