Experimental Input Box

[SMcNeill]

So STx was talking about turning the OEInput into one that could create an ASCII input box (refer: https://www.qb64.org/forum/index.php?topic=1954.msg129200#msg129200 ), and I thought about doing that...

...Then I thought, why don't I just do something completely different and create a graphical input box that'll even work with SCREEN 0 screens??

And that's what we're seeing here:

Code: QB64: [Select]

1. $COLOR:32
2.  
3. 'Just some basic SCREEN 0 stuff to show that we're not messing with our background at all
4. CLS , 1 'dark blue in screen 0
5. PRINT "Foobie Foo FOO!"
6. FOR I = 0 TO 15
7.     COLOR I
8.     PRINT "This is COLOR"; I
9. NEXT
10.  
11. SLEEP: _DELAY .25: _KEYCLEAR
12.  
13. result$ = InBox$("Input Box", "Generic User Input Goes Here") 'And here's a generic input box!
14. PRINT "YOU ENTERED ==> "; result$
15. 'And you can see the screen itself was maintained 100% as we had it before
16.  
17. SLEEP: _DELAY .25: _KEYCLEAR
18. InBox_Place -1, -1
19. InBox_Size 300, 300
20. InBox_Backgrounds _LOADIMAGE("cemetery.jpg", 32), 0
21. InBox_Frame 3, Gold
22. InBox_Title _LOADFONT("courbd.ttf", 32, "monospace"), SkyBlue, -1, Red, Blue
23. InBox_Message _LOADFONT("courbd.ttf", 24, "monospace"), _LOADIMAGE("marble.jpg", 32), -1, &HFFFF0000&&, 0
24. InBox_Input _LOADFONT("courbd.ttf", 18, "monospace"), LightGray, -1, Red, Blue
25. result$ = InBox$("Math Box For Dummies", "Enter some maths!")
26. PRINT "YOU ENTERED ==> "; result$
27.  
28.  
29. SUB Inbox_reset
30.     TYPE UDT
31.         AS INTEGER X, Y, Wide, High, ErrorCode, Box_Justify_Hort, Box_Justify_Vert
32.         AS INTEGER TitleFont, FrameSize, Title_Xoffset
33.         AS INTEGER MessageFont, Message_Xoffset
34.         AS INTEGER InputFont, Input_Xoffset, Inbox_Init
35.         AS _INTEGER64 Screen_Background, Box_Background, Title_Background, Message_Background, Input_Background
36.         AS _UNSIGNED LONG FrameColor, Title_Font_TextColor, Title_Font_TextBackColor
37.         AS _UNSIGNED LONG Message_Font_TextColor, Message_Font_TextBackColor
38.         AS _UNSIGNED LONG Input_Font_TextColor, Input_Font_TextBackColor
39.         AS STRING Title, Message
40.     END TYPE
41.     SHARED InBox_Info AS UDT
42.     'Default Inbox values
43.     InBox_Info.Inbox_Init = -1
44.     InBox_Place -1, -1
45.     InBox_Size 400, 200
46.     InBox_Backgrounds 0, &HFF000000&&
47.     InBox_Frame 3, &HFFFFFFFF&&
48.     InBox_Title 16, &HFF000000&&, -1, &HFFFFFFFF&&, &HFF000000&&
49.     InBox_Message 16, &HFF000000&&, -1, &HFFFFFFFF&&, &HFF000000&&
50.     InBox_Input 16, &HFFD3D3D3&&, -1, &HFF000000&&, 0
51. END SUB
52.  
53. FUNCTION InBox$ (Title AS STRING, Prompt AS STRING)
54.     SHARED InBox_Info AS UDT
55.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
56.     'InBox_Info.ErrorCode
57.     '1 = Attempting to make box wider than current screen allows.
58.     '2 = Attempting to make box taller than current screen allows.
59.     '3 = Attempting to place box off the left side of the allowable screen.
60.     '4 = Attempting to place box above the top of the allowable screen.
61.     '5 = Attempting to place box off the right side of the allowable screen.
62.     '6 = Attempting to place box below the bottom of the allowable screen.
63.     '7 = Invalid screen background image
64.     '8 = Invalid box background image
65.     '9 = Invalid box frame color
66.     '10 = Invalid title font handle
67.     '11 = Invalid title Xoffset (probably trying to print off the box)
68.     '12 = Invalid message font handle
69.  
70.     STATIC AS LONG W, H, BPP, InBox_Software_Handle 'These are defined as STATIC as they're common variable
71.     STATIC AS LONG D, S '                            names, and like this they won't interfer with any dummies
72.     STATIC AS _INTEGER64 Xoffset '                   DIM SHARED variables.
73.  
74.     REDIM WordWrap(0) AS STRING '                    Redimmable array to hold properly formated word wrap text
75.  
76.  
77.     D = _DEST: S = _SOURCE '                         Initial global state variables
78.     A = _AUTODISPLAY
79.  
80.     W = _WIDTH: H = _HEIGHT: BPP = _PIXELSIZE
81.     IF BPP = 0 THEN W = W * _FONTWIDTH: H = H * _FONTHEIGHT 'calculate text screen size, in pixels
82.     InBox_Software_Handle = _NEWIMAGE(W, H, 32) '    Image size for our whole screen
83.  
84.  
85.     IF InBox_Info.Wide > W THEN InBox_Info.ErrorCode = 1: GOTO clean_exit
86.     IF InBox_Info.High > H THEN InBox_Info.ErrorCode = 2: GOTO clean_exit
87.     IF InBox_Info.X < 0 THEN InBox_Info.ErrorCode = 3: GOTO clean_exit
88.     IF InBox_Info.Y < 0 THEN InBox_Info.ErrorCode = 4: GOTO clean_exit
89.     IF InBox_Info.X > W - InBox_Info.Wide THEN InBox_Info.ErrorCode = 5: GOTO clean_exit
90.     IF InBox_Info.Y > H - InBox_Info.High THEN InBox_Info.ErrorCode = 6: GOTO clean_exit
91.     IF InBox_Info.Screen_Background = -1 OR InBox_Info.Screen_Background > &HFFFFFFFF&& THEN InBox_Info.ErrorCode = 7: GOTO clean_exit
92.     IF InBox_Info.Box_Background = -1 OR InBox_Info.Box_Background > &HFFFFFFFF&& THEN InBox_Info.ErrorCode = 8: GOTO clean_exit
93.     IF InBox_Info.FrameColor < 0 OR InBox_Info.FrameColor > &HFFFFFFFF&& THEN InBox_Info.ErrorCode = 9: GOTO clean_exit
94.     IF InBox_Info.TitleFont <= 0 THEN InBox_Info.ErrorCode = 10: GOTO clean_exit
95.     IF InBox_Info.MessageFont <= 0 THEN InBox_Info.ErrorCode = 12: GOTO clean_exit
96.  
97.  
98.     IF InBox_Info.Box_Justify_Hort THEN InBox_Info.X = (W - InBox_Info.Wide) \ 2
99.     IF InBox_Info.Box_Justify_Vert THEN InBox_Info.Y = (H - InBox_Info.High) \ 2
100.     InBox_Info.Title = Title: InBox_Info.Message = Prompt
101.  
102.     _DEST InBox_Software_Handle: _SOURCE InBox_Software_Handle
103.  
104.     'Stuff which we only draw once
105.  
106.     'This is the background for the whole screen, which we can use to cover up the original
107.     IF InBox_Info.Screen_Background < -1 THEN
108.         _PUTIMAGE (0, 0)-(W, H), InBox_Info.Screen_Background
109.     ELSE
110.         CLS , InBox_Info.Screen_Background
111.     END IF
112.  
113.     'This is the background for the box itself.  Color or image, it doesn't matter.
114.     IF InBox_Info.Box_Background < -1 THEN
115.         _PUTIMAGE (InBox_Info.X, InBox_Info.Y)-STEP(InBox_Info.Wide, InBox_Info.High), InBox_Info.Box_Background
116.     ELSE
117.         LINE (InBox_Info.X, InBox_Info.Y)-STEP(InBox_Info.Wide, InBox_Info.High), InBox_Info.Box_Background, BF
118.     END IF
119.  
120.     'This draws the frame around the whole box.
121.     FOR I = 0 TO InBox_Info.FrameSize - 1
122.         LINE (InBox_Info.X + I, InBox_Info.Y + I)-STEP(InBox_Info.Wide - 2 * I, InBox_Info.High - 2 * I), InBox_Info.FrameColor, B
123.     NEXT
124.  
125.  
126.     'and here we gather our information on what parts of the box is left for us to draw/write inside.
127.     top = InBox_Info.Y + I: left = InBox_Info.X + I: right = left + InBox_Info.Wide - 2 * I: bottom = top + InBox_Info.High - 2 * I
128.  
129.  
130.     '*****************************************  START TITLE *****************************************
131.  
132.     'This checks to make certain that our title is short enough to fit onto the screen
133.     _FONT InBox_Info.TitleFont
134.     T2WWA InBox_Info.Title, right - left, WordWrap()
135.     totalprintarea = _FONTHEIGHT * (UBOUND(WordWrap) + 1)
136.  
137.     'I'm only allowing for the title to use up to a maximum of 1/3 of our total display area.
138.     IF totalprintarea > (bottom - top) / 3 THEN 'more than that, and we toss an error.
139.         InBox_Info.ErrorCode = 11: GOTO clean_exit
140.     END IF
141.  
142.     'This is the background for the title area.  Color or image, it doesn't matter.
143.     IF InBox_Info.Title_Background < -1 THEN
144.         _PUTIMAGE (left, top)-(right, top + totalprintarea), InBox_Info.Title_Background
145.     ELSE
146.         LINE (left, top)-(right, top + totalprintarea), InBox_Info.Title_Background, BF
147.     END IF
148.  
149.     'and here, we print the title, depending on its offset/justification
150.     COLOR InBox_Info.Title_Font_TextColor, InBox_Info.Title_Font_TextBackColor
151.     Xoffset = InBox_Info.Title_Xoffset
152.     GOSUB Printout
153.     '******************************************  END TITLE ******************************************
154.     '************************************************************************************************
155.     '****************************************  START MESSAGE ****************************************
156.  
157.     'This checks to make certain that our message is short enough to fit onto the screen
158.     _FONT InBox_Info.MessageFont
159.     T2WWA InBox_Info.Message, right - left, WordWrap()
160.     totalprintarea = _FONTHEIGHT * (UBOUND(WordWrap) + 1)
161.  
162.     'I'm only allowing for the prompt message to use up to a maximum of 1/2 of our remaining display area.
163.     IF totalprintarea > (bottom - top) / 2 THEN 'more than that, and we toss an error.
164.         InBox_Info.ErrorCode = 11: GOTO clean_exit
165.     END IF
166.  
167.     'This is the background for the message area.  Color or image, it doesn't matter.
168.     IF InBox_Info.Message_Background < -1 THEN
169.         _PUTIMAGE (left, top)-(right, bottom), InBox_Info.Message_Background
170.     ELSE
171.         LINE (left, top)-(right, bottom), InBox_Info.Message_Background, BF
172.     END IF
173.  
174.     'and here, we print the message prompt, depending on its offset/justification
175.     COLOR InBox_Info.Message_Font_TextColor, InBox_Info.Message_Font_TextBackColor
176.     Xoffset = InBox_Info.Message_Xoffset: EE = -1
177.     GOSUB Printout
178.     '*****************************************  END MESSAGE *****************************************
179.     '************************************************************************************************
180.     '*****************************************  START INPUT *****************************************
181.     top = top + 5: bottom = bottom - 5 '5 pixel area all around
182.     left = left + 5: right = right - 5
183.  
184.     'This is the background for the input area.  Color or image, it doesn't matter.
185.     fh = _FONTHEIGHT(InBox_Info.InputFont)
186.     fw = _FONTWIDTH(InBox_Info.InputFont)
187.     maxrows = (bottom - top) \ fh
188.     maxcolumns = (right - left) \ fw
189.     maxcharacters = maxrows * maxcolumns - 1 'for cursor
190.  
191.     left_right_offset = (right - left - maxcolumns * fw) \ 2
192.     left = left + left_right_offset
193.     right = right - left_right_offset
194.     top = bottom - maxrows * fh
195.  
196.     IF InBox_Info.Input_Background < -1 THEN
197.         _PUTIMAGE (left, top)-(right, bottom), InBox_Info.Input_Background
198.     ELSE
199.         LINE (left, top)-(right, bottom), InBox_Info.Input_Background, BF
200.     END IF
201.  
202.  
203.     Inbox_Software_Handle2 = _NEWIMAGE(right - left, bottom - top, 32)
204.     Inbox_Software_Handle3 = _NEWIMAGE(right - left, bottom - top + fh * 2, 32)
205.     _DEST Inbox_Software_Handle3: _SOURCE Inbox_Software_Handle3
206.     COLOR InBox_Info.Input_Font_TextColor, InBox_Info.Input_Font_TextBackColor
207.     _FONT InBox_Info.InputFont
208.     '******************************************  END INPUT ******************************************
209.     Inbox_Hardware_Handle = _COPYIMAGE(InBox_Software_Handle, 33)
210.     DIM m AS _MEM: m = _MEMIMAGE(Inbox_Software_Handle3)
211.     DO
212.         _PUTIMAGE (0, 0), Inbox_Hardware_Handle
213.         _PUTIMAGE (0, 0)-(right, bottom), Inbox_Software_Handle3, Inbox_Software_Handle2, (0, 0)-(right, bottom)
214.         Inbox_Hardware_Handle2 = _COPYIMAGE(Inbox_Software_Handle2, 33)
215.         _PUTIMAGE (left, top)-(right, bottom), Inbox_Hardware_Handle2
216.  
217.         IF _KEYDOWN(100307) OR _KEYDOWN(100308) THEN AltDown = -1 ELSE AltDown = 0
218.         k = _KEYHIT
219.         IF AltDown THEN
220.             SELECT CASE k 'ignore all keypresses except ALT-number presses
221.                 CASE 48 TO 57: AltWasDown = -1: alt$ = alt$ + CHR$(k)
222.             END SELECT
223.         ELSE
224.             SELECT CASE k 'without alt, add any keypresses to our input
225.                 CASE 8
226.                     oldin$ = in$
227.                     IF CP > 0 THEN OldCP = CP: CP = CP - 1
228.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2) 'backspace to erase input
229.                 CASE 9
230.                     oldin$ = in$
231.                     in$ = LEFT$(in$, CP) + SPACE$(4) + MID$(in$, CP + 1) 'four spaces for any TAB entered
232.                     OldCP = CP
233.                     CP = CP + 4
234.                 CASE 32 TO 128
235.                     IF _KEYDOWN(100305) OR _KEYDOWN(100306) THEN
236.                         IF k = 118 OR k = 86 THEN
237.                             oldin$ = in$
238.                             in$ = LEFT$(in$, CP) + _CLIPBOARD$ + MID$(in$, CP + 1) 'ctrl-v paste
239.                             'CTRL-V leaves cursor in position before the paste, without moving it after.
240.                             'Feel free to modify that behavior here, if you want it to move to after the paste.
241.                         END IF
242.                         IF k = 122 OR k = 90 THEN SWAP in$, oldin$: SWAP OldCP, CP 'ctrl-z undo
243.                     ELSE
244.                         oldin$ = in$
245.                         in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
246.                         OldCP = CP
247.                         CP = CP + 1
248.                     END IF
249.                 CASE 18176 'Home
250.                     CP = 0
251.                 CASE 20224 'End
252.                     CP = LEN(in$)
253.                 CASE 21248 'Delete
254.                     oldin$ = in$
255.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2)
256.                 CASE 19200 'Left
257.                     CP = CP - 1
258.                     IF CP < 0 THEN CP = 0
259.                 CASE 19712 'Right
260.                     CP = CP + 1
261.                     IF CP > LEN(in$) THEN CP = LEN(in$)
262.             END SELECT
263.         END IF
264.         alt$ = RIGHT$(alt$, 3)
265.         IF AltWasDown = -1 AND AltDown = 0 THEN
266.             v = VAL(alt$)
267.             IF v >= 0 AND v <= 255 THEN in$ = in$ + CHR$(v)
268.             alt$ = "": AltWasDown = 0
269.         END IF
270.         blink = (blink + 1) MOD 30
271.  
272.         in$ = LEFT$(in$, maxcharacters) ' a limit, for now, of no more characters than the screen can hold
273.         IF CP >= maxcharacters THEN CP = maxcharacters 'part of the temporary limit
274.         _DEST Inbox_Software_Handle2: _SOURCE Inbox_Software_Handle2
275.         CLS , 0
276.         _DEST Inbox_Software_Handle3: _SOURCE Inbox_Software_Handle3
277.         CLS , 0
278.         LOCATE 1, 1
279.  
280.         PRINT LEFT$(in$, CP);
281.         IF blink \ 15 THEN PRINT " "; ELSE PRINT "_";
282.         PRINT MID$(in$, CP + 1);
283.  
284.         _DISPLAY
285.         _LIMIT 60
286.     LOOP UNTIL k = 13
287.  
288.     clean_exit:
289.     _DEST D: _SOURCE S
290.     IF A THEN _AUTODISPLAY
291.     _FREEIMAGE InBox_Software_Handle
292.     _FREEIMAGE Inbox_Software_Handle2
293.     _FREEIMAGE Inbox_Software_Handle3
294.  
295.     InBox$ = in$
296.     EXIT SUB
297.  
298.     Printout:
299.  
300.     'This is where we print actual lines to the inbox display
301.     FOR I = 0 TO UBOUND(WordWrap)
302.         IF Xoffset >= 0 THEN
303.             _PRINTSTRING (left, top + _FONTHEIGHT * I), WordWrap(I)
304.         ELSE
305.             l = (right - left - _PRINTWIDTH(WordWrap(I))) / 2
306.             _PRINTSTRING (left + l, top + _FONTHEIGHT * I), WordWrap(I)
307.         END IF
308.     NEXT
309.  
310.     'update the available screen positions
311.     top = top + _FONTHEIGHT * (UBOUND(WordWrap) + 1)
312.  
313.     IF EE THEN EE = 0: RETURN 'Exit Early code to avoid drawing the frame
314.  
315.     'draw the frame again, below the title
316.     LINE (left, top)-(right, top + InBox_Info.FrameSize), InBox_Info.FrameColor, BF
317.  
318.     'update the available screen positons once again
319.     top = top + InBox_Info.FrameSize
320.     RETURN
321. END SUB
322.  
323.  
324. SUB InBox_Place (x AS INTEGER, y AS INTEGER)
325.     SHARED InBox_Info AS UDT
326.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
327.     IF x < 0 THEN
328.         InBox_Info.X = 0
329.         InBox_Info.Box_Justify_Hort = -1
330.     ELSE
331.         InBox_Info.X = x
332.         InBox.Box_Justify_Hort = 0
333.     END IF
334.     IF y < 0 THEN
335.         InBox_Info.Y = 0
336.         InBox_Info.Box_Justify_Vert = -1
337.     ELSE
338.         InBox_Info.Y = y
339.         InBox_Info.Box_Justify_Vert = 0
340.     END IF
341. END SUB
342.  
343. SUB InBox_Size (wide AS INTEGER, high AS INTEGER)
344.     SHARED InBox_Info AS UDT
345.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
346.     InBox_Info.Wide = wide
347.     InBox_Info.High = high
348. END SUB
349.  
350. SUB InBox_Backgrounds (Screen_background AS _INTEGER64, Box_background AS _INTEGER64)
351.     SHARED InBox_Info AS UDT
352.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
353.     InBox_Info.Screen_Background = Screen_background
354.     InBox_Info.Box_Background = Box_background
355. END SUB
356.  
357. SUB InBox_Frame (size AS INTEGER, kolor AS _INTEGER64)
358.     SHARED InBox_Info AS UDT
359.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
360.     InBox_Info.FrameColor = kolor
361.     InBox_Info.FrameSize = size
362. END SUB
363.  
364. SUB InBox_Title (font%, background&&, xOffset%, fc~&, fbg~&)
365.     SHARED InBox_Info AS UDT
366.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
367.     InBox_Info.TitleFont = font%
368.     InBox_Info.Title_Background = background&&
369.     InBox_Info.Title_Xoffset = xOffset%
370.     InBox_Info.Title_Font_TextColor = fc~&
371.     InBox_Info.Title_Font_TextBackColor = fbg~&
372. END SUB
373.  
374. SUB InBox_Message (font%, background&&, xOffset%, fc~&, fbg~&)
375.     SHARED InBox_Info AS UDT
376.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
377.     InBox_Info.MessageFont = font%
378.     InBox_Info.Message_Background = background&&
379.     InBox_Info.Message_Xoffset = xOffset%
380.     InBox_Info.Message_Font_TextColor = fc~&
381.     InBox_Info.Message_Font_TextBackColor = fbg~&
382. END SUB
383.  
384. SUB InBox_Input (font%, background&&, xOffset%, fc~&, fbg~&)
385.     SHARED InBox_Info AS UDT
386.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
387.     InBox_Info.InputFont = font%
388.     InBox_Info.Input_Background = background&&
389.     InBox_Info.Input_Xoffset = xOffset%
390.     InBox_Info.Input_Font_TextColor = fc~&
391.     InBox_Info.Input_Font_TextBackColor = fbg~&
392. END SUB
393.  
394.  
395. SUB T2WWA (temp$, wide%, result() AS STRING) 'Text To Word Wrap Array
396.     DIM BreakPoint AS STRING
397.     BreakPoint = ",./- ;:!" 'I consider all these to be valid breakpoints.  If you want something else, change them.
398.  
399.     text$ = _TRIM$(temp$)
400.     DO
401.         'first find the natural length of the line
402.         FOR i = 1 TO LEN(text$)
403.             p = _PRINTWIDTH(LEFT$(text$, i))
404.             IF p > wide% THEN EXIT FOR
405.         NEXT
406.         IF p < wide% THEN result(count) = RTRIM$(text$): GOTO clean_exit
407.         lineend = i - 1
408.         t$ = RTRIM$(LEFT$(text$, lineend)) 'at most, our line can't be any longer than what fits the screen.
409.         FOR i = lineend TO 1 STEP -1
410.             IF INSTR(BreakPoint, MID$(text$, i, 1)) THEN lineend = i: EXIT FOR
411.         NEXT
412.         result(count) = RTRIM$(LEFT$(text$, lineend))
413.         count = count + 1
414.         IF count > UBOUND(result) THEN REDIM _PRESERVE result(count + 100) AS STRING
415.         text$ = LTRIM$(MID$(text$, lineend + 1))
416.     LOOP UNTIL text$ = ""
417.     clean_exit:
418.     REDIM _PRESERVE result(count) AS STRING
419. END SUB
420.  

Now, there's a LOT of things that I wouldn't recommend doing, like I've done here -- such as using multiple _LOADIMAGE and _LOADFONT commands, with no way to free those resources...   but for a demo, this should work well enough.

I also wouldn't recommend going with the tacky sizes and color schemes that I'm using for the custom window, but they're there to show how many different aspects of the window are customizable.  Backgrounds can be colors, or they can be images -- it doesn't matter.  Fonts really don't matter, except they need to be monospaced.  (And that'll be correct when/if I fix the input to become scrollable.)

At the moment, we can input multi-line text, but only up to the amount of text that fits our input area.  I'm thinking of doing a little tweaking of this later (like next week probably, if I don't move on to something else and forget about this by then), so that it'll work with unlimited length text.  The text input will actually work with it right now, but I've got an artificial limit in place, just cause my CP (Cursor Position) gets all jumbled if I don't, and I haven't sorted it out yet...  All it needs is a quick sort, and then unlimited input text length shouldn't be an issue any more.

Test it out.  Try and break it.  And enjoy it, if it can be of any use to you.

Suggestions for alterations, enhancements, and bug reports are more than welcome.

[Dav]

That looks great. Cant wait to get back home today so i can try it out! I was kind of dabbling with making a simular thing, but yours looks all done and polished.

Edit: hmm, i've never really paid attention to the $color metacommand before. I can see how it can come in handy.

- Dav

[SMcNeill]

That looks great. Cant wait to get back home today so i can try it out! I was kind of dabbling with making a simular thing, but yours looks all done and polished.

Edit: hmm, i've never really paid attention to the $color metacommand before. I can see now where it can come in handy.

- Dav

It just lets you plug in color names for preset color values.   COLOR Gold, Purple, for instance.

[Dav]

I ran back home to get something, and tried out the code. Works well!  Needs v1.5 to use the new DIM method, for those interested. 

Saving it for my toolbox.  I'll give it a good work out later today. So far it seems to work perfectly.

Thanks for sharing.


Edit:  I'm sorry, I meant the new way of combing variables like DIM/TYPE can do now:  AS INTEGER X, Y, Wide, High, etc...

- Dav

[SMcNeill]

Updated:  We now work with scrollable input boxes, with a maximum of 65535 characters (or less, as font size and input width/height limitations allow).  There's a little counter at the bottom of the input area now where it tells you how many characters you've used, and what the limit is that you can type into the box with the current settings.

Code: QB64: [Select]

1. $COLOR:32
2.  
3. 'Just some basic SCREEN 0 stuff to show that we're not messing with our background at all
4. CLS , 1 'dark blue in screen 0
5. PRINT "Foobie Foo FOO!"
6. FOR I = 0 TO 15
7.     COLOR I
8.     PRINT "This is COLOR"; I
9. NEXT
10.  
11. SLEEP: _DELAY .25: _KEYCLEAR
12. InBox_Size 150, 150
13. result$ = InBox$("Input Box", "Generic User Input Goes Here") 'And here's a generic input box!
14. PRINT "YOU ENTERED ==> "; result$
15. 'And you can see the screen itself was maintained 100% as we had it before, except for the result$
16. 'which we printed after closing the InBox
17.  
18. SLEEP: _DELAY .25: _KEYCLEAR
19. InBox_Place -1, -1
20. InBox_Size 300, 300
21. InBox_Backgrounds _LOADIMAGE("cemetery.jpg", 32), 0
22. InBox_Frame 3, Gold
23. InBox_Title _LOADFONT("courbd.ttf", 32, "monospace"), SkyBlue, -1, Red, Blue
24. InBox_Message _LOADFONT("courbd.ttf", 24, "monospace"), _LOADIMAGE("marble.jpg", 32), -1, &HFFFF0000&&, 0
25. InBox_Input _LOADFONT("courbd.ttf", 18, "monospace"), LightGray, -1, Red, Blue
26. result$ = InBox$("Math Box For Dummies", "Enter some maths!")
27. PRINT "YOU ENTERED ==> "; result$
28.  
29.  
30. SUB Inbox_reset
31.     TYPE UDT
32.         AS INTEGER X, Y, Wide, High, ErrorCode, Box_Justify_Hort, Box_Justify_Vert
33.         AS INTEGER TitleFont, FrameSize, Title_Xoffset
34.         AS INTEGER MessageFont, Message_Xoffset
35.         AS INTEGER InputFont, Input_Xoffset, Inbox_Init
36.         AS _INTEGER64 Screen_Background, Box_Background, Title_Background, Message_Background, Input_Background
37.         AS _UNSIGNED LONG FrameColor, Title_Font_TextColor, Title_Font_TextBackColor
38.         AS _UNSIGNED LONG Message_Font_TextColor, Message_Font_TextBackColor
39.         AS _UNSIGNED LONG Input_Font_TextColor, Input_Font_TextBackColor
40.         AS STRING Title, Message
41.     END TYPE
42.     SHARED InBox_Info AS UDT
43.     'Default Inbox values
44.     InBox_Info.Inbox_Init = -1
45.     InBox_Place -1, -1
46.     InBox_Size 400, 200
47.     InBox_Backgrounds 0, &HFF000000&&
48.     InBox_Frame 3, &HFFFFFFFF&&
49.     InBox_Title 16, &HFF000000&&, -1, &HFFFFFFFF&&, &HFF000000&&
50.     InBox_Message 16, &HFF000000&&, -1, &HFFFFFFFF&&, &HFF000000&&
51.     InBox_Input 16, &HFFD3D3D3&&, -1, &HFF000000&&, 0
52. END SUB
53.  
54. FUNCTION InBox$ (Title AS STRING, Prompt AS STRING)
55.     SHARED InBox_Info AS UDT
56.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
57.     'InBox_Info.ErrorCode
58.     '1 = Attempting to make box wider than current screen allows.
59.     '2 = Attempting to make box taller than current screen allows.
60.     '3 = Attempting to place box off the left side of the allowable screen.
61.     '4 = Attempting to place box above the top of the allowable screen.
62.     '5 = Attempting to place box off the right side of the allowable screen.
63.     '6 = Attempting to place box below the bottom of the allowable screen.
64.     '7 = Invalid screen background image
65.     '8 = Invalid box background image
66.     '9 = Invalid box frame color
67.     '10 = Invalid title font handle
68.     '11 = Invalid title Xoffset (probably trying to print off the box)
69.     '12 = Invalid message font handle
70.  
71.     STATIC AS LONG W, H, BPP, InBox_Software_Handle 'These are defined as STATIC as they're common variable
72.     STATIC AS LONG D, S '                            names, and like this they won't interfer with any dummies
73.     STATIC AS _INTEGER64 Xoffset '                   DIM SHARED variables.
74.  
75.     REDIM WordWrap(0) AS STRING '                    Redimmable array to hold properly formated word wrap text
76.  
77.  
78.     D = _DEST: S = _SOURCE '                         Initial global state variables
79.     A = _AUTODISPLAY
80.  
81.     W = _WIDTH: H = _HEIGHT: BPP = _PIXELSIZE
82.     IF BPP = 0 THEN W = W * _FONTWIDTH: H = H * _FONTHEIGHT 'calculate text screen size, in pixels
83.     InBox_Software_Handle = _NEWIMAGE(W, H, 32) '    Image size for our whole screen
84.  
85.  
86.     IF InBox_Info.Wide > W THEN InBox_Info.ErrorCode = 1: GOTO clean_exit
87.     IF InBox_Info.High > H THEN InBox_Info.ErrorCode = 2: GOTO clean_exit
88.     IF InBox_Info.X < 0 THEN InBox_Info.ErrorCode = 3: GOTO clean_exit
89.     IF InBox_Info.Y < 0 THEN InBox_Info.ErrorCode = 4: GOTO clean_exit
90.     IF InBox_Info.X > W - InBox_Info.Wide THEN InBox_Info.ErrorCode = 5: GOTO clean_exit
91.     IF InBox_Info.Y > H - InBox_Info.High THEN InBox_Info.ErrorCode = 6: GOTO clean_exit
92.     IF InBox_Info.Screen_Background = -1 OR InBox_Info.Screen_Background > &HFFFFFFFF&& THEN InBox_Info.ErrorCode = 7: GOTO clean_exit
93.     IF InBox_Info.Box_Background = -1 OR InBox_Info.Box_Background > &HFFFFFFFF&& THEN InBox_Info.ErrorCode = 8: GOTO clean_exit
94.     IF InBox_Info.FrameColor < 0 OR InBox_Info.FrameColor > &HFFFFFFFF&& THEN InBox_Info.ErrorCode = 9: GOTO clean_exit
95.     IF InBox_Info.TitleFont <= 0 THEN InBox_Info.ErrorCode = 10: GOTO clean_exit
96.     IF InBox_Info.MessageFont <= 0 THEN InBox_Info.ErrorCode = 12: GOTO clean_exit
97.  
98.  
99.     IF InBox_Info.Box_Justify_Hort THEN InBox_Info.X = (W - InBox_Info.Wide) \ 2
100.     IF InBox_Info.Box_Justify_Vert THEN InBox_Info.Y = (H - InBox_Info.High) \ 2
101.     InBox_Info.Title = Title: InBox_Info.Message = Prompt
102.  
103.     _DEST InBox_Software_Handle: _SOURCE InBox_Software_Handle
104.  
105.     'Stuff which we only draw once
106.  
107.     'This is the background for the whole screen, which we can use to cover up the original
108.     IF InBox_Info.Screen_Background < -1 THEN
109.         _PUTIMAGE (0, 0)-(W, H), InBox_Info.Screen_Background
110.     ELSE
111.         CLS , InBox_Info.Screen_Background
112.     END IF
113.  
114.     'This is the background for the box itself.  Color or image, it doesn't matter.
115.     IF InBox_Info.Box_Background < -1 THEN
116.         _PUTIMAGE (InBox_Info.X, InBox_Info.Y)-STEP(InBox_Info.Wide, InBox_Info.High), InBox_Info.Box_Background
117.     ELSE
118.         LINE (InBox_Info.X, InBox_Info.Y)-STEP(InBox_Info.Wide, InBox_Info.High), InBox_Info.Box_Background, BF
119.     END IF
120.  
121.     'This draws the frame around the whole box.
122.     FOR I = 0 TO InBox_Info.FrameSize - 1
123.         LINE (InBox_Info.X + I, InBox_Info.Y + I)-STEP(InBox_Info.Wide - 2 * I, InBox_Info.High - 2 * I), InBox_Info.FrameColor, B
124.     NEXT
125.  
126.  
127.     'and here we gather our information on what parts of the box is left for us to draw/write inside.
128.     top = InBox_Info.Y + I: left = InBox_Info.X + I: right = left + InBox_Info.Wide - 2 * I: bottom = top + InBox_Info.High - 2 * I
129.  
130.  
131.     '*****************************************  START TITLE *****************************************
132.  
133.     'This checks to make certain that our title is short enough to fit onto the screen
134.     _FONT InBox_Info.TitleFont
135.     T2WWA InBox_Info.Title, right - left, WordWrap()
136.     totalprintarea = _FONTHEIGHT * (UBOUND(WordWrap) + 1)
137.  
138.     'I'm only allowing for the title to use up to a maximum of 1/3 of our total display area.
139.     IF totalprintarea > (bottom - top) / 3 THEN 'more than that, and we toss an error.
140.         InBox_Info.ErrorCode = 11: GOTO clean_exit
141.     END IF
142.  
143.     'This is the background for the title area.  Color or image, it doesn't matter.
144.     IF InBox_Info.Title_Background < -1 THEN
145.         _PUTIMAGE (left, top)-(right, top + totalprintarea), InBox_Info.Title_Background
146.     ELSE
147.         LINE (left, top)-(right, top + totalprintarea), InBox_Info.Title_Background, BF
148.     END IF
149.  
150.     'and here, we print the title, depending on its offset/justification
151.     COLOR InBox_Info.Title_Font_TextColor, InBox_Info.Title_Font_TextBackColor
152.     Xoffset = InBox_Info.Title_Xoffset
153.     GOSUB Printout
154.     '******************************************  END TITLE ******************************************
155.     '************************************************************************************************
156.     '****************************************  START MESSAGE ****************************************
157.  
158.     'This checks to make certain that our message is short enough to fit onto the screen
159.     _FONT InBox_Info.MessageFont
160.     T2WWA InBox_Info.Message, right - left, WordWrap()
161.     totalprintarea = _FONTHEIGHT * (UBOUND(WordWrap) + 1)
162.  
163.     'I'm only allowing for the prompt message to use up to a maximum of 1/2 of our remaining display area.
164.     IF totalprintarea > (bottom - top) / 2 THEN 'more than that, and we toss an error.
165.         InBox_Info.ErrorCode = 11: GOTO clean_exit
166.     END IF
167.  
168.     'This is the background for the message area.  Color or image, it doesn't matter.
169.     IF InBox_Info.Message_Background < -1 THEN
170.         _PUTIMAGE (left, top)-(right, bottom), InBox_Info.Message_Background
171.     ELSE
172.         LINE (left, top)-(right, bottom), InBox_Info.Message_Background, BF
173.     END IF
174.  
175.     'and here, we print the message prompt, depending on its offset/justification
176.     COLOR InBox_Info.Message_Font_TextColor, InBox_Info.Message_Font_TextBackColor
177.     Xoffset = InBox_Info.Message_Xoffset: EE = -1
178.     GOSUB Printout
179.     '*****************************************  END MESSAGE *****************************************
180.     '************************************************************************************************
181.     '*****************************************  START INPUT *****************************************
182.     left = left + 5: right = right - 5 '5 pixel area all around
183.  
184.     'This is the background for the input area.  Color or image, it doesn't matter.
185.     fh = _FONTHEIGHT(InBox_Info.InputFont)
186.     fw = _FONTWIDTH(InBox_Info.InputFont)
187.     maxrows = (bottom - top - 20) \ fh
188.     maxcolumns = (right - left) \ fw
189.     maxcharacters = maxrows * maxcolumns - 1 'for cursor
190.     maxcharacters = 65534
191.     absolutemax = (65535 \ fh) * maxcolumns
192.     IF absolutemax < maxcharacters THEN maxcharacters = absolutemax
193.  
194.     left_right_offset = (right - left - maxcolumns * fw) \ 2
195.     left = left + left_right_offset
196.     right = right - left_right_offset
197.     top = bottom - (maxrows + 1) * fh - 2
198.  
199.     IF InBox_Info.Input_Background < -1 THEN
200.         _PUTIMAGE (left, top)-(right, bottom - 20), InBox_Info.Input_Background
201.     ELSE
202.         LINE (left, top)-(right, bottom - 20), InBox_Info.Input_Background, BF
203.     END IF
204.  
205.  
206.     Inbox_Software_Handle2 = _NEWIMAGE(right - left, bottom - top, 32)
207.     Inbox_Software_Handle3 = _NEWIMAGE(right - left, 65535, 32)
208.     Inbox_Software_Handle4 = _NEWIMAGE(right - left, 20, 32)
209.     _DEST Inbox_Software_Handle3: _SOURCE Inbox_Software_Handle3
210.     '******************************************  END INPUT ******************************************
211.     Inbox_Hardware_Handle = _COPYIMAGE(InBox_Software_Handle, 33)
212.     DIM m AS _MEM: m = _MEMIMAGE(Inbox_Software_Handle3)
213.     DO
214.  
215.         IF _KEYDOWN(100307) OR _KEYDOWN(100308) THEN AltDown = -1 ELSE AltDown = 0
216.         k = _KEYHIT
217.         IF AltDown THEN
218.             SELECT CASE k 'ignore all keypresses except ALT-number presses
219.                 CASE 48 TO 57: AltWasDown = -1: alt$ = alt$ + CHR$(k)
220.             END SELECT
221.         ELSE
222.             SELECT CASE k 'without alt, add any keypresses to our input
223.                 CASE 8
224.                     oldin$ = in$
225.                     IF CP > 0 THEN OldCP = CP: CP = CP - 1
226.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2) 'backspace to erase input
227.                 CASE 9
228.                     oldin$ = in$
229.                     in$ = LEFT$(in$, CP) + SPACE$(4) + MID$(in$, CP + 1) 'four spaces for any TAB entered
230.                     OldCP = CP
231.                     CP = CP + 4
232.                 CASE 27
233.                     SYSTEM
234.                 CASE 32 TO 128
235.                     IF _KEYDOWN(100305) OR _KEYDOWN(100306) THEN
236.                         IF k = 118 OR k = 86 THEN
237.                             oldin$ = in$
238.                             in$ = LEFT$(in$, CP) + _CLIPBOARD$ + MID$(in$, CP + 1) 'ctrl-v paste
239.                             'CTRL-V leaves cursor in position before the paste, without moving it after.
240.                             'Feel free to modify that behavior here, if you want it to move to after the paste.
241.                         END IF
242.                         IF k = 122 OR k = 90 THEN SWAP in$, oldin$: SWAP OldCP, CP 'ctrl-z undo
243.                     ELSE
244.                         oldin$ = in$
245.                         in$ = LEFT$(in$, CP) + CHR$(k) + MID$(in$, CP + 1) 'add input to our string
246.                         OldCP = CP
247.                         CP = CP + 1
248.                     END IF
249.                 CASE 18176 'Home
250.                     CP = 0
251.                 CASE 20224 'End
252.                     CP = LEN(in$)
253.                 CASE 21248 'Delete
254.                     oldin$ = in$
255.                     in$ = LEFT$(in$, CP) + MID$(in$, CP + 2)
256.                 CASE 19200 'Left
257.                     CP = CP - 1
258.                     IF CP < 0 THEN CP = 0
259.                 CASE 19712 'Right
260.                     CP = CP + 1
261.                     IF CP > LEN(in$) THEN CP = LEN(in$)
262.             END SELECT
263.         END IF
264.         alt$ = RIGHT$(alt$, 3)
265.         IF AltWasDown = -1 AND AltDown = 0 THEN
266.             v = VAL(alt$)
267.             IF v >= 0 AND v <= 255 THEN in$ = in$ + CHR$(v)
268.             alt$ = "": AltWasDown = 0
269.         END IF
270.         blink = (blink + 1) MOD 30
271.  
272.         in$ = LEFT$(in$, maxcharacters) ' a limit, for now, of no more characters than the screen can hold
273.         IF CP >= maxcharacters THEN CP = maxcharacters 'part of the temporary limit
274.         _DEST Inbox_Software_Handle2: _SOURCE Inbox_Software_Handle2
275.         CLS , 0
276.  
277.         _DEST Inbox_Software_Handle3: _SOURCE Inbox_Software_Handle3
278.         CLS , 0
279.  
280.         COLOR InBox_Info.Input_Font_TextColor, InBox_Info.Input_Font_TextBackColor
281.         _FONT InBox_Info.InputFont
282.  
283.         IF blink \ 15 THEN blinker$ = " " ELSE blinker$ = "_"
284.  
285.         LOCATE 1, 1: PRINT LEFT$(in$, CP) + blinker$ + MID$(in$, CP + 1);
286.  
287.  
288.         _DEST Inbox_Software_Handle4: _SOURCE Inbox_Software_Handle4
289.         CLS , 0
290.         COLOR &HAAFFFFFF&&, &H77000000&&
291.         char$ = "(" + _TRIM$(STR$(LEN(in$))) + "/" + _TRIM$(STR$(maxcharacters)) + ")"
292.         _PRINTSTRING (_WIDTH(Inbox_Software_Handle4) - 8 * LEN(char$), 0), char$
293.         Inbox_Hardware_Handle3 = _COPYIMAGE(Inbox_Software_Handle4, 33)
294.  
295.  
296.         _PUTIMAGE (0, 0), Inbox_Hardware_Handle
297.         IF CP = LEN(in$) THEN
298.             top_visible = CP \ maxcolumns - maxrows + 1
299.         ELSE
300.             top_visible = (CP + 1) \ maxcolumns - maxrows + 1
301.         END IF
302.         IF top_visible < 0 THEN top_visible = 0
303.  
304.         _PUTIMAGE (0, 0)-(right, bottom), Inbox_Software_Handle3,_
305.           Inbox_Software_Handle2, (0, top_visible * fh)-STEP(right, bottom)
306.         Inbox_Hardware_Handle2 = _COPYIMAGE(Inbox_Software_Handle2, 33)
307.         _PUTIMAGE (left, top)-(right, bottom), Inbox_Hardware_Handle2
308.         _PUTIMAGE (right - _WIDTH(Inbox_Software_Handle4), bottom - 18)-STEP(_WIDTH(Inbox_Software_Handle4), 20), Inbox_Hardware_Handle3
309.  
310.         _DISPLAY
311.         _LIMIT 60
312.     LOOP UNTIL k = 13
313.  
314.     clean_exit:
315.     _DEST D: _SOURCE S
316.     IF A THEN _AUTODISPLAY
317.     _FREEIMAGE InBox_Software_Handle
318.     _FREEIMAGE Inbox_Software_Handle2
319.     _FREEIMAGE Inbox_Software_Handle3
320.     _FREEIMAGE Inbox_Software_Handle4
321.  
322.     InBox$ = in$
323.     EXIT SUB
324.  
325.     Printout:
326.  
327.     'This is where we print actual lines to the inbox display
328.     FOR I = 0 TO UBOUND(WordWrap)
329.         IF Xoffset >= 0 THEN
330.             _PRINTSTRING (left, top + _FONTHEIGHT * I), WordWrap(I)
331.         ELSE
332.             l = (right - left - _PRINTWIDTH(WordWrap(I))) / 2
333.             _PRINTSTRING (left + l, top + _FONTHEIGHT * I), WordWrap(I)
334.         END IF
335.     NEXT
336.  
337.     'update the available screen positions
338.     top = top + _FONTHEIGHT * (UBOUND(WordWrap) + 1)
339.  
340.     IF EE THEN EE = 0: RETURN 'Exit Early code to avoid drawing the frame
341.  
342.     'draw the frame again, below the title
343.     LINE (left, top)-(right, top + InBox_Info.FrameSize), InBox_Info.FrameColor, BF
344.  
345.     'update the available screen positons once again
346.     top = top + InBox_Info.FrameSize
347.     RETURN
348. END SUB
349.  
350.  
351. SUB InBox_Place (x AS INTEGER, y AS INTEGER)
352.     SHARED InBox_Info AS UDT
353.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
354.     IF x < 0 THEN
355.         InBox_Info.X = 0
356.         InBox_Info.Box_Justify_Hort = -1
357.     ELSE
358.         InBox_Info.X = x
359.         InBox.Box_Justify_Hort = 0
360.     END IF
361.     IF y < 0 THEN
362.         InBox_Info.Y = 0
363.         InBox_Info.Box_Justify_Vert = -1
364.     ELSE
365.         InBox_Info.Y = y
366.         InBox_Info.Box_Justify_Vert = 0
367.     END IF
368. END SUB
369.  
370. SUB InBox_Size (wide AS INTEGER, high AS INTEGER)
371.     SHARED InBox_Info AS UDT
372.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
373.     InBox_Info.Wide = wide
374.     InBox_Info.High = high
375. END SUB
376.  
377. SUB InBox_Backgrounds (Screen_background AS _INTEGER64, Box_background AS _INTEGER64)
378.     SHARED InBox_Info AS UDT
379.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
380.     InBox_Info.Screen_Background = Screen_background
381.     InBox_Info.Box_Background = Box_background
382. END SUB
383.  
384. SUB InBox_Frame (size AS INTEGER, kolor AS _INTEGER64)
385.     SHARED InBox_Info AS UDT
386.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
387.     InBox_Info.FrameColor = kolor
388.     InBox_Info.FrameSize = size
389. END SUB
390.  
391. SUB InBox_Title (font%, background&&, xOffset%, fc~&, fbg~&)
392.     SHARED InBox_Info AS UDT
393.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
394.     InBox_Info.TitleFont = font%
395.     InBox_Info.Title_Background = background&&
396.     InBox_Info.Title_Xoffset = xOffset%
397.     InBox_Info.Title_Font_TextColor = fc~&
398.     InBox_Info.Title_Font_TextBackColor = fbg~&
399. END SUB
400.  
401. SUB InBox_Message (font%, background&&, xOffset%, fc~&, fbg~&)
402.     SHARED InBox_Info AS UDT
403.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
404.     InBox_Info.MessageFont = font%
405.     InBox_Info.Message_Background = background&&
406.     InBox_Info.Message_Xoffset = xOffset%
407.     InBox_Info.Message_Font_TextColor = fc~&
408.     InBox_Info.Message_Font_TextBackColor = fbg~&
409. END SUB
410.  
411. SUB InBox_Input (font%, background&&, xOffset%, fc~&, fbg~&)
412.     SHARED InBox_Info AS UDT
413.     IF InBox_Info.Inbox_Init = 0 THEN Inbox_reset
414.     InBox_Info.InputFont = font%
415.     InBox_Info.Input_Background = background&&
416.     InBox_Info.Input_Xoffset = xOffset%
417.     InBox_Info.Input_Font_TextColor = fc~&
418.     InBox_Info.Input_Font_TextBackColor = fbg~&
419. END SUB
420.  
421.  
422. SUB T2WWA (temp$, wide%, result() AS STRING) 'Text To Word Wrap Array
423.     DIM BreakPoint AS STRING
424.     BreakPoint = ",./- ;:!" 'I consider all these to be valid breakpoints.  If you want something else, change them.
425.  
426.     text$ = _TRIM$(temp$)
427.     DO
428.         'first find the natural length of the line
429.         FOR i = 1 TO LEN(text$)
430.             p = _PRINTWIDTH(LEFT$(text$, i))
431.             IF p > wide% THEN EXIT FOR
432.         NEXT
433.         IF p < wide% THEN result(count) = RTRIM$(text$): GOTO clean_exit
434.         lineend = i - 1
435.         t$ = RTRIM$(LEFT$(text$, lineend)) 'at most, our line can't be any longer than what fits the screen.
436.         FOR i = lineend TO 1 STEP -1
437.             IF INSTR(BreakPoint, MID$(text$, i, 1)) THEN lineend = i: EXIT FOR
438.         NEXT
439.         result(count) = RTRIM$(LEFT$(text$, lineend))
440.         count = count + 1
441.         IF count > UBOUND(result) THEN REDIM _PRESERVE result(count + 100) AS STRING
442.         text$ = LTRIM$(MID$(text$, lineend + 1))
443.     LOOP UNTIL text$ = ""
444.     clean_exit:
445.     REDIM _PRESERVE result(count) AS STRING
446. END SUB
447.  

Best way to showcase it, is to just tell folks to give a try.  Be certain to download and have the resource files in your QB64 directory, and note  that this only works in the current DEVELOPMENT BUILD of QB64, due to me taking advantage of the new DIM syntax for testing purposes.

A couple of screenshots are below, but here's one thing to keep in mind when looking at these:


 

 

We're in a SCREEN 0 text screen, this whole time!!!

How's that for magic??

[Pete]

I'm always in SCREEN 0... Because that's where the magic happens.

I'm guessing this is similar to my SCREEN 0 scrolling text input routine, which has highlighting, cut/copy/paste, and lateral scrolling. I wanted to give yours a try, but I still haven't updated to the newest QB64 version, which allows us to use the AS UDTs. I will, at some point, because I would like to start consolidating the several new variables I'm adding to my WP, into that format. The AS UDT shortcut is a real typing saver.

Pete

[SMcNeill]

No highlighting, or copying, as I wasn’t quite shooting for an entire stand-alone text editor, but it does allow pasting and use of arrow keys to navigate forwards and backwards to make edits for typos and such.  ;)

[bplus]

This is looking very impressive, I went off SmallBASIC looking for something like this way back...

I still have to test it but assume it needs dev 1.5?

Can I grab title bar and move around screen?
In case there is something underneath I need to see to input a proper answer.