Clock (next one from hunderd...)

[Petr]

This is how a child comes in and says: Daddy, what do you want to paint? And can you make it move? So I say - paint hands and numbers....

Here is the result, this time with an external file. I didn't fix anything, even though some of the numbers were rotated, I left it as it was.

Happy New Year!

Code: QB64: [Select]

1. $NoPrefix
2. Title "Kids clock"
3. Dim Shared nrs(14) As Long
4. 'DataCreate "hrsml.txt", "h00h.gif"
5. LoadSubImages
6. Screen NewImage(1024, 768, 32)
7. Cls , RGB32(133)
8. CX = 500: CY = 350: A = -_Pi / 2 + _Pi(2) / 12
9. Circle (535, 419), 340, _RGB32(200)
10. Paint (535, 419), _RGB32(250), _RGB32(200)
11. For t = 0 To 11
12.     Xv = CX + Cos(A) * 250
13.     Yv = CY + Sin(A) * 250
14.     A = A + _Pi(2) / 12
15.     PutImage (Xv, Yv), nrs(t)
16. Next
17.  
18. PCopy Display, 1
19. Do Until k&
20.     k& = KeyDown(27)
21.     PCopy 1, Display
22.     Mode = 1
23.     Select Case Mode '                                   mode: 0 for standard STEPs mode, 1 for smooth steps.
24.         Case 0
25.             Hrs = Int(Timer / 3600)
26.             If Hrs > 12 Then Hrs = Hrs - 12
27.             Min = Int((Timer / 3600 - Hrs) * 60)
28.             Secs = Int(Timer - (Hrs * 3600 + Min * 60))
29.         Case 1
30.             Hrs = Timer / 3600
31.             Min = (Hrs - (Int(Timer / 3600))) * 60
32.             Secs = Timer - (Int(Hrs) * 3600 + Int(Min) * 60)
33.     End Select
34.  
35.     For HrsSel = 1 To 3
36.         Select Case HrsSel
37.             Case 1 'hours
38.                 Asecs = _Pi(2) / 12 * Hrs - _Pi / 2
39.                 iW = 45: iH = 144: Handle = 13: L1 = 170
40.  
41.             Case 2 'minutes
42.                 Asecs = _Pi(2) / 60 * Min - _Pi / 2
43.                 iW = 54: iH = 145: Handle = 14: L1 = 222
44.  
45.             Case 3 'seconds
46.                 Asecs = _Pi(2) / 60 * Secs - _Pi / 2
47.                 iW = 61: iH = 143: Handle = 12: L1 = 200
48.         End Select
49.  
50.         X1 = 535 + Cos(Asecs - .09) * L1
51.         X2 = 535 + Cos(Asecs + .09) * L1
52.         Y1 = 419 + Sin(Asecs - .09) * L1
53.         Y2 = 419 + Sin(Asecs + .09) * L1
54.  
55.         X3 = 535 + Cos(Asecs - .6) * -20
56.         X4 = 535 + Cos(Asecs + .6) * -20
57.         Y3 = 419 + Sin(Asecs - .6) * -20
58.         Y4 = 419 + Sin(Asecs + .6) * -20
59.  
60.         MapTriangle (0, 0)-(iW, iH)-(0, iH), nrs(Handle) To(X1, Y1)-(X3, Y3)-(X4, Y4)
61.         MapTriangle (iW, 0)-(0, 0)-(iW, iH), nrs(Handle) To(X2, Y2)-(X1, Y1)-(X3, Y3)
62.     Next HrsSel
63.     Display
64.     Limit 20
65. Loop
66.  
67. Sub DataCreate (OutputFile As String, InputFile As String) 'this sub is not need for run, but is used between developing this program. This sub create DATA values for us.
68.     img = LoadImage(InputFile$, 32)
69.     img2 = CopyImage(img, 32)
70.  
71.     ff = FreeFile
72.     Open OutputFile$ For Output As #ff
73.     Screen img
74.     Do Until k&
75.         k& = KeyDown(27)
76.         While _MouseInput: Wend
77.         MX = MouseX: MY = MouseY
78.         MB1 = MouseButton(1)
79.         MB2 = MouseButton(2)
80.         If MB1 Then
81.             Do Until MB1 = 0
82.                 PutImage , img2
83.                 Line (MX, MY)-(MouseX, MouseY), &HFF000000, B
84.                 While MouseInput: Wend
85.                 MB1 = MouseButton(1)
86.                 Limit 15
87.             Loop
88.             wMX = MX: wMY = MY: wMx2 = _MouseX: wMy2 = _MouseY
89.         End If
90.         If MB2 Then
91.             If wMx2 Then
92.                 r$ = Str$(wMX) + ", " + Str$(wMY) + ", " + Str$(wMx2) + ", " + Str$(wMy2)
93.                 Print #ff, r$
94.                 wMx2 = 0
95.             End If
96.         End If
97.     Loop
98. End Sub
99.  
100. Sub LoadSubImages
101.     img = LoadImage("H00H.gif", 32)
102.     For lsi = 0 To 14
103.         Read x1, y1, x2, y2, i
104.         wdth = x2 - x1: hght = y2 - y1
105.         nrs(i) = _NewImage(wdth, hght, 32)
106.         PutImage , img, nrs(i), (x1, y1)-(x2, y2)
107.         SetAlpha 0, _RGB32(255) To _RGB32(200), nrs(i)
108.     Next
109.     FreeImage img
110.  
111.     Data 0,4,62,148,12
112.     Data 69,5,115,150,13
113.     Data 118,7,172,153,14
114.     Data 182,9,226,140,8
115.     Data 226,10,310,134,9
116.     Data 320,10,430,144,10
117.     Data 435,11,522,132,11
118.     Data 1,177,59,270,0
119.     Data 64,171,130,260,1
120.     Data 143,170,204,267,2
121.     Data 211,168,280,269,3
122.     Data 282,168,330,265,4
123.     Data 332,167,401,272,5
124.     Data 402,156,469,274,6
125.     Data 474,157,518,265,7
126. End Sub
127.  

[Richard Frost]

Mighty cute.  Is it waterproof?

[Petr]

They are Waterproof Once. :) Like everything. The drawing is done with markers. Have Nice New Year!



:)

[bplus]

Well I can imagine what it is supposed to look like but this forum won't let me save the image correctly, you need to attach the file I think:

Here is what I see:
 

[bplus]

Oh another dah! moment, just click the picture! (I tried a Save Image from right click on it).

Here we go!