Mouse pointers

[Petr]

Today something similar, yet much more fun. The program will allow you to use animated ANI cursors (this first version know only one type, but of course this is not last version) What do you say about an animated Windows cursor under Linux?

Code: QB64: [Select]

1. 'ANI reader - 32 bit files only.    Linux compatible.
2.  
3. file$ = "aero_working_xl.ani"
4.  
5.  
6.  
7. '1] Test, if this is ANI file
8. '------------------------------
9. TYPE ANI_Acon_Header
10.     ID1 AS STRING * 4 'RIFF
11.     Size AS LONG '     ?
12.     ID2 AS STRING * 4 'ACON
13. END TYPE
14. DIM Ani_Head AS ANI_Acon_Header
15. IF _FILEEXISTS(file$) THEN
16.     ch = FREEFILE
17.     OPEN file$ FOR BINARY AS #ch
18.     GET #ch, , Ani_Head
19.     IF Ani_Head.ID1 = "RIFF" AND Ani_Head.ID2 = "ACON" THEN PRINT file$; " is valid. Size: "; Ani_Head.Size + 8
20. ELSE PRINT file$; " not exists.": END
21. END IF
22.  
23. '2] Finding in file position for flag "anih" and reading this head
24. '-----------------------------------------------------------------
25. TYPE anih
26.     ID AS STRING * 4 'anih
27.     Width AS LONG
28.     Height AS LONG
29.     NumFrames AS LONG
30.     NumSteps AS LONG
31.     Frame_Size AS LONG
32.     HeaderSize AS LONG
33.     BitCount AS LONG
34.     NumPlanes AS LONG 'always 1
35.     DisplayRate AS LONG 'default rate = 60/anih.displayrate fps
36.     Flags AS STRING * 4 'currently used 2 bits: bit 31 to 2 are reserved,
37.     'bit 1: if true, then file contains sequence data,
38.     'bit 0: True = Frames are icon or cursor dat, False: Frames are RAW data
39. END TYPE
40. DIM anih AS anih
41. REDIM a_rec(0)
42. Scan file$, "anih", a_rec(), 1
43. GET #ch, a_rec(0), anih
44.  
45. Frames = anih.NumFrames
46. Width = anih.Width
47. Height = anih.Height
48. BpP = anih.BitCount
49. Rate = anih.DisplayRate
50.  
51. '3] Finding start positions for all frames (search flag "icon")
52. '--------------------------------------------------------------
53. REDIM a_rec(0)
54. Scan file$, "icon", a_rec(), Frames 'ok
55.  
56. '4] By the BpP (bites per pixel) value now i set output pixelsize and create array with frames. Record 0 contains video LIMIT between frames.
57. '--------------------------------------------------------------------------------------------------------------------------------------------
58. TYPE Icon
59.     icon AS STRING * 4
60.     cosi AS LONG
61.     Reserved AS INTEGER '       2 bytes, always 00
62.     Image_Type AS INTEGER '     1 = ICO format, 2 = CUR format, others are invalid
63.     Number_images AS INTEGER '  number images in file
64. END TYPE
65.  
66. TYPE Structure '
67.     Image_Width AS _UNSIGNED _BYTE
68.     Image_Height AS _UNSIGNED _BYTE
69.     Image_Color_Palette AS _UNSIGNED _BYTE
70.     Reserved AS _UNSIGNED _BYTE 'always zero
71.     Planes AS INTEGER '          In ICO format: Specifies color planes. Should be 0 or 1.
72.     '                            In CUR format: Specifies the horizontal coordinates of the hotspot in number of pixels from the left.
73.     Bpp AS INTEGER '             In ICO format: Specifies bits per pixel.
74.     '                            In CUR format: Specifies the vertical coordinates of the hotspot in number of pixels from the top.
75.     Size_of_image_data AS LONG
76.     Offset_from_begin AS LONG
77. END TYPE
78.  
79. DIM icon AS Icon
80. DIM structure AS Structure
81. SELECT CASE BpP
82.     CASE 32
83.         DIM Video32(Frames) AS LONG
84.         Video32(0) = 60 / Rate
85.         FOR Create_all_frames = 1 TO Frames
86.             SEEK #ch, a_rec(Create_all_frames - 1)
87.             GET #ch, , icon
88.             GET #ch, , structure
89.             REDIM record AS LONG
90.             Video32(Create_all_frames) = _NEWIMAGE(structure.Image_Width, structure.Image_Height, 32)
91.             x = -structure.Image_Width / 4
92.             Y = structure.Image_Height - 1
93.             _DEST Video32(Create_all_frames)
94.             CLS
95.             FOR frm = 1 TO structure.Image_Height * structure.Image_Width * 4
96.                 GET #ch, , record&
97.                 PSET (x, Y), record&
98.                 x = x + 1: IF x >= structure.Image_Width AND x MOD 4 = 0 THEN Y = Y - 1: x = 0
99.             NEXT frm
100.         NEXT
101.         _DEST 0
102.     CASE ELSE
103.         PRINT "Support for other than 32 bit ANI i prepare.": SLEEP 2: END
104. END SELECT
105. CLOSE #ch
106.  
107. '5] Is time for display it:
108. '--------------------------
109. SCREEN _NEWIMAGE(800, 600, 32)
110. _MOUSEHIDE
111. DO UNTIL _KEYDOWN(27)
112.     WHILE _MOUSEINPUT: WEND
113.     CLS
114.     showANI Video32(), _MOUSEX, _MOUSEY, structure.Image_Width, structure.Image_Height
115.     _LIMIT Video32(0)
116.     _DISPLAY
117. LOOP
118.  
119. FOR Erase_memory = 1 TO UBOUND(video32)
120.     _FREEIMAGE Video32(Erase_memory)
121. NEXT
122. _MOUSESHOW
123. END
124.  
125.  
126. SUB showANI (arr() AS LONG, x, y, Xres, Yres)
127.     SHARED internalindex0
128.     IF internalindex0 = 0 THEN internalindex0 = 1
129.     _PUTIMAGE (x - (Xres / 2), y - (Yres / 2)), arr(internalindex0)
130.     internalindex0 = internalindex0 + 1: IF internalindex0 > UBOUND(arr) THEN internalindex0 = 1
131. END SUB
132.  
133. SUB Scan (file AS STRING, text AS STRING, result(), RECORDS) 'Records = number of records, which are searched
134.     IF _FILEEXISTS(file$) THEN
135.         g = FREEFILE
136.         OPEN file$ FOR BINARY AS #g
137.         content$ = SPACE$(LOF(g))
138.         GET #g, , content$
139.         REDIM result(0)
140.         FOR S = 1 TO LEN(content$)
141.             num = INSTR(S, content$, text$)
142.             IF num THEN
143.                 REDIM _PRESERVE result(i)
144.                 result(i) = num
145.                 S = num
146.                 num = 0
147.                 i = i + 1
148.                 IF RECORDS = i THEN EXIT SUB
149.             END IF
150.         NEXT S
151.         CLOSE #g
152.     ELSE
153.         PRINT "File "; file$; "not exist.": END
154.     END IF
155.     content$ = ""
156. END SUB
157.  
158.  

[bplus]

Hi Petr,

This is weird, I have a perpetual circle circling over the screen. Is this OK to run on Windows?

I was hoping to see an animated cursor.

Oh maybe that's it, the animation? Ha! I thought it was stuck processing...

[Petr]

Hi BPlus,
what you see is not the work of windows, but the result of a program that uses an ANI file that contains just this animated icon. I think it's good to be able to use CUR and ANI files in programs. Soon I will release both versions with the support of 16 color icons. There is bad documentation, so I often have to look for connections. But this is fun for me.

[FellippeHeitor]

Very good job on this one, Petr. It's similar to what Zom-B did for viewing animated GIF files.

https://qb64.org/wiki/GIF_Images

Do you think you could streamline your code so it'd behave more like a library? Maybe a reduced set of methods like Load, Display, Unload, so that the actual inner workings could be hidden away in a $INCLUDE file? That'd be interesting to have.

I have added Zom-B's code to the next release of InForm. Here's the readme that'll come with Beta 8 showing how to display animated GIFs in a form: https://github.com/FellippeHeitor/InForm/blob/Beta8/InForm/extensions/README%20-%20gifplay.txt

Please see the methods I describe in the document above for an idea of what I mean about your animated cursors code.

[Petr]

Hi Fellippe,
Yes, I have such an idea. However, it will be necessary to use the BI file at the beginning and the BM at the end due to the input field declarations. Now, during development, I need to get as many CUR and ANI files as possible for thorough testing. It has the following features: Cursor& = LOADCUR ("curfile_name.cur") and then PlayCUR Cursor&,x, y   the same for ANI files. In Inform I'll look at how it's done there.
I could open a detective office literally because it has happened many times that the content that is mentioned in various sources for these files did not correspond to reality.
Of course, the correct placement of the cursor will also be very important.
This version are "direct", but finaly version i write as BI and BM (and then re-testing it in Win and Linux).

I am glad for your reaction.
 

[FellippeHeitor]

You don't even need to worry about InForm specifics. If it becomes a detachable library, a user of InForm would be able to use it as is, probably.

Again, good investigation job.

[Petr]

Hi. So you say, make it as easy and user-friendly as possible. I tried it. Here is the result, the same thing I do for CUR files, this here is for ANI files. It supports the 16 color ANI and Truecolor ANI, but I have a few ANI files, that do not work right, so I still do it.
I do not have the speed between frames of the shot correct, but that's exactly what I'm doing now.

Code: QB64: [Select]

1. '$include:'ani.bi'
2.  
3. FileA$ = "coin.ani"
4. FileB$ = "dinosau2.ani"
5. FileC$ = "horse.ani"
6.  
7. A& = LoadAni(FileA$)
8. B& = LoadAni(FileB$)
9. C& = LoadAni(FileC$)
10.  
11. SCREEN _NEWIMAGE(800, 600, 32)
12. 'program know playing ANIs and EXTRACT FRAMES from ANI:
13.  
14. FOR Extract = 1 TO FrameAni(A&) '               function return number frames in file
15.     Image& = ExtractAni(A&, Extract) '          function return decoded image
16.     _PUTIMAGE (50 + Extract * 50, 100), Image&
17. NEXT Extract
18. PCOPY _DISPLAY, 1
19. 'this is just option, normal you need not, but it is here for you.
20.  
21.  
22. _MOUSEHIDE
23. DO
24.     PCOPY 1, _DISPLAY
25.     PutAni A&, 100, 200
26.     PutAni B&, 300, 500
27.     WHILE _MOUSEINPUT: WEND
28.     PutAni C&, _MOUSEX, _MOUSEY
29.     _DISPLAY
30.     _LIMIT 20
31. LOOP UNTIL _KEYDOWN(27)
32. _MOUSESHOW
33.  
34. FreeAni A& 'clear it from memory
35. FreeAni B&
36. FreeAni C&
37.  
38. '$include:'ani.bm'
39.  

[FellippeHeitor]

Nice, Petr!

I do not have the speed between frames of the shot correct, but that's exactly what I'm doing now.

Maybe you'll need to keep track of the last time a frame is served, store TIMER for reference, and only serve a new frame after that frame's delay is reached.

[Petr]

Hi all,
This version is beta. If some CUR or ANI file is not displayed correctly, send it here and i look at it.Program allow using CUR (static mouse cursors) or ANI (animated mouse cursors), extracting frames from ANI and do some experiments.
Usage:
CursorA& = LOADCURSOR("Cursor.cur")
CursorsB& = LOADCURSOR("CursorB.ani")
load cursors to memory. If CursorA& or CursorB& return -1, is something wrong (file not exist?)

For inserting it to screen use PUTCURSOR CursorA&, coordinate X, coordinate Y
For erase it from memory use FREECURSOR CursorB&

If loaded cursor is ANI file, you can extract frames:
LENCURSOR return number of frames in ANI file, DECOMPOSECURSOR (source&, frame_number) return image.

So is possible easy all frames view:

For Show = 1 to LENCURSOR(CursorA&)
Image& = DECOMPOSECURSOR(Show)
_PUTIMAGE (100,100), image&,0
SLEEP
NEXT

If you call LENCURSOR or DECOMPOSECURSOR to CUR file, it return always -1 as error code.

In attachment is BAS file, BI file, BM file and folder CURSORS contains all CUR and ANI files, on which i test this program. So if you found some, which is not right displayed, please send it
here. Thank you.