My latest fascination...

[OldMoses]

is with this idea of "branchless" coding.

While writing a library routine to "fit" an image into a predefined area, and trying to see if I can break the development build, I tried to do it in a branchless way. Imagine my astonishment when when 16+ lines of SELECT CASE blocks and IF...THENs distilled into three expressions...

Oh yeah, and I'm liking the new DIM syntax, so long as I don't have to go back to 1.4.

Code: QB64: [Select]

1. 'Image sizing in predefined space using branchless equations
2. SCREEN _NEWIMAGE(800, 700, 32)
3. DO: LOOP UNTIL _SCREENEXISTS
4. _SCREENMOVE 5, 5
5.  
6. 'create test patterns, one wide & one tall
7. W& = _NEWIMAGE(750, 480, 32)
8. _DEST W&
9. COLOR , &HFFFF0000
10. CLS
11. FOR x = 100 TO 90 STEP -1
12.     CIRCLE (150, 240), x, &HFF0000FF
13.     CIRCLE (375, 240), x, &HFF0000FF
14.     CIRCLE (600, 240), x, &HFF0000FF
15. NEXT x
16.  
17. T& = _NEWIMAGE(480, 750, 32)
18. _DEST T&
19. COLOR , &HFF008000
20. CLS
21. FOR x = 1 TO 10
22.     LINE (100 + x, 100 + x)-(380 - x, 380 - x), &HFFFF0000, B
23.     LINE (100 + x, 470 + x)-(380 - x, 650 - x), &HFFFF0000, B
24. NEXT x
25.  
26. 'Or load images of your choosing in lieu of test patterns
27.  
28. _DEST 0
29.  
30. CLS
31. x% = 400: y% = 20: x1% = 650: y1% = 300 '                       use predetermined part of the screen (400, 20)-(650, 300)
32. LINE (x%, y%)-(x1%, y1%), &H7F7F7F7F, B , &H0101 '              show target area
33. Image_Resize x%, y%, x1%, y1%, W&, 0, "c", "u" '                justify up, wide image
34. SLEEP
35.  
36. CLS
37. LINE (x%, y%)-(x1%, y1%), &H7F7F7F7F, B , &H0101 '              show target area
38. Image_Resize x%, y%, x1%, y1%, T&, 0, "r", "c" '                justify right, tall image
39. SLEEP
40.  
41. CLS
42. x% = 0: y% = 0: x1% = _WIDTH - 1: y1% = _HEIGHT - 1 '           use full screen
43. Image_Resize x%, y%, x1%, y1%, W&, 0, "c", "u" '                justify up, wide image
44. SLEEP
45.  
46. CLS
47. Image_Resize x%, y%, x1%, y1%, T&, 0, "l", "c" '                justify left, tall image
48. SLEEP
49.  
50. CLS
51. Image_Resize x%, y%, x1%, y1%, W&, 0, "c", "d" '                justify down, wide image
52. SLEEP
53.  
54. CLS
55. x% = 25: y% = 450: x1% = 250: y1% = 580 '                       use predetermined part of the screen (25, 450)-(250, 580)
56. LINE (x%, y%)-(x1%, y1%), &H7F7F7F7F, B , &H0101 '              show target area
57. Image_Resize x%, y%, x1%, y1%, W&, 0, "c", "c" '                justify center, wide image
58. SLEEP
59.  
60. CLS
61. LINE (x%, y%)-(x1%, y1%), &H7F7F7F7F, B , &H0101 '              show target area
62. Image_Resize x%, y%, x1%, y1%, T&, 0, "c", "c" '                justify center, tall image
63.  
64. 'and you get the idea...
65.  
66. END
67.  
68. SUB Image_Resize (xpos AS INTEGER, ypos AS INTEGER, xlim AS INTEGER, ylim AS INTEGER, i AS LONG, d AS LONG, xj AS STRING, yj AS STRING)
69.  
70.     'Syntax: upper left x, upper left y, lower right x, lower right y, image handle, destination handle, horizontal justification, vertical justification
71.     'horizontal justifications= "l" left, "c" center, "r" right
72.     'vertical justifications= "u" up, "c" center, "d" down
73.     DIM AS INTEGER xs, ys, xp, yp, xl, yl
74.     xp = xpos: yp = ypos: xl = xlim: yl = ylim
75.     DIM AS SINGLE rt, xrt, yrt
76.     xrt = (xl - xp) / _WIDTH(i) '                               width of area divided by width of image
77.     yrt = (yl - yp) / _HEIGHT(i) '                              height of area divided by height of image
78.     rt = ABS((xrt * (xrt < yrt)) + (yrt * (yrt <= xrt))) '      pick the smaller of the two ratios to fit area
79.     xs = _WIDTH(i) * rt '                                       final image size ratio in x
80.     ys = _HEIGHT(i) * rt '                                      final image size ratio in y
81.  
82.     xp = xp * ABS(xj = "l") + (_SHR(xl - xp, 1) + xp - _SHR(xs, 1)) * ABS(xj = "c") + (xl - xs) * ABS(xj = "r")
83.     xl = xp + xs
84.     yp = yp * ABS(yj = "u") + (_SHR(yl - yp, 1) + yp - _SHR(ys, 1)) * ABS(yj = "c") + (yl - ys) * ABS(yj = "d")
85.     yl = yp + ys
86.     _PUTIMAGE (xp, yp)-(xl, yl), i, d
87.  
88. END SUB 'Image_Resize
89.  

[Pete]

Impossible. How could you use your noodle, and not come up with spaghetti? :D

Nice concept, Andy. I've been thinking about ways to keep the cats in the herd, too. For me, it will probably never happen, because use run and gun coders can't stand a plan.

Thanks for posting this,

Pete

[OldMoses]

Impossible. How could you use your noodle, and not come up with spaghetti? :D

Nice concept, Andy. I've been thinking about ways to keep the cats in the herd, too. For me, it will probably never happen, because use run and gun coders can't stand a plan.

Thanks for posting this,

Pete

I saved a lot of typing in the code segment so that I'd have enough strength left to put that extra "when" in m post.... ;)

[Pete]

Well well, good for you!

Pete :D