Tetris by _vince

[The Librarian]

Tetris

Author: @_vince
Source: qb64.org Forum
URL: https://www.qb64.org/forum/index.php?topic=626.0
Version: 2018
Tags: [2d], [game], [tetris]

Description:
clean and simple tetris implementation. you can change variables size, sw, and sh for custom board sizes.

20:55 < _vince> ive said it before but i think tetris is the ultimate test of a
                programmer
20:55 < _vince> as it combines all programming concepts but doesnt demand any
                specialized knowledge

controls:
* arrow keys: movement, up: rotate
* shift + left/right/down: hard left/right/drop
* spacebar: hard drop
* +/-: change speed
* p: pause
* Enter: restart
* Esc: quit

Source Code:

Code: QB64: [Select]

1. randomize timer
2. deflng a-z
3.  
4. dim shared piece(6, 3, 1)
5. dim shared piece_color(6)
6. dim shared size, sw, sh
7.  
8. size = 35
9. sw = 10
10. sh = 20
11.  
12. redim shared board(sw - 1, sh - 1)
13.  
14. piece(0,0,0)=0: piece(0,1,0)=1: piece(0,2,0)=1: piece(0,3,0)=0
15. piece(0,0,1)=0: piece(0,1,1)=1: piece(0,2,1)=1: piece(0,3,1)=0
16. piece(1,0,0)=1: piece(1,1,0)=1: piece(1,2,0)=1: piece(1,3,0)=1
17. piece(1,0,1)=0: piece(1,1,1)=0: piece(1,2,1)=0: piece(1,3,1)=0
18. piece(2,0,0)=0: piece(2,1,0)=0: piece(2,2,0)=1: piece(2,3,0)=1
19. piece(2,0,1)=0: piece(2,1,1)=1: piece(2,2,1)=1: piece(2,3,1)=0
20. piece(3,0,0)=0: piece(3,1,0)=1: piece(3,2,0)=1: piece(3,3,0)=0
21. piece(3,0,1)=0: piece(3,1,1)=0: piece(3,2,1)=1: piece(3,3,1)=1
22. piece(4,0,0)=0: piece(4,1,0)=1: piece(4,2,0)=1: piece(4,3,0)=1
23. piece(4,0,1)=0: piece(4,1,1)=0: piece(4,2,1)=1: piece(4,3,1)=0
24. piece(5,0,0)=0: piece(5,1,0)=1: piece(5,2,0)=1: piece(5,3,0)=1
25. piece(5,0,1)=0: piece(5,1,1)=1: piece(5,2,1)=0: piece(5,3,1)=0
26. piece(6,0,0)=0: piece(6,1,0)=1: piece(6,2,0)=1: piece(6,3,0)=1
27. piece(6,0,1)=0: piece(6,1,1)=0: piece(6,2,1)=0: piece(6,3,1)=1
28.  
29. screen _newimage(sw*size, sh*size, 32)
30.  
31. piece_color(0) = _rgb(0,200,0)
32. piece_color(1) = _rgb(200,0,0)
33. piece_color(2) = _rgb(156,85,211)
34. piece_color(3) = _rgb(219,112,147)
35. piece_color(4) = _rgb(0,100,250)
36. piece_color(5) = _rgb(230,197,92)
37. piece_color(6) = _rgb(0,128,128)
38.  
39. dim t as double
40.  
41. redraw = -1
42.  
43. speed = 10
44. lines = 0
45. pause = 0
46. putpiece = 0
47. startx = (sw - 4)/2
48.  
49. pn = int(rnd*7)
50. px = startx
51. py = 1
52. rot = 0
53.  
54. title$ = "lines="+ltrim$(str$(lines))+",speed="++ltrim$(str$(speed))
55. _title title$
56.  
57. t = timer
58.  
59. do
60.         if (timer - t) > (1/speed) and not pause then
61.                 if valid(pn, px, py + 1, rot) then py = py + 1 else putpiece = -1
62.  
63.                 t = timer
64.                 redraw = -1
65.         end if
66.  
67.         if putpiece then
68.                 if valid(pn, px, py, rot) then
69.                         n = place(pn, px, py, rot)
70.                         if n then
71.                                 lines = lines + n
72.                                 title$ = "lines="+ltrim$(str$(lines))+",speed="++ltrim$(str$(speed))
73.                                 _title title$
74.                         end if
75.                 end if
76.  
77.                 pn = int(rnd*7)
78.                 px = startx
79.                 py = 0
80.                 rot = 0
81.  
82.                 putpiece = 0
83.                 redraw = -1
84.  
85.                 if not valid(pn, px, py, rot) then
86.                         for y=0 to sh-1
87.                                 for x=0 to sw-1
88.                                         board(x, y) = 0
89.                                 next
90.                         next
91.                         lines = 0
92.                         title$ = "lines="+ltrim$(str$(lines))+",speed="++ltrim$(str$(speed))
93.                         _title title$
94.                 end if
95.         end if
96.  
97.         if redraw then
98.                 line (0,0)-(sw*size, sh*size),_rgb(0,0,0),bf
99.                 for y=0 to sh - 1
100.                         for x=0 to sw - 1
101.                                 if board(x, y) <> 0 then
102.                                         line (x*size, y*size)-step(size-2, size-2), piece_color(board(x, y)-1), bf
103.                                 else
104.                                         line (x*size, y*size)-step(size-2, size-2), _rgb(50,50,50), b
105.                                 end if
106.                         next
107.                 next
108.  
109.                 for y=0 to 1
110.                         for x=0 to 3
111.                                 rotate xx, yy, x, y, pn, rot
112.                                 if piece(pn, x, y) then line ((px + xx)*size, (py + yy)*size)-step(size-2, size-2), piece_color(pn), bf
113.                         next
114.                 next
115.  
116.                 _display
117.                 redraw = 0
118.         end if
119.  
120.         k = _keyhit
121.         if k then
122.                 shift = _keydown(100304) or _keydown(100303)
123.                 select case k
124.                 case 18432 'up
125.                         if valid(pn, px, py, (rot + 1) mod 4) then rot = (rot + 1) mod 4
126.                         pause = 0
127.                 case 19200 'left
128.                         if shift then
129.                                 for xx=0 to sw-1
130.                                         if not valid(pn, px - xx, py, rot) then exit for
131.                                 next
132.                                 px = px - xx + 1
133.                         else
134.                                 if valid(pn, px - 1, py, rot) then px = px - 1
135.                         end if
136.                         pause = 0
137.                 case 19712 'right
138.                         if shift then
139.                                 for xx=px to sw-1
140.                                         if not valid(pn, xx, py, rot) then exit for
141.                                 next
142.                                 px = xx - 1
143.                         else
144.                                 if valid(pn, px + 1, py, rot) then px = px + 1
145.                         end if
146.                         pause = 0
147.                 case 20480, 32 'down
148.                         if shift or k = 32 then
149.                                 for yy=py to sh-1
150.                                         if not valid(pn, px, yy, rot) then exit for
151.                                 next
152.                                 py = yy - 1
153.                                 putpiece = -1
154.                         else
155.                                 if valid(pn, px, py + 1, rot) then py = py + 1
156.                         end if
157.                         pause = 0
158.                 case 112 'p
159.                         pause = not pause
160.                 case 13 'enter
161.                         for y=0 to sh-1
162.                                 for x=0 to sw-1
163.                                         board(x, y) = 0
164.                                 next
165.                         next
166.                         pn = int(rnd*7)
167.                         px = startx
168.                         py = 0
169.                         rot = 0
170.                         putpiece = 0
171.                         lines = 0
172.                         title$ = "lines="+ltrim$(str$(lines))+",speed="++ltrim$(str$(speed))
173.                         _title title$
174.                 case 43, 61 'plus
175.                         if speed < 100 then
176.                                 speed = speed + 1
177.                                 title$ = "lines="+ltrim$(str$(lines))+",speed="++ltrim$(str$(speed))
178.                                 _title title$
179.                         end if
180.                 case 95, 45
181.                         if speed > 1 then
182.                                 speed = speed - 1
183.                                 title$ = "lines="+ltrim$(str$(lines))+",speed="++ltrim$(str$(speed))
184.                                 _title title$
185.                         end if
186.                 case 27
187.                         exit do
188.                 end select
189.  
190.                 redraw = -1
191.         end if
192. loop
193. system
194.  
195. sub rotate(xx, yy, x, y, pn, rot)
196.         select case pn
197.         case 0
198.                 rot_new = 0
199.         case 1 to 3
200.                 rot_new = rot mod 2
201.         case 4 to 6
202.                 rot_new = rot
203.         end select
204.  
205.         select case rot_new
206.         case 0
207.                 xx = x
208.                 yy = y
209.         case 1
210.                 xx = y + 2
211.                 yy = 2 - x
212.         case 2
213.                 xx = 4 - x
214.                 yy = 1 - y
215.         case 3
216.                 xx = 2 - y
217.                 yy = x - 1
218.         end select
219. end sub
220.  
221. function valid(pn, px, py, rot)
222.         for y=0 to 1
223.                 for x=0 to 3
224.                         rotate xx, yy, x, y, pn, rot
225.                         if py + yy >= 0 then
226.                                 if piece(pn, x, y) then
227.                                         if (px + xx >= sw) or (px + xx < 0) then
228.                                                 valid = 0
229.                                                 exit function
230.                                         end if
231.                                         if (py + yy >= sh) then
232.                                                 valid = 0
233.                                                 exit function
234.                                         end if
235.                                         if (py >= 0) then
236.                                         if board(px + xx, py + yy) then
237.                                                 valid = 0
238.                                                 exit function
239.                                         end if
240.                                         end if
241.                                 end if
242.                         end if
243.                 next
244.         next
245.  
246.         valid = -1
247. end function
248.  
249. function place(pn, px, py, rot)
250.         lines = 0
251.  
252.         for y=0 to 1
253.                 for x=0 to 3
254.                         rotate xx, yy, x, y, pn, rot
255.                         if py + yy >= 0 then if piece(pn, x, y) then board(px + xx, py + yy) = pn + 1
256.                 next
257.         next
258.  
259.         'clear lines
260.         for y=py-1 to py+2
261.                 if y>=0 and y<sh then
262.                         clr = -1
263.                         for x=0 to sw - 1
264.                                 if board(x, y) = 0 then
265.                                         clr = 0
266.                                         exit for
267.                                 end if
268.                         next
269.  
270.                         if clr then
271.                                 lines = lines + 1
272.                                 for yy=y to 1 step -1
273.                                         for x=0 to sw-1
274.                                                 board(x, yy) = board(x, yy-1)
275.                                         next
276.                                 next
277.                         end if
278.                 end if
279.         next
280.  
281.         place = lines
282. end function
283.