Rebus of Letters

[bplus]

improvement possible: variable number of letters
then nested comparison loops will be universal

Yeah my program writer uses the actual number of letters and the actual letters when it writes the Solver Program to run. Along with the Operation to use: add, subtract, multiple, divide and inputs number of words if it's to be addition.

Bout time I cleaned up the Program Writer and presented it.

[bplus]

I found a much easier way to input and process the Cryptarithm Puzzles. We had done these puzzles years ago at JB forum. With JB what you print onto the output screen can be copy and pasted through clipboard so there and then we were outputting programs on screen then copy / pasting as New bas code to run. But hardly any difference between printing to screen and printing to file.

Anyway, I rewrote the Input part of the puzzle and all the ramifications it involved and then rewrote and reran all the solvers. All the .bas files now start with word Solve (the equation).bas as the filename. The ones that have all 10 digits run about 20 minutes and on my CPU I can easily run 3 at a time.

So here is Writer #2:

Code: QB64: [Select]

1. _TITLE "Cryptarithm Program Writer #2 ASMD" 'b+ 2020-09-01
2. ' for rebus challenge by danilin ref:  https://www.qb64.org/forum/index.php?topic=2961.msg122153#msg122153
3. ' Takes input for words to add and solve and writes a program to do that.
4.  
5. ' 2020-08-31 Let's "add" more than 2 words -  Cryptarithm Program Writer +.bas
6. ' write 1 solution because we don't want to run through all 10 digits of 10 letter permutations
7. ' We probably want the letter of the last word to go first (be the last to change). Done that was easy!
8. ' No not done we need to make the last word first!
9.  
10. ' 2020-08-31 PM Let's do more than just add  -  Cryptarithm Program Writer ASMD.bas
11. ' Had to add  "_DEFINE A-Z AS _INTEGER64" to programs being written, as one test returned answer
12. ' with e notation.
13.  
14. ' 2020-09-01 Got a huge hint from tsh73 from years ago at JB Forum how to make the input to the
15. ' Program Writer a one line, simply enter the whole equation. We will use spaces to separate
16. ' the words from the operators or = sign. Simply smart!
17.  
18. _DEFINE A-Z AS _INTEGER64
19. SCREEN _NEWIMAGE(1200, 400, 32) 'need a wider screen taller screen for lot's of solutions
20. _DELAY .25
21. _SCREENMOVE _MIDDLE
22. restart:
23. PRINT "             For our word equation use the following operator symbols:"
24. PRINT "  + add, - subtract, * multiply, \ integer divide and = sign with final word"
25. PRINT "       Make sure there is a space between each word and operator or = sign."
26. PRINT "                        Example > hip * hip = hurray"
27. PRINT "                   No more than 10 different letters total."
28. PRINT
29. LINE INPUT " > "; eq$
30.  
31. ' debug with this old one from JB
32. 'eq$ = "noon + moon + soon = june"
33.  
34. REDIM word(0) AS STRING
35. Split eq$, " ", word()
36. nWords = UBOUND(word)
37. list$ = "": start$ = ""
38. ' collect and count letters
39. FOR w = nWords TO 0 STEP -2 'make sure first letter of = word is at top of list 10 permutations take while
40.     FOR i = 1 TO LEN(word(w))
41.         L$ = MID$(word(w), i, 1)
42.         IF i = 1 THEN start$ = L$ + start$: wordCnt = wordCnt + 1 ' make sure the first letter of the last word is listed first, never used wordCnt
43.         addit = -1
44.         FOR j = 1 TO LEN(list$)
45.             IF L$ = MID$(list$, j, 1) THEN addit = 0
46.         NEXT
47.         IF addit THEN list$ = list$ + L$
48.     NEXT
49. NEXT
50. PRINT "Letter list, length, start$, eq$: "; list$, LEN(list$), start$, eq$
51. LL = LEN(list$)
52. INPUT " Enter anything to quit, just enter to continue..."; quit$
53. IF LEN(quit$) THEN END
54.  
55. 'OK here we start writing the file
56. p = INSTR(eq$, "\") 'cant open file with "\" in title
57. IF p THEN
58.     eqq$ = MID$(eq$, 1, p - 1) + "idvd" + MID$(eq$, p + 1)
59. ELSE
60.     eqq$ = eq$
61. END IF
62. p = INSTR(eqq$, "*") 'cant open file with "*" in title
63. IF p THEN
64.     eqq$ = MID$(eqq$, 1, p - 1) + "mult" + MID$(eqq$, p + 1)
65. END IF
66.  
67. OPEN "Solve (" + eqq$ + ").bas" FOR OUTPUT AS #1
68. S1$ = " ' written by Cryptarithm Program Writer #2 ASMD.bas b+ 2020-09-01"
69. PRINT #1, "_TITLE " + CHR$(34) + "Solve (" + eq$ + ").bas" + CHR$(34) + S1$
70. PRINT #1, "SCREEN _NEWIMAGE(1200, 720, 32) 'need a wider screen taller screen for lot's of solutions"
71. PRINT #1, "_DELAY .25"
72. PRINT #1, "_SCREENMOVE _MIDDLE"
73. PRINT #1, "_DEFINE A-Z AS _INTEGER64"
74. PRINT #1, "DIM a(" + _TRIM$(STR$(LL)) + ")"
75.  
76. S$ = "" ' Header for solution columns, aint we full of hope!
77. FOR i = 0 TO nWords STEP 2 ' setup a header actually should do this at start reguardless of solutions or not
78.     IF i = 0 THEN
79.         S$ = S$ + CHR$(34) + " " + word(i) + CHR$(34)
80.     ELSE
81.         S$ = S$ + CHR$(34) + word(i - 1) + word(i) + CHR$(34)
82.     END IF
83.     IF i <> nWords THEN S$ = S$ + ", "
84. NEXT
85. Header$ = S$ ' if there are allot of multiple solutions the we could pause, then cls and fill another with header
86. PRINT #1, "PRINT " + S$
87.  
88. FOR i = 1 TO LEN(list$)
89.     IF INSTR(start$, MID$(list$, i, 1)) THEN
90.         PRINT #1, "FOR " + MID$(list$, i, 1) + " = 1 to 9: a(" + _TRIM$(STR$(i)) + ") = " + MID$(list$, i, 1)
91.     ELSE
92.         PRINT #1, "FOR " + MID$(list$, i, 1) + " = 0 to 9: a(" + _TRIM$(STR$(i)) + ") = " + MID$(list$, i, 1)
93.     END IF
94. NEXT
95.  
96. PRINT #1, "FOR xx = 1 TO " + _TRIM$(STR$(LL - 1))
97. PRINT #1, "FOR yy = xx + 1 TO " + _TRIM$(STR$(LL))
98. PRINT #1, "IF a(xx) = a(yy) THEN GOTO skip"
99. PRINT #1, "NEXT"
100. PRINT #1, "NEXT"
101.  
102. 'ten = 100 * t + 10 * e + n
103. FOR w = 0 TO nWords STEP 2
104.     S$ = word(w) + " = "
105.     LW = LEN(word(w))
106.     FOR i = 1 TO LW
107.         S$ = S$ + "10 ^ " + _TRIM$(STR$(LW - i)) + " * " + MID$(word(w), i, 1)
108.         IF i <> LW THEN S$ = S$ + " + "
109.     NEXT
110.     PRINT #1, S$
111. NEXT
112.  
113. 'IF ten + two = four THEN
114. PRINT #1, "IF " + eq$ + " THEN" '  here we have a solution
115.  
116. 'PRINT count, ten, two, four
117. S$ = ""
118. FOR i = 0 TO nWords STEP 2
119.     S$ = S$ + word(i)
120.     IF i <> nWords THEN S$ = S$ + ", "
121. NEXT
122. PRINT #1, "PRINT " + S$
123. 'PRINT #1, "PRINT: PRINT " + CHR$(34) + "  Press any to end..." + CHR$(34)
124. 'PRINT #1, "SLEEP"
125. 'PRINT #1, "END"
126. PRINT #1, "END IF"
127.  
128. PRINT #1, "skip:"
129. FOR i = 1 TO LL
130.     PRINT #1, "NEXT"
131. NEXT
132. PRINT #1, "PRINT " + CHR$(34) + " Run is done, goodbye!" + CHR$(34)
133. CLOSE #1
134. PRINT "File Ready"
135. GOTO restart
136.  
137. SUB Split (SplitMeString AS STRING, delim AS STRING, loadMeArray() AS STRING)
138.     DIM curpos AS LONG, arrpos AS LONG, LD AS LONG, dpos AS LONG 'fix use the Lbound the array already has
139.     curpos = 1: arrpos = LBOUND(loadMeArray): LD = LEN(delim)
140.     dpos = INSTR(curpos, SplitMeString, delim)
141.     DO UNTIL dpos = 0
142.         loadMeArray(arrpos) = MID$(SplitMeString, curpos, dpos - curpos)
143.         arrpos = arrpos + 1
144.         IF arrpos > UBOUND(loadMeArray) THEN REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO UBOUND(loadMeArray) + 1000) AS STRING
145.         curpos = dpos + LD
146.         dpos = INSTR(curpos, SplitMeString, delim)
147.     LOOP
148.     loadMeArray(arrpos) = MID$(SplitMeString, curpos)
149.     REDIM _PRESERVE loadMeArray(LBOUND(loadMeArray) TO arrpos) AS STRING 'get the ubound correct
150. END SUB
151.  
152.  

and here is the load of Solvers I've written with it tonight, a couple of subtraction, division and multiplication but mostly addition of two or more words:

[DANILIN]

Brilliant work synthesizing programs from a program

I remembered doing the same thing in Excel for an idea
Quadrat Economy Danilins
where regular changes in the code are made in Excel

 

And without Excel and without synthesis it takes into account 10 letters
there are probably "IF" before cycles

Original code:

Code: QB64: [Select]

1. ' Russian Rebus of Letters from Digitals.bas
2. NN = 5: DIM a(NN)
3. FOR u = 1 TO 9: a(1) = u
4.     FOR d = 1 TO 9: a(2) = d
5.         FOR a = 0 TO 9: a(3) = a
6.             FOR r = 0 TO 9: a(4) = r
7.                 FOR k = 0 TO 9: a(5) = k
8. FOR xx = 1 TO NN-1
9.    FOR yy = xx + 1 TO NN
10.       IF a(xx) = a(yy) THEN GOTO 55
11. NEXT yy: NEXT xx
12.              udar = 1000*u + 100*d + 10*a + r
13.              draka = d*10000 + r*1000 + a*100 + k*10 + a
14.                   IF udar + udar = draka THEN PRINT udar, draka
15. 55 NEXT: NEXT: NEXT: NEXT: NEXT
16. END

[bplus]

Yes, your example for handling IF's was very helpful. I was prepared to systematically run through the combinations.

[TempodiBasic]

Hi Bplus and DANILIN

so I can see that you like the crytography and the use of brute force of  PC machine to solve it.

Do you think that it is possible to apply this method for solve the Lettera del Diavolo di Agrigento (Letter of devil that stays in Agrigento)?
here a link to the issuehttps://sites.google.com/site/beatacorbera/lettera-del-diavolo and the letter https://sites.google.com/site/beatacorbera/_/rsrc/1317142844724/lettera-del-diavolo/LETTERA%20DEL%20DIAVOLO.jpg?height=1553&width=1118

Thanks to read

[DANILIN]

Theoretically without a key except for letter differences
this algorithm compares letters with each other
requires up to 26*25/2=325 comparisons each turn
and it will give out words from different letters

And one day this text will add up to a readable one

Code: QB64: [Select]

1. NN = 26: DIM a(NN)
2. FOR a = 1 TO 26: a(1) = a
3.     FOR b = 1 TO 26: a(2) = b
4.         ...
5.             FOR y = 1 TO 26: a(25) = y
6.                 FOR z = 1 TO 26: a(26) = z
7. FOR xx = 1 TO NN-1: FOR yy = xx+1 TO NN
8.       IF a(xx) = a(yy) THEN GOTO 55
9. NEXT yy: NEXT xx

Then output prepared letter combination
main thing is that order is observed

I'll check it out for myself:

Code: QB64: [Select]

1. NN = 5: DIM a(NN): s = 0 ' danilin.bas
2. FOR d = 0 TO 26: a(1) = d
3.     FOR a = 0 TO 26: a(2) = a
4.         FOR n = 0 TO 26: a(3) = n
5.             FOR i = 0 TO 26: a(4) = i
6.                 FOR l = 0 TO 26: a(5) = l
7.     FOR xx = 1 TO NN - 1: FOR yy = xx+1 TO NN
8.           IF a(xx) = a(yy) THEN GOTO 55
9.     NEXT yy: NEXT xx
10. s = s+1
11. Word$ = CHR$(65+a(1)) + CHR$(65+a(2)) + CHR$(65+a(3)) + CHR$(65+a(4)) + CHR$(65+a(5)) + CHR$(65+a(4)) + CHR$(65+a(3))
12. PRINT s; Word$;
13. IF Word$ = "DANILIN" THEN END
14.  
15. 55 NEXT: NEXT: NEXT: NEXT: NEXT
16. END

DANILIN # 1'082'619 by 5 seconds

[bplus]

Hey @TempodiBasic

I don't consider these Solvers = cryptography, they are letter/word equations/puzzles to be solved besides, some of them have more than one solution.

Any cryptography of worth would not repeat the same value for same letter, too easy!

[TempodiBasic]

@bplus
before to run you must be able to walk, and before to walk you must be able to stand on your feet...

Yes the scrolling frame is the second pattern used into cryptography after the substitution one to one from a symbol to another of another kind. The third step, generally, is the substitution one symbol to many symbol following a math scheme.
Here I post an example of the easyest cryptography  taken from this link https://www.google.com/url?sa=i&url=https%3A%2F%2Fpdfslide.net%2Fdocuments%2Fsettimana-enigmistica-3270-con-soluzioni.html&psig=AOvVaw1YIuX2pFgB3ItXqzNONtDT&ust=1599600916868000&source=images&cd=vfe&ved=0CA4QtaYDahcKEwjQ0JL3_9frAhUAAAAAHQAAAAAQCw

L'ANEDDOTO CIFRATO
123456-78-9
8 IO 9 3 Il 2 - IO 8 12
13 2 Il Brando 8 14 6 14 8
13 - 8 9 3 15 16 7 3 Il
6 7 3 - 8 Il 7 8 12 17
6 Il 6 - 8 - 18 2 Il 18
2 invece 7 3 - 12 6 4 8 12
17 3 - 8 - 17 4 16 2 13
8 . - 13 8 - 17 2 12 6 13
13 8 - IO 8 19 19 3 2 12
6 - 7 6 4 3 17 6 - 3 Il
20 3 Il 6 - 7 3 accompagnar­
velo I 6 12 17 2 Il 8 13 IO
6 Il 15 6 • - 15 6 Il 6 Il
7 2 13 2 - 8 13 - 19 16
3 Il 18 8 19 13 3 2 .
Sostituite una lettera ad ogni numero.

Good Luck to translate into italian language. (using a foreign language to write the message: this can be another way to make more difficult the cryptography because everyone is used to think and talk in own native language and not in other languages.)

[DANILIN]

Program lists combinations of 7 letters
before word ZYXWVUT
reporting results every 15 seconds
practically changing 2nd letter
and it takes about 3 hours for all iterations

Code: QB64: [Select]

1. start = TIMER: NN = 7: t = 0: DIM a(NN): DIM s AS DOUBLE: s = 0:' zyxwvut.bas
2. FOR a = 0 TO 25: a(1) = a
3.     FOR b = 0 TO 25: a(2) = b
4.         FOR c = 0 TO 25: a(3) = c
5.             FOR d = 0 TO 25: a(4) = d
6.                 FOR e = 0 TO 25: a(5) = e
7.                     FOR f = 0 TO 25: a(6) = f
8.                         FOR g = 0 TO 25: a(7) = g
9.     FOR xx = 1 TO NN - 1: FOR yy = xx + 1 TO NN: IF a(xx) = a(yy) THEN GOTO 55
10.     NEXT yy: NEXT xx
11. s = s + 1: finish = TIMER: q = INT(finish - start)
12. Word$ = CHR$(65+a(1)) + CHR$(65+a(2)) + CHR$(65+a(3)) + CHR$(65+a(4)) + CHR$(65+a(5)) + CHR$(65+a(6)) + CHR$(65+a(7))
13. IF q-t = 15 THEN PRINT q; "s. "; INT(s /10^6); "mln. "; Word$; ,: t = q
14. IF Word$ = "ZYXWVUT" THEN PRINT s; Word$; ,: finish = TIMER: PRINT finish - start: END
15.    55 NEXT: NEXT: NEXT: NEXT: NEXT: NEXT: NEXT
16. finish = TIMER: PRINT finish - start: END

+ 9\9\20

Code: QB64: [Select]

1. start = TIMER: NN = 7: t = 0: DIM a(NN): DIM s AS DOUBLE: s = 0 ' zyxwvut.bas
2. FOR a = 25 TO 25: a(1) = a
3.     FOR b = 24 TO 25: a(2) = b
4.         FOR c = 0 TO 25: a(3) = c
5.             FOR d = 0 TO 25: a(4) = d
6.                 FOR e = 0 TO 25: a(5) = e
7.                     FOR f = 0 TO 25: a(6) = f
8.                         FOR g = 0 TO 25: a(7) = g
9. FOR xx = 1 TO NN - 1: FOR yy = xx + 1 TO NN: IF a(xx) = a(yy) THEN 55
10.          NEXT yy: NEXT xx: s = s + 1
11. Word$ = CHR$(65+a(1)) + CHR$(65+a(2)) + CHR$(65+a(3)) + CHR$(65+a(4)) + CHR$(65+a(5)) + CHR$(65+a(6)) + CHR$(65+a(7))
12. IF Word$ = "ZYXWVUT" THEN 77
13.   55 NEXT: NEXT: NEXT: NEXT
14.       PRINT INT(s/10^6); "mln. "; Word$; ,
15. NEXT: NEXT: NEXT
16. 77 PRINT s; Word$; ,: finish = TIMER: PRINT finish - start: END

 

Below: all combination of 7 digital is factorial 7! = 1*2*3*4*5*6*7 = 5040

[bplus]

Program lists combinations of 7 letters
before word ZYXWVUT
reporting results every 15 seconds
practically changing 2nd letter
and it takes about 3 hours for all iterations

Code: QB64: [Select]

1. start = TIMER: NN = 7: t = 0: DIM a(NN): DIM s AS DOUBLE: s = 0:' zyxwvut.bas
2. FOR a = 0 TO 25: a(1) = a
3.     FOR b = 0 TO 25: a(2) = b
4.         FOR c = 0 TO 25: a(3) = c
5.             FOR d = 0 TO 25: a(4) = d
6.                 FOR e = 0 TO 25: a(5) = e
7.                     FOR f = 0 TO 25: a(6) = f
8.                         FOR g = 0 TO 25: a(7) = g
9.     FOR xx = 1 TO NN - 1: FOR yy = xx + 1 TO NN: IF a(xx) = a(yy) THEN GOTO 55
10.     NEXT yy: NEXT xx
11. s = s + 1: finish = TIMER: q = INT(finish - start)
12. Word$ = CHR$(65+a(1)) + CHR$(65+a(2)) + CHR$(65+a(3)) + CHR$(65+a(4)) + CHR$(65+a(5)) + CHR$(65+a(6)) + CHR$(65+a(7))
13. IF q-t = 15 THEN PRINT q; "s. "; INT(s /10^6); "mln. "; Word$; ,: t = q
14. IF Word$ = "ZYXWVUT" THEN PRINT s; Word$; ,: finish = TIMER: PRINT finish - start: END
15.    55 NEXT: NEXT: NEXT: NEXT: NEXT: NEXT: NEXT
16. finish = TIMER: PRINT finish - start: END

@DANILIN  sorry this does not make sense to me maybe I miss something or something lost in translation but
there is 1 combination of 7 letters using all 7 letters
and there are 2^7 sets of combination subsets of a 7 element set including the combination of no letters.

There are 7! Permutations of 7 letters that is only 5040 which should take less than a minute to generate even on slow computer.

Lets see if I can dig up the code that will list perms of abcdefg

Ah here we go! 5040 permutations. This thing can do whole words too!

Code: QB64: [Select]

1. _TITLE "Permutations with value translator" 'B+ add value translator 2019-03-31
2. 'from "Permutations wo recursion"  translate from SmallBasic to QB64 2019-03-31
3. 'from "Permutations" translation from: PowerBASIC, tsh copy from Liberty link 2017-02-04
4.  
5. SCREEN _NEWIMAGE(800, 600, 32)
6. _SCREENMOVE 300, 40
7.  
8. REDIM results$(0)
9. loadPermsValues results$()
10. 'display result$
11. FOR i = 0 TO UBOUND(results$)
12.     PRINT i + 1, results$(i)
13.     IF i MOD 30 = 29 THEN
14.         PRINT "press any to continue..."
15.         SLEEP
16.         CLS
17.     END IF
18. NEXT
19.  
20. ValuesData:
21. DATA "a","b","c","d","e","f","g","END"
22.  
23. 'this reads data from ValuesData line and translates Permutations to those values
24. SUB loadPermsValues (r() AS STRING)
25.     'load values array one way or another? read data
26.     REDIM values(0) AS STRING
27.     RESTORE ValuesData
28.     DO
29.         READ r$
30.         IF r$ = "END" THEN
31.             done = 1
32.         ELSE
33.             n = n + 1
34.             REDIM _PRESERVE values(n) AS STRING
35.             values(n) = r$
36.         END IF
37.     LOOP UNTIL done
38.     n = UBOUND(values)
39.     DIM a(0 TO n + 1) '+1 needed due to bug in LB that checks loop condition: until (i=0) or (a(i)<a(i+1))
40.     FOR i = 0 TO n: a(i) = i: NEXT 'load a() with minimum values
41.     DO
42.         b$ = ""
43.         FOR i = 1 TO n
44.             b$ = b$ + values(a(i)) + " "
45.         NEXT
46.         REDIM _PRESERVE r(e)
47.         r(e) = b$
48.         e = e + 1
49.  
50.         i = n
51.         DO
52.             i = i - 1
53.         LOOP UNTIL (i = 0) OR (a(i) < a(i + 1))
54.         j = i + 1
55.         k = n
56.         WHILE j < k
57.             SWAP a(j), a(k)
58.             j = j + 1
59.             k = k - 1
60.         WEND
61.         IF i > 0 THEN
62.             j = i + 1
63.             WHILE a(j) < a(i)
64.                 j = j + 1
65.             WEND
66.             SWAP a(i), a(j)
67.         END IF
68.     LOOP UNTIL i = 0
69.     EXIT SUB
70. END SUB
71.  
72.  

[bplus]

And for combinations here is how Steve handled the listing of Combinations of 60 numbers taken 6 at a time:

Code: QB64: [Select]

1. ' print ordered list of combo rCn, r = 6 n = 60 Steve McNeill 2019-03-28
2.  
3. PRINT "Calculating..."
4. OPEN "6 Combos from 60 Numbers.txt" FOR OUTPUT AS #1
5. FOR num1 = 1 TO 55
6.     LOCATE 2, 1: PRINT num1,
7.     FOR num2 = num1 + 1 TO 56
8.         LOCATE 3, 1: PRINT num2,
9.         FOR num3 = num2 + 1 TO 57
10.             LOCATE 4, 1: PRINT num3,
11.             FOR num4 = num3 + 1 TO 58
12.                 LOCATE 5, 1: PRINT num4,
13.                 FOR num5 = num4 + 1 TO 59
14.                     LOCATE 6, 1: PRINT num5,
15.                     FOR num6 = num5 + 1 TO 60
16.                         LOCATE 7, 1: PRINT num6
17.                         s$ = LTRIM$(STR$(num1)) + ","
18.                         IF num1 < 10 THEN s$ = "0" + s$
19.                         IF num2 < 10 THEN s$ = s$ + "0"
20.                         s$ = s$ + LTRIM$(STR$(num2)) + ","
21.                         IF num3 < 10 THEN s$ = s$ + "0"
22.                         s$ = s$ + LTRIM$(STR$(num3)) + ","
23.                         IF num4 < 10 THEN s$ = s$ + "0"
24.                         s$ = s$ + LTRIM$(STR$(num4)) + ","
25.                         IF num5 < 10 THEN s$ = s$ + "0"
26.                         s$ = s$ + LTRIM$(STR$(num5)) + ","
27.                         IF num6 < 10 THEN s$ = s$ + "0"
28.                         s$ = s$ + LTRIM$(STR$(num6))
29.                         PRINT #1, s$
30.                     NEXT
31.                 NEXT
32.             NEXT
33.         NEXT
34.     NEXT
35. NEXT
36.  
37.  

Now I will make a program to generate all the combinations of an n element set because I've been meaning to do that :)

[bplus]

Sometimes I impress myself:
Ordered Combinations Generator (using letters to represent elements in a set)
https://www.qb64.org/forum/index.php?topic=2999.msg122579#msg122579