Isometric Mapping Demo

[SMcNeill]

Hi Steve,

Reading about _DONTBLEND in help, it says that such will make the background opaque and block the background. When I use transparent colors with fTri, I usually want just a layer of see through color over what's behind. It's looking like I want to stick with original fTri that frees image to keep pure transparent layers going.

Update: confirmed the transparency is lost with _DONTBLEND

Thanks for your thoughts :)

I'm lost as to what the heck is wrong with _DONTBLEND; it appears to work as it should for me:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. _DONTBLEND
3. PSET (0, 0), &HAAFFFFFF
4. PRINT HEX$(POINT(0, 0))

How is the transparency lost?  When _dontblend is used, all we do is set the color to exactly what we specify it to be. 

As for the wiki, I have no idea what the heck this is supposed to mean:

Use CLS or _DONTBLEND to make a new surface background _ALPHA 255 or opaque.

_DONTBLEND doesn't change the alpha levels.  Unless my experience using it is just overly weird, all it does for us is directly put our specified colors to the image, without trying to blend the alpha levels and such like normal. 

Is there some secret trick to this command that I've been missing all these years??

[bplus]

Hi Steve,

Here is my test code for the _DONTBLEND. First run it to see the shade of transparent used with fTri that uses _FREEIMAGE. Then run main code with fQuad1 that runs fTri with the _DONTBLEND, you can see it is full opaque blue and so much lighter because solid.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "fTri Tests, click 4 points to draw transparent quad" 'b+ 2019-12-15 discovered a problem with fTri or using it with fQuad
3.  
4. CONST xmax = 800, ymax = 600
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 300, 40
7. DIM pi, oldMouse
8. DIM mx(1 TO 4), my(1 TO 4)
9. DO
10.     CLS
11.     oldMouse = -1
12.     WHILE pi < 4 'get 4 mouse clicks
13.         _PRINTSTRING (5, 5), SPACE$(20)
14.         _PRINTSTRING (5, 5), "Need 4 clicks, have" + STR$(pi)
15.         WHILE _MOUSEINPUT: WEND
16.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN 'new mouse down
17.             pi = pi + 1
18.             mx(pi) = _MOUSEX: my(pi) = _MOUSEY
19.             CIRCLE (mx(pi), my(pi)), 2
20.         END IF
21.         oldMouse = _MOUSEBUTTON(1)
22.         _DISPLAY
23.         _LIMIT 60
24.     WEND
25.     _PRINTSTRING (5, 5), "Sleeping, click or press key... or esc"
26.     'fquad1 mx(1), my(1), mx(2), my(2), mx(3), my(3), mx(4), my(4), &H880000FF '>>>>>>>>>>>>>>>>>>> switch between fquad and fquad1
27.     fquad mx(1), my(1), mx(2), my(2), mx(3), my(3), mx(4), my(4), &H880000FF '>>>>>>>>>>>>>>>>>>> switch between fquad and fquad1
28.     _DISPLAY
29.     cSleep 45 '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< dang!! this is working either fixed 2019-12-16 2nd time oldMouse = -1 at start
30.     'Pause 30 ' <<<<<<<<<<<<<<<<<<<< well this isn't working either!!!!!!!!!!!!!! now fixed (2x's, Steves fix was better)
31.     'SLEEP
32.     pi = 0 'point index
33. LOOP UNTIL _KEYDOWN(27)
34.  
35.  
36. ' my original fTri that never had a problem with
37. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
38. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
39.     DIM D AS LONG, a&
40.     D = _DEST
41.     a& = _NEWIMAGE(1, 1, 32)
42.     _DEST a&
43.     PSET (0, 0), K
44.     _DEST D
45.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
46.     _FREEIMAGE a& '<<< this is important!
47. END SUB
48.  
49. '2019-11-20 Steve saves some time with STATIC and saves and restores last dest
50. SUB ftri1 (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
51.     DIM D AS LONG
52.     STATIC a&
53.     D = _DEST
54.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32): _DONTBLEND a& '<< fix ??
55.     _DEST a&
56.     PSET (0, 0), K
57.     _DEST D
58.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
59. END SUB
60.  
61. ' original fill quad that may be at fault using Steve's fTri version
62. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is opposite of x4, y4
63. SUB fquad1 (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
64.     ftri1 x1, y1, x2, y2, x4, y4, K
65.     ftri1 x3, y3, x2, y2, x4, y4, K
66. END SUB
67.  
68. 'update 2019-12-16 needs orig fTri
69. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is opposite of x4, y4
70. SUB fquad (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
71.     ftri x1, y1, x2, y2, x3, y3, K
72.     ftri x3, y3, x4, y4, x1, y1, K
73. END SUB
74.  
75. 'update 2019-12-16 in ...test\graphics\fTri tests.bas
76. SUB cSleep (secsWait AS DOUBLE) 'wait for keypress or mouseclick, solves midnight problem nicely I think
77.     DIM wayt AS INTEGER, oldMouse AS INTEGER, k AS LONG, startTime AS DOUBLE
78.  
79.     oldMouse = -1 '2019-12-16 2nd fix today assume an old mouse click is still active
80.     startTime = TIMER
81.     wayt = 1
82.     _KEYCLEAR
83.     WHILE wayt
84.         WHILE _MOUSEINPUT: WEND
85.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN wayt = 0
86.         oldMouse = _MOUSEBUTTON(1) ' <<< this is Steve's cool way to get clear of mouse click
87.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: wayt = 0
88.         IF TIMER - startTime < 0 THEN 'past midnight
89.             IF TIMER + 24 * 60 * 60 - startTime > secsWait THEN wayt = 0
90.         ELSE
91.             IF TIMER - startTime >= secsWait THEN wayt = 0
92.         END IF
93.         _LIMIT 30
94.     WEND
95. END SUB
96.  
97. 'try Steve's Pause, nope doesn't work either!!!!
98. SUB Pause (time AS _FLOAT)
99.     DIM ExitTime AS _FLOAT, oldMouse AS INTEGER, k AS LONG
100.  
101.     _KEYCLEAR 'clear the keyboard buffer so we don't automatically exit the routine
102.     'WHILE _MOUSEINPUT OR _MOUSEBUTTON(1): WEND 'clear mouse too
103.     oldMouse = -1 'in case a mouse down still active
104.     IF time <= 0 THEN ExitTime = 1.18E+1000 ELSE ExitTime = time + TIMER
105.     DO
106.         WHILE _MOUSEINPUT: WEND: IF _MOUSEBUTTON(1) AND NOT oldMouse THEN EXIT SUB
107.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: EXIT SUB 'clear any stray key events so they don't mess with code outside the Pause.
108.         oldMouse = _MOUSEBUTTON(1)
109.         _LIMIT 10
110.     LOOP UNTIL ExitTime < TIMER
111. END SUB
112.  
113.  

[SMcNeill]

Doing some testing at the computer, I sorted out what was wrong with what I told you:

Code: [Select]

SUB ftri1 (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    DIM D AS LONG
    STATIC a&
    D = _DEST
    IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
    _DEST a&
    _DONTBLEND a& 'set the image to not blend, so your new color will set itself without blending
    PSET (0, 0), K
    _BLEND a& 'but then turn blending on for the image, so when you use _MAPTRIANGLE, it'll blend into the other screen as desired.
    _DEST D
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
END SUB
See if the above doesn't work as intended.  ;)

We can't leave blending off with an image, if we want to blend it with another image.  (Which is kind of oddish.  I would think that all we'd care about is the _DEST blending state, not the _SOURCE's as well...)

Have blending off when setting your pixel, then turn it back on before making use of the _MAPTRIANGLE command.  It should fix the issue.  (I think.)

EDIT:

Testing, I think the code works as intended now:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "fTri Tests, click 4 points to draw transparent quad" 'b+ 2019-12-15 discovered a problem with fTri or using it with fQuad
3.  
4. CONST xmax = 800, ymax = 600
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE 300, 40
7. DIM pi, oldMouse
8. DIM mx(1 TO 4), my(1 TO 4)
9. DO
10.     CLS
11.     oldMouse = -1
12.     WHILE pi < 4 'get 4 mouse clicks
13.         _PRINTSTRING (5, 5), SPACE$(20)
14.         _PRINTSTRING (5, 5), "Need 4 clicks, have" + STR$(pi)
15.         WHILE _MOUSEINPUT: WEND
16.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN 'new mouse down
17.             pi = pi + 1
18.             mx(pi) = _MOUSEX: my(pi) = _MOUSEY
19.             CIRCLE (mx(pi), my(pi)), 2
20.         END IF
21.         oldMouse = _MOUSEBUTTON(1)
22.         _DISPLAY
23.         _LIMIT 60
24.     WEND
25.     _PRINTSTRING (5, 5), "Sleeping, click or press key... or esc"
26.     'fquad1 mx(1), my(1), mx(2), my(2), mx(3), my(3), mx(4), my(4), &H880000FF '>>>>>>>>>>>>>>>>>>> switch between fquad and fquad1
27.     fquad mx(1), my(1), mx(2), my(2), mx(3), my(3), mx(4), my(4), &H880000FF '>>>>>>>>>>>>>>>>>>> switch between fquad and fquad1
28.     _DISPLAY
29.     cSleep 45 '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< dang!! this is working either fixed 2019-12-16 2nd time oldMouse = -1 at start
30.     'Pause 30 ' <<<<<<<<<<<<<<<<<<<< well this isn't working either!!!!!!!!!!!!!!
31.     'SLEEP
32.     pi = 0 'point index
33. LOOP UNTIL _KEYDOWN(27)
34.  
35.  
36. ' my original fTri that never had a problem with
37. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
38. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
39.     DIM D AS LONG, a&
40.     D = _DEST
41.     a& = _NEWIMAGE(1, 1, 32)
42.     _DEST a&
43.     PSET (0, 0), K
44.     _DEST D
45.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
46.     _FREEIMAGE a& '<<< this is important!
47. END SUB
48.  
49. '2019-11-20 Steve saves some time with STATIC and saves and restores last dest
50. SUB ftri1 (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
51.     DIM D AS LONG
52.     STATIC a&
53.     D = _DEST
54.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
55.     _DEST a&
56.     _DONTBLEND a&
57.     PSET (0, 0), K
58.     _BLEND a&
59.     _DEST D
60.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
61. END SUB
62.  
63. ' original fill quad that may be at fault using Steve's fTri version
64. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is opposite of x4, y4
65. SUB fquad1 (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
66.     ftri1 x1, y1, x2, y2, x4, y4, K
67.     ftri1 x3, y3, x2, y2, x4, y4, K
68. END SUB
69.  
70. 'update 2019-12-16 needs orig fTri
71. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is opposite of x4, y4
72. SUB fquad (x1, y1, x2, y2, x3, y3, x4, y4, K AS _UNSIGNED LONG)
73.     ftri x1, y1, x2, y2, x3, y3, K
74.     ftri x3, y3, x4, y4, x1, y1, K
75. END SUB
76.  
77. 'update 2019-12-16 in ...test\graphics\fTri tests.bas
78. SUB cSleep (secsWait AS DOUBLE) 'wait for keypress or mouseclick, solves midnight problem nicely I think
79.     DIM wayt AS INTEGER, oldMouse AS INTEGER, k AS LONG, startTime AS DOUBLE
80.  
81.     oldMouse = -1 '2019-12-16 2nd fix today assume an old mouse click is still active
82.     startTime = TIMER
83.     wayt = 1
84.     _KEYCLEAR
85.     WHILE wayt
86.         WHILE _MOUSEINPUT: WEND
87.         IF _MOUSEBUTTON(1) AND oldMouse = 0 THEN wayt = 0
88.         oldMouse = _MOUSEBUTTON(1) ' <<< this is Steve's cool way to get clear of mouse click
89.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: wayt = 0
90.         IF TIMER - startTime < 0 THEN 'past midnight
91.             IF TIMER + 24 * 60 * 60 - startTime > secsWait THEN wayt = 0
92.         ELSE
93.             IF TIMER - startTime >= secsWait THEN wayt = 0
94.         END IF
95.         _LIMIT 30
96.     WEND
97. END SUB
98.  
99. 'try Steve's Pause, nope doesn't work either!!!!
100. SUB Pause (time AS _FLOAT)
101.     DIM ExitTime AS _FLOAT, oldMouse AS INTEGER, k AS LONG
102.  
103.     _KEYCLEAR 'clear the keyboard buffer so we don't automatically exit the routine
104.     'WHILE _MOUSEINPUT OR _MOUSEBUTTON(1): WEND 'clear mouse too
105.     oldMouse = -1 'in case a mouse down still active
106.     IF time <= 0 THEN ExitTime = 1.18E+1000 ELSE ExitTime = time + TIMER
107.     DO
108.         WHILE _MOUSEINPUT: WEND: IF _MOUSEBUTTON(1) AND NOT oldMouse THEN EXIT SUB
109.         k = _KEYHIT: IF k > 0 THEN _KEYCLEAR: EXIT SUB 'clear any stray key events so they don't mess with code outside the Pause.
110.         oldMouse = _MOUSEBUTTON(1)
111.         _LIMIT 10
112.     LOOP UNTIL ExitTime < TIMER
113. END SUB

[bplus]

Steve, I think you still have fQuad1 line still commented out and are using fQuad line with the other fTri used.
 I am still seeing a bright solid blue when I uncomment fquad1 and comment fquad.

fquad1 tests with the STATIC a& with _DONTBLEND and fquad tests the working fTri that uses _FREEIMAGE.


Update: OK so I tried testing some other ranges of Alpha and discovered Steve's fix for fTri is working fine and the original fTri isn't registering anything see-able in low ranges of Alpha.

So I am confused, maybe fTri was broken all along? This is sort of the same problem with the version of Titled Ellipse Fill I came up with yesterday, low alpha's are not see-able.

[SMcNeill]

Steve, I think you still have fQuad1 line still commented out and are using fQuad line with the other fTri used.
 I am still seeing a bright solid blue when I uncomment fquad1 and comment fquad.

fquad1 tests with the STATIC a& with _DONTBLEND and fquad tests the working fTri that uses _FREEIMAGE.


Update: OK so I tried testing some other ranges of Alpha and discovered Steve's fix for fTri is working fine and the original fTri isn't registering anything see-able in low ranges of Alpha.

So I am confused, maybe fTri was broken all along? This is sort of the same problem with the version of Titled Ellipse Fill I came up with yesterday, low alpha's are not see-able.

Is it just a case of low alpha getting blended out into the background?  Take an image with 255 alpha, blend it with 10 alpha, and it fades it into the background.  Take a background with 0 alpha, blend it with 10 alpha, and it’s going to end up so faded as to be transparent in almost all cases.  (Particularly with my poor eyes an high gamma/contrast settings...)

[bplus]

Steve it was the _DONTBLEND / _BLEND thing, not only did it make the Fill Triangle code work better it fixed the problem I had doing tiltled ellipse fills from a Flat Filled Ellipse and RotoZooming the tilt onto the drawing. I guess I misunderstood how drawing transparencies were taking place on a 0 alpha background.