Author Topic: Artillery Wanted (Read 13698 times)

bplus · « **Reply #45 on:** June 28, 2019, 03:15:43 pm »

Quote from: SierraKen on June 28, 2019, 02:31:49 pm

Wow that is interesting. Mine uses POINT to only detect the brown dirt, nothing else. Like if it hits the text in the sky, it just goes through it. And since the sky is blue, it won't detect that either. This is what I have on mine:
Code: QB64: [Select]
IF POINT(bx, by) = _RGB32(74, 86, 58) THEN

I'm not sure what else would help you, I am very, very new on POINT. This is probably the very first time I ever used it.

Ah! only for dirt? not the bases? not the hill? wait the hill is same as dirt for yours... OK. Come to think of it, I did see some tunneling through the bases. What stops tunneling is gravity's effect of pulling down harder making ball go farther that it's radius.

For help, I probably need some but not for the "tunneling" problem. :-))
I will just take a snap shot of screen before showing the new ball and clear screen between each loop with it.
OR do it like Tanks Battle, take a snapshot at start and then record all holes made by explosions, redraw screen at each loop and redraw all the holes in it. But it was really cool, to me, to see the ball cleared without having to clear the screen each loop.

SierraKen · « **Reply #46 on:** June 28, 2019, 08:54:45 pm »

Yeah, only for dirt. The bases I use coordinate variables, just like my Wall Detection Example, only variables. I thought about it later how I could have used POINT instead but that's OK.

johnno56 · « **Reply #47 on:** June 29, 2019, 05:44:36 am »

If memory serves correctly, in the original dos version of Scorched Earth, 'tunnelling' was an 'option'... Tunnelling or not, I just enjoy blowing stuff up... Now, a nice addition, would be 'collapsible' landscape.... You know, blast a crater in the ground, then watch the sides of the crater slide towards the bottom of the crater... Just a though...

J

bplus · « **Reply #48 on:** July 02, 2019, 12:05:18 am »

Well after one goofy setback after another, I finally got my MOD worked out. Computer is playing decent game.

Code: QB64: [Select]

OPTION _EXPLICIT
 
'Ken:
'I've always wanted to make this game ever since I started programming in the 80's.
'This was made using the BASIC and compile language QB64 from QB64.org
'This was created by Ken G. with much help from others below.
'Thank you to B+ for posting much of this math code on the QB64.org forum!
'Also thank you to johnno56 for a little help on the explosions, from the QB64.org forum.
'It takes the computer a little time to learn how to hit your base.
'Created on June 25, 2019.
 
'Hi Ken, I made a couple of changes to the game. Do you recognize it :D  MOD 2019-07-01 B+
 
CONST xmax = 1200, ymax = 740
_TITLE "Ken's Artillery MOD B+  Hey! They only have one cannon ball between the two of them :D" 'mod B+ makeover started 2019-06-25
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 100, 0
RANDOMIZE TIMER
 
TYPE ball
    x AS SINGLE
    y AS SINGLE
    dx AS SINGLE
    dy AS SINGLE
END TYPE
 
TYPE Contestent
    baseX AS INTEGER 'butt end of cannon
    baseY AS INTEGER
    baseC AS _UNSIGNED LONG
    cannonAngle AS SINGLE
    velocity AS SINGLE
    points AS INTEGER
END TYPE
 
CONST skyC = &HFF9988FF
CONST ballC = &HFF000000
CONST groundC = &HFF405020
CONST cannonC = &HFF884422
CONST printC = &HFFEEDDCC
CONST groundY = 680
CONST gravity = .05
CONST cannonLength = 100
CONST baseLength = 100
CONST baseHeight = 30
CONST ballRadius = 5
DIM SHARED bg AS LONG, c AS Contestent, p AS Contestent, b AS ball, airX, turn, lastWind
 
bg = _NEWIMAGE(xmax, ymax, 32) 'get bg snap shot area ready
COLOR printC, groundC
setPlayerConstants
DO
    initGame
    WHILE _KEYHIT <> 27 AND p.points <> 5 AND c.points <> 5
        turn = (turn + 1) MOD 2
        IF turn THEN PlayerFire ELSE ComputerFire
    WEND
    _DELAY 3
LOOP
 
SUB setPlayerConstants
    p.baseX = 10: c.baseX = xmax - 10
    p.baseY = groundY - baseHeight: c.baseY = groundY - baseHeight
    p.baseC = &HFF880000: c.baseC = &HFF000088
    p.cannonAngle = _D2R(360 - 45)
    p.velocity = 7
END SUB
 
SUB initGame
    p.points = 0: c.points = 0
    MakeMountain xmax / 2, rrnd(200, (xmax - 220) / 2.3), ymax
    LINE (0, groundY)-(xmax, ymax), groundC, BF 'ground
    LINE (p.baseX, p.baseY)-STEP(baseLength, baseHeight), p.baseC, BF
    LINE (c.baseX, c.baseY)-STEP(-baseLength, baseHeight), c.baseC, BF
    SetDisplayWind
    showScore
END SUB
 
SUB PlayerFire
    DIM kh AS LONG
    p.cannonAngle = 360 - _R2D(p.cannonAngle)
    'IF p.cannonAngle = 360 THEN p.cannonAngle = 0
    LOCATE 44, 1: PRINT "Power: Left/Right   Angle: Up/Down   Fire: Spacebar";
    LOCATE 45, 1: PRINT "Power (0-10): " + TS$(p.velocity);
    LOCATE 46, 1: PRINT "Angle (0-90): " + TS$(p.cannonAngle);
    _DISPLAY
    WHILE kh <> 32
        kh = _KEYHIT
        IF kh = 18432 AND p.cannonAngle + 1 < 90 THEN p.cannonAngle = p.cannonAngle + 1
        IF kh = 20480 AND p.cannonAngle - 1 > 0 THEN p.cannonAngle = p.cannonAngle - 1
        IF kh = 19712 AND (p.velocity + .2 <= 10) THEN p.velocity = p.velocity + .2
        IF kh = 19200 AND (p.velocity - .2 >= .2) THEN p.velocity = p.velocity - .2
        LOCATE 45, 1: PRINT SPACE$(50);
        LOCATE 46, 1: PRINT SPACE$(50);
        LOCATE 45, 1: PRINT "Power (0-10): " + TS$(p.velocity);
        LOCATE 46, 1: PRINT "Angle (0-90): " + TS$(p.cannonAngle);
        _DISPLAY
        _LIMIT 200
    WEND
    LOCATE 44, 1: PRINT SPACE$(60);
    LOCATE 45, 1: PRINT SPACE$(50);
    LOCATE 46, 1: PRINT SPACE$(50);
    p.cannonAngle = _D2R(360 - p.cannonAngle)
    drawCannon cannonC
    b.x = p.baseX + baseLength * COS(p.cannonAngle)
    b.y = p.baseY + baseLength * SIN(p.cannonAngle)
    b.dx = p.velocity * COS(p.cannonAngle)
    b.dy = p.velocity * SIN(p.cannonAngle)
    _DISPLAY
    _PUTIMAGE , 0, bg
    playBall
END SUB
 
SUB ComputerFire
    IF airX <> lastWind THEN 'new wind blowing make adjustments
        c.cannonAngle = _D2R(180 + 50 - 1000 * airX / 15)
        c.velocity = 7 + 1000 * airX / 9
        lastWind = airX
    END IF
    drawCannon cannonC
    b.x = c.baseX + baseLength * COS(c.cannonAngle)
    b.y = c.baseY + baseLength * SIN(c.cannonAngle)
    b.dx = c.velocity * COS(c.cannonAngle)
    b.dy = c.velocity * SIN(c.cannonAngle)
    LOCATE 45, xmax / 8 - 10: PRINT TS$(c.velocity);
    LOCATE 46, xmax / 8 - 10: PRINT TS$(_R2D(c.cannonAngle) - 180);
    _DISPLAY
    _PUTIMAGE , 0, bg
    playBall
    IF b.x - (p.baseX + .5 * baseLength) > 0 THEN
        c.velocity = c.velocity + (b.x - p.baseX + .5 * baseLength) / 1000
    ELSE
        c.velocity = c.velocity - ((groundY - b.y) + (p.baseX + .5 * baseLength - b.x)) / 1000
    END IF
    LOCATE 45, xmax / 8 - 10: PRINT SPACE$(10);
    LOCATE 46, xmax / 8 - 10: PRINT SPACE$(10);
    _DISPLAY
END SUB
 
SUB drawCannon (K AS _UNSIGNED LONG)
    IF turn THEN 'players
        LINE (p.baseX, p.baseY)-STEP(baseLength * COS(p.cannonAngle), baseLength * SIN(p.cannonAngle)), K
    ELSE
        LINE (c.baseX, c.baseY)-STEP(baseLength * COS(c.cannonAngle), baseLength * SIN(c.cannonAngle)), K
    END IF
END SUB
 
SUB playBall
    DIM explosion
    WHILE _KEYHIT <> 27
        _PUTIMAGE , bg, 0 'clear last
        b.dx = b.dx + airX
        b.dy = b.dy + gravity
        b.x = b.x + b.dx
        b.y = b.y + b.dy
        fcirc b.x, b.y, ballRadius, ballC 'draw new
        CenterPrint 45, "                      "
        CenterPrint 45, TS$(b.x) + ", " + TS$(b.y)
        IF b.y >= 0 THEN
            _SOURCE bg 'oh! need this to read point(x, y) off bg !!!!!!!!!1
            IF POINT(b.x, b.y) <> skyC THEN 'explosions
                FOR explosion = 0 TO 14.5 STEP .25
                    fcirc b.x, b.y, explosion, _RGB32(RND * 255, RND * 255, 0)
                    SOUND 100 + explosion, .25
                    _DISPLAY
                    _DELAY .01
                NEXT
                IF POINT(b.x, b.y) = c.baseC THEN ' computer base hit
                    p.points = p.points + 1
                    showScore
                    SOUND 500, 1: SOUND 550, 1: SOUND 600, 1: SOUND 650, 1: SOUND 700, 1
                ELSEIF POINT(b.x, b.y) = p.baseC THEN ' player base hit
                    c.points = c.points + 1
                    showScore
                    SOUND 700, 1: SOUND 650, 1: SOUND 600, 1: SOUND 550, 1: SOUND 500, 1
                END IF
                fcirc b.x, b.y, 3 * ballRadius, skyC
                'take a snap of new background when ever we blow up
                CenterPrint 45, "                      "
                _DISPLAY
                _PUTIMAGE , 0, bg '<<<< use this after debug
                EXIT WHILE
            END IF
        END IF
        _DISPLAY
        _LIMIT 30
    WEND
    CenterPrint 45, "                      "
    drawCannon skyC
    _PUTIMAGE , 0, bg
    'take a snap for next player
END SUB
 
SUB showScore
    DIM s$
    s$ = "Human: " + TS$(p.points) + "  Computer: " + TS$(c.points)
    IF p.points = 5 THEN s$ = s$ + "  YOU WIN!"
    IF c.points = 5 THEN s$ = s$ + "  Computer won."
    CenterPrint 46, s$
    _DISPLAY
END SUB
 
SUB SetDisplayWind
    airX = rrnd(-20, 20)
    CenterPrint 44, SPACE$(24)
    IF airX < 0 THEN CenterPrint 44, "<<< Wind at: " + TS$(INT(10 * airX) / 10)
    IF airX > 0 THEN CenterPrint 44, "Wind at: " + TS$(INT(10 * airX) / 10) + " >>>"
    airX = airX / 1000
    _DISPLAY
END SUB
 
SUB MakeMountain (xcenter, maxHeight, mountainbaseY)
    DIM centerDist, i, xc, yc, xl, xr, dir
    LINE (0, 0)-(xmax + 50, ymax + 50), skyC, BF
    centerDist = 15 * RND + 15
    FOR i = 1 TO 5
        IF RND < .5 THEN dir = -1 ELSE dir = 1
        xc = xcenter + dir * centerDist
        yc = maxHeight - centerDist - RND * 25
        xl = xc - rrnd(1.15 * yc, yc)
        xr = xc + rrnd(1.15 * yc, yc)
        IF mountainbaseY - yc < mountainbaseY THEN
            ftri xl, mountainbaseY, xc, mountainbaseY - yc, xr, mountainbaseY, _RGB32(110 - i * 4, RND * 20 + 100 - i * 2, 100 - i * 8)
        ELSE
            EXIT FOR
        END IF
        centerDist = centerDist + 40 * RND + 30
    NEXT
END SUB
 
SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    DIM a&
    a& = _NEWIMAGE(1, 1, 32)
    _DEST a&
    PSET (0, 0), K
    _DEST 0
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
    _FREEIMAGE a& '<<< this is important!
END SUB
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
FUNCTION rrnd (n1, n2) 'return real number between n1, n2
    rrnd = (n2 - n1) * RND + n1
END FUNCTION
 
SUB CenterPrint (row, s$)
    LOCATE row, .125 * (xmax - 8 * LEN(s$)) / 2: PRINT s$;
END SUB
 
FUNCTION TS$ (n)
    TS$ = _TRIM$(STR$(INT(n * 100 + .5) / 100)) 'I have to add .5 for rounding coreectly
END FUNCTION
 

EDIT: a couple of minor tweaks 2019-07-02

johnno56 · « **Reply #49 on:** July 02, 2019, 08:25:03 am »

The player needs to be crack shot if winning is the goal. Quite a marksman that enemy player!!

bplus · « **Reply #50 on:** July 02, 2019, 08:57:05 am »

Quote from: johnno56 on July 02, 2019, 08:25:03 am

The player needs to be crack shot if winning is the goal. Quite a marksman that enemy player!!

Yes, you will fall asleep if the enemy doesn't keep you on your toes! Once you get a feel for the shots, it's a pretty even game, it alternate's who goes first after a win.

johnno56 · « **Reply #51 on:** July 02, 2019, 05:24:15 pm »

Sooo.... There is a good chance I can be beaten? Hmm... I have an idea for an invulnerability power-up... Activate the ability at 'start up'.... that's it... lol

Pete · « **Reply #52 on:** July 03, 2019, 04:10:57 pm »

Great sound effects. Nice that the mountain size changes each round. I wish the wind would change during the round. Also, there needs to be a display for the power and the angle as they are changed. The AI needs some work, as it constantly attacks the same hole it makes.

Pete

bplus · « **Reply #53 on:** July 03, 2019, 04:56:09 pm »

Quote from: Pete on July 03, 2019, 04:10:57 pm

Great sound effects. Nice that the mountain size changes each round. I wish the wind would change during the round. Also, there needs to be a display for the power and the angle as they are changed. The AI needs some work, as it constantly attacks the same hole it makes.

Pete

Hi Pete,

If you are commenting on my MOD (which does have the mountains), the power and angle are displayed and changed with the arrow keys by the human player. (Power and angle displayed when computer is firing but not labeled.)

You are right about AI locking in on Power and Angle setting. I never noticed that happening when testing but sure enough it happened the first time I reviewed it. That's easy enough to fix!

Changing wind? That sucks when you are developing AI, but sure when does wind ever stay exactly the same?
Again easy fix, that would actually fix the other problem of AI locked in a Power and Angle setting, the wind would force change. Good! 2 birds, one stone, I will just change the wind... and label Computer's Power and Angle display.

bplus · « **Reply #54 on:** July 04, 2019, 01:57:27 pm »

OK Pete's recommendations adapted, I kind of like the change in the way wind is handled in this MOD:

Code: QB64: [Select]

OPTION _EXPLICIT
 
'Ken:
'I've always wanted to make this game ever since I started programming in the 80's.
'This was made using the BASIC and compile language QB64 from QB64.org
'This was created by Ken G. with much help from others below.
'Thank you to B+ for posting much of this math code on the QB64.org forum!
'Also thank you to johnno56 for a little help on the explosions, from the QB64.org forum.
'It takes the computer a little time to learn how to hit your base.
'Created on June 25, 2019.
 
'Hi Ken, I made a couple of changes to the game. Do you recognize it :D  MOD 2019-07-01 B+
' 2019-07-03 fix items mentioned by Pete label Computer Power and Angle display, apply constant wind change.
 
CONST xmax = 1200, ymax = 740
_TITLE "Ken's Artillery MOD B+  Hey! They only have one cannon ball between the two of them :D" 'mod B+ makeover started 2019-06-25
SCREEN _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE 100, 0
RANDOMIZE TIMER
 
TYPE ball
    x AS SINGLE
    y AS SINGLE
    dx AS SINGLE
    dy AS SINGLE
END TYPE
 
TYPE Contestent
    baseX AS INTEGER 'butt end of cannon
    baseY AS INTEGER
    baseC AS _UNSIGNED LONG
    cannonAngle AS SINGLE
    velocity AS SINGLE
    points AS INTEGER
END TYPE
 
CONST skyC = &HFF9988FF
CONST ballC = &HFF000000
CONST groundC = &HFF405020
CONST cannonC = &HFF884422
CONST printC = &HFFEEDDCC
CONST groundY = 680
CONST gravity = .05
CONST cannonLength = 100
CONST baseLength = 100
CONST baseHeight = 30
CONST ballRadius = 5
DIM SHARED bg AS LONG, c AS Contestent, p AS Contestent, b AS ball, airX, turn, lastWind
 
bg = _NEWIMAGE(xmax, ymax, 32) 'get bg snap shot area ready
COLOR printC, groundC
setPlayerConstants
DO
    initGame
    WHILE _KEYHIT <> 27 AND p.points <> 5 AND c.points <> 5
        SetDisplayWind
        turn = (turn + 1) MOD 2
        IF turn THEN PlayerFire ELSE ComputerFire
    WEND
    _DELAY 3
LOOP
 
SUB setPlayerConstants
    p.baseX = 10: c.baseX = xmax - 10
    p.baseY = groundY - baseHeight: c.baseY = groundY - baseHeight
    p.baseC = &HFF880000: c.baseC = &HFF000088
    p.cannonAngle = _D2R(360 - 45)
    p.velocity = 7
END SUB
 
SUB initGame
    p.points = 0: c.points = 0
    MakeMountain xmax / 2, rrnd(200, (xmax - 220) / 2.3), ymax
    LINE (0, groundY)-(xmax, ymax), groundC, BF 'ground
    LINE (p.baseX, p.baseY)-STEP(baseLength, baseHeight), p.baseC, BF
    LINE (c.baseX, c.baseY)-STEP(-baseLength, baseHeight), c.baseC, BF
    airX = rrnd(-20, 20)
    SetDisplayWind
    showScore
END SUB
 
SUB PlayerFire
    DIM kh AS LONG
    p.cannonAngle = 360 - _R2D(p.cannonAngle)
    'IF p.cannonAngle = 360 THEN p.cannonAngle = 0
    LOCATE 44, 1: PRINT "Power: Left/Right   Angle: Up/Down   Fire: Spacebar";
    LOCATE 45, 10: PRINT "Power (0-10): " + TS$(p.velocity);
    LOCATE 46, 10: PRINT "Angle (0-90): " + TS$(p.cannonAngle);
    _DISPLAY
    WHILE kh <> 32
        kh = _KEYHIT
        IF kh = 18432 AND p.cannonAngle + 1 < 90 THEN p.cannonAngle = p.cannonAngle + 1
        IF kh = 20480 AND p.cannonAngle - 1 > 0 THEN p.cannonAngle = p.cannonAngle - 1
        IF kh = 19712 AND (p.velocity + .2 <= 10) THEN p.velocity = p.velocity + .2
        IF kh = 19200 AND (p.velocity - .2 >= .2) THEN p.velocity = p.velocity - .2
        LOCATE 45, 10: PRINT SPACE$(25);
        LOCATE 46, 10: PRINT SPACE$(25);
        LOCATE 45, 10: PRINT "Power (0-10): " + TS$(p.velocity);
        LOCATE 46, 10: PRINT "Angle (0-90): " + TS$(p.cannonAngle);
        _DISPLAY
        _LIMIT 200
    WEND
    LOCATE 44, 1: PRINT SPACE$(55);
    LOCATE 45, 10: PRINT SPACE$(25);
    LOCATE 46, 10: PRINT SPACE$(25);
    p.cannonAngle = _D2R(360 - p.cannonAngle)
    drawCannon cannonC
    b.x = p.baseX + baseLength * COS(p.cannonAngle)
    b.y = p.baseY + baseLength * SIN(p.cannonAngle)
    b.dx = p.velocity * COS(p.cannonAngle)
    b.dy = p.velocity * SIN(p.cannonAngle)
    _DISPLAY
    _PUTIMAGE , 0, bg
    playBall
END SUB
 
SUB ComputerFire
    IF ABS(airX - lastWind) > 2 OR c.cannonAngle <= _D2R(5 + 180) THEN 'new game or wind
        c.cannonAngle = _D2R(180 + 50 - airX / 7)
        c.velocity = 7.2 + airX / 10
        lastWind = airX
    END IF
    drawCannon cannonC
    b.x = c.baseX + baseLength * COS(c.cannonAngle)
    b.y = c.baseY + baseLength * SIN(c.cannonAngle)
    b.dx = c.velocity * COS(c.cannonAngle)
    b.dy = c.velocity * SIN(c.cannonAngle)
    LOCATE 45, xmax / 8 - 25: PRINT "Power: " + TS$(c.velocity);
    LOCATE 46, xmax / 8 - 25: PRINT "Angle: " + TS$(_R2D(c.cannonAngle) - 180);
    _DISPLAY
    _PUTIMAGE , 0, bg
    playBall
    IF b.x - (p.baseX + .5 * baseLength) > 0 THEN
        c.velocity = c.velocity + (b.x - p.baseX + .5 * baseLength) / 1000
    ELSE
        c.velocity = c.velocity - ((groundY - b.y) + (p.baseX + .5 * baseLength - b.x)) / 1000
    END IF
    LOCATE 45, xmax / 8 - 25: PRINT SPACE$(25);
    LOCATE 46, xmax / 8 - 25: PRINT SPACE$(25);
    _DISPLAY
END SUB
 
SUB drawCannon (K AS _UNSIGNED LONG)
    IF turn THEN 'players
        LINE (p.baseX, p.baseY)-STEP(baseLength * COS(p.cannonAngle), baseLength * SIN(p.cannonAngle)), K
    ELSE
        LINE (c.baseX, c.baseY)-STEP(baseLength * COS(c.cannonAngle), baseLength * SIN(c.cannonAngle)), K
    END IF
END SUB
 
SUB playBall
    DIM explosion
    WHILE _KEYHIT <> 27
        _PUTIMAGE , bg, 0 'clear last
        b.dx = b.dx + airX / 1000
        b.dy = b.dy + gravity
        b.x = b.x + b.dx
        b.y = b.y + b.dy
        fcirc b.x, b.y, ballRadius, ballC 'draw new
        CenterPrint 45, "                      "
        CenterPrint 45, TS$(b.x) + ", " + TS$(b.y)
        IF b.y >= 0 THEN
            _SOURCE bg 'oh! need this to read point(x, y) off bg !!!!!!!!!1
            IF POINT(b.x, b.y) <> skyC THEN 'explosions
                FOR explosion = 0 TO 14.5 STEP .25
                    fcirc b.x, b.y, explosion, _RGB32(RND * 255, RND * 255, 0)
                    SOUND 100 + explosion, .25
                    _DISPLAY
                    _DELAY .01
                NEXT
                IF POINT(b.x, b.y) = c.baseC THEN ' computer base hit
                    p.points = p.points + 1
                    showScore
                    SOUND 500, 1: SOUND 550, 1: SOUND 600, 1: SOUND 650, 1: SOUND 700, 1
                ELSEIF POINT(b.x, b.y) = p.baseC THEN ' player base hit
                    c.points = c.points + 1
                    showScore
                    SOUND 700, 1: SOUND 650, 1: SOUND 600, 1: SOUND 550, 1: SOUND 500, 1
                END IF
                fcirc b.x, b.y, 3 * ballRadius, skyC
                'take a snap of new background when ever we blow up
                CenterPrint 45, "                      "
                _DISPLAY
                _PUTIMAGE , 0, bg '<<<< use this after debug
                EXIT WHILE
            END IF
        END IF
        _DISPLAY
        _LIMIT 30
    WEND
    CenterPrint 45, "                      "
    drawCannon skyC
    _PUTIMAGE , 0, bg
END SUB
 
SUB showScore
    DIM s$
    s$ = "Human: " + TS$(p.points) + "  Computer: " + TS$(c.points)
    IF p.points = 5 THEN s$ = s$ + "  YOU WIN!"
    IF c.points = 5 THEN s$ = s$ + "  Computer won."
    CenterPrint 46, s$
    _DISPLAY
END SUB
 
SUB SetDisplayWind
    airX = airX + rrnd(-1.5, 1.5)
    IF airX < -20 THEN airX = -19.99
    IF airX > 20 THEN airX = 19.99
    CenterPrint 44, SPACE$(24)
    IF airX < 0 THEN CenterPrint 44, "<<< Wind at: " + TS$(airX)
    IF airX > 0 THEN CenterPrint 44, "Wind at: " + TS$(airX) + " >>>"
    _DISPLAY
END SUB
 
SUB MakeMountain (xcenter, maxHeight, mountainbaseY)
    DIM centerDist, i, xc, yc, xl, xr, dir
    LINE (0, 0)-(xmax + 50, ymax + 50), skyC, BF
    centerDist = 15 * RND + 15
    FOR i = 1 TO 5
        IF RND < .5 THEN dir = -1 ELSE dir = 1
        xc = xcenter + dir * centerDist: yc = maxHeight - centerDist - RND * 25
        xl = xc - rrnd(1.15 * yc, yc): xr = xc + rrnd(1.15 * yc, yc)
        IF mountainbaseY - yc < mountainbaseY THEN
            ftri xl, mountainbaseY, xc, mountainbaseY - yc, xr, mountainbaseY, _RGB32(110 - i * 4, RND * 20 + 100 - i * 2, 100 - i * 8)
        ELSE
            EXIT FOR
        END IF
        centerDist = centerDist + 40 * RND + 30
    NEXT
END SUB
 
SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    DIM a&
    a& = _NEWIMAGE(1, 1, 32)
    _DEST a&
    PSET (0, 0), K
    _DEST 0
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
    _FREEIMAGE a& '<<< this is important!
END SUB
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
FUNCTION rrnd (n1, n2) 'return real number between n1, n2
    rrnd = (n2 - n1) * RND + n1
END FUNCTION
 
SUB CenterPrint (row, s$)
    LOCATE row, .125 * (xmax - 8 * LEN(s$)) / 2: PRINT s$;
END SUB
 
FUNCTION TS$ (n)
    TS$ = _TRIM$(STR$(INT(n * 100 + .5) / 100)) 'I have to add .5 for rounding coreectly
END FUNCTION
 

Pete · « **Reply #55 on:** July 04, 2019, 02:22:47 pm »

The AI is much better now! I won a couple, and lost a couple. Nice job!

Pete

News:

Author Topic: Artillery Wanted (Read 13698 times)

bplus

Re: Artillery Wanted

SierraKen

Re: Artillery Wanted

johnno56

Re: Artillery Wanted

bplus

Re: Artillery Wanted

johnno56

Re: Artillery Wanted

bplus

Re: Artillery Wanted

johnno56

Re: Artillery Wanted

Pete

Re: Artillery Wanted

bplus

Re: Artillery Wanted

bplus

Re: Artillery Wanted

Pete

Re: Artillery Wanted