Stars (Number guessing program)

[bplus]

I found this program surfing old Basic code and wondered what it was about:

Code: QB64: [Select]

1. 10 Print Tab(34); "STARS"
2. 20 Print Tab(15); "CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
3. 30 Print: Print: Print
4. 100 Rem *** STARS - PEOPLE'S COMPUTER CENTER, MENLO PARK, CA
5. 140 Rem *** A IS LIMIT ON NUMBER, M IS NUMBER OF GUESSES
6. 150 A = 100: M = 7
7. 170 Input "DO YOU WANT INSTRUCTIONS"; A$
8. 190 If Left$(A$, 1) = "N" Then 280
9. 200 Rem *** INSTRUCTIONS ON HOW TO PLAY
10. 210 Print "I AM THINKING OF A WHOLE NUMBER FROM 1 TO"; A
11. 220 Print "TRY TO GUESS MY NUMBER.  AFTER YOU GUESS, I"
12. 230 Print "WILL TYPE ONE OR MORE STARS (*).  THE MORE"
13. 240 Print "STARS I TYPE, THE CLOSER YOU ARE TO MY NUMBER."
14. 250 Print "ONE STAR (*) MEANS FAR AWAY, SEVEN STARS (*******)"
15. 260 Print "MEANS REALLY CLOSE!  YOU GET"; M; "GUESSES."
16. 270 Rem *** COMPUTER THINKS OF A NUMBER
17. 280 Print
18. 290 Print
19. 300 X = Int(A * Rnd(1) + 1)
20. 310 Print "OK, I AM THINKING OF A NUMBER, START GUESSING."
21. 320 Rem *** GUESSING BEGINS, HUMAN GETS M GUESSES
22. 330 For K = 1 To M
23.    340 Print
24.    350 Print "YOUR GUESS";
25.    360 Input G
26.    370 If G = X Then 600
27.    380 D = Abs(G - X)
28.    390 If D >= 64 Then 510
29.    400 If D >= 32 Then 500
30.    410 If D >= 16 Then 490
31.    420 If D >= 8 Then 480
32.    430 If D >= 4 Then 470
33.    440 If D >= 2 Then 460
34.    450 Print "*";
35.    460 Print "*";
36.    470 Print "*";
37.    480 Print "*";
38.    490 Print "*";
39.    500 Print "*";
40.    510 Print "*";
41.    520 Print
42. 530 Next K
43. 540 Rem *** DID NOT GUESS IN M GUESSES
44. 550 Print
45. 560 Print "SORRY, THAT'S"; M; "GUESSES. THE NUMBER WAS"; X
46. 580 GoTo 650
47. 590 Rem *** WE HAVE A WINNER
48. 600 Print: For N = 1 To 79
49.    610 Print "*";
50. 620 Next N
51. 630 Print: Print
52. 640 Print "YOU GOT IT IN"; K; "GUESSES!!!  LET'S PLAY AGAIN..."
53. 650 GoTo 280
54. 660 End
55.  
56.  

I translated to more modern Basic and learned a little about LOGs.

Code: QB64: [Select]

1. _Title "Stars: Guess number 1 to 100, get star rating 1 to 7, get 7 guesses, ...zzz = press any." 'b+ 2021-11-06
2. 1 Cls: Randomize Timer: GoSub StarChart ' start over
3. N = Int(100 * Rnd) + 1: nG = 1: Print ' N 'secret number : nG = number of guesses up to 7 allowed
4. 2 Print " Guess #"; _Trim$(Str$(nG));: Input " enter > ", G
5. If G = N Then Print "That's it in"; nG; "guesses...zzz": Sleep: GoTo 1
6. Print " Rating: "; String$(7 - Int(Log(Abs(G - N)) / Log(2)), "* ")
7. If nG = 7 Then Print "Sorry, that's 7 guesses, the number was"; N; "...zzz": Sleep: GoTo 1
8. nG = nG + 1: GoTo 2 ' another guess
9. StarChart: ' number of stars for number you are off
10. Print Spc(35); "Star Chart:"
11. For i = 1 To 100 ' this also tests my formula to compare to original game
12.     If 7 - Int(Log(i) / Log(2)) <> last Then Print Spc(28); "For"; 7 - Int(Log(i) / Log(2)); "Stars, min off ="; i
13.     last = 7 - Int(Log(i) / Log(2))
14. Next
15. Return
16.  
17. 'Test code for Star Chart LOG and convert to LOG(2) to convert to Star Rating
18. 'For p = 0 To 6
19. '    Print p, Log(2 ^ p) / Log(2) ' yes! When you are of 2 ^ x from number you get 7 - x stars
20. 'Next
21.  
22.  

With the help of the Star Chart (and rewriting the program) it's not hard to pick up the strategy to play the game and usually get the number in 7 guesses.

I should probably reduce the density of the code. It's starting to look like MasterGy's ;-))

[bplus]

Code easier to read and Star Rating easier to count:

Code: QB64: [Select]

1. _Title "Stars: Guess number 1 to 100, get star rating 1 to 7, get 7 guesses, ...zzz = press any." 'b+ 2021-11-06
2. ' 2021-11-07 make code more readable and star rating easier to count
3. Do
4.     Cls
5.     Randomize Timer
6.     GoSub StarChart '                         very helpful for handling star ratings
7.     N = Int(100 * Rnd) + 1 '                  secret number
8.     nG = 1 '                                  reset number of guesses
9.     While nG <= 7 '                           allowing 7 guesses
10.         Print " Guess #"; _Trim$(Str$(nG)); ' show what guess we're on
11.         Input " enter > ", G '                enter guess
12.         If G = N Then Print Spc(26); "That's it in"; nG; "guesses...zzz": Sleep: Exit While
13.         Print " Rating: "; xCopy$(7 - Int(Log(Abs(G - N)) / Log(2)), "* ")
14.         nG = nG + 1
15.     Wend
16.     If nG = 8 Then Print "Sorry, that's 7 guesses, the number was"; N; "...zzz": Sleep
17. Loop
18.  
19. StarChart: '                                  number of stars for number you are off
20. Print Spc(35); "Star Chart:"
21. For i = 1 To 100 '                            this also tests my formula to compare to original game
22.     If 7 - Int(Log(i) / Log(2)) <> last Then Print Spc(28); "For"; 7 - Int(Log(i) / Log(2)); "Stars, min off ="; i
23.     last = 7 - Int(Log(i) / Log(2)) '         convert number difference into star ratimg, save changes as last
24. Next
25. Print
26. Return
27.  
28. 'Test code for Star Chart LOG and convert to LOG(2) to convert to Star Rating
29. 'For p = 0 To 6
30. '    Print p, Log(2 ^ p) / Log(2) ' yes! When you are of 2 ^ x from number you get 7 - x stars
31. 'Next
32.  
33. Function xCopy$ (x, strng$) ' make x copies of string
34.     Dim i As Long, b$
35.     For i = 1 To x
36.         b$ = b$ + strng$
37.     Next
38.     xCopy$ = b$
39. End Function
40.  
41.