Clicker

[FellippeHeitor]

Here's an endless game with a ridiculously large mouse pointer.

Code: QB64: [Select]

1. _MOUSEHIDE
2. _TITLE "Clicker"
3.  
4. TYPE Object
5.     x AS INTEGER
6.     y AS INTEGER
7.     w AS INTEGER
8.     h AS INTEGER
9.     xv AS INTEGER
10.     yv AS INTEGER
11.     fg AS INTEGER
12.     bg AS INTEGER
13.     state AS _BYTE
14. END TYPE
15.  
16. DIM SHARED obj(1 TO 10) AS Object
17. DIM SHARED mouse(1 TO 8) AS STRING
18. DIM SHARED activeObjects AS INTEGER
19. DIM SHARED score AS LONG, level AS LONG
20.  
21. createObjects
22. createMouse
23.  
24. level = 1
25.  
26. DO
27.     pollMouse
28.     checkMouseAction
29.  
30.     COLOR , 0
31.     CLS
32.     updateObjects
33.     showObjects
34.  
35.     top$ = "Level:" + STR$(level) + "  *  Score:" + STR$(score)
36.     COLOR 15, 0
37.     _PRINTSTRING (1, 1), top$
38.  
39.     IF _MOUSEX > 0 AND _MOUSEY > 0 THEN
40.         showMouse
41.     END IF
42.     _DISPLAY
43.     limit = 60 * (level / 2)
44.     IF limit < 200 THEN _LIMIT limit
45. LOOP
46.  
47. SUB pollMouse
48.     WHILE _MOUSEINPUT: WEND
49. END SUB
50.  
51. SUB checkMouseAction STATIC
52.     IF _MOUSEBUTTON(1) THEN
53.         IF mouseDown = 0 THEN
54.             mouseDown = -1
55.         END IF
56.     ELSE
57.         IF mouseDown THEN
58.             mouseDown = 0
59.             destroyObject _MOUSEX, _MOUSEY
60.             IF activeObjects = 0 THEN
61.                 PLAY "T120 L16 O3 E G C"
62.                 createObjects
63.                 level = level + 1
64.             END IF
65.         END IF
66.     END IF
67. END SUB
68.  
69. SUB createObjects
70.     RANDOMIZE TIMER
71.     FOR i = 1 TO UBOUND(obj)
72.         obj(i).x = _CEIL(RND * 70)
73.         obj(i).y = _CEIL(RND * 20)
74.         obj(i).w = 10
75.         obj(i).h = 5
76.         obj(i).xv = 1 - RND * 2
77.         obj(i).yv = 1 - RND * 2
78.         obj(i).fg = _CEIL(RND * 15)
79.         obj(i).bg = _CEIL(RND * 7)
80.         IF obj(i).bg = 0 THEN obj(i).bg = 1
81.         obj(i).state = -1
82.     NEXT
83.     activeObjects = UBOUND(obj)
84. END SUB
85.  
86. SUB destroyObject (x AS INTEGER, y AS INTEGER)
87.     FOR i = UBOUND(obj) TO 1 STEP -1
88.         IF x >= obj(i).x AND x <= obj(i).x + obj(i).w - 1 THEN
89.             IF y >= obj(i).y AND y <= obj(i).y + obj(i).h - 1 THEN
90.                 IF obj(i).state THEN
91.                     FOR z = 1 TO 5
92.                         obj(i).x = obj(i).x - 2
93.                         obj(i).y = obj(i).y - 1
94.                         obj(i).w = obj(i).w + 4
95.                         obj(i).h = obj(i).h + 2
96.                         pollMouse
97.                         showObjects
98.                         showMouse
99.                         _DISPLAY
100.                         _LIMIT 30
101.                     NEXT
102.                     obj(i).state = 0
103.                     score = score + obj(i).bg
104.                     activeObjects = activeObjects - 1
105.                     EXIT FOR
106.                 END IF
107.             END IF
108.         END IF
109.     NEXT
110. END SUB
111.  
112. SUB createMouse
113.     RESTORE mouseData
114.     i = 1
115.     DO
116.         READ a
117.         IF a = -1 THEN EXIT DO
118.         IF a = 0 THEN i = i + 1: _CONTINUE
119.         mouse(i) = mouse(i) + CHR$(a)
120.     LOOP
121.  
122.     mouseData:
123.     DATA 220,0
124.     DATA 219,219,220,0
125.     DATA 219,219,219,219,220,0
126.     DATA 219,219,219,219,219,219,220,0
127.     DATA 219,219,219,219,219,219,219,219,220,0
128.     DATA 219,219,219,219,219,219,223,223,223,223,0
129.     DATA 219,223,32,32,223,219,219,0
130.     DATA 32,32,32,32,32,32,219,219,0
131.     DATA -1
132. END SUB
133.  
134. SUB showObjects
135.     FOR i = 1 TO UBOUND(obj)
136.         IF obj(i).state = -1 THEN
137.             box obj(i).x, obj(i).y, obj(i).w, obj(i).h, obj(i).fg, obj(i).bg
138.  
139.             COLOR obj(i).fg, obj(i).bg
140.             _PRINTSTRING (obj(i).x + (obj(i).w \ 2), obj(i).y + obj(i).h \ 2), LTRIM$(STR$(obj(i).bg))
141.         END IF
142.     NEXT
143. END SUB
144.  
145. SUB updateObjects STATIC
146.     IF TIMER - lastUpdate! < .5 THEN EXIT SUB
147.     lastUpdate! = TIMER
148.  
149.     FOR i = 1 TO UBOUND(obj)
150.         IF obj(i).state = -1 THEN
151.             obj(i).x = obj(i).x + obj(i).xv
152.             IF obj(i).x < 1 OR obj(i).x + obj(i).w > _WIDTH THEN obj(i).xv = obj(i).xv * -1
153.  
154.             obj(i).y = obj(i).y + obj(i).yv
155.             IF obj(i).y < 1 OR obj(i).y + obj(i).h > _HEIGHT THEN obj(i).yv = obj(i).yv * -1
156.         END IF
157.     NEXT
158. END SUB
159.  
160. SUB showMouse
161.     FOR i = 1 TO 8
162.         IF (_MOUSEY + i) - 1 <= 25 THEN
163.             FOR j = _MOUSEX TO _MOUSEX + LEN(mouse(i)) - 1
164.                 IF j > 80 THEN EXIT FOR
165.                 m$ = MID$(mouse(i), (j - _MOUSEX) + 1, 1)
166.                 IF m$ <> " " THEN
167.                     COLOR 15, SCREEN((_MOUSEY + i) - 1, j, 1) \ 16
168.                     _PRINTSTRING (j, (_MOUSEY + i) - 1), m$
169.                 END IF
170.             NEXT
171.         END IF
172.     NEXT
173. END SUB
174.  
175. SUB box (x AS INTEGER, y AS INTEGER, w AS INTEGER, h AS INTEGER, fg AS INTEGER, bg AS INTEGER)
176.     prevFG = _DEFAULTCOLOR
177.     prevBG = _BACKGROUNDCOLOR
178.     COLOR fg, bg
179.  
180.     FOR i = x TO x + w - 1
181.         IF i < 1 OR i > _WIDTH THEN _CONTINUE
182.         FOR j = y TO y + h - 1
183.             IF j < 1 OR j > _HEIGHT THEN _CONTINUE
184.             IF (i = x OR i = x + w - 1) AND (j > y AND j < y + h - 1) THEN
185.                 _PRINTSTRING (i, j), CHR$(186)
186.             ELSE
187.                 IF j = y OR j = y + h - 1 AND (i > x AND i < x + w - 1) THEN
188.                     _PRINTSTRING (i, j), CHR$(205)
189.                 ELSE
190.                     _PRINTSTRING (i, j), CHR$(32)
191.                 END IF
192.             END IF
193.         NEXT
194.     NEXT
195.  
196.     IF x >= 1 AND x <= _WIDTH AND y >= 1 AND y <= _HEIGHT THEN _PRINTSTRING (x, y), CHR$(201)
197.     IF x + w - 1 >= 1 AND x + w - 1 <= _WIDTH AND y >= 1 AND y <= _HEIGHT THEN _PRINTSTRING (x + w - 1, y), CHR$(187)
198.     IF x >= 1 AND x <= _WIDTH AND y + h - 1 >= 1 AND y + h - 1 <= _HEIGHT THEN _PRINTSTRING (x, y + h - 1), CHR$(200)
199.     IF x + w - 1 >= 1 AND x + w - 1 <= _WIDTH AND y + h - 1 >= 1 AND y + h - 1 <= _HEIGHT THEN _PRINTSTRING (x + w - 1, y + h - 1), CHR$(188)
200.  
201.     COLOR prevFG, prevBG
202. END SUB

[TempodiBasic]

Great and fun!

A fine example for
_DEFAULTCOLOR
_BACKGROUNDCOLOR
_CONTINUE
_CEIL
etc etc etc..
Thanks

[TempodiBasic]

Fellippe I'm sorry but your creature is so fine that has put me into creative status so I find this MOD in my imagination:

Code: QB64: [Select]

1. _MOUSEHIDE
2. _TITLE "Boundaries: a X-mutant of Clicker"
3.  
4. TYPE Object
5.     x AS INTEGER
6.     y AS INTEGER
7.     w AS INTEGER
8.     h AS INTEGER
9.     xv AS INTEGER
10.     yv AS INTEGER
11.     fg AS INTEGER
12.     bg AS INTEGER
13.     state AS _BYTE
14. END TYPE
15.  
16. DIM SHARED obj(1 TO 10) AS Object
17. DIM SHARED mouse(1 TO 8) AS STRING
18. DIM SHARED activeObjects AS INTEGER
19. DIM SHARED score AS LONG, level AS LONG
20. DIM SHARED Lives AS INTEGER
21. SCREEN 0
22. _BLINK ON
23.  
24. Lives = 5
25. createObjects
26. createMouse
27.  
28. level = 1
29.  
30. DO
31.     pollMouse
32.     checkMouseAction
33.  
34.     COLOR , 0
35.     CLS
36.     updateObjects
37.  
38.  
39.     top$ = "[Level:" + STR$(level) + "  *  Score:" + STR$(score) + "  *  Lives:" + STR$(Lives) + "]"
40.     COLOR 15, 0
41.     box 1, 1, _WIDTH, _HEIGHT, 15, 0
42.     _PRINTSTRING (2, 1), top$
43.     showObjects
44.  
45.     IF Lives = 0 THEN Again
46.     IF _MOUSEX > 0 AND _MOUSEY > 0 THEN
47.         showMouse
48.     END IF
49.     _DISPLAY
50.     limit = 60 * (level / 2)
51.     IF limit < 200 THEN _LIMIT limit
52. LOOP
53.  
54. SUB RestartLevel
55.     IF Lives > 0 THEN Lives = Lives - 1
56.     box _WIDTH / 2 - 11, _HEIGHT / 2, 22, 5, 31, 0
57.     COLOR 15, 0
58.     _PRINTSTRING (_WIDTH / 2 - 5, _HEIGHT / 2 + 2), "BOX ESCAPED"
59.     _DISPLAY
60.     SLEEP 3
61.     _PRINTSTRING (_WIDTH / 2 - 9, _HEIGHT / 2 + 2), "YOU DIE, TRY AGAIN"
62.     _DISPLAY
63.     SLEEP 2
64.     createObjects
65. END SUB
66.  
67. SUB Again
68.     box _WIDTH / 2 - 12, _HEIGHT / 2, 24, 5, 31, 0
69.     COLOR 15, 0
70.     _PRINTSTRING (_WIDTH / 2 - 4, _HEIGHT / 2 + 2), "GAME OVER"
71.     _DISPLAY
72.     SLEEP 3
73.     _PRINTSTRING (_WIDTH / 2 - 6, _HEIGHT / 2 + 2), "GAME RESTART"
74.     _DISPLAY
75.     SLEEP 3
76.     Lives = 5
77.     showObjects
78. END SUB
79.  
80. SUB pollMouse
81.     WHILE _MOUSEINPUT
82.         IF INKEY$ <> "" THEN EXIT WHILE
83.     WEND
84. END SUB
85.  
86. SUB checkMouseAction STATIC
87.     IF _MOUSEBUTTON(1) THEN
88.         IF mouseDown = 0 THEN
89.             mouseDown = -1
90.         END IF
91.     ELSE
92.         IF mouseDown THEN
93.             mouseDown = 0
94.             destroyObject _MOUSEX, _MOUSEY
95.             IF activeObjects = 0 THEN
96.                 PLAY "T120 L16 O3 E G C"
97.                 createObjects
98.                 level = level + 1
99.             END IF
100.         END IF
101.     END IF
102. END SUB
103.  
104. SUB createObjects
105.     RANDOMIZE TIMER
106.     FOR i = 1 TO UBOUND(obj)
107.         obj(i).x = _CEIL(RND * 55) + 10
108.         obj(i).y = _CEIL(RND * 10) + 8
109.         obj(i).w = 10
110.         obj(i).h = 5
111.         obj(i).xv = 1 - RND * 2
112.         obj(i).yv = 1 - RND * 2
113.         obj(i).fg = _CEIL(RND * 15)
114.         obj(i).bg = _CEIL(RND * 7)
115.         IF obj(i).bg = 0 THEN obj(i).bg = 1
116.         IF obj(i).fg = obj(i).bg THEN obj(i).fg = obj(i).bg + 8
117.         obj(i).state = -1
118.     NEXT
119.     activeObjects = UBOUND(obj)
120. END SUB
121.  
122. SUB destroyObject (x AS INTEGER, y AS INTEGER)
123.     FOR i = UBOUND(obj) TO 1 STEP -1
124.         IF x >= obj(i).x AND x <= obj(i).x + obj(i).w - 1 THEN
125.             IF y >= obj(i).y AND y <= obj(i).y + obj(i).h - 1 THEN
126.                 IF obj(i).state THEN
127.                     FOR z = 1 TO 5
128.                         obj(i).x = obj(i).x - 2
129.                         obj(i).y = obj(i).y - 1
130.                         obj(i).w = obj(i).w + 4
131.                         obj(i).h = obj(i).h + 2
132.                         pollMouse
133.                         showObjects
134.                         showMouse
135.                         _DISPLAY
136.                         _LIMIT 30
137.                     NEXT
138.                     obj(i).state = 0
139.                     score = score + obj(i).bg
140.                     activeObjects = activeObjects - 1
141.                     EXIT FOR
142.                 END IF
143.             END IF
144.         END IF
145.     NEXT
146. END SUB
147.  
148. SUB createMouse
149.     RESTORE mouseData
150.     i = 1
151.     DO
152.         READ a
153.         IF a = -1 THEN EXIT DO
154.         IF a = 0 THEN i = i + 1: _CONTINUE
155.         mouse(i) = mouse(i) + CHR$(a)
156.     LOOP
157.  
158.     mouseData:
159.     DATA 220,0
160.     DATA 219,219,220,0
161.     DATA 219,219,219,219,220,0
162.     DATA 219,219,219,219,219,219,220,0
163.     DATA 219,219,219,219,219,219,219,219,220,0
164.     DATA 219,219,219,219,219,219,223,223,223,223,0
165.     DATA 219,223,32,32,223,219,219,0
166.     DATA 32,32,32,32,32,32,219,219,0
167.     DATA -1
168. END SUB
169.  
170. SUB showObjects
171.     FOR i = 1 TO UBOUND(obj)
172.         IF obj(i).state = -1 THEN
173.             box obj(i).x, obj(i).y, obj(i).w, obj(i).h, obj(i).fg, obj(i).bg
174.  
175.             COLOR obj(i).fg, obj(i).bg
176.             _PRINTSTRING (obj(i).x + (obj(i).w \ 2), obj(i).y + obj(i).h \ 2), LTRIM$(STR$(obj(i).bg))
177.         END IF
178.     NEXT
179. END SUB
180.  
181. SUB updateObjects STATIC
182.     IF TIMER - lastUpdate! < .5 THEN EXIT SUB
183.     lastUpdate! = TIMER
184.  
185.     FOR i = 1 TO UBOUND(obj)
186.         IF obj(i).state = -1 THEN
187.             obj(i).x = obj(i).x + obj(i).xv
188.             IF obj(i).x < 1 OR obj(i).x + obj(i).w > _WIDTH THEN RestartLevel 'obj(i).xv = obj(i).xv * -1
189.  
190.             obj(i).y = obj(i).y + obj(i).yv
191.             IF obj(i).y < 1 OR obj(i).y + obj(i).h > _HEIGHT THEN RestartLevel 'obj(i).yv = obj(i).yv * -1
192.         END IF
193.     NEXT
194. END SUB
195.  
196. SUB showMouse
197.     FOR i = 1 TO 8
198.         IF (_MOUSEY + i) - 1 <= 25 THEN
199.             FOR j = _MOUSEX TO _MOUSEX + LEN(mouse(i)) - 1
200.                 IF j > 80 THEN EXIT FOR
201.                 m$ = MID$(mouse(i), (j - _MOUSEX) + 1, 1)
202.                 IF m$ <> " " THEN
203.                     COLOR 15, SCREEN((_MOUSEY + i) - 1, j, 1) \ 16
204.                     _PRINTSTRING (j, (_MOUSEY + i) - 1), m$
205.                 END IF
206.             NEXT
207.         END IF
208.     NEXT
209. END SUB
210.  
211. SUB box (x AS INTEGER, y AS INTEGER, w AS INTEGER, h AS INTEGER, fg AS INTEGER, bg AS INTEGER)
212.     prevFG = _DEFAULTCOLOR
213.     prevBG = _BACKGROUNDCOLOR
214.     COLOR fg, bg
215.  
216.     FOR i = x TO x + w - 1
217.         IF i < 1 OR i > _WIDTH THEN _CONTINUE
218.         FOR j = y TO y + h - 1
219.             IF j < 1 OR j > _HEIGHT THEN _CONTINUE
220.             IF (i = x OR i = x + w - 1) AND (j > y AND j < y + h - 1) THEN
221.                 _PRINTSTRING (i, j), CHR$(186)
222.             ELSE
223.                 IF j = y OR j = y + h - 1 AND (i > x AND i < x + w - 1) THEN
224.                     _PRINTSTRING (i, j), CHR$(205)
225.                 ELSE
226.                     _PRINTSTRING (i, j), CHR$(32)
227.                 END IF
228.             END IF
229.         NEXT
230.     NEXT
231.  
232.     IF x >= 1 AND x <= _WIDTH AND y >= 1 AND y <= _HEIGHT THEN _PRINTSTRING (x, y), CHR$(201)
233.     IF x + w - 1 >= 1 AND x + w - 1 <= _WIDTH AND y >= 1 AND y <= _HEIGHT THEN _PRINTSTRING (x + w - 1, y), CHR$(187)
234.     IF x >= 1 AND x <= _WIDTH AND y + h - 1 >= 1 AND y + h - 1 <= _HEIGHT THEN _PRINTSTRING (x, y + h - 1), CHR$(200)
235.     IF x + w - 1 >= 1 AND x + w - 1 <= _WIDTH AND y + h - 1 >= 1 AND y + h - 1 <= _HEIGHT THEN _PRINTSTRING (x + w - 1, y + h - 1), CHR$(188)
236.  
237.     COLOR prevFG, prevBG
238. END SUB
239.  

the X-mutant brings these news:
changed goal: don't let escape the box out of the borders
no simple box with no borders and no caption (it can appear in your creature when Fg and Bg are the same)
you have only 5 lives to accomplish this goal, after you die and restart

I have a real trouble...
also if the program is in SCREEN 0 and I force using _BLINK statement I have got no blinking message boxes...
? ? ?
Why? I don't understand.
Thanks to awaking my imagination

[FellippeHeitor]

I have a real trouble...
also if the program is in SCREEN 0 and I force using _BLINK statement I have got no blinking message boxes...
? ? ?
Why? I don't understand.

_BLINK is on by default, no need to turn it on again.

You’re trying to make blinking colors by adding 8 to the background colors. However, they originally only go up to 8. Eight + 8 = 16, which would be blinking BLACK. Real blinking colors start after 16 (17 is blinking blue, which is color 1 + 16).

Now I don’t remember if you can have blinking background or only blinking foreground. It may error out.

[TempodiBasic]

Hi Fellippe
sorry for my bad comunication...
if you see at rows 56 and 68 of my X-mutant MOD I pass the light white blinking code to sub BOX for foreground color

but if you run my code you cannot see any blinking box, for this reason I have forced using _BLINK ON, but with no results.

Thanks

[Pete]

Science has determined those game boxes would multiply every bit as fast with a smaller pointer. How each box feels about that is a completely different discussion meant for the off-topic board.

Pete :D

[TempodiBasic]

Hi Pete
what do you think of the issue of blinking in SCREEN 0 ?

surely the issue doesn't come from PRINT  or COLOR
as this code demonstrates

Code: QB64: [Select]

1. CLS , 4
2. box 4, 4, 16, 6, 31, 1
3. box 14, 14, 16, 6, 30, 2
4. box 34, 14, 16, 6, 29, 3
5. box 34, 4, 16, 6, 28, 5
6. END
7.  
8. SUB box (x AS INTEGER, y AS INTEGER, w AS INTEGER, h AS INTEGER, fg AS INTEGER, bg AS INTEGER)
9.     prevFG = _DEFAULTCOLOR
10.     prevBG = _BACKGROUNDCOLOR
11.     COLOR fg, bg
12.  
13.     FOR i = x TO x + w - 1
14.         IF i < 1 OR i > _WIDTH THEN _CONTINUE
15.         FOR j = y TO y + h - 1
16.             IF j < 1 OR j > _HEIGHT THEN _CONTINUE
17.             IF (i = x OR i = x + w - 1) AND (j > y AND j < y + h - 1) THEN
18.                 _PRINTSTRING (i, j), CHR$(186)
19.             ELSE
20.                 IF j = y OR j = y + h - 1 AND (i > x AND i < x + w - 1) THEN
21.                     _PRINTSTRING (i, j), CHR$(205)
22.                 ELSE
23.                     _PRINTSTRING (i, j), CHR$(32)
24.                 END IF
25.             END IF
26.         NEXT
27.     NEXT
28.  
29.     IF x >= 1 AND x <= _WIDTH AND y >= 1 AND y <= _HEIGHT THEN _PRINTSTRING (x, y), CHR$(201)
30.     IF x + w - 1 >= 1 AND x + w - 1 <= _WIDTH AND y >= 1 AND y <= _HEIGHT THEN _PRINTSTRING (x + w - 1, y), CHR$(187)
31.     IF x >= 1 AND x <= _WIDTH AND y + h - 1 >= 1 AND y + h - 1 <= _HEIGHT THEN _PRINTSTRING (x, y + h - 1), CHR$(200)
32.     IF x + w - 1 >= 1 AND x + w - 1 <= _WIDTH AND y + h - 1 >= 1 AND y + h - 1 <= _HEIGHT THEN _PRINTSTRING (x + w - 1, y + h - 1), CHR$(188)
33.  
34.     COLOR prevFG, prevBG
35. END SUB
36.  

so where do i search the glitch of loosing the blinking text in screen 0?

Thanks

PS: what is your modification (variant) of these boxes' games?

[FellippeHeitor]

_DISPLAY stops blinking. I finally understand your question.

As per the wiki:

IF _DISPLAY is used, blinking is disabled, even if _BLINK is ON, but high intensity backgrounds aren't enabled in this case.

[bplus]

Fellippe must have had my eyesight in mind when he created this code.

Thanks TempodiBasic, with just Fellippe's code I could see the pointer but not the point of playing. :)