Screenmove actual program screen

[SMcNeill]

I think the demo here speaks for itself:

Code: QB64: [Select]

1. $COLOR:32
2. _DEFINE A-Z AS LONG
3. SCREEN _NEWIMAGE(1020, 780, 32)
4. ScreenMove_Middle
5. PRINT "Your desktop dimensions: "; _DESKTOPWIDTH, _DESKTOPHEIGHT
6. PRINT "Your program dimensions: "; _WIDTH, _HEIGHT
7. PRINT "Your program borders   : "; glutGet(506)
8. PRINT "Your program titlebar  : "; glutGet(507)
9. PRINT
10. PRINT "To properly center your program, it should be at:"
11. PRINT (_DESKTOPWIDTH - _WIDTH) / 2,
12. PRINT (_DESKTOPHEIGHT - _HEIGHT) / 2
13. PRINT
14. PRINT "Using Screenmove_Middle, it is currently at:"
15. PRINT glutGet(100), glutGet(101)
16. PRINT
17. SLEEP
18. PRINT "Using _SCREENMOVE _MIDDLE, the screen is placed at:"
19. _SCREENMOVE _MIDDLE
20. PRINT glutGet(100), glutGet(101)
21. PRINT
22. PRINT "Which, as you can see, doesn't account for our borders or titlebar width and height."
23. SLEEP
24.  
25. CLS
26. PRINT "Maybe a better example would be to move the screen to 0,0."
27. _SCREENMOVE 0, 0
28. PRINT "Notice how the titlebar and borders are still here?"
29. PRINT "Our program is actually at: "; glutGet(100), glutGet(101)
30. SLEEP
31.  
32. ScreenMove 0, 0
33. PRINT "And notice how our program window now starts at 0,0, like we told it to?"
34. PRINT "And, as you can see, we're now actually at :"; glutGet(100), glutGet(101)
35. SLEEP
36.  
37. CLS
38.  
39. PRINT "And, best of all, since all these values are calculated manually, you don't need to worry about using a _DELAY with them, at   the beginning of your code, as we're manually setting our X/Y position and not trying to do it automatically."
40.  
41. SUB ScreenMove_Middle
42.     $IF BORDERDEC = UNDEFINED THEN
43.         $LET BORDERDEC = TRUE
44.         DECLARE LIBRARY
45.             FUNCTION glutGet& (BYVAL what&)
46.         END DECLARE
47.     $END IF
48.     BorderWidth = glutGet(506)
49.     TitleBarHeight = glutGet(507)
50.     _SCREENMOVE (_DESKTOPWIDTH - _WIDTH - BorderWidth) / 2 + 1, (_DESKTOPHEIGHT - _HEIGHT - BorderWidth) / 2 - TitleBarHeight + 1
51. END SUB
52.  
53. SUB ScreenMove (x, y)
54.     $IF BORDERDEC = UNDEFINED THEN
55.         $LET BORDERDEC = TRUE
56.         DECLARE LIBRARY
57.         FUNCTION glutGet& (BYVAL what&)
58.         END DECLARE
59.     $END IF
60.     BorderWidth = glutGet(506)
61.     TitleBarHeight = glutGet(507)
62.     _SCREENMOVE x - BorderWidth, y - BorderWidth - TitleBarHeight
63. END SUB
64.  

Note: I found these subtle positioning differences to be vital for me, in another little batch program which tries to interact with my screen in various ways.  Clicks were often not registering as my screen simply wasn't where I expected it to be.  A box from (0,0)-(100,100), wasn't really at those coordinates, as it was instead at (borderwidth, borderwidth + titlebarheight)-STEP(100,100)...

Which was more than enough to throw all my work off and cause all sorts of unintentional glitches.  ;)