Author Topic: Gapper, Give it a try! (updated[11/19/21]) (Read 5045 times)

Cobalt · « **on:** November 18, 2021, 01:36:35 pm »

So I present Gapper. Surf the grid changing its color to rack up points. But beware the Seeker who is out to get you!

Being absurdly busy of late this has taken far longer than it should of, but its coming along.

There is a few things to iron out yet; Bonus squares, ~~the ability to "Gap", the 5000 point bonus life~~, and the high score list.
But based on my trial runs everything seems to be working as close to original as possible. Granted my own tests hardly find anything that might be hidden or obscure. So I could use some other players to make sure they can not find anything!

The seeker has a very subtle speed curve and wont reach full speed till closer to Level 8 now.

need to find a way to add the intro screens as data without it taking 2.4mb of space(original BMP was only 900k)

Controls: Arrow Keys
Space Bar- place a temporary gap in the line.
~~(introduced a bug, you only get an extra life if you have exact multiples of 5000! fixing this soon)~~ Fixed(again)

Code: QB64: [Select]

'Gapper(1986) Clone
'10\25\2019 Cobalt
'ÃInital Start; Layout, Gapper, Seeker, L1 Grid finished [13:55EDT]
'ÀCorreted 'Catcher' to 'Seeker' as per original game
'10\31\2021
'ÃFixed Seeker movement issue with help from Bplus and Keybone, used ABS as per Bplus
'Àadded startup screen, player initials input,game options
'11\1\2021
'ÃAdded the instructions screens
'Àenabled collision of Seeker and Gapper
'11\11\2021
'ÃFinished all 8 boards
'11\13\2021
'ÃInserted Bplus's code for detecting completed boxes.
'11\14\2021
'ÃIntegrated Bplus's code for detecting completed boxes and filling them.
'ÃAdded score amount to filled boxes
'ÃLevels now end when boxes are full
'ÀScore is now kept
'11\15\2021
'ÃFixed a few minor bugs with help from Bplus
'ÃReplaced each level creation sub with a master so now all levels created with in a single sub, saved ~210 lines
'ÀChanged Seeker speed to use reducing timer to move faster as levels progress.
'11\18\2021
'ÃAdded extra life at 5000 point intervals
'ÀAdded ability to create "Gaps" on board
 
TYPE GameData
 Player AS STRING * 4
 Score AS LONG
 Lives AS _BYTE
 Level AS _BYTE
 GX AS INTEGER 'Gapper X location
 GY AS INTEGER 'Gapper Y location
 GD AS _BYTE 'Gapper direction
 SX AS INTEGER
 SY AS INTEGER
 SS AS _BYTE 'Seeker speed
 SD AS _BYTE 'Seeker direction
 Start AS _BYTE 'is level started or not(nothing happens until started)
 FPS AS INTEGER
 Quit AS _BYTE
 Caught AS _BYTE 'has the seeker caught the gapper?
 Gapped AS _BYTE 'has the player used the gap feature?
 Gap_time AS SINGLE 'the time the gap was placed. Gaps last less time at higher levels
 'board info
 CellHeight AS _BYTE
 CellWidth AS _BYTE
 Rows AS _BYTE
 Columns AS _BYTE
 Offx AS _BYTE
 Offy AS _BYTE
 Needed AS _BYTE 'number of cells needing finished to win level
 Finished AS _BYTE 'number of cells currently boxed in
END TYPE
 
TYPE High_Scores
 Nam AS STRING * 4
 Score AS LONG
 Level AS INTEGER
END TYPE
 
CONST TRUE = -1, FALSE = NOT TRUE, Gapper = 1, Seeker = 2
CONST UP = 1, DOWN = 2, LEFT = 3, RIGHT = 4
CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
CONST Key_Space = 32, Key_Enter = 13
CONST Cyan = &HFF10E0E0~& '_RGB32(0, 170, 170)
CONST Magenta = &HFFC040C0~&
CONST OffWhite = &HFFC0C0C0~&
CONST Brown = &HFFB06000~&
CONST Yellow = &HFFFFFF00~&
CONST Black = &HFF000000~&
CONST DB_Blue = &HFF0000FF~&
 
Level_data:
DATA 104,60,3,3,4,10,9,0,14,626,374
DATA 76,44,4,4,8,12,16,8,18,616,370
DATA 60,36,5,5,10,10,25,12,14,612,374
DATA 48,24,7,6,16,16,42,24,26,600,362
DATA 36,24,7,8,16,16,44,24,26,458,362
DATA 36,24,7,8,16,16,40,168,26,458,362
DATA 36,24,7,8,16,16,44,168,26,600,362
DATA 36,24,7,8,16,16,56,24,26,600,362
 
SCREEN _NEWIMAGE(640, 440, 32)
DIM SHARED Layer(11) AS LONG, G AS GameData, Frames%
DIM SHARED Scores(10) AS High_Scores
DIM SHARED FinishedBox(72) AS _BYTE, T1 AS LONG, T2 AS LONG
 
Layer(0) = _DISPLAY
Layer(1) = _NEWIMAGE(640, 440, 32) 'mix layer
Layer(2) = _NEWIMAGE(320, 220, 32) 'Grid Layer
Layer(3) = _NEWIMAGE(640, 440, 32) 'Sprite layer
Layer(4) = _NEWIMAGE(320, 220, 32) 'Info layer
Layer(5) = _NEWIMAGE(640, 440, 32) 'Collision 'Gapper\Catcher' layer
Layer(6) = _NEWIMAGE(640, 440, 32) 'Collision 'Grid' layer
Layer(7) = _NEWIMAGE(640, 440, 32) 'debug layer
Layer(8) = _NEWIMAGE(320, 220, 32) 'Menu layer
Layer(9) = _NEWIMAGE(320, 240, 32) 'instructions layer
Layer(10) = _NEWIMAGE(320, 8, 32) 'title bar layer
Layer(11) = _NEWIMAGE(320, 220, 32) 'point test location layer
 
_FONT 8, Layer(4)
_FONT 8, Layer(8)
_FONT 8, Layer(9)
_FONT 8, Layer(10)
_FONT 8, Layer(2)
_PRINTMODE _KEEPBACKGROUND , Layer(10)
_PRINTMODE _KEEPBACKGROUND , Layer(8)
_PRINTMODE _KEEPBACKGROUND , Layer(9)
_PRINTMODE _KEEPBACKGROUND , Layer(2)
_CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
_CLEARCOLOR _RGB32(0, 0, 0), Layer(7)
 
_SCREENMOVE 16, 16
_SOURCE Layer(6)
T1 = _FREETIMER
T2 = _FREETIMER
ON TIMER(T1, 1) FPS
ON TIMER(T2, .05) Move_Seeker
 
Game_INIT
Title_Startup
 
 
SUB Play_game
 DO
  IF _KEYDOWN(27) THEN ExitFlag%% = TRUE: G.Quit = TRUE
  IF _KEYDOWN(Key_Up) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, UP) THEN G.GD = UP
  END IF
  IF _KEYDOWN(Key_Down) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, DOWN) THEN G.GD = DOWN
  END IF
  IF _KEYDOWN(Key_Left) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, LEFT) THEN G.GD = LEFT
  END IF
  IF _KEYDOWN(Key_Right) THEN
   G.Start = TRUE
   IF NOT Collision_Grid(Gapper, RIGHT) THEN G.GD = RIGHT
  END IF
  IF _KEYDOWN(32) AND G.Gapped = FALSE AND G.Start THEN
   G.Gapped = TRUE
   G.Score = G.Score - 5
   Create_Gap
  END IF
  IF G.Start THEN Move_Gapper ':Move_Seeker
  IF G.Gapped THEN Time_Gap 'if there is a gap then check how long its been there
 
  FOR i%% = 1 TO G.Columns * G.Rows
   IF BoxSurrounded(i%%) THEN FinishedBox(i%%) = TRUE
   IF FinishedBox(i%%) THEN FillBox i%%
  NEXT i%%
 
  Game_Data_Update
  _PUTIMAGE (0, 0)-STEP(639, 15), Layer(10), Layer(1) 'title bar
  _PUTIMAGE , Layer(4), Layer(1) 'information bar
  _PUTIMAGE , Layer(2), Layer(1) 'game board
  Place_Gapper
  Place_Seeker
  IF G.Caught THEN 'seeker caught 'em
   ClearLayer Layer(5)
   Reset_Pos
   DrawBoard
   G.Lives = G.Lives - 1
   IF G.Lives = -1 THEN ExitFlag%% = TRUE
  END IF
  ' _PRINTSTRING (600, 0), STR$(G.FPS), Layer(7)
  _PUTIMAGE , Layer(7), Layer(1) 'debug layer
  _PUTIMAGE , Layer(1), Layer(0)
  _LIMIT 60
  ClearLayer Layer(1)
  Frames% = Frames% + 1
  IF G.Finished = G.Needed THEN _DELAY .5: Change_Level
 LOOP UNTIL ExitFlag%%
END SUB
 
SUB Place_Gapper
 old& = _DEST
 _DEST Layer(5)
 LINE (G.GX - 2, G.GY - 2)-STEP(20, 18), Black, BF
 'place gapper-----
 _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(1), (318, 218)-STEP(15, 13)
 'place Gapper shadow
 _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(5), (318, 218)-STEP(15, 13)
 ' _DEST old&
END SUB
 
SUB Place_Seeker
 'place Seeker----
 _PUTIMAGE (G.SX, G.SY), Layer(3), Layer(1), (341, 218)-STEP(14, 11)
 '-----------------
END SUB
 
 
SUB Game_INIT
 _DEST Layer(3)
 'Player----
 DRAW "c" + STR$(Cyan) + "drurd8l2dr3u9d2rd5ru5rd5ru5ru2d9r3ul2u8r2dlbl3c" + STR$(Magenta) + "u3ld3lu3ld3"
 DRAW "bd7d3ru3rd3ru3bu3br3r4ul4bl9l4dr4"
 '----------
 DRAW "br20bu7"
 'Seeker----
 DRAW "c" + STR$(Cyan) + "r3dl3bd10r3ul3br10r3dl3bu10r3ul3c" + STR$(Magenta) + "bd2brl3dr3bd5l3dr3bl6l3ur3"
 DRAW "bu5l3ur3d2lr5dl5dr5dl5"
 '------------
 Title_Header
 _DEST Layer(5)
 LINE (0, 0)-STEP(639, 439), Black, BF
 _DEST Layer(0)
 G.Score = 0
 G.Lives = 2
 G.Level = 1
END SUB
 
SUB Title_Header
 'Header
 _DEST Layer(10)
 LINE (84, 0)-STEP(151, 8), Magenta, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Magenta
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
END SUB
 
SUB Game_Data_Update
 'Info area updating ---------------
 _PRINTSTRING (7, 192), "Score[      ]    Lives[ ]    Level[  ]", Layer(4)
 _PRINTSTRING (95 - ((LEN(LTRIM$(STR$(G.Score))) - 1) * 8), 192), LTRIM$(STR$(G.Score)), Layer(4)
 _PRINTSTRING (191, 192), LTRIM$(STR$(G.Lives)), Layer(4)
 _PRINTSTRING (295 - ((LEN(LTRIM$(STR$(G.Level))) - 1) * 8), 192), LTRIM$(STR$(G.Level)), Layer(4)
 '-----------------------------------
END SUB
 
SUB DrawBoard
 _DEST Layer(2)
 SELECT CASE G.Level
  CASE 1 TO 8 'draw level 1 grid
   Master_Level G.Level
  CASE ELSE 'after level 8 board is random between 5 and 8
   Master_Level INT(RND * 4) + 5
 END SELECT
 _DEST Layer(0)
 ClearLayer Layer(6)
 _PUTIMAGE , Layer(2), Layer(6) 'make a copy for the collision layer
END SUB
 
SUB ClearLayer (L&)
 _DEST L&
 CLS
 _DEST _DISPLAY
END SUB
 
SUB ClearLayerTrans (L&)
 _DEST L&
 CLS , 0
 _DEST _DISPLAY
END SUB
 
FUNCTION Collision_Seeker%%
 Result%% = FALSE
 _SOURCE Layer(5)
 IF POINT(G.SX, G.SY) <> Black THEN Result%% = TRUE
 IF POINT(G.SX + 8, G.SY) <> Black THEN Result%% = TRUE
 IF POINT(G.SX, G.SY + 8) <> Black THEN Result%% = TRUE
 IF POINT(G.SX + 8, G.SY + 8) <> Black THEN Result%% = TRUE
 Collision_Seeker = Result%%
 _SOURCE Layer(6)
END FUNCTION
 
FUNCTION Collision_Grid%% (who%%, Direction%%)
 Result%% = TRUE 'always assume collision
 SELECT CASE who%% 'who are we checking collision for?
  CASE Gapper
   SELECT CASE Direction%%
    CASE UP 'see if there is grid up from Gappers position
     Check~& = POINT(G.GX + 8, G.GY + 5)
    CASE DOWN 'see if there is Grid below Gapper
     Check~& = POINT(G.GX + 8, G.GY + 9)
    CASE LEFT 'check for grid to the left of Gapper
     Check~& = POINT(G.GX + 6, G.GY + 7)
    CASE RIGHT 'Check for grid to the Right of Gapper
     Check~& = POINT(G.GX + 10, G.GY + 7)
   END SELECT
  CASE Seeker
   SELECT CASE Direction%%
    CASE UP 'see if there is grid up from Gappers position
     Check~& = POINT(G.SX + 8, G.SY + 5)
    CASE DOWN 'see if there is Grid below Gapper
     Check~& = POINT(G.SX + 8, G.SY + 9)
    CASE LEFT 'check for grid to the left of Gapper
     Check~& = POINT(G.SX + 6, G.SY + 7)
    CASE RIGHT 'Check for grid to the Right of Gapper
     Check~& = POINT(G.SX + 10, G.SY + 7)
   END SELECT
 END SELECT
 Blue~%% = _BLUE32(Check~&) 'check for Blue, grid is Cyan in color
 IF Blue~%% THEN Result%% = FALSE 'there is grid to move onto, no collision with edge of grid
 Collision_Grid = Result%%
 '_SOURCE Layer(0)
END FUNCTION
 
SUB Move_Seeker
 IF G.Start THEN
  Seeker_Logic
  SELECT CASE G.SD
   CASE UP
    IF NOT Collision_Grid(Seeker, UP) THEN G.SY = G.SY - 2
   CASE DOWN
    IF NOT Collision_Grid(Seeker, DOWN) THEN G.SY = G.SY + 2
   CASE LEFT
    IF NOT Collision_Grid(Seeker, LEFT) THEN G.SX = G.SX - 2
   CASE RIGHT
    IF NOT Collision_Grid(Seeker, RIGHT) THEN G.SX = G.SX + 2
  END SELECT
 END IF
 IF Collision_Seeker THEN G.Caught = TRUE
END SUB
 
SUB Move_Gapper
 SELECT CASE G.GD
  CASE UP
   IF NOT Collision_Grid(Gapper, UP) THEN G.GY = G.GY - 2
  CASE DOWN
   IF NOT Collision_Grid(Gapper, DOWN) THEN G.GY = G.GY + 2
  CASE LEFT
   IF NOT Collision_Grid(Gapper, LEFT) THEN G.GX = G.GX - 2
  CASE RIGHT
   IF NOT Collision_Grid(Gapper, RIGHT) THEN G.GX = G.GX + 2
 END SELECT
 Color_Line
END SUB
 
SUB Seeker_Logic
 DistX% = (G.SX - G.GX) 'find X distance between seeker and gapper
 DistY% = (G.SY - G.GY) 'find Y distance between Seeker and Gapper
 IF ABS(DistX%) > ABS(DistY%) THEN 'if player is farther on the X then
  IF DistX% < 0 THEN
   Turn_Seeker RIGHT 'try going right to get closer
  ELSE
   Turn_Seeker LEFT 'try going left to get closer
  END IF
 ELSE 'player is farther on the Y then
  IF DistY% < 0 THEN
   Turn_Seeker DOWN 'try going down to get closer
  ELSE
   Turn_Seeker UP 'try going up to get closer
  END IF
 END IF
END SUB
 
SUB Turn_Seeker (Direction%%)
 SELECT CASE Direction%%
  CASE UP
   IF NOT Collision_Grid(Seeker, UP) THEN G.SD = UP
  CASE DOWN
   IF NOT Collision_Grid(Seeker, DOWN) THEN G.SD = DOWN
  CASE LEFT
   IF NOT Collision_Grid(Seeker, LEFT) THEN G.SD = LEFT
  CASE RIGHT
   IF NOT Collision_Grid(Seeker, RIGHT) THEN G.SD = RIGHT
 END SELECT
END SUB
 
SUB Color_Line
 _DEST Layer(2)
 LINE (4 + G.GX \ 2, 3 + G.GY \ 2)-STEP(0, 0), Magenta, BF
 _DEST Layer(0)
END SUB
 
SUB FPS
 G.FPS = Frames%
 Frames% = 0
END SUB
 
SUB Title_Startup
 Load_Scores
 _DEST Layer(8)
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 LINE (0, 140)-STEP(639, 8), Brown, BF
 COLOR Black
 _PRINTSTRING (0, 141), "Score:"
 _PRINTSTRING (220, 141), "Level:"
 _PRINTSTRING (100 - (LEN(LTRIM$(STR$(G.Score))) * 8), 141), STR$(G.Score) + "."
 _PRINTSTRING (284 - (LEN(LTRIM$(STR$(G.Level))) * 8), 141), STR$(G.Level)
 
 COLOR Yellow
 _PRINTSTRING (100, 160), "P: Play a game."
 _PRINTSTRING (100, 170), "Q: Quit"
 _PRINTSTRING (100, 180), "N: New Player"
 _PRINTSTRING (100, 190), "I: Instuctions"
 
 Get_Player
 IF Search_For_Player THEN AddPlayer 'first time this player has played!
 Display_HighScores
 Get_Menu_Selection
END SUB
 
SUB Get_Player
 Blink%% = TRUE: I$ = ""
 _DEST Layer(8)
 COLOR Magenta
 LINE (0, 210)-STEP(219, 9), Black, BF
 _PRINTSTRING (0, 210), "Enter your initials:"
 COLOR OffWhite
 DO 'Initials input Loop
  KBD& = _KEYHIT
  SELECT CASE KBD&
   CASE 8 'delete
    IF LEN(I$) THEN I$ = LEFT$(I$, LEN(I$) - 1)
    LINE (168, 210)-(248, 219), Black, BF
   CASE 32 TO 122 'characters
    IF LEN(I$) < 3 THEN I$ = I$ + CHR$(KBD&)
    LINE (168, 210)-(248, 219), Black, BF
   CASE 13 'accept input(if any)
    IF RTRIM$(I$) <> "" THEN ExitFlag%% = TRUE ELSE BEEP
   CASE 27
    ExitFlag%% = TRUE
    G.Quit = TRUE
  END SELECT
  COLOR OffWhite
  _PRINTSTRING (168, 210), I$
  IF Blink%% THEN COLOR Black ELSE COLOR OffWhite
  _PRINTSTRING (168 + LEN(I$) * 8, 210), "_"
  _PUTIMAGE , Layer(8), _DISPLAY
  _LIMIT 30
  t%% = t%% + 1
  IF t%% = 4 THEN Blink%% = NOT Blink%%: t%% = 0
 LOOP UNTIL ExitFlag%%
 G.Player = I$
END SUB
 
SUB Get_Menu_Selection
 LINE (0, 210)-STEP(200, 9), Black, BF
 _PRINTSTRING (0, 210), "Please enter selection:  "
 DO
  KBD& = _KEYHIT
  SELECT CASE KBD&
   CASE ASC("p") OR ASC("P")
    New_Game
    DrawBoard
    TIMER(T1&) ON
    TIMER(T2&) ON
    Play_game
    TIMER(T1&) OFF
    TIMER(T2&) OFF
 
    CLS
    _KEYCLEAR
   CASE ASC("q") OR ASC("Q")
    ExitFlag%% = TRUE
    G.Quit = TRUE
   CASE ASC("n") OR ASC("N")
    Get_Player
    LINE (0, 210)-STEP(200, 9), Black, BF
    _PRINTSTRING (0, 210), "Please enter selection:  "
   CASE ASC("i") OR ASC("I")
    Instructions
   CASE 27
    'ExitFlag%% = TRUE
    'G.Quit = TRUE
  END SELECT
  _PUTIMAGE , Layer(8), _DISPLAY
 LOOP UNTIL ExitFlag%%
END SUB
 
SUB Display_HighScores
 _DEST Layer(8)
 IF LTRIM$(RTRIM$(Scores(1).Nam)) <> "" THEN
  COLOR Magenta
  _PRINTSTRING (0, 24), "High scores:"
  FOR i%% = 1 TO 10
   IF G.Player = Scores(i%%).Nam THEN
    COLOR Yellow 'player shows up Yellow
   ELSEIF i%% = 1 THEN
    COLOR Magenta 'High score if not player shows magenta
   ELSE
    COLOR OffWhite 'everybody else is off white
   END IF
  NEXT i%%
 END IF
END SUB
 
SUB Instructions
 ClearLayer Layer(0)
 _DEST Layer(9)
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
 _PRINTSTRING (84, 10), "OBJECT"
 _PRINTSTRING (1, 20), "To color all the blue lines"
 _PRINTSTRING (1, 30), "red by moving your man GAPPER"
 _PRINTSTRING (1, 40), "with the arrow keys.  At the"
 _PRINTSTRING (1, 50), "same time, you myst avoid"
 _PRINTSTRING (1, 60), "the SEEKER."
 
 _PRINTSTRING (84, 80), "POINTS"
 _PRINTSTRING (1, 90), "Fifty points are awarded for"
 _PRINTSTRING (1, 100), "each square that you surround"
 _PRINTSTRING (1, 110), "in red.  100 points are given"
 _PRINTSTRING (1, 120), "when you encircle the extra"
 _PRINTSTRING (1, 130), "point box while it is on. Each"
 _PRINTSTRING (1, 140), "gap costs 5 points."
 
 _PRINTSTRING (84, 150), "GAPPING"
 _PRINTSTRING (1, 160), "You can create a temporary"
 _PRINTSTRING (1, 170), "gap in the lines by pressing"
 _PRINTSTRING (1, 180), "the SPACE bar or RETURN.  The"
 _PRINTSTRING (1, 190), "word ON appears as long as the"
 _PRINTSTRING (1, 200), "gap is active.  Neither you nor"
 _PRINTSTRING (1, 210), "the seeker can cross the gap."
 
 _PRINTSTRING (0, 230), "Press a key..."
 _PUTIMAGE , Layer(9), _DISPLAY
 _DELAY .5
 _KEYCLEAR
 'end of page 1
 DO: _LIMIT 24: LOOP WHILE INKEY$ = ""
 CLS
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
 _PRINTSTRING (84, 10), "LEVELS"
 _PRINTSTRING (1, 20), "The level increases each time"
 _PRINTSTRING (1, 30), "you complete a screen.  The"
 _PRINTSTRING (1, 40), "seeker gets faster, the gap"
 _PRINTSTRING (1, 50), "time shorter and there will"
 _PRINTSTRING (1, 60), "be more boxes."
 
 _PRINTSTRING (84, 80), "LIVES"
 _PRINTSTRING (1, 90), "You start out with 2 extra"
 _PRINTSTRING (1, 100), "men.  One more will be given"
 _PRINTSTRING (1, 110), "for each 5000 points."
 
 _PRINTSTRING (84, 130), "START"
 _PRINTSTRING (1, 140), "When the grid appears, you"
 _PRINTSTRING (1, 150), "Will be in the top left and"
 _PRINTSTRING (1, 160), "the seeker at the low right."
 _PRINTSTRING (1, 170), "Press a key to begin each new"
 _PRINTSTRING (1, 180), "screen."
 
 _PRINTSTRING (0, 230), "Press a key..."
 'end of page 2
 _PUTIMAGE , Layer(9), _DISPLAY
 _DELAY .5
 _KEYCLEAR
 DO: _LIMIT 24: LOOP WHILE INKEY$ = ""
 ClearLayer Layer(0)
END SUB
 
SUB Load_Scores
 OPEN "Gapper.HSL" FOR BINARY AS #1
 GET #1, , Count%%
 FOR i%% = 1 TO Count%%
  GET #1, , Scores(i%%).Nam
  GET #1, , Scores(i%%)
  GET #1, , Scores(i%%)
 NEXT i%%
 CLOSE #1
END SUB
 
FUNCTION Search_For_Player
 FOR i%% = 1 TO 10
  IF G.Player = Scores(i%%).Nam THEN Result%% = TRUE: i%% = 11 ELSE Result%% = FALSE
 NEXT i%%
 Search_For_Player = Result%%
END FUNCTION
 
SUB AddPlayer
 OPEN "Gapper.HSL" FOR BINARY AS #1
 GET #1, , Count%%
 IF Count%% < 10 THEN Count%% = Count%% + 1
 PUT #1, 1, Count%%
 PUT #1, 1 + 10 * Count%%, G.Player
 PUT #1, , NULL& 'filler for score
 PUT #1, , NULL% 'filler for level
 CLOSE #1
 Load_Scores 'reload score list
END SUB
 
SUB Reset_Pos
 PLAY "o1l32aacceegg"
 _DELAY .25
 G.Start = FALSE
 G.Caught = FALSE
 G.Finished = 0
 ClearLayerTrans Layer(2)
 FOR i%% = 0 TO 72
  FinishedBox(i%%) = FALSE
 NEXT i%%
END SUB
 
 
 
FUNCTION BoxSurrounded%% (boxNumber AS INTEGER) 'save already tested boxes in shared array BoxesSurrounded()
 'Bplus contributed code. 11\12\2021
 'some variables changed to use existing, `**` comments are added
 _SOURCE Layer(2)
 IF FinishedBox(boxNumber) = 0 THEN '**Is the box completed already?
  row = INT((boxNumber - 1) / G.Columns) '[cellsPerCpl)] '**which row
  col = (boxNumber - 1) MOD G.Columns + 1 '[cellsAcross + 1] '**which column
 
  Good%% = TRUE
  FOR I% = row * G.CellHeight TO (row + 1) * G.CellHeight STEP 4 '**No need to check every pixel
   IF POINT(G.Offx + (col - 1) * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
   IF POINT(G.Offx + col * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE
  NEXT I%
 
  IF Good%% THEN '**only check other lines if it hasn't failed yet
   FOR I% = (col - 1) * G.CellWidth TO col * G.CellWidth STEP 4 '**No need to check every pixel
    IF POINT(G.Offx + I%, G.Offy + row * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
    IF POINT(G.Offx + I%, G.Offy + (row + 1) * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE
   NEXT I%
  END IF
  IF Good%% THEN BoxSurrounded = -1: G.Finished = G.Finished + 1: G.Score = G.Score + 50: PLAY "o3l54eeggee": Check_Score 'all OK
 ELSE
  BoxSurrounded = -1
 END IF
 _SOURCE Layer(6)
END FUNCTION
 
SUB FillBox (boxNumber)
 ' _DELAY .25
 _DEST Layer(2)
 row = INT((boxNumber - 1) / G.Columns)
 col = (boxNumber - 1) MOD G.Columns + 1
 LINE (G.Offx + (col - 1) * G.CellWidth + 3, G.Offy + row * G.CellHeight + 3)-STEP(G.CellWidth - 6, G.CellHeight - 6), OffWhite, BF
 COLOR Black
 _PRINTSTRING (G.Offx + (col - 1) * G.CellWidth + 3 + (INT(G.CellWidth \ 2) - 8), G.Offy + row * G.CellHeight + 3 + (INT(G.CellHeight \ 2) - 8)), "50", Layer(2)
 COLOR OffWhite
 _DEST Layer(0)
END SUB
 
SUB Change_Level
 G.Level = G.Level + 1
 speed! = (.05 - (G.Level / 1000) * 5)
 IF speed! <= .015 THEN speed! = .015
 ON TIMER(T2, speed!) Move_Seeker
 ClearLayerTrans Layer(2)
 ClearLayer Layer(5)
 ClearLayer Layer(6)
 DrawBoard
 G.Finished = 0
 FOR i%% = 0 TO 72
  FinishedBox(i%%) = FALSE
 NEXT i%%
END SUB
 
SUB Master_Level (Level)
 G.Start = FALSE
 RESTORE Level_data
 FOR i%% = 1 TO Level 'load level data
  READ G.CellWidth, G.CellHeight, G.Rows, G.Columns, G.Offx, G.Offy, G.Needed, G.GX, G.GY, G.SX, G.SY
 NEXT i%%
 SELECT CASE Level 'create levels
  CASE 1 TO 4, 8
   FOR i%% = 0 TO G.Rows
    LINE (G.Offx, G.Offy + i%% * G.CellHeight)-STEP(G.CellWidth * G.Columns, 0), Cyan 'horizontal lines
   NEXT i%%
   FOR i%% = 0 TO G.Columns
    LINE (G.Offx + i%% * G.CellWidth, G.Offy)-STEP(0, G.CellHeight * G.Rows), Cyan 'vertical lines
   NEXT i%%
  CASE 5 ' "Â" shaped level
   FOR i%% = 0 TO 4
    LINE (16, 16 + i%% * 24)-STEP(288, 0), Cyan 'horizontal lines
    LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
   NEXT i%%
   FOR i%% = 0 TO 2
    LINE (88, 136 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (16 + i%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
    LINE (268 + i%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
   NEXT i%%
  CASE 6 ' "Å" shaped level
   FOR i%% = 0 TO 3
    LINE (16, 64 + i%% * 24)-STEP(288, 0), Cyan 'horizontal lines
    LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
   NEXT i%%
   LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 
   FOR i%% = 0 TO 1
    LINE (88, 16 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (88, 160 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (16 + i%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
    LINE (268 + i%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
   NEXT i%%
  CASE 7 ' "Á" shaped level
   FOR i%% = 0 TO 4
    LINE (16, 88 + i%% * 24)-STEP(288, 0), Cyan 'horizontal lines
    LINE (88 + i%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
   NEXT i%%
   FOR i%% = 0 TO 1
    LINE (88, 16 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
    LINE (16 + i%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
    LINE (268 + i%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
   NEXT i%%
   LINE (88, 16 + i%% * 24)-STEP(144, 0), Cyan 'horizontal lines
 END SELECT
END SUB
 
SUB Check_Score
 STATIC Current_life AS _BYTE
 IF G.Score = 0 THEN Current_life = 0 'reset on new game
 IF INT(G.Score \ 5000) = Current_life + 1 THEN 'Bonus Life, only worry about the thousands place to
  '                                                            avoid issues with non-5000 exact multiples
  Current_life = Current_life + 1
  G.Lives = G.Lives + 1
  TIMER(T2) OFF
  _DELAY .05
  PLAY "o6l32GFED#"
  TIMER(T2) ON
 END IF
END SUB
 
SUB Create_Gap
 STATIC X%, Y%, D%
 IF G.Gapped THEN 'when a new gap is made get the pos. this sub is called to erase too
  X% = G.GX + 8 'Xpos of gapper center
  Y% = G.GY + 7 'Ypos of gapper center
  D% = G.GD 'direction of gap(up\down or left\right)
  G.Gap_time = TIMER
 END IF
 SELECT CASE D%
  CASE UP, DOWN
   _DEST Layer(6) 'draw the gap to the detection layer
   IF G.Gapped THEN LINE (X%, Y% - 1)-STEP(0, 2), Black ELSE LINE (X%, Y% - 1)-STEP(0, 2), Cyan 'erase or restore
   _DEST Layer(2) 'also display gap on visual layer (can only gap where you've been so restore to Magenta)
   'layer 2 is 320x220 so we must half the x,y points
   IF G.Gapped THEN LINE (.5 * X%, .5 * Y% - 3)-STEP(0, 5), Black ELSE LINE (.5 * X%, .5 * Y% - 3)-STEP(0, 5), Magenta 'erase or restore
  CASE LEFT, RIGHT
   _DEST Layer(6) 'draw the gap to the detection layer
   IF G.Gapped THEN LINE (X% - 1, Y% - 1)-STEP(2, 1), Black, BF ELSE LINE (X% - 1, Y% - 1)-STEP(2, 1), Cyan, BF 'erase or restore
   _DEST Layer(2) 'also display gap on visual layer (can only gap where you've been so restore to Magenta)
   'layer 2 is 320x220 so we must half the x,y points
   IF G.Gapped THEN LINE (.5 * X% - 3, .5 * Y% - 1)-STEP(5, 1), Black, BF ELSE LINE (.5 * X% - 3, .5 * Y% - 1)-STEP(5, 1), Magenta, BF 'erase or restore
 END SELECT
 ' _DEST Layer(0)
 ' CLS
 ' _PUTIMAGE , Layer(2), Layer(0)
 ' G.GY = G.GY + 16
 ' _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(0), (318, 218)-STEP(15, 13)
 ' END
END SUB
 
SUB Time_Gap
 IF G.Level <= 20 THEN Max_Time! = 500 - (G.Level * 20) ELSE Max_Time! = 100
 Max_Time! = Max_Time! / 100 'convert to seconds (5 sec to 1 sec)
 
 IF G.Gap_time + Max_Time! <= TIMER THEN 'gap time up
  G.Gapped = FALSE
  Create_Gap 'call the SUB again to fill in gap
 END IF
END SUB
 
SUB New_Game
 G.Score = 0
 G.Lives = 2
 FOR i%% = 0 TO 72
  FinishedBox(i%%) = FALSE
 NEXT i%%
 ClearLayerTrans Layer(2)
 Check_Score 'reset extra lives counter
END SUB
 

bplus · « **Reply #1 on:** November 18, 2021, 03:45:41 pm »

Hi Cobalt,

When I was playing first game, the chaser got stuck @ top line near right corner when that box lit up from being enclosed (or just before that). It remained stuck until next level started. Maybe a fluke?

Cobalt · « **Reply #2 on:** November 18, 2021, 06:48:37 pm »

Quote from: bplus on November 18, 2021, 03:45:41 pm

Hi Cobalt,

When I was playing first game, the chaser got stuck @ top line near right corner when that box lit up from being enclosed (or just before that). It remained stuck until next level started. Maybe a fluke?

Yeah its done that a few times since I switched over to using a TIMER to control the seeker speed. not sure if its a nuance of the timers and I'm doing something wrong or if Timers have an unknown issue? I cant use _DELAY anywhere without turning the timer off and back on. as I did try to add a little delay for the box enclosed sound, to mimic the original game better. (the sound pauses game play momentarily, pretty sure it was originally coded in some form of basic). Not sure how to diagnose this further to confirm one way or another as to why the timer seems to stop working. The FPS timer doesn't seem to have this issue though.

xra7en · « **Reply #3 on:** November 18, 2021, 07:43:30 pm »

8000 1st guy level 6 :-)
fun game - reminds me of an old arcade game.. just can't remember.
here is a suggestion for harder, can't go backward.

Cobalt · « **Reply #4 on:** November 18, 2021, 09:36:58 pm »

Quote from: xra7en on November 18, 2021, 07:43:30 pm

8000 1st guy level 6 :-)
fun game - reminds me of an old arcade game.. just can't remember.
here is a suggestion for harder, can't go backward.

People claim the original game was a take on something called "Amidar".

Harder huh? Apparently you haven't made it to the level where the seeker becomes faster than the gapper! (not sure if I will leave it that way as it becomes a kill level) the player moves at a rate of 1px every .0167 sec(roughly 60x second). At max speed the seeker moves at 1px every .015 sec. and the gap lasts shorter and shorter period of time too.

xra7en · « **Reply #5 on:** November 19, 2021, 04:23:37 am »

Never played Amidar
I was thinking of QIX

=67

I used to play that a lot.

Yours has a nice addictive nature to it. The "ok-one-more-level" type LOL!!

News:

Author Topic: Gapper, Give it a try! (updated[11/19/21]) (Read 5045 times)

Cobalt

Gapper, Give it a try! (updated[11/19/21])

bplus

Re: Gapper, Give it a try!

Cobalt

Re: Gapper, Give it a try!

xra7en

Re: Gapper, Give it a try!

Cobalt

Re: Gapper, Give it a try!

xra7en

Re: Gapper, Give it a try! (updated)