Using Win32 API functions to see date when file was created, accessed, modified.

[Dav]

Playing around with (and learning) Win32 API functions some more.  Here's a way to retrieve a files created data, and modified and accessed date.  Not 100% sure I'm doing it right, but in my testing here it seems to work when comparing results to what my windows file managers reports on the files.  I included the SetFileTime function in the code too, but I didn't use it here.

WINDOWS ONLY CODE.

- Dav

Code: QB64: [Select]

1. '============
2. 'FILETIME.BAS (FOR WINDOWS ONLY)
3. '============
4. 'Win32 API fucntions to get/set time info of a file.
5. 'Shows when file was created, modified, accessed.
6. 'QB64 code by Dav, AUG/2020
7.  
8. 'All API info found on this page:
9. 'http://allapi.mentalis.org/apilist/apilist.php
10.  
11. CONST OPEN_EXISTING = 3
12.  
13. TYPE FILETIME
14.     dwLowDateTime AS LONG
15.     dwHighDateTime AS LONG
16. END TYPE
17.  
18. TYPE SYSTEMTIME
19.     wYear AS INTEGER
20.     wMonth AS INTEGER
21.     wDayOfWeek AS INTEGER
22.     wDay AS INTEGER
23.     wHour AS INTEGER
24.     wMinute AS INTEGER
25.     wSecond AS INTEGER
26.     wMilliseconds AS INTEGER
27. END TYPE
28.  
29. DECLARE DYNAMIC LIBRARY "kernel32"
30.     FUNCTION GetFileTime& (BYVAL hFile&, lpCreationTime AS FILETIME, lpLastAccessTime AS FILETIME, lpLastWriteTime AS FILETIME)
31.     FUNCTION SetFileTime& (BYVAL hFile&, lpCreationTime AS FILETIME, lpLastAccessTime AS FILETIME, lpLastWriteTime AS FILETIME)
32.     FUNCTION CreateFileA& (lpFileName$, BYVAL dwDesiredAccess&, BYVAL dwShareMode&, BYVAL lpSecurityAttributes&, BYVAL dwCreationDisposition&, BYVAL dwFlagsAndAttributes&, BYVAL hTemplateFile&)
33.     FUNCTION CloseHandle& (BYVAL hObject AS LONG)
34.     FUNCTION FileTimeToSystemTime& (lpFileTime AS FILETIME, lpSystemTime AS SYSTEMTIME)
35.     FUNCTION FileTimeToLocalFileTime& (lpFileTime AS FILETIME, lpLocalFileTime AS FILETIME)
36. END DECLARE
37.  
38. DIM F1 AS FILETIME, F2 AS FILETIME, F3 AS FILETIME, SysTime AS SYSTEMTIME
39.  
40.  
41. fil$ = "qb64.exe" 'use qb64.exe for a test
42. PRINT "Results for file: "; fil$
43. PRINT "----------------"
44.  
45. 'create file handle (using open as existing, so not creating a file)
46. hFile = CreateFileA(fil$, 0, 0, 0, OPEN_EXISTING, 0, 0)
47.  
48. 'Get file's time info
49. x& = GetFileTime(hFile, F1, F2, F3)
50.  
51. IF x& = -1 THEN
52.     PRINT "Invalid handle error. File not opened.": END
53. END IF
54.  
55. 'See when file was created.....
56. x& = FileTimeToLocalFileTime(F1, F1) 'Convert file time to local file time
57. x& = FileTimeToSystemTime(F1, SysTime) 'Convert file time to system file time
58. PRINT "Created : "; SysTime.wMonth; "/"; SysTime.wDay; "/"; SysTime.wYear
59.  
60. 'See when file was last accessed.....
61. x& = FileTimeToLocalFileTime(F2, F1) 'Convert file time to local file time
62. x& = FileTimeToSystemTime(F1, SysTime) 'Convert file time to system file time
63. PRINT "Accessed: "; SysTime.wMonth; "/"; SysTime.wDay; "/"; SysTime.wYear
64.  
65. 'See when file was last modified.....
66. x& = FileTimeToLocalFileTime(F3, F1) 'Convert file time to local file time
67. x& = FileTimeToSystemTime(F1, SysTime) 'Convert file time to system file time
68. PRINT "Modified: "; SysTime.wMonth; "/"; SysTime.wDay; "/"; SysTime.wYear
69.  
70. 'close file handle
71. x& = CloseHandle(hFile)
72.  
73.  

[Dav]

Sorry, Looks like this is already in the wiki under libraries - and showing a better example. You can delete this post if you want.

- Dav