Virtual Terminal Escape Sequences (Windows 10+)

[SpriggsySpriggs]

Happened across this MSDN page on using Virtual Terminal escape sequences and thought it would be neat to try in QB64. So, I converted the example on the page. Perhaps someone would be interested enough to make something more with it.

The code:

Code: QB64: [Select]

1. Option _Explicit
2. $Console:Only
3.  
4. Type COORD
5.     As Integer X, Y
6. End Type
7.  
8. Type SMALL_RECT
9.     As Integer Left, Top, Right, Bottom
10. End Type
11.  
12. Type CONSOLE_SCREEN_BUFFER_INFO
13.     As COORD dwSize, dwCursorPosition
14.     As _Unsigned Integer wAttributes
15.     As SMALL_RECT srWindow
16.     As COORD dwMaximumWindowSize
17. End Type
18.  
19. Const INVALID_HANDLE_VALUE = -1
20.  
21. Const STD_OUTPUT_HANDLE = -11
22. Const ENABLE_VIRTUAL_TERMINAL_PROCESSING = &H0004
23.  
24. Const ESC = ""
25. Const CSI = "["
26.  
27. Declare CustomType Library
28.     Function GetStdHandle%& (ByVal nStdHandle As _Unsigned Long)
29.     Sub GetConsoleMode (ByVal hConsoleHandle As _Offset, Byval lpMode As _Offset)
30.     Sub SetConsoleMode (ByVal hConsoleHandle As _Offset, Byval dwMode As _Unsigned Long)
31.     Sub GetConsoleScreenBufferInfo (ByVal hConsoleOutput As _Offset, Byval lpConsoleScreenBufferInfo As _Offset)
32. End Declare
33.  
34. EnableVTMode
35. Dim As _Offset hOut: hOut = GetStdHandle(STD_OUTPUT_HANDLE)
36. If hOut = INVALID_HANDLE_VALUE Then End
37. Dim As CONSOLE_SCREEN_BUFFER_INFO ScreenBufferInfo
38. GetConsoleScreenBufferInfo hOut, _Offset(ScreenBufferInfo)
39. Dim As COORD Size
40. Size.X = ScreenBufferInfo.srWindow.Right - ScreenBufferInfo.srWindow.Left + 1
41. Size.Y = ScreenBufferInfo.srWindow.Bottom - ScreenBufferInfo.srWindow.Top + 1
42.  
43. 'Enter the alternate buffer
44. Print CSI; "?1049h";
45.  
46. 'Clear screen, tab stops, set, stop at columns 16, 32
47. Print CSI; "1;1H";
48. Print CSI; "2J";
49.  
50. Dim As Long iNumTabStops: iNumTabStops = 4 '(0, 20, 40, width)
51. Print CSI; "3g"; 'Clear all tab stops
52. Print CSI; "1;20H"; 'Move to column 20
53. Print ESC; "H"; 'Set a tab stop
54.  
55. Print CSI; "1;40H"; 'Move to column 40
56. Print ESC; "H"; 'Set a tab stop
57.  
58. 'Set scrolling margins to 3, h-2
59. Print CSI; "3;"; LTrim$(Str$(Size.Y - 2)) + "r";
60. Dim As Long iNumLines: iNumLines = Size.Y - 4
61.  
62. Print CSI; "1;1H";
63. Print CSI; "102;30m";
64. Print "Windows 10 Anniversary Update - VT Example";
65. Print CSI; "0m";
66.  
67. 'Print a top border - Yellow
68. Print CSI; "2;1H";
69. PrintHorizontalBorder Size, -1
70.  
71. 'Print a bottom border
72. Print CSI; LTrim$(Str$(Size.Y - 1)); "1H";
73. PrintHorizontalBorder Size, 0
74.  
75. 'Draw columns
76. Print CSI; "3;1H";
77. Dim As Long lin
78. For lin = 0 To (iNumLines * iNumTabStops) - 1
79.     PrintVerticalBorder
80.     If lin + 1 <> iNumLines * iNumTabStops Then Print Chr$(9);
81. Next
82.  
83. PrintStatusLine "Press any key to see text printed between tab stops.", Size
84. Sleep
85.  
86. 'Fill columns with output
87. Print CSI; "3;1H";
88. For lin = 0 To iNumLines - 1
89.     Dim As Long tabs
90.     For tabs = 0 To iNumTabStops - 2
91.         PrintVerticalBorder
92.         Print "line="; LTrim$(Str$(lin));
93.         Print Chr$(9);
94.     Next
95.     PrintVerticalBorder
96.     If lin + 1 <> iNumLines Then Print Chr$(9);
97. Next
98.  
99. PrintStatusLine "Press any key to demonstrate scroll margins", Size
100. Sleep
101.  
102. Print CSI; "3;1H";
103. For lin = 0 To (iNumLines * 2) - 1
104.     Print CSI; "K";
105.     For tabs = 0 To iNumTabStops - 2
106.         PrintVerticalBorder
107.         Print "line="; LTrim$(Str$(lin));
108.         Print Chr$(9);
109.     Next
110.     PrintVerticalBorder
111.     If lin + 1 <> iNumLines * 2 Then
112.         Print
113.     End If
114. Next
115.  
116. PrintStatusLine "Press any key to exit", Size
117. Sleep
118.  
119. Print CSI; "?1049l";
120.  
121. Sub EnableVTMode ()
122.     Dim As _Offset hOut
123.     hOut = GetStdHandle(STD_OUTPUT_HANDLE)
124.     Dim As _Unsigned Long dwMode
125.     GetConsoleMode hOut, _Offset(dwMode)
126.     dwMode = dwMode Or ENABLE_VIRTUAL_TERMINAL_PROCESSING
127.     SetConsoleMode hOut, dwMode
128. End Sub
129.  
130. Sub PrintVerticalBorder ()
131.     Print ESC; "(0";
132.     Print CSI; "104;93m";
133.     Print "x";
134.     Print CSI; "0m";
135.     Print ESC; "(B";
136. End Sub
137.  
138. Sub PrintHorizontalBorder (Size As COORD, fIsTop As _Byte)
139.     Print ESC; "(0";
140.     Print CSI; "104;93m";
141.     If fIsTop Then Print "l"; Else Print "m";
142.     Dim As Long i
143.     For i = 1 To Size.X - 2
144.         Print "q";
145.     Next
146.     If fIsTop Then Print "k"; Else Print "j";
147.     Print CSI; "0m";
148.     Print ESC; "(B";
149. End Sub
150.  
151. Sub PrintStatusLine (pszMessage As String, Size As COORD)
152.     Print CSI; LTrim$(Str$(Size.Y)); "1H";
153.     Print CSI; "K";
154.     Print pszMessage;
155. End Sub

A screenshot of the output: