String Math

[bplus]

bplus, please explain how you handle big numbers in your nInverse function

@jack  I did once already, in English, no code:
https://www.qb64.org/forum/index.php?topic=3984.msg133309#msg133309

Did you see that?

nInverse of string o 9's looks OK to me>

Code: QB64: [Select]

1. Option _Explicit
2. _Title "String Math 2021-06-14" ' b+ from SM2 (2021 June) a bunch of experiments to fix and improve speeds.
3.  
4. Randomize Timer 'now that it's seems to be running silent
5. Screen _NewImage(1200, 700, 32)
6. _Delay .25
7. _ScreenMove _Middle
8.  
9. 'test new stuff
10. Dim j As Long
11. For j = 1 To 40
12.     Print nInverse$(String$(j, "9"), 100)
13. Next
14. End
15.  
16.  
17. ' This is used in nInverse$ not by Mr$ because there it saves time!
18. Function subtr1$ (a$, b$)
19.     Dim As Long la, lb, lResult, i, ca, cb, w
20.     Dim result$, fa$, fb$
21.  
22.     la = Len(a$): lb = Len(b$)
23.     If la > lb Then lResult = la Else lResult = lb
24.     result$ = Space$(lResult)
25.     fa$ = result$: fb$ = result$
26.     Mid$(fa$, lResult - la + 1) = a$
27.     Mid$(fb$, lResult - lb + 1) = b$
28.     For i = lResult To 1 Step -1
29.         ca = Val(Mid$(fa$, i, 1))
30.         cb = Val(Mid$(fb$, i, 1))
31.         If cb > ca Then ' borrow 10
32.             Mid$(result$, i, 1) = Right$(Str$(10 + ca - cb), 1)
33.             w = i - 1
34.             While w > 0 And Mid$(fa$, w, 1) = "0"
35.                 Mid$(fa$, w, 1) = "9"
36.                 w = w - 1
37.             Wend
38.             Mid$(fa$, w, 1) = Right$(Str$(Val(Mid$(fa$, w, 1)) - 1), 1)
39.         Else
40.             Mid$(result$, i, 1) = Right$(Str$(ca - cb), 1)
41.         End If
42.     Next
43.     subtr1$ = result$
44. End Function
45.  
46. Function TrimLead0$ (s$) 'for treating strings as number (pos integers)
47.     Dim copys$
48.     Dim As Long i, find
49.     copys$ = _Trim$(s$) 'might as well remove spaces too
50.     i = 1: find = 0
51.     While i < Len(copys$) And Mid$(copys$, i, 1) = "0"
52.         i = i + 1: find = 1
53.     Wend
54.     If find = 1 Then copys$ = Mid$(copys$, i)
55.     If copys$ = "" Then TrimLead0$ = "0" Else TrimLead0$ = copys$
56. End Function
57.  
58. ' catchy? mr$ for math regulator  cop$ = " + - * / " 1 of 4 basic arithmetics
59.  
60. ' This uses Subtr1$ is Positive Integer only!
61. ' DP = Decimal places = says when to quit if don't find perfect divisor before
62. Function nInverse$ (n$, DP As Long) 'assume decimal at very start of the string of digits returned
63.     Dim m$(1 To 9), si$, r$, outstr$, d$
64.     Dim i As Long
65.     For i = 1 To 9
66.         si$ = _Trim$(Str$(i))
67.         m$(i) = mult$(si$, n$)
68.     Next
69.     outstr$ = ""
70.     If n$ = "0" Then nInverse$ = "Div 0": Exit Function
71.     If n$ = "1" Then nInverse$ = "1": Exit Function
72.     outstr$ = "." 'everything else n > 1 is decimal 8/17
73.     r$ = "10"
74.     Do
75.         While LT(r$, n$) ' 2021-06-08 this should be strictly Less Than
76.             outstr$ = outstr$ + "0" '            add 0 to the  output string
77.             If Len(outstr$) = DP + 1 Then nInverse$ = outstr$: Exit Function 'DP length?
78.             r$ = r$ + "0"
79.         Wend
80.         For i = 9 To 1 Step -1
81.             If LTE(m$(i), r$) Then d$ = _Trim$(Str$(i)): Exit For
82.         Next
83.         outstr$ = outstr$ + d$
84.         If Len(outstr$) = DP + 1 Then nInverse$ = outstr$: Exit Function
85.         r$ = subtr1$(r$, mult$(d$, n$)) 'r = r -d*n    ' 2021-06-08 subtr1 works faster
86.         If TrimLead0$(r$) = "0" Then nInverse$ = outstr$: Exit Function ' add trimlead0$ 6/08
87.         r$ = r$ + "0" 'add another place
88.     Loop
89. End Function
90.  
91. Function mult$ (a$, b$) 'assume both positive integers prechecked as all digits strings
92.     Dim As Long la, lb, m, g, dp
93.     Dim As _Unsigned _Integer64 v18, sd, co
94.     Dim f18$, f1$, t$, build$, accum$
95.  
96.     If a$ = "0" Then mult$ = "0": Exit Function
97.     If b$ = "0" Then mult$ = "0": Exit Function
98.     If a$ = "1" Then mult$ = b$: Exit Function
99.     If b$ = "1" Then mult$ = a$: Exit Function
100.     'find the longer number and make it a mult of 18 to take 18 digits at a time from it
101.     la = Len(a$): lb = Len(b$)
102.     If la > lb Then
103.         m = Int(la / 18) + 1
104.         f18$ = Right$(String$(m * 18, "0") + a$, m * 18)
105.         f1$ = b$
106.     Else
107.         m = Int(lb / 18) + 1
108.         f18$ = Right$(String$(m * 18, "0") + b$, m * 18)
109.         f1$ = a$
110.     End If
111.     For dp = Len(f1$) To 1 Step -1 'dp = digit position of the f1$
112.         build$ = "" 'line builder
113.         co = 0
114.         'now taking 18 digits at a time Thanks Steve McNeill
115.         For g = 1 To m
116.             v18 = Val(Mid$(f18$, (m - g) * 18 + 1, 18))
117.             sd = Val(Mid$(f1$, dp, 1))
118.             t$ = Right$(String$(19, "0") + _Trim$(Str$(v18 * sd + co)), 19)
119.             co = Val(Mid$(t$, 1, 1))
120.             build$ = Mid$(t$, 2) + build$
121.         Next g
122.         If co Then build$ = _Trim$(Str$(co)) + build$
123.         If dp = Len(f1$) Then
124.             accum$ = build$
125.         Else
126.             accum$ = add$(accum$, build$ + String$(Len(f1$) - dp, "0"))
127.         End If
128.     Next dp
129.     mult$ = accum$
130. End Function
131.  
132. ' LTE    Less Than or Equal for 2 Big numbers in String form
133. 'this function needs TrimLead0$(s$)
134. Function LTE (a$, b$) ' a$ Less Than or Equal b$  comparison of 2 strings
135.     Dim ca$, cb$
136.     Dim As Long la, lb, i
137.     ca$ = TrimLead0$(a$): cb$ = TrimLead0(b$)
138.     la = Len(ca$): lb = Len(cb$)
139.     If ca$ = cb$ Then
140.         LTE = -1
141.     ElseIf la < lb Then ' a is smaller
142.         LTE = -1
143.     ElseIf la > lb Then ' a is bigger
144.         LTE = 0
145.     ElseIf la = lb Then ' equal lengths
146.         For i = 1 To Len(ca$)
147.             If Val(Mid$(ca$, i, 1)) > Val(Mid$(cb$, i, 1)) Then
148.                 LTE = 0: Exit Function
149.             ElseIf Val(Mid$(ca$, i, 1)) < Val(Mid$(cb$, i, 1)) Then
150.                 LTE = -1: Exit Function
151.             End If
152.         Next
153.     End If
154. End Function
155.  
156.  
157. 'need this for ninverse faster than subtr$ for sign
158. Function LT (a$, b$) ' a$ Less Than or Equal b$  comparison of 2 strings
159.     Dim ca$, cb$
160.     Dim As Long la, lb, i
161.     ca$ = TrimLead0$(a$): cb$ = TrimLead0(b$)
162.     la = Len(ca$): lb = Len(cb$)
163.     If la < lb Then ' a is smaller
164.         LT = -1
165.     ElseIf la > lb Then ' a is bigger
166.         LT = 0
167.     ElseIf la = lb Then ' equal lengths
168.         For i = 1 To Len(ca$)
169.             If Val(Mid$(ca$, i, 1)) > Val(Mid$(cb$, i, 1)) Then
170.                 LT = 0: Exit Function
171.             ElseIf Val(Mid$(ca$, i, 1)) < Val(Mid$(cb$, i, 1)) Then
172.                 LT = -1: Exit Function
173.             End If
174.         Next
175.     End If
176. End Function
177.  
178. Function add$ (a$, b$) 'add 2 positive integers assume a and b are just numbers no - signs
179.     'set a and b numbers to same length and multiple of 18 so can take 18 digits at a time
180.     Dim As Long la, lb, m, g
181.     Dim sa As _Unsigned _Integer64, sb As _Unsigned _Integer64, co As _Unsigned _Integer64
182.     Dim fa$, fb$, t$, new$, result$
183.     la = Len(a$): lb = Len(b$)
184.     If la > lb Then m = Int(la / 18) + 1 Else m = Int(lb / 18) + 1
185.     fa$ = Right$(String$(m * 18, "0") + a$, m * 18)
186.     fb$ = Right$(String$(m * 18, "0") + b$, m * 18)
187.  
188.     'now taking 18 digits at a time Thanks Steve McNeill
189.     For g = 1 To m
190.         sa = Val(Mid$(fa$, (m - g) * 18 + 1, 18))
191.         sb = Val(Mid$(fb$, (m - g) * 18 + 1, 18))
192.         t$ = Right$(String$(36, "0") + _Trim$(Str$(sa + sb + co)), 36)
193.         co = Val(Mid$(t$, 1, 18))
194.         new$ = Mid$(t$, 19)
195.         result$ = new$ + result$
196.     Next
197.     If co Then result$ = Str$(co) + result$
198.     add$ = result$
199. End Function
200.  
201.  

 

All you guys are posting allot of interesting things for handling Big Numbers, wish I had more time to study all these  wonderful ideas, soon I hope.

[jack]

bplus, yes the string of 9's work ok but if you feedback the result of that into nInverse to get back the original number it fails
BTW TreeBeard's division is pretty fast, 1/999999999999999999999998999999999999999999999999 to 2785 digits in 0.054 seconds

[bplus]

bplus, yes the string of 9's work ok but if you feedback the result of that into nInverse to get back the original number it fails
BTW TreeBeard's division is pretty fast, 1/999999999999999999999998999999999999999999999999 to 2785 digits in 0.054 seconds

nInverse only meant to work on positive Integers.

[bplus]

OK nInverse$ can only do positive integers but Mr$ can Divide$ any number into 1 so this!

An inverse of a string o 9s and then divide$ through mr$ the result into 1 reversing the inverse!
BUT only show 1 or 2 places in decimal and when nInverse$ use way more than 100 Decimal places but only show first 100 so screens continue to make sense, when see ZZZ that means SLEEPing press any key...

Thusly we can run pretty impressive string of 9's.

Code: QB64: [Select]

1. Option _Explicit
2. _Title "String Math 2021-06-14" ' b+ from SM2 (2021 June) a bunch of experiments to fix and improve speeds.
3. ' June 2021 fix some old String Math procedures, better nInverse with new LT frunction, remove experimental procedures.
4. ' Now with decent sqrRoot it works independent of Mr$() = Math Regulator that handles signs and decimals and calls to
5. ' add$(), subtr$, mult$, divide$ (100 significant digits),  add$(), subtr$, mult$ are exact!
6. ' If you need higher precsion divide, I recommend use nInverse on denominator (integer)
7. ' then add sign and decimal and mult$() that number with numerator to get divsion answer in higher precision than 100.
8. ' (See how Mr$() handles division and just call nInverse$ with what precision you need.)
9. ' The final function showDP$() is for displaying these number to a set amount of Decimal Places.
10.  
11. ' The main code is sampler of tests performed with these functions.
12.  
13. Randomize Timer 'now that it's seems to be running silent
14. Screen _NewImage(1200, 700, 32)
15. _Delay .25
16. _ScreenMove _Middle
17.  
18. 'test new stuff
19. Dim j As Long, inv$, invinv$
20. For j = 1 To 200
21.     inv$ = nInverse$(String$(j, "9"), 1000)
22.     invinv$ = mr$("1", "/", inv$)
23.     Print showDP(inv$, 100)
24.     Print showDP$(invinv$, 2)
25.     If j Mod 20 = 0 Then Print "ZZZ...": Sleep
26. Next
27. End
28.  
29.  
30. Function add$ (a$, b$) 'add 2 positive integers assume a and b are just numbers no - signs
31.     'set a and b numbers to same length and multiple of 18 so can take 18 digits at a time
32.     Dim As Long la, lb, m, g
33.     Dim sa As _Unsigned _Integer64, sb As _Unsigned _Integer64, co As _Unsigned _Integer64
34.     Dim fa$, fb$, t$, new$, result$
35.     la = Len(a$): lb = Len(b$)
36.     If la > lb Then m = Int(la / 18) + 1 Else m = Int(lb / 18) + 1
37.     fa$ = Right$(String$(m * 18, "0") + a$, m * 18)
38.     fb$ = Right$(String$(m * 18, "0") + b$, m * 18)
39.  
40.     'now taking 18 digits at a time Thanks Steve McNeill
41.     For g = 1 To m
42.         sa = Val(Mid$(fa$, (m - g) * 18 + 1, 18))
43.         sb = Val(Mid$(fb$, (m - g) * 18 + 1, 18))
44.         t$ = Right$(String$(36, "0") + _Trim$(Str$(sa + sb + co)), 36)
45.         co = Val(Mid$(t$, 1, 18))
46.         new$ = Mid$(t$, 19)
47.         result$ = new$ + result$
48.     Next
49.     If co Then result$ = Str$(co) + result$
50.     add$ = result$
51. End Function
52.  
53. ' This is used in nInverse$ not by Mr$ because there it saves time!
54. Function subtr1$ (a$, b$)
55.     Dim As Long la, lb, lResult, i, ca, cb, w
56.     Dim result$, fa$, fb$
57.  
58.     la = Len(a$): lb = Len(b$)
59.     If la > lb Then lResult = la Else lResult = lb
60.     result$ = Space$(lResult)
61.     fa$ = result$: fb$ = result$
62.     Mid$(fa$, lResult - la + 1) = a$
63.     Mid$(fb$, lResult - lb + 1) = b$
64.     For i = lResult To 1 Step -1
65.         ca = Val(Mid$(fa$, i, 1))
66.         cb = Val(Mid$(fb$, i, 1))
67.         If cb > ca Then ' borrow 10
68.             Mid$(result$, i, 1) = Right$(Str$(10 + ca - cb), 1)
69.             w = i - 1
70.             While w > 0 And Mid$(fa$, w, 1) = "0"
71.                 Mid$(fa$, w, 1) = "9"
72.                 w = w - 1
73.             Wend
74.             Mid$(fa$, w, 1) = Right$(Str$(Val(Mid$(fa$, w, 1)) - 1), 1)
75.         Else
76.             Mid$(result$, i, 1) = Right$(Str$(ca - cb), 1)
77.         End If
78.     Next
79.     subtr1$ = result$
80. End Function
81.  
82. ' 2021-06-08 fix up with new mr call that decides the sign and puts the greater number first
83. Function subtr$ (sum$, minus$) ' assume both numbers are positive all digits
84.     Dim As Long m, g, p
85.     Dim VB As _Unsigned _Integer64, vs As _Unsigned _Integer64, tenE18 As _Unsigned _Integer64
86.     Dim ts$, tm$, sign$, LG$, sm$, t$, result$
87.  
88.     ts$ = _Trim$(sum$): tm$ = _Trim$(minus$) ' fixed subtr$ 2021-06-05
89.     If trim0(ts$) = trim0$(tm$) Then subtr$ = "0": Exit Function 'proceed knowing not equal
90.     tenE18 = 1000000000000000000 'yes!!! no dang E's
91.     sign$ = ""
92.     m = Int(Len(ts$) / 18) + 1
93.     LG$ = Right$(String$(m * 18, "0") + ts$, m * 18)
94.     sm$ = Right$(String$(m * 18, "0") + tm$, m * 18)
95.  
96.     'now taking 18 digits at a time From Steve I learned we can do more than 1 digit at a time
97.     For g = 1 To m
98.         VB = Val(Mid$(LG$, m * 18 - g * 18 + 1, 18))
99.         vs = Val(Mid$(sm$, m * 18 - g * 18 + 1, 18))
100.         If vs > VB Then
101.             t$ = Right$(String$(18, "0") + _Trim$(Str$(tenE18 - vs + VB)), 18)
102.             p = (m - g) * 18
103.             While p > 0 And Mid$(LG$, p, 1) = "0"
104.                 Mid$(LG$, p, 1) = "9"
105.                 p = p - 1
106.             Wend
107.             If p > 0 Then Mid$(LG$, p, 1) = _Trim$(Str$(Val(Mid$(LG$, p, 1)) - 1))
108.         Else
109.             t$ = Right$(String$(18, "0") + _Trim$(Str$(VB - vs)), 18)
110.         End If
111.         result$ = t$ + result$
112.     Next
113.     subtr$ = result$
114. End Function
115.  
116. Function TrimLead0$ (s$) 'for treating strings as number (pos integers)
117.     Dim copys$
118.     Dim As Long i, find
119.     copys$ = _Trim$(s$) 'might as well remove spaces too
120.     i = 1: find = 0
121.     While i < Len(copys$) And Mid$(copys$, i, 1) = "0"
122.         i = i + 1: find = 1
123.     Wend
124.     If find = 1 Then copys$ = Mid$(copys$, i)
125.     If copys$ = "" Then TrimLead0$ = "0" Else TrimLead0$ = copys$
126. End Function
127.  
128. ' catchy? mr$ for math regulator  cop$ = " + - * / " 1 of 4 basic arithmetics
129. ' Fixed so that add and subtract have signs calc'd in Mr and correct call to add or subtract made
130. ' with bigger minus smaller in subtr$() call
131. Function mr$ (a$, cop$, b$)
132.     Dim op$, ca$, cb$, aSgn$, bSgn$, postOp$, sgn$
133.     Dim As Long adp, bdp, dp, lpop, aLTb
134.  
135.     op$ = _Trim$(cop$) 'save fixing each time
136.     ca$ = _Trim$(a$): cb$ = _Trim$(b$) 'make copies in case we change
137.     'strip signs and decimals
138.     If Left$(ca$, 1) = "-" Then
139.         aSgn$ = "-": ca$ = Mid$(ca$, 2)
140.     Else
141.         aSgn$ = ""
142.     End If
143.     dp = InStr(ca$, ".")
144.     If dp > 0 Then
145.         adp = Len(ca$) - dp
146.         ca$ = Mid$(ca$, 1, dp - 1) + Mid$(ca$, dp + 1)
147.     Else
148.         adp = 0
149.     End If
150.     If Left$(cb$, 1) = "-" Then
151.         bSgn$ = "-": cb$ = Mid$(cb$, 2)
152.     Else
153.         bSgn$ = ""
154.     End If
155.     dp = InStr(cb$, ".")
156.     If dp > 0 Then
157.         bdp = Len(cb$) - dp
158.         cb$ = Mid$(cb$, 1, dp - 1) + Mid$(cb$, dp + 1)
159.     Else
160.         bdp = 0
161.     End If
162.     If op$ = "+" Or op$ = "-" Or op$ = "/" Then 'add or subtr  even up strings on right of decimal
163.         'even up the right sides of decimals if any
164.         If adp > bdp Then dp = adp Else dp = bdp
165.         If adp < dp Then ca$ = ca$ + String$(dp - adp, "0")
166.         If bdp < dp Then cb$ = cb$ + String$(dp - bdp, "0")
167.     ElseIf op$ = "*" Then
168.         dp = adp + bdp
169.     End If
170.     If op$ = "*" Or op$ = "/" Then
171.         If aSgn$ = bSgn$ Then sgn$ = "" Else sgn$ = "-"
172.     End If
173.  
174.     'now according to signs and op$ call add$ or subtr$
175.     If op$ = "-" Then ' make it adding according to signs because that is done for + next!
176.         If bSgn$ = "-" Then bSgn$ = "" Else bSgn$ = "-" ' flip bSgn$ with op$
177.         op$ = "+" ' turn this over to + op already done! below
178.     End If
179.     If op$ = "+" Then
180.         If aSgn$ = bSgn$ Then 'really add
181.             postOp$ = add$(ca$, cb$)
182.             sgn$ = aSgn$
183.         ElseIf aSgn$ <> bSgn$ Then 'have a case of subtraction
184.             'but which is first and which is 2nd and should final sign be pos or neg
185.             If TrimLead0$(ca$) = TrimLead0(cb$) Then 'remove case a = b
186.                 mr$ = "0": Exit Function
187.             Else
188.                 aLTb = LTE(ca$, cb$)
189.                 If aSgn$ = "-" Then
190.                     If aLTb Then ' b - a = pos
191.                         postOp$ = subtr$(cb$, ca$)
192.                         sgn$ = ""
193.                     Else '  a > b so a - sgn wins  - (a - b)
194.                         postOp$ = subtr$(ca$, cb$)
195.                         sgn$ = "-"
196.                     End If
197.                 Else ' b has the - sgn
198.                     If aLTb Then ' result is -
199.                         postOp$ = subtr$(cb$, ca$)
200.                         sgn$ = "-"
201.                     Else ' result is pos
202.                         postOp$ = subtr$(ca$, cb$)
203.                         sgn$ = ""
204.                     End If
205.                 End If
206.             End If
207.         End If
208.     ElseIf op$ = "*" Then
209.         postOp$ = mult$(ca$, cb$)
210.     ElseIf op$ = "/" Then
211.         postOp$ = divide$(ca$, cb$)
212.     End If ' which op
213.     If op$ <> "/" Then 'put dp back
214.         lpop = Len(postOp$) ' put decimal back if there is non zero stuff following it
215.         If Len(Mid$(postOp$, lpop - dp + 1)) Then ' fix 1 extra dot appearing in 10000! ?!
216.             If TrimLead0$(Mid$(postOp$, lpop - dp + 1)) <> "0" Then '  .0   or .00 or .000  ??
217.                 postOp$ = Mid$(postOp$, 1, lpop - dp) + "." + Mid$(postOp$, lpop - dp + 1)
218.             End If
219.         End If
220.     End If
221.     mr$ = trim0$(postOp$) 'trim lead 0's then tack on sign
222.     If mr$ <> "0" Then mr$ = sgn$ + mr$
223. End Function
224.  
225. Function divide$ (n$, d$) ' goal here is 100 digits precision not 100 digits past decimal
226.     Dim di$, ndi$
227.     Dim As Long nD
228.     If n$ = "0" Then divide$ = "0": Exit Function
229.     If d$ = "0" Then divide$ = "div 0": Exit Function
230.     If d$ = "1" Then divide$ = n$: Exit Function
231.  
232.     ' aha! found a bug when d$ gets really huge 100 is no where near enough!!!!
233.     ' 2021-06-03 fix by adding 100 to len(d$), plus have to go a little past 100 like 200
234.     di$ = Mid$(nInverse$(d$, Len(d$) + 200), 2) 'chop off decimal point after
235.     nD = Len(di$)
236.     ndi$ = mult$(n$, di$)
237.     ndi$ = Mid$(ndi$, 1, Len(ndi$) - nD) + "." + Right$(String$(nD, "0") + Right$(ndi$, nD), nD)
238.     divide$ = ndi$
239. End Function
240.  
241. ' This uses Subtr1$ is Positive Integer only!
242. ' DP = Decimal places = says when to quit if don't find perfect divisor before
243. Function nInverse$ (n$, DP As Long) 'assume decimal at very start of the string of digits returned
244.     Dim m$(1 To 9), si$, r$, outstr$, d$
245.     Dim i As Long
246.     For i = 1 To 9
247.         si$ = _Trim$(Str$(i))
248.         m$(i) = mult$(si$, n$)
249.     Next
250.     outstr$ = ""
251.     If n$ = "0" Then nInverse$ = "Div 0": Exit Function
252.     If n$ = "1" Then nInverse$ = "1": Exit Function
253.     outstr$ = "." 'everything else n > 1 is decimal 8/17
254.     r$ = "10"
255.     Do
256.         While LT(r$, n$) ' 2021-06-08 this should be strictly Less Than
257.             outstr$ = outstr$ + "0" '            add 0 to the  output string
258.             If Len(outstr$) = DP + 1 Then nInverse$ = outstr$: Exit Function 'DP length?
259.             r$ = r$ + "0"
260.         Wend
261.         For i = 9 To 1 Step -1
262.             If LTE(m$(i), r$) Then d$ = _Trim$(Str$(i)): Exit For
263.         Next
264.         outstr$ = outstr$ + d$
265.         If Len(outstr$) = DP + 1 Then nInverse$ = outstr$: Exit Function
266.         r$ = subtr1$(r$, mult$(d$, n$)) 'r = r -d*n    ' 2021-06-08 subtr1 works faster
267.         If TrimLead0$(r$) = "0" Then nInverse$ = outstr$: Exit Function ' add trimlead0$ 6/08
268.         r$ = r$ + "0" 'add another place
269.     Loop
270. End Function
271.  
272. Function mult$ (a$, b$) 'assume both positive integers prechecked as all digits strings
273.     Dim As Long la, lb, m, g, dp
274.     Dim As _Unsigned _Integer64 v18, sd, co
275.     Dim f18$, f1$, t$, build$, accum$
276.  
277.     If a$ = "0" Then mult$ = "0": Exit Function
278.     If b$ = "0" Then mult$ = "0": Exit Function
279.     If a$ = "1" Then mult$ = b$: Exit Function
280.     If b$ = "1" Then mult$ = a$: Exit Function
281.     'find the longer number and make it a mult of 18 to take 18 digits at a time from it
282.     la = Len(a$): lb = Len(b$)
283.     If la > lb Then
284.         m = Int(la / 18) + 1
285.         f18$ = Right$(String$(m * 18, "0") + a$, m * 18)
286.         f1$ = b$
287.     Else
288.         m = Int(lb / 18) + 1
289.         f18$ = Right$(String$(m * 18, "0") + b$, m * 18)
290.         f1$ = a$
291.     End If
292.     For dp = Len(f1$) To 1 Step -1 'dp = digit position of the f1$
293.         build$ = "" 'line builder
294.         co = 0
295.         'now taking 18 digits at a time Thanks Steve McNeill
296.         For g = 1 To m
297.             v18 = Val(Mid$(f18$, (m - g) * 18 + 1, 18))
298.             sd = Val(Mid$(f1$, dp, 1))
299.             t$ = Right$(String$(19, "0") + _Trim$(Str$(v18 * sd + co)), 19)
300.             co = Val(Mid$(t$, 1, 1))
301.             build$ = Mid$(t$, 2) + build$
302.         Next g
303.         If co Then build$ = _Trim$(Str$(co)) + build$
304.         If dp = Len(f1$) Then
305.             accum$ = build$
306.         Else
307.             accum$ = add$(accum$, build$ + String$(Len(f1$) - dp, "0"))
308.         End If
309.     Next dp
310.     mult$ = accum$
311. End Function
312.  
313. 'this function needs TrimLead0$(s$)
314. Function LTE (a$, b$) ' a$ Less Than or Equal b$  comparison of 2 strings
315.     Dim ca$, cb$
316.     Dim As Long la, lb, i
317.     ca$ = TrimLead0$(a$): cb$ = TrimLead0(b$)
318.     la = Len(ca$): lb = Len(cb$)
319.     If ca$ = cb$ Then
320.         LTE = -1
321.     ElseIf la < lb Then ' a is smaller
322.         LTE = -1
323.     ElseIf la > lb Then ' a is bigger
324.         LTE = 0
325.     ElseIf la = lb Then ' equal lengths
326.         For i = 1 To Len(ca$)
327.             If Val(Mid$(ca$, i, 1)) > Val(Mid$(cb$, i, 1)) Then
328.                 LTE = 0: Exit Function
329.             ElseIf Val(Mid$(ca$, i, 1)) < Val(Mid$(cb$, i, 1)) Then
330.                 LTE = -1: Exit Function
331.             End If
332.         Next
333.     End If
334. End Function
335.  
336. 'need this for ninverse faster than subtr$ for sign
337. Function LT (a$, b$) ' a$ Less Than or Equal b$  comparison of 2 strings
338.     Dim ca$, cb$
339.     Dim As Long la, lb, i
340.     ca$ = TrimLead0$(a$): cb$ = TrimLead0(b$)
341.     la = Len(ca$): lb = Len(cb$)
342.     If la < lb Then ' a is smaller
343.         LT = -1
344.     ElseIf la > lb Then ' a is bigger
345.         LT = 0
346.     ElseIf la = lb Then ' equal lengths
347.         For i = 1 To Len(ca$)
348.             If Val(Mid$(ca$, i, 1)) > Val(Mid$(cb$, i, 1)) Then
349.                 LT = 0: Exit Function
350.             ElseIf Val(Mid$(ca$, i, 1)) < Val(Mid$(cb$, i, 1)) Then
351.                 LT = -1: Exit Function
352.             End If
353.         Next
354.     End If
355. End Function
356.  
357. Function TrimTail0$ (s$)
358.     Dim copys$
359.     Dim As Long dp, i, find
360.     copys$ = _Trim$(s$) 'might as well remove spaces too
361.     TrimTail0$ = copys$
362.     dp = InStr(copys$, ".")
363.     If dp > 0 Then
364.         i = Len(copys$): find = 0
365.         While i > dp And Mid$(copys$, i, 1) = "0"
366.             i = i - 1: find = 1
367.         Wend
368.         If find = 1 Then
369.             If i = dp Then
370.                 TrimTail0$ = Mid$(copys$, 1, dp - 1)
371.             Else
372.                 TrimTail0$ = Mid$(copys$, 1, i)
373.             End If
374.         End If
375.     End If
376. End Function
377.  
378. Function trim0$ (s$)
379.     Dim cs$, si$
380.     cs$ = s$
381.     si$ = Left$(cs$, 1)
382.     If si$ = "-" Then cs$ = Mid$(cs$, 2)
383.     cs$ = TrimLead0$(cs$)
384.     cs$ = TrimTail0$(cs$)
385.     If Right$(cs$, 1) = "." Then cs$ = Mid$(cs$, 1, Len(cs$) - 1)
386.     If si$ = "-" Then trim0$ = si$ + cs$ Else trim0$ = cs$
387. End Function
388.  
389. ' for displaying truncated numbers say to 60 digits
390. Function showDP$ (num$, nDP As Long)
391.     Dim cNum$
392.     Dim As Long dp, d, i
393.     cNum$ = num$ 'since num$ could get changed
394.     showDP$ = num$
395.     dp = InStr(num$, ".")
396.     If dp > 0 Then
397.         If Len(Mid$(cNum$, dp + 1)) > nDP Then
398.             d = Val(Mid$(cNum$, dp + nDP + 1, 1))
399.             If d > 4 Then
400.                 cNum$ = "0" + cNum$ ' tack on another 0 just in case 9's all the way to left
401.                 dp = dp + 1
402.                 i = dp + nDP
403.                 While Mid$(cNum$, i, 1) = "9" Or Mid$(cNum$, i, 1) = "."
404.                     If Mid$(cNum$, i, 1) = "9" Then
405.                         Mid$(cNum$, i, 1) = "0"
406.                     End If
407.                     i = i - 1
408.                 Wend
409.                 Mid$(cNum$, i, 1) = _Trim$(Str$(Val(Mid$(cNum$, i, 1)) + 1)) 'last non 9 digit
410.                 cNum$ = Mid$(cNum$, 1, dp + nDP) 'chop it
411.                 showDP$ = trim0$(cNum$)
412.             Else
413.                 showDP$ = Mid$(cNum$, 1, dp + nDP)
414.             End If
415.         End If
416.     End If
417. End Function
418.