International Characters Input Routine

[FellippeHeitor]

This is limited to the accented characters available in the builtin ascii table. Hit the accent, then hit the letter.

´ + a should result in á.

No warranties. Tested on a Windows machine set to Brazilian Portuguese.

Code: QB64: [Select]

1. DIM replEntries AS LONG
2. REDIM replTableSource(1 TO 100) AS STRING, replTableDest(1 TO 100) AS STRING
3. RESTORE replTable
4. i& = 0
5. DO
6.     READ a$
7.     IF a$ = "**END**" THEN EXIT DO
8.     READ b%
9.     i& = i& + 1
10.     IF i& > UBOUND(replTableSource) THEN
11.         REDIM _PRESERVE replTableSource(1 TO UBOUND(replTableSource) + 100) AS STRING
12.         REDIM _PRESERVE replTableDest(1 TO UBOUND(replTableDest) + 100) AS STRING
13.     END IF
14.     replTableSource(i&) = a$
15.     replTableDest(i&) = CHR$(b%)
16.     replEntries = replEntries + 1
17. LOOP
18.  
19. ON TIMER(.4) GOSUB blinkCursor
20. TIMER ON
21.  
22. PRINT "International Characters Input Routine"
23. PRINT
24. row = CSRLIN
25. DO
26.     GOSUB showText
27.     GOSUB showCursor
28.  
29.     k& = _KEYHIT
30.  
31.     SELECT CASE k&
32.         CASE -222
33.             IF _KEYDOWN(100303) OR _KEYDOWN(100304) THEN 'shift
34.                 IF LEN(nextAccent$) > 0 THEN
35.                     nextChar$ = nextAccent$ + "^"
36.                 ELSE
37.                     nextAccent$ = "^"
38.                 END IF
39.             ELSE
40.                 IF LEN(nextAccent$) > 0 THEN
41.                     nextChar$ = nextAccent$ + "~"
42.                     nextAccent$ = ""
43.                 ELSE
44.                     nextAccent$ = "~"
45.                 END IF
46.             END IF
47.         CASE -219
48.             IF _KEYDOWN(100303) OR _KEYDOWN(100304) THEN 'shift
49.                 IF LEN(nextAccent$) > 0 THEN
50.                     nextChar$ = nextAccent$ + "`"
51.                     nextAccent$ = ""
52.                 ELSE
53.                     nextAccent$ = "`"
54.                 END IF
55.             ELSE
56.                 IF LEN(nextAccent$) > 0 THEN
57.                     nextChar$ = nextAccent$ + "'"
58.                     nextAccent$ = ""
59.                 ELSE
60.                     nextAccent$ = "'"
61.                 END IF
62.             END IF
63.         CASE 32 TO 126, 209, 241, 199, 231
64.             nextChar$ = nextAccent$ + CHR$(k&)
65.             nextAccent$ = ""
66.         CASE 8
67.             IF LEN(text$) > 0 THEN text$ = LEFT$(text$, LEN(text$) - 1)
68.         CASE 13
69.             GOSUB showText
70.             cursor = 0
71.             GOSUB showCursor
72.             text$ = ""
73.             row = row + 1
74.     END SELECT
75.  
76.     FOR i = 1 TO replEntries
77.         IF replTableSource(i) = nextChar$ THEN
78.             nextChar$ = replTableDest(i)
79.             EXIT FOR
80.         END IF
81.     NEXT
82.     text$ = text$ + nextChar$
83.     IF LEN(nextChar$) > 0 THEN nextChar$ = "": nextAccent$ = ""
84.     _LIMIT 30
85. LOOP
86.  
87. END
88. blinkCursor:
89. cursor = NOT cursor
90. RETURN
91.  
92. showText:
93. LOCATE row, 1
94. PRINT text$;
95. RETURN
96.  
97. showCursor:
98. IF cursor THEN PRINT "_ " ELSE PRINT "  "
99. RETURN
100.  
101. replTable:
102. DATA ^a,131,"'a",160,`a,133
103. DATA "'E",144
104. DATA ^e,136,"'e",130,`e,138
105. DATA "'i",161,`i,141
106. DATA ^o,147,"'o",162,`o,149
107. DATA ^u,150,"'u",163,`u,151
108. DATA ~N,165,Ñ,165,~n,164,ñ,164
109. DATA "'C",128,"'c",135
110. DATA Ç,128,ç,135
111. DATA **END**

[freetrav]

Why would I use this instead of simply loading the appropriate keyboard driver at the OS level?

(I have my Windows and Linux keyboards set to US-International, by default.)

[FellippeHeitor]

If you won't ever need international characters to be input, you won't use this.

If you've ever tried entering international characters into a QB64 program, you'll know why this could be useful, as there is no support for this natively currently, even if your OS is properly set.

[freetrav]

Indeed, you appear to be correct - but the question now becomes why QB64 doesn't honor the OS setting?