Math Flash Card Trainer for Children

[SMcNeill]

Code: QB64: [Select]

1. TYPE ResultsType
2.     num1 AS LONG
3.     op AS LONG
4.     num2 AS LONG
5.     num3 AS LONG
6.     answer AS LONG
7.     correct AS LONG
8. END TYPE
9.  
10.  
11. _TITLE "Flash Card Math Trainer"
12. DEFLNG A-Z
13. $RESIZE:SMOOTH
14. _DELAY 0.5
15. WS = _NEWIMAGE(1280, 720, 32) 'WorkScreen
16. SCREEN WS
17.  
18. DIM SHARED WF 'Workfont
19. WF = _LOADFONT("C:\Windows\Fonts\Cour.ttf", 150)
20.  
21.  
22. DIM SHARED RST 'Result Font
23. RST = _LOADFONT("C:\Windows\Fonts\Cour.ttf", 50)
24.  
25. REDIM SHARED Results(0) AS ResultsType
26. DIM SHARED GameTime, Difficulty
27.  
28. CONST Red = _RGB32(255, 0, 0)
29. CONST White = _RGB32(255, 255, 255)
30. CONST Black = _RGB32(0, 0, 0)
31. CONST Blue = _RGB32(0, 0, 255)
32. CONST Green = _RGB32(0, 255, 0)
33. CONST Yellow = _RGB32(255, 255, 0)
34.  
35. CONST Plus = 1, Minus = 2, Times = 3, Divide = 4
36.  
37.  
38.  
39. RANDOMIZE TIMER
40.  
41.  
42. t1 = _FREETIMER
43. ON TIMER(t1, 1) CountDown
44.  
45.  
46.  
47. MainChoiceScreen mode, Difficulty, length
48.  
49. SELECT CASE length 'This is the number of seconds we're going to test ourselves
50.     CASE 1: GameTime = 15
51.     CASE 2: GameTime = 30
52.     CASE 3: GameTime = 60
53.     CASE 4: GameTime = 120
54.     CASE 5: GameTime = 300
55. END SELECT
56.  
57. SELECT CASE Difficulty 'This determines how hard the game will be
58.     CASE 1: LowLimit = 0: HighLimit = 10
59.     CASE 2: LowLimit = 0: HighLimit = 12
60.     CASE 3: LowLimit = 0: HighLimit = 99
61.     CASE 4: LowLimit = 10: HighLimit = 89
62. END SELECT
63.  
64.  
65. TIMER(t1) ON
66.  
67.  
68.  
69. DO
70.     _LIMIT 10
71.     num1 = RND * HighLimit + LowLimit
72.  
73.     SELECT CASE mode 'Only give the user the numbers they wanted to play with
74.         CASE 1: op = 1
75.         CASE 2: op = 2
76.         CASE 3: op = RND + 1
77.         CASE 4: op = 3
78.         CASE 5: op = 4
79.         CASE 6: op = RND + 3
80.         CASE 7: op = RND: IF op = 0 THEN op = 1 ELSE op = 3
81.         CASE 8: op = INT(RND * 4) + 1
82.     END SELECT
83.  
84.     num2 = RND * HighLimit + LowLimit
85.  
86.     IF op = 4 THEN 'it's divide, let's get the numbers in the proper order
87.         DO
88.             num1 = RND * HighLimit + LowLimit
89.             num2 = RND * HighLimit + LowLimit
90.             num1 = num1 * num2
91.         LOOP UNTIL num1 < 100
92.     END IF
93.     IF op = 2 AND num1 < num2 THEN SWAP num1, num2
94.     DrawCard num1, op, num2
95.     DrawUserClickAreas
96.     GetUserAnswer answer$
97.     CheckAnswer num1, op, num2, answer$
98.     DisplayTime
99.     _DISPLAY
100. LOOP
101.  
102.  
103. SUB MainChoiceScreen (mode, difficulty, length)
104. CLS
105. _FONT RST
106. PRINT "Welcome to Math Flash!"
107. _FONT 16
108. LOCATE 5, 1: PRINT "Your personal math trainer!"
109. PRINT
110. PRINT "What would you like to learn to work with today?"
111. PRINT "1) Addition"
112. PRINT "2) Subtraction"
113. PRINT "3) Addition and Subtraction"
114. PRINT "4) Multiplication"
115. PRINT "5) Division"
116. PRINT "6) Multiplication and Division"
117. PRINT "7) Addition and Multiplication"
118. PRINT "8) ALL of them"
119. PRINT "9) QUIT THE TRAINER"
120.  
121. DO
122.     _LIMIT 10
123.     a = VAL(INKEY$)
124. LOOP UNTIL a > 0 AND a < 10
125. IF a = 9 THEN SYSTEM
126.  
127. PRINT
128. PRINT
129. PRINT "How difficult do you wish for this game to be?"
130. PRINT "1) Easy"
131. PRINT "2) Normal"
132. PRINT "3) Hard"
133. PRINT "4) Grueling"
134. DO
135.     _LIMIT 10
136.     b = VAL(INKEY$)
137. LOOP UNTIL b > 0 AND b < 5
138.  
139. PRINT
140. PRINT
141. PRINT "How long a game do you want?"
142. PRINT "1) Very Short"
143. PRINT "2) Short"
144. PRINT "3) Average"
145. PRINT "4) Long"
146. PRINT "5) Bring It On, Long!"
147.  
148. DO
149.     c = VAL(INKEY$)
150. LOOP UNTIL c > 0 AND c < 6
151.  
152. _FONT RST
153. CLS
154. LOCATE 7
155. DO: LOOP UNTIL INKEY$ = "" 'Clear the keyboard buffer
156. PRINT "<LEFT CLICK> TO BEGIN MATH FLASH CARDS!"
157. DO
158.     _LIMIT 10
159.     x = mouseclick
160. LOOP UNTIL x = 1
161.  
162. CLS
163. _FONT WF
164. mode = a: difficulty = b: length = c
165. END SUB
166.  
167.  
168.  
169. SUB DisplayTime
170. _FONT RST
171. COLOR White, Black
172. LOCATE 1, 1000: PRINT GameTime; "LEFT  "
173. _FONT WF
174. END SUB
175.  
176. SUB CountDown
177. GameTime = GameTime - 1
178. IF GameTime <= 0 THEN ShowResults 'Clock has ran out
179.  
180. END SUB
181.  
182. SUB ShowResults
183. Score = 0
184. _AUTODISPLAY
185. CLS , Black
186. _FONT 16
187. COLOR White, Black
188. PRINT "YOUR ANSWER"; TAB(40); "CORRECT ANSWER"
189. FOR i = 1 TO UBOUND(results)
190.     text$ = Num2Str(Results(i).num1)
191.     SELECT CASE Results(i).op
192.         CASE 1: text$ = text$ + " + "
193.         CASE 2: text$ = text$ + " - "
194.         CASE 3: text$ = text$ + " * "
195.         CASE 4: text$ = text$ + " / "
196.     END SELECT
197.  
198.     IF Results(i).correct = -1 THEN
199.         COLOR Green, Black
200.         Correct = Correct + 1
201.         YourText$ = text$ + Num2Str(Results(i).num2) + " = " + Num2Str(Results(i).answer)
202.     ELSE
203.         COLOR Red, Black
204.         Wrong = Wrong + 1
205.         IF Results(i).correct = 1 THEN
206.             YourText$ = text$ + Num2Str(Results(i).num2) + " = " + "SKIPPED"
207.         ELSE
208.             YourText$ = text$ + Num2Str(Results(i).num2) + " = " + Num2Str(Results(i).answer)
209.         END IF
210.     END IF
211.     CorrectText$ = text$ + Num2Str(Results(i).num2) + " = " + Num2Str(Results(i).num3)
212.     PRINT YourText$; TAB(40);
213.     COLOR White, Black
214.     PRINT CorrectText$
215. NEXT
216. PRINT
217. PRINT "You got "; Correct; " correct answers, and "; Wrong; " wrong."
218. PRINT "If this was a test, you would have scored "; INT(100 * (Correct / (i - 1))); "%"
219. ScoreMultiplier = 25 * Difficulty
220. Score = ScoreMultiplier * Correct + ScoreMultiplier * -Wrong
221. PRINT
222. PRINT
223. PRINT "YOUR GAME SCORE IS: "; Score
224. PRINT
225. SELECT CASE Difficulty
226.     CASE 1: file$ = "Easy.txt": diff$ = "EASY"
227.     CASE 2: file$ = "Average.txt": diff$ = "NORMAL"
228.     CASE 3: file$ = "Hard.txt": diff$ = "HARD"
229.     CASE 4: file$ = "Grueling.txt": diff$ = "GRUELING"
230. END SELECT
231. IF _FILEEXISTS(file$) THEN
232.     'life should be good as we have an existing file.
233. ELSE
234.     'if not, then let's make a blank highscore file for the proper difficulty.
235.     OPEN file$ FOR OUTPUT AS #1
236.     FOR i = 1 TO 25
237.         PRINT #1, "None"
238.         PRINT #1, 0
239.         PRINT #1, "None"
240.     NEXT
241.     CLOSE #1
242. END IF
243. OPEN file$ FOR INPUT AS #1
244. DIM person(25) AS STRING, score(25), diff$(25)
245. HS = 0 'no high score until we validate it
246. FOR i = 1 TO 25
247.     LINE INPUT #1, person(i)
248.     INPUT #1, score(i)
249.     LINE INPUT #1, diff$(i)
250.     IF Score > score(i) AND NOT HS THEN
251.         PRINT "CONGRATULATIONS!!  YOU GOT A HIGH SCORE!"
252.         PRINT "What name would you like to be known by? ";
253.         INPUT person$
254.         IF i < 25 THEN person(i + 1) = person(i): score(i + 1) = score(i): diff$(i + 1) = diff$(i)
255.         person(i) = person$: score(i) = Score: diff$(i) = diff$
256.         i = i + 1: HS = -1
257.     END IF
258. NEXT
259. CLOSE #1
260.  
261. PRINT "Press <ANY KEY> to see the "; diff$; " HIGH SCORES"
262. SLEEP
263. CLS
264. PRINT diff$; " HIGH SCORERS"
265. FOR i = 1 TO 25
266.     PRINT person(i); TAB(20); score(i); TAB(40); diff$(i)
267. NEXT
268.  
269. OPEN file$ FOR OUTPUT AS #1
270. FOR i = 1 TO 25
271.     PRINT #1, person(i)
272.     PRINT #1, score(i)
273.     PRINT #1, diff$(i)
274. NEXT
275. CLOSE
276.  
277.  
278. PRINT
279. PRINT "Do the test again? (Y/N)"
280. DO
281.     _LIMIT 10
282.     a$ = UCASE$(INKEY$)
283. LOOP UNTIL a$ = "Y" OR a$ = "N"
284. IF a$ = "Y" THEN
285.     SHELL _DONTWAIT "Untitled.exe"
286. END IF
287. _DELAY 1
288. SYSTEM
289.  
290. END SUB
291.  
292. SUB CheckAnswer (num1, op, num2, answer$)
293. ans = VAL(answer$)
294. SELECT CASE op
295.     CASE Plus: num3 = num1 + num2
296.     CASE Minus: num3 = num1 - num2
297.     CASE Times: num3 = num1 * num2
298.     CASE Divide: num3 = num1 / num2
299. END SELECT
300. QuestionsAsked = UBOUND(results) + 1
301. REDIM _PRESERVE Results(QuestionsAsked) AS ResultsType
302. Results(QuestionsAsked).num1 = num1
303. Results(QuestionsAsked).op = op
304. Results(QuestionsAsked).num2 = num2
305. Results(QuestionsAsked).num3 = num3
306. Results(QuestionsAsked).answer = ans
307.  
308. _FONT RST
309. COLOR White, Black
310. LOCATE 1, 1: PRINT "Last Answer:"
311. IF ans = num3 AND answer$ <> "" THEN
312.     Correct = Correct + 1
313.     GameTime = GameTime + 1 'A bonus to time for each correct answer
314.     COLOR Green, Black
315.     LOCATE 1, 400: PRINT "CORRECT!"
316.     Results(QuestionsAsked).correct = -1
317. ELSE
318.     Wrong = Wrong + 1
319.     GameTime = GameTime - 2 'A penalty to time for each wrong answer
320.     COLOR Red, Black
321.     LOCATE 1, 400: PRINT "WRONG!  "
322.     Results(QuestionsAsked).correct = 0
323.     IF answer$ = "" THEN Results(QuestionsAsked).correct = 1
324. END IF
325. COLOR White, Black
326. _FONT WF
327. DisplayTime
328. _DISPLAY
329. END SUB
330.  
331.  
332. SUB DisplayUserAnswer (answer$)
333. COLOR Black, White
334. LINE (700, 100)-(1100, 300), White, BF
335. top = 125
336. left = (400 - GetPrintWidth(answer$, WF)) / 2 + 700
337. _PRINTSTRING (left, top), answer$
338. END SUB
339.  
340.  
341. SUB GetUserAnswer (answer$)
342. done = 0: answer$ = ""
343. DO
344.     _LIMIT 30
345.     Button = mouseclick
346.     IF Button = 1 THEN 'We have a mouse click somewhere
347.         x = _MOUSEX: y = _MOUSEY
348.         IF y >= 400 AND y <= 600 THEN 'they clicked down where the numbers and OK button are
349.             num = 0
350.             IF x \ 100 = (x + 10) \ 100 THEN num = x \ 100 'they didn't click on the 10 pixel blank space between numbers
351.             IF num > 0 AND num < 12 THEN 'It's a click on either a number or the OK button on the top row
352.                 IF num = 10 THEN num = 0
353.                 IF num = 11 THEN
354.                     done = -1
355.                 ELSE
356.                     answer$ = answer$ + LTRIM$(RTRIM$(STR$(num)))
357.                 END IF
358.             END IF
359.         END IF
360.         IF y >= 610 AND y <= 710 AND x >= 100 AND x <= 1200 THEN done = -1 'Click on the bottom ENTER area
361.     END IF
362.     DisplayUserAnswer answer$
363.     DisplayTime
364.     _DISPLAY
365. LOOP UNTIL done
366. END SUB
367.  
368.  
369.  
370. SUB DrawUserClickAreas
371. FOR i = 1 TO 10
372.     left = 100 * i
373.     LINE (left, 400)-(left + 90, 600), Yellow, BF
374.     COLOR Black, 0
375.     _PRINTSTRING (left + 10, 425), Num2Str$(i MOD 10)
376. NEXT
377. LINE (100, 610)-(1200, 710), Green, BF
378. LINE (1100, 400)-(1200, 710), Green, BF
379. _PRINTSTRING (425, 595), "ENTER"
380. END SUB
381.  
382.  
383.  
384. SUB DrawCard (num1, operator, num2) 'Pass it our 3 numbers like 3, plus, 3 would be 3 + 3 = ?
385. COLOR Red, 0
386. LINE (100, 100)-(650, 300), White, BF
387. text$ = Num2Str(num1)
388. SELECT CASE operator
389.     CASE Plus: text$ = text$ + "+"
390.     CASE Minus: text$ = text$ + "-"
391.     CASE Times: text$ = text$ + "*"
392.     CASE Divide: text$ = text$ + "/"
393. END SELECT
394. text$ = text$ + Num2Str(num2) + "="
395. top = 125
396. left = (550 - GetPrintWidth(text$, WF)) / 2 + 100
397. _PRINTSTRING (left, top), text$
398. END SUB
399.  
400. FUNCTION Num2Str$ (num)
401. Num2Str$ = LTRIM$(RTRIM$(STR$(num)))
402. END FUNCTION
403.  
404. FUNCTION GetPrintWidth (text AS STRING, fonthandle)
405. w = _WIDTH: h = _HEIGHT
406. dc = _DEFAULTCOLOR: bg = _BACKGROUNDCOLOR
407. d = _DEST: s = _SOURCE
408. t = _NEWIMAGE(w, h, 32)
409. _DEST t: _SOURCE t
410. _FONT fonthandle
411. COLOR _RGB32(255, 0, 0), _RGB32(255, 255, 255)
412. PRINT text;
413. DIM m AS _MEM
414. m = _MEMIMAGE(t)
415. p = 0 'pointer
416. DO
417.     _MEMGET m, m.OFFSET + p, c 'Get our color
418.     p = p + 4 'increase 4 as we're working with 4-byte long values for RGBA color
419.     GetPrintWidth = GetPrintWidth + 1
420. LOOP UNTIL NOT c 'until we don't have no color no more
421. _MEMFREE m
422. _FREEIMAGE t
423. _DEST d: _SOURCE s
424. END FUNCTION
425.  
426. FUNCTION mouseclick%
427. DO WHILE _MOUSEINPUT 'check mouse status
428.     scroll% = scroll% + _MOUSEWHEEL ' if scrollwheel changes, watch the change here
429.     IF _MOUSEBUTTON(1) THEN 'left mouse pushed down
430.         speedup = 1
431.     ELSEIF _MOUSEBUTTON(2) THEN 'right mouse pushed down
432.         speedup = 2
433.     ELSEIF _MOUSEBUTTON(3) THEN 'middle mouse pushed down
434.         speedup = 3
435.     END IF
436.     IF speedup THEN 'buton was pushed down
437.         mouseclickxxx1% = _MOUSEX: mouseclickyyy1% = _MOUSEY 'see where button was pushed down at
438.         DO WHILE _MOUSEBUTTON(speedup) 'while button is down
439.             i% = _MOUSEINPUT
440.         LOOP 'finishes when button is let up
441.         IF mouseclickxxx1% >= _MOUSEX - 2 AND mouseclickxxx1% <= _MOUSEX + 2 AND mouseclickyyy1% >= _MOUSEY - 2 AND mouseclickyyy1% <= _MOUSEY + 2 THEN 'if mouse hasn't moved (ie  clicked down, dragged somewhere, then released)
442.             mouseclick% = speedup
443.         ELSE
444.             mouseclick% = 0
445.         END IF
446.     END IF
447. LOOP
448. IF scroll% < 0 THEN mouseclick% = 4
449. IF scroll% > 0 THEN mouseclick% = 5
450. END FUNCTION
451.  

A simple little game which kids can use to help them learn basic math.  Does addition, subtraction, multiplication, and division. 

Just copy and paste into the QB64 IDE, compile and you're good to go!  :)

[Todd_Bevins]

Hi I just found this and think it looks great.  Thanks for posting it and I am anxious to dissect this to understand how you did everything.  :)

[bplus]

Hey I remember working on this!

_TITLE "Flash Card Math Trainer by Steve McNeil, 2017-10-28 fix by bplus" ' >>> yeah for the +
' >>> all >>>>>>> and <<<<<< comments are from bplus
' >>> 2017-10-28 This fix does not involve SHELL or RUN, just an outer loop
' >>> that sets up a new test, then the inner loop conducts the test.
' >>> As it should be done! ;-))  ;D
' >>> PS a credit to Steve that I can follow his code enough to fix it.

' >>> Now who wants to fix all the text at extreme left side of the screen in setups for test?