Simple demo of 3 different way to make graphic in QB64

[TempodiBasic]

Hi
thanks to Bplus for sharing his Tangram 1.
thanks to Galleon to leave QB64 to QB64 community
thanks to QB64 team developers to maintain QB64

here I post a simple demo that shows 3 different ways to do graphic using QB64.
If you find of interest here you can see an array with 3 dimensions.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. SCREEN _NEWIMAGE(1280, 740, 32)
4.  
5. _TITLE "Tangram 1 by Bplus" 'b+ 2020-11-09 & 10
6. _DELAY .5
7. _SCREENMOVE 70, 5 'sorry this works for my screen, yours is likely different
8.  
9. ' ============================= Instructions ==================================================
10. '
11. ' The little dot on the pieces are handles for dragging pieces or rotating them with mousewheel.
12. ' Don't drag a handle near another or the pieces will stick together, press r if they do.
13. '
14. '=================================================================================================
15.  
16. CONST sqr2d2 = SQR(2) / 2 ' for converting lengths with 45/90 triangles.
17.  
18. CONST True = -1, False = 0, X = 1, Y = 2, Escape = 27, Space = 32, Rmax = 114, Rmin = 82
19. CONST Normal = 1, MapTriangle = 2, Opengl = 3, White = _RGB32(255), Up = 18432, Down = 20480
20.  
21.  
22. TYPE objType
23.     cx AS SINGLE
24.     cy AS SINGLE
25.     lenBase AS SINGLE
26.     rotDegrees AS SINGLE
27.     colr AS _UNSIGNED LONG
28.     typ AS LONG
29. END TYPE
30.  
31.  
32. DIM SHARED GlInit AS INTEGER, GrActive AS INTEGER
33. DIM SHARED VertObj(1 TO 7, 1 TO 2, 1 TO 5) AS SINGLE
34. ' vo(number of object, cohordinate, value of vertex with 5  as center cohordinate) ' TdB
35.  
36. REDIM SHARED obj(1 TO 7) AS objType
37. REDIM SHARED copy(1 TO 7) AS objType
38.  
39. DIM mx AS SINGLE, my AS SINGLE, mb AS SINGLE, mw AS SINGLE
40. DIM i AS INTEGER, Kb AS INTEGER, mode AS STRING
41.  
42.  
43. _FONT 16
44. Initialize
45.  
46. CLS
47. info
48. CLS
49. message "Tangram 1 Normal mode: press space to change graphic", 0, 0
50. _DISPLAY
51. _DELAY 2
52.  
53. DO
54.     CLS
55.     Kb = _KEYHIT
56.     IF Kb = Escape THEN TheEND
57.     IF Kb = Space THEN
58.         IF GrActive < Opengl THEN GrActive = GrActive + 1 ELSE GrActive = Normal ' TdB
59.         IF GrActive = 1 THEN
60.             mode = "Tangram 1 Normal mode: press space to change graphic"
61.         ELSEIF GrActive = MapTriangle THEN
62.             mode = "Tangram 1 MapTriangle mode: press space to change graphic"
63.         ELSEIF GrActive = 3 THEN
64.             mode = "Tangram 1 OpenGl mode: press space to change graphic"
65.             GrActive = 5
66.         END IF
67.         '    infoscreen
68.         CLS
69.         message mode, 0, 0
70.         _DISPLAY
71.         _DELAY 2
72.         IF GrActive = 5 THEN GrActive = 3
73.     END IF
74.     IF Kb = Rmax OR Kb = Rmin THEN 'reset or fix
75.         FOR i = 1 TO 7
76.             obj(i) = copy(i)
77.         NEXT
78.     END IF
79.     WHILE _MOUSEINPUT
80.         mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1): mw = _MOUSEWHEEL
81.         FOR i = 1 TO 7
82.             IF _HYPOT(obj(i).cx - mx, obj(i).cy - my) < 20 THEN ' mouse is down near a piece center
83.                 IF mb THEN obj(i).cx = mx: obj(i).cy = my
84.                 IF mw THEN obj(i).rotDegrees = obj(i).rotDegrees + mw
85.             END IF
86.         NEXT
87.     WEND
88.  
89.     FOR i = 1 TO 7
90.         drawObj i
91.     NEXT i
92.  
93.     _DISPLAY
94.     _LIMIT 10 'peharps we must change this fps to 30
95. LOOP
96. END
97.  
98. '-------------SUBs/Functions area-------------------
99. SUB TheEND
100.     DIM k AS STRING
101.     CLS
102.     message "Do you really quit? Y/N", 0, 0
103.     _DISPLAY
104.     WHILE k <> "Y" AND k <> "N": k = UCASE$(INKEY$): WEND
105.     IF k = "Y" THEN END ELSE CLS
106. END SUB
107.  
108. SUB info
109.     message "TANGRAM 1   by Bplus", 0, 5
110.     message " Usage: press r or R reset, press spacebar to change graphic mode", -1, 11
111.     message "        use Left Mouse Button to drag and drop the pieces by circles", -1, 12
112.     message "        use Mouse Wheel to rotate the pieces while mouse points to circles", -1, 13
113.     message "Press a key to continue...", 0, 18
114.     _DISPLAY
115.     WHILE INKEY$ = "": WEND
116. END SUB
117.  
118. SUB message (t AS STRING, Xt AS INTEGER, Yt AS INTEGER)
119.     IF LEN(t) THEN
120.         IF Xt = -1 THEN
121.             Xt = 1
122.         ELSEIF Xt = 0 THEN
123.             Xt = INT(((_WIDTH / _FONTWIDTH(_FONT)) - LEN(t)) / 2)
124.         ELSEIF Xt = -2 THEN
125.             Xt = INT(_WIDTH / _FONTWIDTH(_FONT)) - LEN(t)
126.         END IF
127.         IF Yt = -1 THEN
128.             Yt = 1
129.         ELSEIF Yt = 0 THEN
130.             Yt = INT((_HEIGHT / _FONTHEIGHT(_FONT)) / 2)
131.         ELSEIF Yt = -2 THEN
132.             Yt = INT(_HEIGHT / _FONTHEIGHT(_FONT))
133.         END IF
134.         LOCATE Yt, Xt
135.         PRINT t;
136.     END IF
137. END SUB
138.  
139. SUB drawObj (i AS LONG)
140.     SELECT CASE obj(i).typ
141.         CASE 1 'tri45
142.             tri45 i
143.         CASE 2 ' square
144.             square i
145.         CASE 3 ' parallel
146.             parallel i
147.     END SELECT
148.  
149.     VertObj(i, X, 5) = obj(i).cx ' TdB
150.     VertObj(i, Y, 5) = obj(i).cy ' TdB
151.     CIRCLE (VertObj(i, X, 5), VertObj(i, Y, 5)), 2, &HFF000000 ' here it draws the little circle
152.     CIRCLE (VertObj(i, X, 5), VertObj(i, Y, 5)), 3, &HFFFFFFFF ' so we can use _GL_POINTS
153.  
154. END SUB
155.  
156. SUB tri45 (i AS SINGLE)
157.     DIM rotRad AS SINGLE, bx AS SINGLE, by AS SINGLE
158.  
159.     rotRad = _D2R(obj(i).rotDegrees)
160.     bx = obj(i).cx + .25 * obj(i).lenBase * COS(_PI(.5) + rotRad)
161.     by = obj(i).cy + .25 * obj(i).lenBase * SIN(_PI(.5) + rotRad)
162.     VertObj(i, X, 1) = bx + .5 * obj(i).lenBase * COS(_PI + rotRad)
163.     VertObj(i, Y, 1) = by + .5 * obj(i).lenBase * SIN(_PI + rotRad)
164.     VertObj(i, X, 2) = bx + .5 * obj(i).lenBase * COS(rotRad)
165.     VertObj(i, Y, 2) = by + .5 * obj(i).lenBase * SIN(rotRad)
166.     VertObj(i, X, 3) = obj(i).cx + .25 * obj(i).lenBase * COS(_PI(1.5) + rotRad)
167.     VertObj(i, Y, 3) = obj(i).cy + .25 * obj(i).lenBase * SIN(_PI(1.5) + rotRad)
168.  
169.     IF GrActive = 1 THEN
170.         ntri VertObj(i, X, 1), VertObj(i, Y, 1), VertObj(i, X, 2), VertObj(i, Y, 2), VertObj(i, X, 3), VertObj(i, Y, 3), obj(i).colr ' here we must use _GL_TRIANGLES
171.     ELSEIF GrActive = 2 THEN
172.         ftri VertObj(i, X, 1), VertObj(i, Y, 1), VertObj(i, X, 2), VertObj(i, Y, 2), VertObj(i, X, 3), VertObj(i, Y, 3), obj(i).colr ' here we must use _GL_TRIANGLES
173.     END IF
174. END SUB
175.  
176. SUB square (i AS SINGLE) ' 1 square
177.     DIM in AS INTEGER
178.     DIM rotRad AS SINGLE
179.     rotRad = _D2R(obj(i).rotDegrees)
180.     FOR in = 1 TO 4
181.         VertObj(i, X, in) = obj(i).cx + obj(i).lenBase * sqr2d2 * COS(_PI / 2 * in + rotRad)
182.         VertObj(i, Y, in) = obj(i).cy + obj(i).lenBase * sqr2d2 * SIN(_PI / 2 * in + rotRad)
183.     NEXT
184.  
185.     ftri VertObj(i, X, 1), VertObj(i, Y, 1), VertObj(i, X, 2), VertObj(i, Y, 2), VertObj(i, X, 3), VertObj(i, Y, 3), obj(i).colr ' here we must use _GL_QUADS
186.     ftri VertObj(i, X, 3), VertObj(i, Y, 3), VertObj(i, X, 4), VertObj(i, Y, 4), VertObj(i, X, 1), VertObj(i, Y, 1), obj(i).colr
187. END SUB
188.  
189. SUB parallel (i AS SINGLE)
190.  
191.     DIM rotRad AS SINGLE, arm AS SINGLE
192.  
193.     rotRad = _D2R(obj(i).rotDegrees)
194.     arm = .5 * obj(i).lenBase * sqr2d2
195.     VertObj(i, X, 1) = obj(i).cx + arm * COS(_PI(1.25) + rotRad)
196.     VertObj(i, Y, 1) = obj(i).cy + arm * SIN(_PI(1.25) + rotRad)
197.     VertObj(i, X, 2) = VertObj(i, X, 1) + obj(i).lenBase * COS(0 + rotRad)
198.     VertObj(i, Y, 2) = VertObj(i, Y, 1) + obj(i).lenBase * SIN(0 + rotRad)
199.     VertObj(i, X, 3) = obj(i).cx + arm * COS(_PI(.25) + rotRad)
200.     VertObj(i, Y, 3) = obj(i).cy + arm * SIN(_PI(.25) + rotRad)
201.     VertObj(i, X, 4) = VertObj(i, X, 3) + obj(i).lenBase * COS(_PI + rotRad)
202.     VertObj(i, Y, 4) = VertObj(i, Y, 3) + obj(i).lenBase * SIN(_PI + rotRad)
203.  
204.     ftri VertObj(i, X, 1), VertObj(i, Y, 1), VertObj(i, X, 2), VertObj(i, Y, 2), VertObj(i, X, 3), VertObj(i, Y, 3), obj(i).colr 'here we must use _GL_QUADS
205.     ftri VertObj(i, X, 3), VertObj(i, Y, 3), VertObj(i, X, 4), VertObj(i, Y, 4), VertObj(i, X, 1), VertObj(i, Y, 1), obj(i).colr
206. END SUB
207.  
208. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
209.     DIM D AS LONG
210.     STATIC a&
211.     D = _DEST
212.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
213.     _DEST a&
214.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
215.     PSET (0, 0), K
216.     _BLEND a& '<<<< new 2019-12-16 fix
217.     _DEST D
218.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
219. END SUB
220.  
221. SUB ntri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
222.     LINE (x1, y1)-(x2, y2), K
223.     LINE (x2, y2)-(x3, y3), K
224.     LINE (x3, y3)-(x1, y1), K
225.     PAINT ((x1 + x2 + x3) / 3, (y1 + y2 + y3) / 3), K
226. END SUB
227.  
228. SUB Initialize
229.  
230.     obj(1).typ = 1: obj(1).cx = _WIDTH / 2 - 125: obj(1).cy = _HEIGHT / 2: obj(1).lenBase = 500: obj(1).rotDegrees = 90: obj(1).colr = &HFFFF8800
231.     drawObj 1
232.  
233.     obj(2).typ = 1: obj(2).cx = _WIDTH / 2: obj(2).cy = _HEIGHT / 2 - 125: obj(2).lenBase = 500: obj(2).rotDegrees = 180: obj(2).colr = &HFF008800
234.     drawObj 2
235.  
236.     obj(3).typ = 1: obj(3).cx = _WIDTH / 2 - 2: obj(3).cy = _HEIGHT / 2 + 65: obj(3).lenBase = 250: obj(3).rotDegrees = 0: obj(3).colr = &HFF000066
237.     drawObj 3
238.  
239.     obj(4).typ = 1: obj(4).cx = _WIDTH / 2 + 125 + 64: obj(4).cy = _HEIGHT / 2 - 125: obj(4).lenBase = 250: obj(4).rotDegrees = 270: obj(4).colr = &HFF00DDDD
240.     drawObj 4
241.  
242.     obj(5).typ = 1: obj(5).cx = _WIDTH / 2 + 125 + 64: obj(5).cy = _HEIGHT / 2 + 125 + 62.5: obj(5).lenBase = 500 * sqr2d2: obj(5).rotDegrees = 135
243.     obj(5).colr = &HFF880000
244.     drawObj 5
245.  
246.     obj(6).typ = 2: obj(6).cx = _WIDTH / 2 + 125: obj(6).cy = _HEIGHT / 2: obj(6).lenBase = 250 * sqr2d2: obj(6).rotDegrees = 0
247.     obj(6).colr = &HFFFFFF00
248.     drawObj 6
249.  
250.     obj(7).typ = 3: obj(7).cx = _WIDTH / 2 - 62.5: obj(7).cy = _HEIGHT / 2 + 125 + 62.5: obj(7).lenBase = 250: obj(7).rotDegrees = 0
251.     obj(7).colr = &HFF0000FF
252.     drawObj 7
253.  
254.     DIM i AS INTEGER
255.  
256.     FOR i = 1 TO 7 'make a copy of settings in case a handle gets stuck on another
257.         copy(i) = obj(i)
258.     NEXT
259.     GlInit = True ' TdB
260.     GrActive = Normal ' TdB
261.  
262. END SUB
263.  
264.  
265. '---------------OpenGL AREA---------------------------
266. SUB _GL ()
267.     DIM i AS INTEGER
268.     IF GlInit = True THEN InitGl
269.     IF GrActive <> Opengl THEN EXIT SUB
270.  
271.     _glClear _GL_COLOR_BUFFER_BIT
272.     ' here it draws GL objects
273.     FOR i = 1 TO 7
274.         drawObj i
275.         IF obj(i).typ = 1 THEN
276.             GLTri45 i
277.         ELSEIF obj(i).typ = 2 THEN
278.             GLQuadr i
279.         ELSEIF obj(i).typ = 3 THEN
280.             GLParall i
281.         END IF
282.         DIM sRc AS INTEGER, sGc AS INTEGER, sBc AS INTEGER, sAc AS INTEGER
283.         DIM glRc AS SINGLE, glGc AS SINGLE, glBc AS SINGLE, glAc AS SINGLE
284.         sRc = _RED32(White)
285.         sGc = _GREEN32(White)
286.         sBc = _BLUE32(White)
287.         sAc = _ALPHA32(White)
288.         glRc = Proportion(0, 255, 0, 1, sRc)
289.         glGc = Proportion(0, 255, 0, 1, sGc)
290.         glBc = Proportion(0, 255, 0, 1, sBc)
291.         glAc = Proportion(0, 255, 0, 1, sAc)
292.         _glColor4f glRc, glGc, glBc, glAc
293.  
294.         _glPointSize 8
295.         _glBegin _GL_POINTS
296.         _glVertex2f Proportion(0, 1280, -1, 1, VertObj(i, X, 5)), Proportion(0, 740, 1, -1, VertObj(i, Y, 5))
297.         _glEnd
298.         _glPointSize 1
299.     NEXT
300.     _glFlush
301. END SUB
302.  
303. SUB GLQuadr (i AS INTEGER)
304.     DIM a AS INTEGER, sRc AS INTEGER, sGc AS INTEGER, sBc AS INTEGER, sAc AS INTEGER
305.     DIM glRc AS SINGLE, glGc AS SINGLE, glBc AS SINGLE, glAc AS SINGLE
306.     sRc = _RED32(obj(i).colr)
307.     sGc = _GREEN32(obj(i).colr)
308.     sBc = _BLUE32(obj(i).colr)
309.     sAc = _ALPHA32(obj(i).colr)
310.     glRc = Proportion(0, 255, 0, 1, sRc)
311.     glGc = Proportion(0, 255, 0, 1, sGc)
312.     glBc = Proportion(0, 255, 0, 1, sBc)
313.     glAc = Proportion(0, 255, 0, 1, sAc)
314.     _glColor4f glRc, glGc, glBc, glAc
315.     _glBegin _GL_QUADS
316.     FOR a = 1 TO 4 STEP 1
317.         _glVertex2f Proportion(0, 1280, -1, 1, VertObj(i, X, a)), Proportion(0, 740, 1, -1, VertObj(i, Y, a))
318.     NEXT a
319.     _glEnd
320. END SUB
321.  
322. SUB GLParall (i AS INTEGER)
323.     DIM a AS INTEGER, sRc AS INTEGER, sGc AS INTEGER, sBc AS INTEGER, sAc AS INTEGER
324.     DIM glRc AS SINGLE, glGc AS SINGLE, glBc AS SINGLE, glAc AS SINGLE
325.     sRc = _RED32(obj(i).colr)
326.     sGc = _GREEN32(obj(i).colr)
327.     sBc = _BLUE32(obj(i).colr)
328.     sAc = _ALPHA32(obj(i).colr)
329.     glRc = Proportion(0, 255, 0, 1, sRc)
330.     glGc = Proportion(0, 255, 0, 1, sGc)
331.     glBc = Proportion(0, 255, 0, 1, sBc)
332.     glAc = Proportion(0, 255, 0, 1, sAc)
333.     _glColor4f glRc, glGc, glBc, glAc
334.  
335.     _glBegin _GL_QUADS
336.     FOR a = 1 TO 4 STEP 1
337.         _glVertex2f Proportion(0, 1280, -1, 1, VertObj(i, X, a)), Proportion(0, 740, 1, -1, VertObj(i, Y, a))
338.     NEXT a
339.     _glEnd
340. END SUB
341.  
342. SUB GLTri45 (i AS INTEGER)
343.     DIM a AS INTEGER, sRc AS INTEGER, sGc AS INTEGER, sBc AS INTEGER, sAc AS INTEGER
344.     DIM glRc AS SINGLE, glGc AS SINGLE, glBc AS SINGLE, glAc AS SINGLE
345.     sRc = _RED32(obj(i).colr)
346.     sGc = _GREEN32(obj(i).colr)
347.     sBc = _BLUE32(obj(i).colr)
348.     sAc = _ALPHA32(obj(i).colr)
349.     glRc = Proportion(0, 255, 0, 1, sRc)
350.     glGc = Proportion(0, 255, 0, 1, sGc)
351.     glBc = Proportion(0, 255, 0, 1, sBc)
352.     glAc = Proportion(0, 255, 0, 1, sAc)
353.     _glColor4f glRc, glGc, glBc, glAc
354.  
355.     _glBegin _GL_TRIANGLES
356.     FOR a = 1 TO 3 STEP 1
357.         _glVertex2f Proportion(0, 1280, -1, 1, VertObj(i, X, a)), Proportion(0, 740, 1, -1, VertObj(i, Y, a))
358.     NEXT a
359.     _glEnd
360. END SUB
361.  
362. SUB InitGl
363.     _glViewport 0, 0, 1280, 740
364.     _glClearColor 0, 0, 0, 1
365. END SUB
366.  
367. FUNCTION Proportion (min1, max1, min2, max2, value)
368.     ' min1: max1 = min2:max2= value: X
369.     ' (max1-min1): Value = (max2-min2) : X
370.     ' X = ((max2-min2) * value)/ (max1-min1)
371.     Proportion = (((max2 - min2) * value) / (max1 - min1)) + min2
372. END FUNCTION
373.  

At beginning I have tried to use the title of the window as a label for feedback to user, but I have had so many troubles that I have lost a week of free time! With the suggestion on discord I have found another way, using splashscreen message.
In this demo the 3 different modes of making graphic are used separately, but if you see in code of others you can see also how to use them together.

[bplus]

For the record B+ didn't do the above, it's a mod that doesn't seem to work for me anyway.

[TempodiBasic]

So  now we know that the added or modified code doesn't work on your machine!
If someoneelse have a similar result running this code we can focus on the few commands added by me to your opera to catch the mistake or the glitch!
Sorry to waste your opera, I like so much that I have thought to use it for show different ways of graphic output. Its original MapTriangle use is very explicative! The original code is linear and easy to read.
Again thanks to share it!

[SMcNeill]

If I change the limit to 30, the program works.  A limit 10 just causes it to go unresponsive and freeze before ever starting.

And why the heck it's having that reaction is beyond me.  All the following code comes before the LIMIT, and shouldn't be affected by it at all:

Code: Text: [Select]

1. Initialize
2.  
3. CLS
4. info
5. CLS
6. message "Tangram 1 Normal mode: press space to change graphic", 0, 0
7. _DISPLAY
8. _DELAY 2

There's display routines in there, and pauses, and user needed keypresses....  And all these things should trigger before that LIMIT ever does anything whatsoever...

So why the heck does changing the limit from 10 to 30 allow the program to work, when it won't otherwise???

[bplus]

Right it doesn't make sense for 30 to work better than the hanging.

Steve should get best answer for pointing to _LIMIT 30. It now works fine on my system. :)

I am sorry I missed this comment:

Code: QB64: [Select]

1. _LIMIT 10 'peharps we must change this fps to 30
2.  

Yes perhaps we should :)

[TempodiBasic]

@Steve, Bplus

Thanks for feedbacks

I love this community!

PS Bplus passes the laurel to Steve so I change the Green Best answer