Attempting PLAY & MIDI-like songs using _SNDRAW

[Dav]

I'm trying to come up with a way to play several musical notes at the same time, unlike the PLAY which only plays one at a time. So I combined the the SPLAY thing I made for the holiday thread (which used sound files), with the _SNDRAW command to make/play the notes, and it wil play MIDI like songs in the background.

This is just beginning, only 15 notes working, but it seems to have some possibilities.  I'll keep working on it.  Any suggestions welcomed... 

- Dav

Code: QB64: [Select]

1. '==============
2. 'SNDRAWPLAY.BAS v1.00
3. '==============
4. 'Attempting a PLAY-like song format using _SNDRAW
5. 'Plays notes and allows more than one note to sound at the same time.
6. 'Can play notes in the background.
7. 'Coded By Dav, JAN/2021
8.  
9. 'For now, there only 15 notes playable, about 2 octaves.
10. ' e1 f1 g1 a1 b1 | c2 d2 e2 f2 g2 a2 b2 | c3 d3 e3
11. 'You can play a chord of notes by grouping inside ()
12. ' (c2 e2 g2)
13.  
14. 'Assign current note/rest length values like this...
15. 'WN = Whole note, HN = Half note, DQ = Dotted quarter note
16. 'QN = Quarter note, EN = Eighth note, SN = Sixteenth note
17.  
18. 'Rests - nothing played, but time continues
19. 'RN = Rest note.  Uses current note length value set.
20. 'For example, to rest a quarter note, do this:
21. 'QN RN
22.  
23. 'Assign Tempos like this (always must be in 4 characters):
24. 'T120  ... or T060   ...  or  T100
25.  
26. 'Assign current meter (for whole length value to work)
27. 'M3  (thats for 3/4)....  M4   (Thats for 4/4)
28.  
29. '========================================================
30.  
31.  
32. '=== Playing all notes...
33.  
34. 'Set tempo 120, meter 4/4, set sixteen note value
35. SPLAY "t120 m4 sn e1f1g1a1b1c2d2e2f2g2a2b2c3d3e3"
36.  
37. DO
38.     COLOR RND * 16
39.     PRINT "Testing all notes...e1 to e3..."
40. LOOP WHILE _SNDRAWLEN
41. _SNDRAWDONE
42.  
43.  
44. '=== Playing some chords...
45.  
46. 'Set tempo 120, meter 4/4, set sixteen note value, play all notes
47. 'Note: You don't have to include spaces, but I did here...
48. SPLAY "qn (c2 e2 g2) (f2a2c3) (g2b2d3) (f2a2c3) (c2 e2 g2)"
49.  
50. DO
51.     COLOR RND * 16
52.     PRINT "Playing chords..."
53. LOOP WHILE _SNDRAWLEN
54. _SNDRAWDONE
55.  
56.  
57. '=== Playing a song.... part of Silent Night.,,,
58.  
59. Song$ = ""
60. Song$ = Song$ + "t100m3dq(c2e2g2)en(c2f2a2)qn(c2e2g2)wn(g1c2e2)"
61. Song$ = Song$ + "dq(c2e2g2)en(c2f2a2)qn(c2e2g2)wn(g1c2e2)"
62. Song$ = Song$ + "hn(d3b2g2)qnd3(g2b2)c3(d3g2f2)"
63. Song$ = Song$ + "dq(c2e2g2)en(c2f2a2)qn(c2e2g2)wn(g1c2e2)"
64. SPLAY Song$
65.  
66. DO
67.     COLOR RND * 16
68.     PRINT "Silent Night ";
69.     IF INKEY$ <> "" THEN EXIT DO
70. LOOP WHILE _SNDRAWLEN
71. _SNDRAWDONE
72.  
73. END
74.  
75.  
76.  
77.  
78. SUB SPLAY (Music$)
79.  
80.     rate = _SNDRATE
81.  
82.     'Set Defaults, just in case empty
83.     IF Tempo = 0 THEN Tempo = 60
84.     IF Meter = 0 THEN Meter = 3
85.     IF NoteValue = 0 THEN NoteValue = 1
86.  
87.     Music$ = UCASE$(Music$)
88.     cur = 1
89.  
90.     DO
91.  
92.         'skip any spaces
93.         IF MID$(Music$, cur, 1) = " " THEN cur = cur + 1
94.  
95.         'Check for tempo
96.         IF MID$(Music$, cur, 1) = "T" THEN
97.             cur = cur + 1
98.             Tempo = VAL(MID$(Music$, cur, 3)): cur = cur + 3
99.         END IF
100.  
101.         'Check for Meter
102.         IF MID$(Music$, cur, 1) = "M" THEN
103.             cur = cur + 1
104.             Meter = VAL(MID$(Music$, cur, 1)): cur = cur + 1
105.         END IF
106.  
107.         'Get notevalue
108.         SELECT CASE MID$(Music$, cur, 2)
109.             CASE IS = "DQ": cur = cur + 2: NoteValue = 1.5
110.             CASE IS = "EN": cur = cur + 2: NoteValue = .5
111.             CASE IS = "QN": cur = cur + 2: NoteValue = 1
112.             CASE IS = "HN": cur = cur + 2: NoteValue = 2
113.             CASE IS = "WN": cur = cur + 2
114.                 IF Meter = 3 THEN NoteValue = 3 ELSE NoteValue = 4
115.             CASE IS = "SN": cur = cur + 2: NoteValue = .25
116.         END SELECT
117.  
118.         'If regular note/rest found (not a group)
119.         SELECT CASE MID$(Music$, cur, 2)
120.  
121.             CASE IS = "E1": note = 329.63: cur = cur + 2: GOSUB LoadNote
122.             CASE IS = "F1": note = 349.23: cur = cur + 2: GOSUB LoadNote
123.             CASE IS = "G1": note = 392.00: cur = cur + 2: GOSUB LoadNote
124.             CASE IS = "A1": note = 440.00: cur = cur + 2: GOSUB LoadNote
125.             CASE IS = "B1": note = 493.88: cur = cur + 2: GOSUB LoadNote
126.             CASE IS = "C2": note = 523.25: cur = cur + 2: GOSUB LoadNote
127.             CASE IS = "D2": note = 587.33: cur = cur + 2: GOSUB LoadNote
128.  
129.             CASE IS = "E2": note = 659.25: cur = cur + 2: GOSUB LoadNote
130.             CASE IS = "F2": note = 698.46: cur = cur + 2: GOSUB LoadNote
131.             CASE IS = "G2": note = 783.99: cur = cur + 2: GOSUB LoadNote
132.             CASE IS = "A2": note = 880.00: cur = cur + 2: GOSUB LoadNote
133.             CASE IS = "B2": note = 987.77: cur = cur + 2: GOSUB LoadNote
134.             CASE IS = "C3": note = 1046.50: cur = cur + 2: GOSUB LoadNote
135.             CASE IS = "D3": note = 1174.66: cur = cur + 2: GOSUB LoadNote
136.             CASE IS = "E3": note = 1318.51: cur = cur + 2: GOSUB LoadNote
137.             CASE IS = "RN": note = 0: cur = cur + 2: GOSUB LoadNote
138.         END SELECT
139.  
140.         'if group of notes found
141.         IF MID$(Music$, cur, 1) = "(" THEN
142.             cur = cur + 1
143.             'Grab up until ')' found
144.             Group$ = ""
145.             DO
146.                 a$ = MID$(Music$, cur, 1): cur = cur + 1
147.                 IF a$ = ")" THEN EXIT DO
148.                 IF a$ <> " " THEN Group$ = Group$ + a$
149.             LOOP
150.  
151.             NumOfNotes = LEN(Group$) / 2
152.             Length = (60 * NoteValue / Tempo)
153.             FOR L = 0 TO Length * rate STEP NumOfNotes
154.  
155.                 FOR N = 1 TO LEN(Group$) STEP 2
156.                     'fade = EXP(-L / rate * 8)
157.                     note$ = MID$(Group$, N, 2)
158.                     IF note$ = "E1" THEN _SNDRAW SIN((L / rate) * 329.63 * ATN(1) * 8) '* fade
159.                     IF note$ = "F1" THEN _SNDRAW SIN((L / rate) * 349.23 * ATN(1) * 8) '* fade
160.                     IF note$ = "G1" THEN _SNDRAW SIN((L / rate) * 392.00 * ATN(1) * 8) '* fade
161.                     IF note$ = "A1" THEN _SNDRAW SIN((L / rate) * 440.00 * ATN(1) * 8) '* fade
162.                     IF note$ = "B1" THEN _SNDRAW SIN((L / rate) * 493.88 * ATN(1) * 8) '* fade
163.                     IF note$ = "C2" THEN _SNDRAW SIN((L / rate) * 523.25 * ATN(1) * 8) '* fade
164.                     IF note$ = "D2" THEN _SNDRAW SIN((L / rate) * 587.33 * ATN(1) * 8) '* fade
165.                     IF note$ = "E2" THEN _SNDRAW SIN((L / rate) * 659.25 * ATN(1) * 8) '* fade
166.                     IF note$ = "F2" THEN _SNDRAW SIN((L / rate) * 698.46 * ATN(1) * 8) '* fade
167.                     IF note$ = "G2" THEN _SNDRAW SIN((L / rate) * 783.99 * ATN(1) * 8) '* fade
168.                     IF note$ = "A2" THEN _SNDRAW SIN((L / rate) * 880.00 * ATN(1) * 8) '* fade
169.                     IF note$ = "B2" THEN _SNDRAW SIN((L / rate) * 987.77 * ATN(1) * 8) '* fade
170.                     IF note$ = "C3" THEN _SNDRAW SIN((L / rate) * 1046.50 * ATN(1) * 8) '* fade
171.                     IF note$ = "D3" THEN _SNDRAW SIN((L / rate) * 1174.66 * ATN(1) * 8) '* fade
172.                     IF note$ = "E3" THEN _SNDRAW SIN((L / rate) * 1318.51 * ATN(1) * 8) '* fade
173.                 NEXT
174.  
175.             NEXT
176.  
177.         END IF
178.  
179.         IF cur >= LEN(Music$) THEN EXIT DO
180.  
181.         'IF INKEY$ <> "" THEN EXIT SUB
182.  
183.     LOOP
184.  
185.     EXIT SUB
186.  
187.     '=========================================================
188.     LoadNote:
189.     '========
190.     Length = (60 * NoteValue / Tempo)
191.     FOR L = 0 TO Length * rate
192.         'fade = EXP(-l / rate * 8)
193.         IF note = 0 THEN
194.             _SNDRAW 0
195.         ELSE
196.             _SNDRAW SIN((L / rate) * note * ATN(1) * 8) '* fade
197.         END IF
198.     NEXT
199.     RETURN
200.  
201. END SUB
202.  
203.  

[SierraKen]

Wow that is pretty nice sounding. Sounds like an organ. :)

[Dav]

I guess it does.  Your mantle clock using _SNDRAW got me on the idea to this, @SierraKen. 

Here's a better test code.  Playing some background music while doing more intense graphics.  Looks like it plays OK while doing other tasks, and _LIMIT 30 doesn't seem to mess with it, but there is a noticeable delay when the music has to be loaded again.  I guess there's no way around that. 

- Dav

Code: QB64: [Select]

1. 'SNDRAWPLAY test by Dav
2.  
3. SCREEN _NEWIMAGE(600, 600, 32): h2 = _HEIGHT / 2
4.  
5. s$ = "" 'a little tune to use
6. s$ = s$ + "t120 en (c2f1a1)(f2c2a1)(a2f2c2)(c3f2a2)dq(b2g2d2)"
7. s$ = s$ + "qn (c2f1a1) en (f2c2a1)(a2f2c2)(c3f2a2) qn (d3b2g2)(b2g2)"
8. s$ = s$ + "en (c2f1a1)(f2c2a1)(a2f2c2)(c3f2a2)qn(b2g2d2)en(g2)wn(a2f2c2)dqrn"
9.  
10. DO
11.  
12.     'Start music if no sound playing
13.     IF _SNDRAWLEN = 0 THEN SPLAY s$
14.  
15.  
16.     'something to display while music playing
17.     t = TIMER
18.     FOR x = 0 TO _WIDTH
19.         FOR y = 0 TO _HEIGHT
20.             r = SIN(1.1 * t) * h2 - y + h2
21.             LINE (x, y)-(x, y), _RGB(r, r - y, -r), BF
22.         NEXT: t = t + .01
23.     NEXT
24.  
25.     _LIMIT 30: _DISPLAY
26.  
27. LOOP UNTIL INKEY$ <> ""
28.  
29. END
30.  
31.  
32.  
33.  
34. SUB SPLAY (Music$)
35.  
36.     rate = _SNDRATE
37.  
38.     'Set Defaults, just in case empty
39.     IF Tempo = 0 THEN Tempo = 60
40.     IF Meter = 0 THEN Meter = 3
41.     IF NoteValue = 0 THEN NoteValue = 1
42.  
43.     Music$ = UCASE$(Music$)
44.     cur = 1
45.  
46.     DO
47.  
48.         'skip any spaces
49.         IF MID$(Music$, cur, 1) = " " THEN cur = cur + 1
50.  
51.         'Check for tempo
52.         IF MID$(Music$, cur, 1) = "T" THEN
53.             cur = cur + 1
54.             Tempo = VAL(MID$(Music$, cur, 3)): cur = cur + 3
55.         END IF
56.  
57.         'Check for Meter
58.         IF MID$(Music$, cur, 1) = "M" THEN
59.             cur = cur + 1
60.             Meter = VAL(MID$(Music$, cur, 1)): cur = cur + 1
61.         END IF
62.  
63.         'Get notevalue
64.         SELECT CASE MID$(Music$, cur, 2)
65.             CASE IS = "DQ": cur = cur + 2: NoteValue = 1.5
66.             CASE IS = "EN": cur = cur + 2: NoteValue = .5
67.             CASE IS = "QN": cur = cur + 2: NoteValue = 1
68.             CASE IS = "HN": cur = cur + 2: NoteValue = 2
69.             CASE IS = "WN": cur = cur + 2
70.                 IF Meter = 3 THEN NoteValue = 3 ELSE NoteValue = 4
71.             CASE IS = "SN": cur = cur + 2: NoteValue = .25
72.         END SELECT
73.  
74.         'If regular note/rest found (not a group)
75.         SELECT CASE MID$(Music$, cur, 2)
76.  
77.             CASE IS = "E1": note = 329.63: cur = cur + 2: GOSUB LoadNote
78.             CASE IS = "F1": note = 349.23: cur = cur + 2: GOSUB LoadNote
79.             CASE IS = "G1": note = 392.00: cur = cur + 2: GOSUB LoadNote
80.             CASE IS = "A1": note = 440.00: cur = cur + 2: GOSUB LoadNote
81.             CASE IS = "B1": note = 493.88: cur = cur + 2: GOSUB LoadNote
82.             CASE IS = "C2": note = 523.25: cur = cur + 2: GOSUB LoadNote
83.             CASE IS = "D2": note = 587.33: cur = cur + 2: GOSUB LoadNote
84.  
85.             CASE IS = "E2": note = 659.25: cur = cur + 2: GOSUB LoadNote
86.             CASE IS = "F2": note = 698.46: cur = cur + 2: GOSUB LoadNote
87.             CASE IS = "G2": note = 783.99: cur = cur + 2: GOSUB LoadNote
88.             CASE IS = "A2": note = 880.00: cur = cur + 2: GOSUB LoadNote
89.             CASE IS = "B2": note = 987.77: cur = cur + 2: GOSUB LoadNote
90.             CASE IS = "C3": note = 1046.50: cur = cur + 2: GOSUB LoadNote
91.             CASE IS = "D3": note = 1174.66: cur = cur + 2: GOSUB LoadNote
92.             CASE IS = "E3": note = 1318.51: cur = cur + 2: GOSUB LoadNote
93.             CASE IS = "RN": note = 0: cur = cur + 2: GOSUB LoadNote
94.         END SELECT
95.  
96.         'if group of notes found
97.         IF MID$(Music$, cur, 1) = "(" THEN
98.             cur = cur + 1
99.             'Grab up until ')' found
100.             Group$ = ""
101.             DO
102.                 a$ = MID$(Music$, cur, 1): cur = cur + 1
103.                 IF a$ = ")" THEN EXIT DO
104.                 IF a$ <> " " THEN Group$ = Group$ + a$
105.             LOOP
106.  
107.             NumOfNotes = LEN(Group$) / 2
108.             Length = (60 * NoteValue / Tempo)
109.             FOR L = 0 TO Length * rate STEP NumOfNotes
110.  
111.                 FOR N = 1 TO LEN(Group$) STEP 2
112.                     'fade = EXP(-L / rate * 8)
113.                     note$ = MID$(Group$, N, 2)
114.                     IF note$ = "E1" THEN _SNDRAW SIN((L / rate) * 329.63 * ATN(1) * 8) '* fade
115.                     IF note$ = "F1" THEN _SNDRAW SIN((L / rate) * 349.23 * ATN(1) * 8) '* fade
116.                     IF note$ = "G1" THEN _SNDRAW SIN((L / rate) * 392.00 * ATN(1) * 8) '* fade
117.                     IF note$ = "A1" THEN _SNDRAW SIN((L / rate) * 440.00 * ATN(1) * 8) '* fade
118.                     IF note$ = "B1" THEN _SNDRAW SIN((L / rate) * 493.88 * ATN(1) * 8) '* fade
119.                     IF note$ = "C2" THEN _SNDRAW SIN((L / rate) * 523.25 * ATN(1) * 8) '* fade
120.                     IF note$ = "D2" THEN _SNDRAW SIN((L / rate) * 587.33 * ATN(1) * 8) '* fade
121.                     IF note$ = "E2" THEN _SNDRAW SIN((L / rate) * 659.25 * ATN(1) * 8) '* fade
122.                     IF note$ = "F2" THEN _SNDRAW SIN((L / rate) * 698.46 * ATN(1) * 8) '* fade
123.                     IF note$ = "G2" THEN _SNDRAW SIN((L / rate) * 783.99 * ATN(1) * 8) '* fade
124.                     IF note$ = "A2" THEN _SNDRAW SIN((L / rate) * 880.00 * ATN(1) * 8) '* fade
125.                     IF note$ = "B2" THEN _SNDRAW SIN((L / rate) * 987.77 * ATN(1) * 8) '* fade
126.                     IF note$ = "C3" THEN _SNDRAW SIN((L / rate) * 1046.50 * ATN(1) * 8) '* fade
127.                     IF note$ = "D3" THEN _SNDRAW SIN((L / rate) * 1174.66 * ATN(1) * 8) '* fade
128.                     IF note$ = "E3" THEN _SNDRAW SIN((L / rate) * 1318.51 * ATN(1) * 8) '* fade
129.                 NEXT
130.  
131.             NEXT
132.  
133.         END IF
134.  
135.         IF cur >= LEN(Music$) THEN EXIT DO
136.  
137.         'IF INKEY$ <> "" THEN EXIT SUB
138.  
139.     LOOP
140.  
141.     EXIT SUB
142.  
143.     '=========================================================
144.     LoadNote:
145.     '========
146.     Length = (60 * NoteValue / Tempo)
147.     FOR L = 0 TO Length * rate
148.         'fade = EXP(-l / rate * 8)
149.         IF note = 0 THEN
150.             _SNDRAW 0
151.         ELSE
152.             _SNDRAW SIN((L / rate) * note * ATN(1) * 8) '* fade
153.         END IF
154.     NEXT
155.     RETURN
156.  
157. END SUB
158.  
159.  

[FellippeHeitor]

Great job, Dav. I assume the format is the same as the version with audio files you shared before?

Now about:

I'm trying to come up with a way to play several musical notes at the same time, unlike the PLAY which only plays one at a time.

Just a reminder that PLAY has been upgraded by Galleon with QB64 to play multiple notes, using a comma as an indicator of simultaneous play:

Code: QB64: [Select]

1. PLAY "O2 L8 C,E,G L1 C,E,G"

[Dav]

Wow! How did I miss that!  Thanks, @FellippeHeitor. 

Oh well...back to the puzzle games!

Edit:  now I'm wondering how hard it would be to convert a simple midi file of a keyboard instrument song to PLAY statements. Maybe will explore that...

- Dav

[Dav]

@FellippeHeitor:  Is there a way to stop PLAY from playing notes once it's been started? 

- Dav

[FellippeHeitor]

There's no stopping _SNDRAW output, except when the buffer is empty again (_SNDRAWLEN = 0). What PLAY does internally is actually generate sound waves, exactly like you are doing with your program above.

[Dav]

OK. Obrigado.

I think i'll ditch this sndraw stuff and go back to using sound files/packs, bring something more unique to the QB64 music table.  Ive got a playing/recording system going with more octaves, am putting together a keyboard virtual instrument thing, like the tank drum program I made earlier. 

- Dav

[Petr]

The way to mute _SNDRAW immediately is to multiply the unplayed audio data by zero. In addition to the audio program - you can now easily lay out your ogg files via _MEMSOUND and add various sound effects, including mixing audio into each other. Just add the samples. But then it's a good idea to check if the samples are in the range -32767 to 32768 (they are INTEGER type) so that the sound is not overheated. I'm literally crawling very slow through the programs now, because (traditionally) I can't catch up. The only reason I started avoiding to _SNDRAW, is poor stereo output.

[Dav]

Thank you, @Petr.  I have not experimented with _MEMSOUND very much.  My piano app uses ogg sounds.  Will try to get it in forum posting shape soon.  I will highly value your advice with using _MEMSOUND.

- Dav

[SierraKen]

Awesome Felippe! I never knew you could do multiple notes at once either.
Another good thing about PLAY is that you can play the sounds as other code is going too by adding MB in the beginning. SOUND command doesn't do that.
This is from the Wiki page:
MF - Play music in the foreground (each note must be completed before another can start).
MB - Play music in the background while program code execution continues (QB64 has no note buffer limits).