Stars w/ Time Screensaver

[CloudZimmermann]

Program: Stars w/ Time Screensaver
Creator:  Cloud Zimmermann
Date:      1/7/2020

Code: QB64: [Select]

1. ' Program: Stars w/ Time
2. ' Creator: Cloud Zimmermann
3. ' Created: 1/7/2020
4.  
5. DECLARE SUB DrawDigit (d AS INTEGER, p AS INTEGER, x AS INTEGER, y AS INTEGER)
6. DECLARE SUB DrawClock (clock AS ANY)
7. CLS
8. SCREEN 7, 0, 0, 1
9.  
10. quit% = 0
11.  
12. TYPE StarType
13.     x AS INTEGER
14.     y AS INTEGER
15.     z AS INTEGER
16.     c AS INTEGER
17. END TYPE
18.  
19. TYPE ClockType
20.     x AS INTEGER
21.     y AS INTEGER
22.     t AS STRING * 12
23.     c AS INTEGER
24.     dx AS INTEGER
25.     dy AS INTEGER
26. END TYPE
27.  
28. DIM clock AS ClockType
29. clock.x = 5
30. clock.y = 5
31. clock.c = 8
32. clock.dx = 1
33. clock.dy = 1
34.  
35. count% = 30
36.  
37. DIM Star(1 TO count%) AS StarType
38.  
39. RANDOMIZE TIMER
40. FOR i% = 1 TO count%
41.     Star(i%).x = INT(RND * 320) + 1
42.     Star(i%).y = INT(RND * 200) + 1
43.     Star(i%).z = INT(RND * 4) + INT(RND * 1) + 1
44.     Star(i%).c = INT(RND * 16) + 1
45. NEXT i%
46.  
47.  
48.  
49. WHILE quit% = 0
50.     CLS
51.     IF INKEY$ <> "" THEN quit% = 1
52.  
53.     FOR i% = 1 TO count%
54.         Star(i%).y = Star(i%).y + Star(i%).z
55.         PSET (Star(i%).x, Star(i%).y), Star(i%).c
56.         IF Star(i%).y > 200 THEN Star(i%).y = Star(i%).y - 200
57.     NEXT i%
58.  
59.     'LOCATE 5, 5: COLOR 3
60.     'PRINT TIME$
61.  
62.     CALL DrawClock(clock)
63.  
64.     PCOPY 0, 1
65.     _LIMIT 60
66.  
67. WEND
68.  
69. SUB DrawClock (clock AS ClockType)
70.     clock.x = clock.x + clock.dx
71.     clock.y = clock.y + clock.dy
72.  
73.     tmp$ = TIME$
74.     FOR pointer% = 1 TO LEN(tmp$)
75.         digit% = VAL(MID$(tmp$, pointer%, 1))
76.         CALL DrawDigit(digit%, pointer%, clock.x, clock.y)
77.     NEXT pointer%
78.  
79.     'PSET (clock.x, clock.y), clock.c
80.  
81.     IF clock.x <= 0 OR clock.x >= 320 - 46 THEN clock.dx = -clock.dx
82.     IF clock.y <= 0 OR clock.y >= 200 - 6 THEN clock.dy = -clock.dy
83. END SUB
84.  
85. SUB DrawDigit (d AS INTEGER, p AS INTEGER, x AS INTEGER, y AS INTEGER)
86.     tmp$ = "BC11M" + STR$(x) + "," + STR$(y) + " BM+" + STR$(5 * p) + ",0"
87.     IF d = 1 THEN tmp$ = tmp$ + "BM+3,0D4"
88.     IF d = 2 THEN tmp$ = tmp$ + "R3D2L3D2R3"
89.     IF d = 3 THEN tmp$ = tmp$ + "R3D2L3R3D2L3"
90.     IF d = 4 THEN tmp$ = tmp$ + "D2R3U2D4"
91.     IF d = 5 THEN tmp$ = tmp$ + "BM+3,0L3D2R3D2L3"
92.     IF d = 6 THEN tmp$ = tmp$ + "BM+3,0L3D4R3U2L3"
93.     IF d = 7 THEN tmp$ = tmp$ + "R3D4"
94.     IF d = 8 THEN tmp$ = tmp$ + "R3D4L3U4D2R3"
95.     IF d = 9 THEN tmp$ = tmp$ + "R3L3D2R3U2D4"
96.     IF d = 0 THEN tmp$ = tmp$ + "R3D4L3U4"
97.     DRAW tmp$
98. END SUB
99.  

[Richard Frost]

Why are all the stars falling? 
Is it the end of the Universe? 
And why do they have so many colors?
Are they going to a costume party?

The clock needs to be a little bigger before a cat will chase it.

[Cobalt]

Pretty neat!

Have you given any thought to maybe giving random values to the clocks movement so it goes faster or slower around the screen?  And you know if you made the 'stars' shades of blue it would look like rain! and you could add random flashes like lightning! Could call it the "Rainy Day Screen Saver"!

[Cobalt]

well went ahead and mocked it up.

hope you don't mind too much. Commented most everything I changed and did.

Code: QB64: [Select]

1. ' Program: Stars w/ Time
2. ' Creator: Cloud Zimmermann
3. ' Created: 1/7/2020
4.  
5. 'slight modification by Cobalt on 5/16/2020 to make it a rainy day. everything but the lightning :-(
6.  
7. DECLARE SUB DrawDigit (d AS INTEGER, p AS INTEGER, x AS INTEGER, y AS INTEGER)
8. DECLARE SUB DrawClock (clock AS ANY)
9. CLS
10. 'SCREEN 7, 0, 0, 1
11.  
12. 'lets cover the basics!
13. CONST TRUE = -1, FALSE = NOT TRUE
14. 'lets make the screen a little bigger and give ourselves more color room.
15. SCREEN _NEWIMAGE(640, 480, 32)
16.  
17. 'make a temp layer to draw upon, to simulate screen 7 layers
18. Temp& = _NEWIMAGE(640, 480, 32)
19.  
20. _DELAY .1 'wait a moment for screen to materialize!
21. _TITLE "Rainy Day Screen Saver!"
22.  
23. 'move this here to cover new random items
24. RANDOMIZE TIMER
25.  
26. quit% = 0
27.  
28. 'swapping our variable types to allow for more variation
29. TYPE StarType
30.  x AS SINGLE
31.  y AS SINGLE
32.  z AS SINGLE
33.  c AS _UNSIGNED LONG
34. END TYPE
35.  
36. TYPE ClockType
37.  x AS SINGLE
38.  y AS SINGLE
39.  t AS STRING * 12
40.  c AS _UNSIGNED LONG
41.  dx AS SINGLE
42.  dy AS SINGLE
43. END TYPE
44.  
45.  
46. DIM clock AS ClockType
47. 'lets allow the clock to start in other locations
48. clock.x = INT(RND * 550) + 5
49. clock.y = INT(RND * 460) + 5
50. clock.c = _RGB32(192) '8
51. clock.dx = RND * 3 + .75
52. clock.dy = RND * 3 + .75
53.  
54.  
55.  
56. 'add a bit of variance to our rainy day(increased base to help with larger screen area)
57. count% = INT(RND * 175) + 75
58.  
59. DIM Star(1 TO count%) AS StarType
60.  
61. FOR i% = 1 TO count%
62.  Star(i%).x = INT(RND * 640) + 1
63.  Star(i%).y = INT(RND * 480) + 1
64.  Star(i%).z = (RND * 2.5)
65.  'make the rain shades of blue(brightened a bit to make it easier to see).
66.  Star(i%).c = _RGB32(16, INT(RND * 80) + 32, (32 + INT(Star(i%).z * 96)) + 48)
67. NEXT i%
68.  
69. _DEST Temp& 'draw everything to the temp layer( like screen 7's layer 1)
70.  
71. COLOR clock.c
72.  
73. WHILE quit% = 0
74.  CLS
75.  IF INKEY$ <> "" THEN quit% = 1
76.  
77.  FOR i% = 1 TO count%
78.   Star(i%).y = Star(i%).y + Star(i%).z
79.   Star(i%).z = Star(i%).z * 1.05
80.   PSET (Star(i%).x, Star(i%).y), Star(i%).c
81.   'resetting the drops height when it reaches the "ground" and vary its velocity
82.   'and move the drop to a new x location
83.   IF Star(i%).y > 480 THEN Star(i%).y = Star(i%).y - 480: Star(i%).z = (RND * 2.5): Star(i%).x = INT(RND * 640) + 1
84.  
85.  
86.  NEXT i%
87.  
88.  'LOCATE 5, 5: COLOR 3
89.  'PRINT TIME$
90.  
91.  DrawClock clock 'don't need CALL anymore
92.  ' PCOPY 0, 1
93.  _PUTIMAGE , Temp&, _DISPLAY 'lets PCOPY the temp layer to our display
94.  CLS
95.  _LIMIT 60
96.  '_DELAY .5
97. WEND
98. _DEST _DISPLAY
99.  
100. SUB DrawClock (clock AS ClockType)
101.  STATIC X_Flag%%, Y_Flag%%
102.  ' tmp$ = TIME$
103.  ' FOR pointer% = 1 TO LEN(tmp$)
104.  '  digit% = VAL(MID$(tmp$, pointer%, 1))
105.  ' CALL DrawDigit(digit%, pointer%, clock.x, clock.y)
106.  ' NEXT pointer%
107.  
108.  DrawTime clock.x, clock.y 'not as clever as DrawDigit, but very simple
109.  
110.  'PSET (clock.x, clock.y), clock.c
111.  
112.  'simple!
113.  'clock.x = clock.x + clock.dx
114.  'clock.y = clock.y + clock.dy
115.  'IF clock.x <= 0 OR clock.x >= 640 - 64 THEN clock.dx = -clock.dx
116.  'IF clock.y <= 0 OR clock.y >= 480 - 12 THEN clock.dy = -clock.dy
117.  
118.  'not so simple
119.  IF clock.x <= 2 THEN X_Flag%% = FALSE: clock.dx = RND * 3 + .5
120.  IF clock.x >= 640 - 64 THEN X_Flag%% = TRUE: clock.dx = RND * 3 + .5
121.  IF clock.y <= 2 THEN Y_Flag%% = FALSE: clock.dy = RND * 3 + .5
122.  IF clock.y >= 480 - 12 THEN Y_Flag%% = TRUE: clock.dy = RND * 3 + .5
123.  IF X_Flag%% = TRUE THEN clock.x = clock.x - clock.dx ELSE clock.x = clock.x + clock.dx
124.  IF Y_Flag%% = TRUE THEN clock.y = clock.y - clock.dy ELSE clock.y = clock.y + clock.dy
125.  
126. END SUB
127.  
128. SUB DrawDigit (d AS INTEGER, p AS INTEGER, x AS INTEGER, y AS INTEGER)
129.  TimeColor~& = _RGB32(0, 112, 192) 'now using 32bit colors we need to make our clock color
130.  'only thing missing is the `:`? Numbers look really good, I think anyway!
131.  tmp$ = "BC" + STR$(TimeColor~&) + "M" + STR$(x) + "," + STR$(y) + " BM+" + STR$(5 * p) + ",0"
132.  IF d = 1 THEN tmp$ = tmp$ + "BM+3,0D4"
133.  IF d = 2 THEN tmp$ = tmp$ + "R3D2L3D2R3"
134.  IF d = 3 THEN tmp$ = tmp$ + "R3D2L3R3D2L3"
135.  IF d = 4 THEN tmp$ = tmp$ + "D2R3U2D4"
136.  IF d = 5 THEN tmp$ = tmp$ + "BM+3,0L3D2R3D2L3"
137.  IF d = 6 THEN tmp$ = tmp$ + "BM+3,0L3D4R3U2L3"
138.  IF d = 7 THEN tmp$ = tmp$ + "R3D4"
139.  IF d = 8 THEN tmp$ = tmp$ + "R3D4L3U4D2R3"
140.  IF d = 9 THEN tmp$ = tmp$ + "R3L3D2R3U2D4"
141.  IF d = 0 THEN tmp$ = tmp$ + "R3D4L3U4"
142.  DRAW tmp$
143. END SUB
144.  
145. SUB DrawTime (X!, Y!)
146.  _PRINTSTRING (X!, Y!), TIME$
147. END SUB

[Richard Frost]

The sky is falling!  The sky is falling!  - Chicken Little