a little demo about VIEW WINDOW and PMAP: beginners info

[TempodiBasic]

Hi guys
seeing that it is in the air to talk about managing of physical screen of pc and how to change its dimensions and cohordinate's system and moreover how to fragment it into more little areas that are indipendent among them for dimensions, cohordinate's system
I post here my little contibution
a demonstration lesson about VIEW WINDOW and PMAP using also _PRINTSTRING and _MOUSEcohordinates as Bplus has stressed that are out of this system and must be adapted to interact properly with it.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3.  
4. ' 0-799<--->    0-599 ^
5. '                     |
6. '                     v
7.  
8. DO: LOOP UNTIL _SCREENEXISTS
9. _TITLE "Window View and PMAP: some info"
10. _SCREENMOVE 10, 10
11.  
12. COLOR _RGB32(0, 10, 255)
13.  
14. LINE (-2, -2)-(802, 602), _RGB32(255, 0, 0), B
15. _PRINTSTRING (10, 10), "Remember you can make graphic out of screen!"
16. SLEEP 2
17. CLS
18. WINDOW (-10, -10)-(810, 610)
19. LINE (-2, -2)-(802, 602), _RGB32(255, 0, 0), B
20. _PRINTSTRING (10, 10), "Remember you can make graphic out of screen!"
21. SLEEP 2
22. CLS
23. _PRINTSTRING (10, 10), "You cannot set an area of screen not visible (out of screen visible) by VIEW!"
24. _PRINTSTRING (10, 40), " you'll get an error messagebox, please choose to continue"
25. VIEW (-2, -2)-(802, 602), _RGB32(200, 20, 20), _RGB32(0, 0, 255)
26. SLEEP 1
27.  
28. VIEW (1, 1)-(798, 598), _RGB32(127, 127, 127), _RGB32(200, 10, 250)
29. _PRINTSTRING (10, 10), "You can choose the whole screen with coordinates or only VIEW with no parameters"
30. SLEEP 2
31. CLS
32. WINDOW SCREEN(1, -10)-(850, 400) ' used SCREEN to maintain the y = 0 at top and y = max at bottom
33. LINE (-2, -2)-(802, 602), _RGB32(200, 20, 20), B
34. _PRINTSTRING (10, 10), "Each graphic instruction follow the dimensions of WINDOW instruction"
35. SLEEP 2
36. _PRINTSTRING (10, 30), " the exceptions are _PRINTSTRING and _MOUSEpositions. "
37. _PRINTSTRING (10, 60), "In fact this text and line are in different positions"
38. LINE (10, 30)-(140, 30), _RGB32(255, 120, 10)
39. SLEEP 4
40. _PRINTSTRING (10, 90), "Move mouse in the next demo"
41. SLEEP 2
42. CLS
43. WINDOW (1, -10)-(850, 400)
44. a% = 10: b% = 40: c% = b% + 20
45. DO
46.     IF _MOUSEINPUT THEN
47.         WHILE _MOUSEINPUT: WEND
48.         mx% = _MOUSEX
49.         my% = _MOUSEY
50.         LMB% = _MOUSEBUTTON(1)
51.         RMB% = _MOUSEBUTTON(2)
52.         CLS
53.         _PRINTSTRING (10, 20), "X = " + STR$(mx%) + "  Y= " + STR$(my%)
54.         _PRINTSTRING (160, 20), " Move mouse to TopLeft and BottomRight corner of screen and see its value"
55.  
56.         _PRINTSTRING (a%, b%), "press Right Mouse Button to move this text on the screen to mouse's position"
57.         _PRINTSTRING (a%, c%), "press Left Mouse Button to quit this demonstration"
58.         _PRINTSTRING (a%, c% + 40), " Lines and text aren't on the same position!"
59.         LINE (a%, b%)-(a% + 100, b%), _RGB32(10, 200, 10)
60.         LINE (a%, c%)-(a% + 100, c%), _RGB32(10, 200, 10)
61.         IF RMB% THEN
62.             a% = mx%
63.             b% = my%
64.             c% = my% + 20
65.         END IF
66.         _DISPLAY
67.     END IF
68. LOOP UNTIL _MOUSEBUTTON(1)
69. DO: LOOP UNTIL NOT _MOUSEINPUT
70. _AUTODISPLAY
71. CLS
72. VIEW
73. WINDOW
74. COLOR _RGB32(255, 0, 0)
75. _PRINTSTRING (20, 10), "In sum: VIEW selects an area of the screen visible. WINDOW defines custom dimensions of that area"
76. _PRINTSTRING (20, 30), "WINDOW inverts Y-axis, SCREEN parameter restores the original direction of Y-axis"
77. SLEEP 2
78. VIEW (100, 100)-(500, 200), _RGB32(127, 127, 127)
79. WINDOW SCREEN(1, 1)-(100, 100)
80. LINE (50, 50)-(150, 50), _RGB32(127, 1, 127)
81.  
82. VIEW (100, 300)-(500, 400), _RGB32(127, 127, 127)
83. WINDOW SCREEN(1, 1)-(200, 100)
84. LINE (50, 50)-(150, 50), _RGB32(127, 1, 127)
85.  
86. VIEW (100, 500)-(500, 598), _RGB32(127, 127, 127)
87. WINDOW SCREEN(-100, 100)-(100, 1) ' the WINDOW statement has an inner sorting of dimensions
88. LINE (50, 50)-(150, 50), _RGB32(127, 1, 127)
89. SLEEP 4
90. VIEW
91. WINDOW
92. CLS
93. _PRINTSTRING (10, 10), " Now draw by mouse in the upper rectangle by left click, quit by Right click"
94. VIEW (100, 100)-(500, 200), , _RGB32(127, 127, 0)
95. WINDOW SCREEN(1, 1)-(300, 300)
96. LINE (50, 50)-(150, 50), _RGB32(127, 1, 127)
97.  
98. VIEW (100, 300)-(500, 400), , _RGB32(127, 127, 0)
99. WINDOW SCREEN(1, 1)-(200, 100)
100. LINE (50, 50)-(150, 50), _RGB32(127, 1, 127)
101. SLEEP 2
102. DO
103.  
104.     WHILE _MOUSEINPUT: WEND
105.     mx% = _MOUSEX
106.     my% = _MOUSEY
107.     LMB% = _MOUSEBUTTON(1)
108.     RMB% = _MOUSEBUTTON(2)
109.     IF LMB% THEN
110.         IF mx% > 99 AND mx% < 501 THEN
111.             IF my% > 99 AND my% < 201 THEN
112.                 ' it draws in the first viewport
113.                 VIEW (100, 100)-(500, 200), , _RGB32(127, 127, 0)
114.                 WINDOW SCREEN(1, 1)-(300, 300)
115.                 LINE (50, 50)-(150, 50), _RGB32(127, 1, 127)
116.  
117.  
118.                 LINE -STEP(INT(PMAP(mx%, 2)), INT(PMAP(my%, 3))), _RGB32(200, 100, 200, 255)
119.                 _DISPLAY
120.                 VIEW
121.                 COLOR _RGB32(200, 200, 0)
122.                 _PRINTSTRING (100, 250), STR$(mx%) + " -> " + STR$(INT(PMAP(mx%, 2))) + "  " + STR$(my%) + " --> " + STR$(INT(PMAP(my%, 3)))
123.  
124.                 ' it draws in the second viewport
125.                 VIEW (100, 300)-(500, 400), , _RGB32(127, 127, 0)
126.                 WINDOW SCREEN(1, 1)-(200, 100)
127.                 LINE (50, 50)-(150, 50), _RGB32(127, 1, 127)
128.  
129.  
130.                 LINE -STEP(INT(PMAP(mx%, 2)), INT(PMAP(my%, 3))), _RGB32(255, 255, 255, 255)
131.                 _DISPLAY
132.                 VIEW
133.                 COLOR _RGB32(255)
134.                 _PRINTSTRING (100, 450), STR$(mx%) + " -> " + STR$(INT(PMAP(mx%, 2))) + "  " + STR$(my%) + " --> " + STR$(INT(PMAP(my%, 3)))
135.                 _DISPLAY
136.             END IF
137.         END IF
138.     END IF
139.  
140. LOOP UNTIL RMB%
141. _AUTODISPLAY
142. VIEW
143. WINDOW
144. CLS
145. _PRINTSTRING (10, 10), "Thanks to watching"
146. SLEEP 2
147. SYSTEM

Thanks to read

[OldMoses]

Nice presentation. Some of the sleep statements could be a little longer for us slow readers. ;)

I've found WINDOW to be a good way to predetermine how my graphics interacts with the data generated. I use it quite a lot, particularly for quickie applications. There is a tradeoff, I can define my space in R3 like I'm used to, but then I have to be aware to alter how any trig functions behave. It can be a bit of a pain working between vector and polar coordinates. This was how I handled the space flight program I've been endlessly working on. Generate a sub-image with custom coordinates using VIEW & WINDOW then _PUTIMAGE to the mainscreen.

One painful lesson I learned from that approach, if your "model space" is much larger than your "display space" and contains a lot of "off-screen" details, you're well served to use logical operators that avoid the processing time of drawing things that will not actually be displayed. Otherwise, things can slow to a crawl if the graphics are complex, such as liberal use of Steve's fcirc, in my case.

I'm going to have to get familiar with PMAP, it suddenly occurred to me that it might hold the key to doing some mouse selection bugs I've been dealing with.

[TempodiBasic]

Thanks OldMoses
I'll adjust a bit those SLEEPs

I have little experience with WINDOW and PMAP  while a bit more with VIEW but I find their use very useful in some kind of graphic work.

I found an example of Mandelbrot fractal in Qbasic with use of WINDOW VIEW and PMAP. It was ok but I have thought to make it a bit more adaptable so I convert the program into a SUB and I play to draw Mandelbrot Fractal in 3 different viewport just to show how can be useful such instructions.
Thanks to read and to try following code.

Code: QB64: [Select]

1. ' a little demonstration about WINDOW, VIEW and PMAP
2. SCREEN _NEWIMAGE(800, 600, 8)
3. DO: LOOP UNTIL _SCREENEXISTS
4. _TITLE "a little demonstration about WINDOW, VIEW and PMAP"
5. _SCREENMOVE 10, 10
6.  
7. 'This example uses the VIEW and WINDOW statements to define a graphics
8. 'viewport and window. The PMAP function is used to convert viewport
9. 'coordinates to window coordinates.  The program generates a fractal
10. 'that shows a subset of the complex numbers called the "Mandelbrot Set."
11.  
12. DEFINT A-Z 'Default variable type is integer.
13.  
14. 'Set maximum number of iterations per point.
15. CONST MAXLOOP = 30, MAXSIZE = 1000000
16. CONST FALSE = 0, TRUE = NOT FALSE 'Boolean constants.
17.  
18. ' set maximum viewport parameters (whole screen)
19. CONST VLm = 0, VUm = 0, VRm = 799, VBm = 599
20. ' set  first viewport  parameters
21. CONST VL1 = 50, VU1 = 50, VR1 = 200, VB1 = 500
22.  
23. ' set  second viewport  parameters
24. CONST VL2 = 300, VU2 = 300, VR2 = 700, VB2 = 500
25.  
26. 'Set window paramters.
27. CONST WLeft = -1000, WRight = 250, WTop = 625, WBottom = -625
28.  
29. ' declaration global variables
30. DIM SHARED ColorRange AS INTEGER
31.  
32. ColorRange = 15
33.  
34. 'Define viewport and corresponding window
35. ' the whole window
36. VIEW (VLm, VUm)-(VRm, VBm), 0, ColorRange
37. WINDOW (WLeft, WTop)-(WRight, WBottom)
38. DrawMandelbrot VLm, VRm, VBm, VUm
39.  
40. ' a vertical little window
41. VIEW (VL1, VU1)-(VR1, VB1), 0, ColorRange
42. WINDOW (WLeft, WTop)-(WRight, WBottom)
43. DrawMandelbrot VL1, VR1, VB1, VU1
44.  
45. ' an horizhontal window
46. VIEW (VL2, VU2)-(VR2, VB2), 0, ColorRange
47. WINDOW (WLeft, WTop)-(WRight, WBottom)
48. DrawMandelbrot VL2, VR2, VB2, VU2
49.  
50. LOCATE 1, 10: PRINT "Press any key to quit.";
51. END
52.  
53. SUB DrawMandelbrot (Left AS INTEGER, Right AS INTEGER, Bottom AS INTEGER, Up AS INTEGER)
54.  
55.     DIM Xlength AS INTEGER, Ylength AS INTEGER, Y AS INTEGER, X AS INTEGER
56.     DIM ColorWidth AS INTEGER, LogicY AS INTEGER, LogicX AS INTEGER
57.     DIM OldColor AS INTEGER, PColor AS INTEGER, RealNum&, ImagNum&
58.     DIM MandelX&, MandelY&
59.  
60.     Xlength = Right - Left
61.     Ylength = Bottom - Up
62.     ColorWidth = MAXLOOP \ ColorRange
63.  
64.     'Loop through each pixel in viewport and calculate whether or not
65.     'it is in the Mandelbrot Set.
66.     FOR Y = 0 TO Ylength 'Loop through every line in the viewport.
67.         LogicY = PMAP(Y, 3) 'Get the pixel's logical y coordinate.
68.         PSET (WLeft, LogicY) 'Plot leftmost pixel in the line.
69.         OldColor = 0 'Start with background color.
70.  
71.         FOR X = 0 TO Xlength 'Loop through every pixel in the line.
72.             LogicX = PMAP(X, 2) 'Get the pixel's logical x coordinate.
73.             MandelX& = LogicX
74.             MandelY& = LogicY
75.  
76.             'Do the calculations to see if this point is in the Mandelbrot Set.
77.             FOR I = 1 TO MAXLOOP
78.                 RealNum& = MandelX& * MandelX&
79.                 ImagNum& = MandelY& * MandelY&
80.                 IF (RealNum& + ImagNum&) >= MAXSIZE THEN EXIT FOR
81.                 MandelY& = (MandelX& * MandelY&) \ 250 + LogicY
82.                 MandelX& = (RealNum& - ImagNum&) \ 500 + LogicX
83.             NEXT I
84.  
85.             'Assign a color to the point.
86.             PColor = I \ ColorWidth
87.  
88.             'If color has changed, draw a line from the last point
89.             'referenced to the new point, using the old color.
90.             IF PColor <> OldColor THEN
91.                 LINE -(LogicX, LogicY), (ColorRange - OldColor)
92.                 OldColor = PColor
93.             END IF
94.  
95.             IF INKEY$ <> "" THEN END
96.         NEXT X
97.  
98.         'Draw the last line segment to the right edge of the viewport.
99.         LINE -(LogicX, LogicY), (ColorRange - OldColor)
100.  
101.     NEXT Y
102. END SUB
103.