Re: Daring Dan in 'Math Climber'

[FellippeHeitor]

Yes, Linux has issues with sound in QB64.  I am glad it is working for you.

Already fixed in dev builds.

[Pete]

I had a TI99 4A, but I don't remember FRED. That's OK though. At my age, I don't remember other 4-letter words, either. Well, I like it. Nice happy dance when Dan gets to the top, but lacking some excitement when a wrong answer is input. I'd rather see Dan fall on his ascii, instead of just climbing down.

Also, I showed your game to my good friend Donald J. Trump. He asked  me to make to following improvements...

Code: QB64: [Select]

1. _TITLE "Math Climber"
2.  
3. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
4. '   Game based on FRED for the TI99/4a computer
5. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
6. DIM SHARED text AS STRING
7. RANDOMIZE TIMER
8.  
9. CONST False = 0
10. CONST True = -1
11.  
12. TYPE Math
13.     ans AS SINGLE
14.     sym AS INTEGER
15.     exp1 AS INTEGER
16.     exp2 AS INTEGER
17.  
18.     side AS _BYTE
19. END TYPE
20.  
21. DIM SHARED Math AS Math
22.  
23. DIM SHARED UhOh AS LONG
24. DIM SHARED WellDone AS LONG
25.  
26. DIM SHARED Limit AS INTEGER
27. DIM SHARED Frames AS INTEGER
28. Limit = 30
29.  
30. DIM SHARED Level AS STRING
31.  
32. DIM SHARED Mag AS INTEGER
33. DIM SHARED zoom AS INTEGER
34. DIM SHARED xScreen AS INTEGER
35. DIM SHARED yScreen AS INTEGER
36. zoom = 3
37.  
38. DIM SHARED uClimb AS INTEGER
39. DIM SHARED xClimb AS INTEGER
40. DIM SHARED yClimb AS INTEGER
41.  
42. DIM SHARED Sprite(64) AS LONG
43.  
44. DIM SHARED Red AS _UNSIGNED LONG
45. DIM SHARED Blue AS _UNSIGNED LONG
46. DIM SHARED Cyan AS _UNSIGNED LONG
47. DIM SHARED Black AS _UNSIGNED LONG
48. DIM SHARED White AS _UNSIGNED LONG
49. DIM SHARED Yellow AS _UNSIGNED LONG
50. DIM SHARED Magents AS _UNSIGNED LONG
51.  
52. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
53. '   The object of this game is to solve math problems and try to get your
54. '   character to the top of the wall.  Can you do it?
55. '
56. '   Changes from original:
57. '   Different colors and graphics
58. '   Climber cllimbs up the middle of the wall instead of on the side
59. '   Added Subtraction, Multiplication, and Division
60. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
61.  
62. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
63. '   Increase Zoom to enlarge the screen
64. '   For people like me who are blind in one eye while not able to see out of the other
65. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
66.  
67. Mag = 8 * zoom
68. xScreen = 128 * zoom
69. yScreen = 96 * zoom
70. SCREEN _NEWIMAGE(xScreen, yScreen, 32)
71.  
72. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/
73. '   Load Colors and Graphics
74. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\
75. Loader
76.  
77. ' \/\/\/\/\/\/\/\/\/\/\/
78. '   Introduction Text
79. ' /\/\/\/\/\/\/\/\/\/\/\
80. Intro
81.  
82. ' \/\/\/\/\/\/\/\/\/\/\/
83. '   Main Program Loop
84. ' /\/\/\/\/\/\/\/\/\/\/\
85. Main
86.  
87. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/
88. '   Game Over - Play Again?
89. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\
90. GameOver -1
91. END
92.  
93. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
94. '   Convert Decimal to Binary
95. '   Length limits the length of the binary value returned
96. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
97. FUNCTION BinValue$ (Value AS INTEGER, Length AS INTEGER)
98.     DIM temp AS STRING
99.  
100.     WHILE Value <> 0
101.         temp = RIGHT$(STR$(Value MOD 2), 1) + temp
102.         Value = Value \ 2
103.     WEND
104.  
105.     BinValue = RIGHT$(STRING$(Length, 48) + temp, Length)
106. END FUNCTION
107.  
108. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/
109. '   Load Colors and Graphics
110. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\
111. SUB Loader
112.     ' \/\/\/\/\/\/\/
113.     '   Medium Red
114.     ' /\/\/\/\/\/\/\
115.     Red = _RGB32(252, 85, 84)
116.  
117.     ' \/\/\/\/\/\/\/
118.     '   Dark Blue
119.     ' /\/\/\/\/\/\/\
120.     Blue = _RGB32(84, 85, 237)
121.  
122.     ' \/\/\/\/
123.     '   Cyan
124.     ' /\/\/\/\
125.     Cyan = _RGB32(66, 235, 245)
126.  
127.     ' \/\/\/\/\/
128.     '   Black
129.     ' /\/\/\/\/\
130.     Black = _RGB(0, 0, 0)
131.  
132.     ' \/\/\/\/\/
133.     '   White
134.     ' /\/\/\/\/\
135.     White = _RGB32(255, 255, 255)
136.  
137.     ' \/\/\/\/\/
138.     '   Yellow
139.     ' /\/\/\/\/\
140.     Yellow = _RGB32(230, 206, 128)
141.  
142.     ' \/\/\/\/\/
143.     ' Magenta
144.     ' /\/\/\/\/\
145.     Magenta = _RGB32(201, 91, 186)
146.  
147.     ' \/\/\/\/\/\/\/\/\/\/
148.     '   Happy/Sad Faces
149.     ' /\/\/\/\/\/\/\/\/\/\
150.     CallChar 1, "3C7EDBFFFFDB663C", Yellow, White
151.     CallChar 2, "3C7EDBFFFFE75A3C", Yellow, White
152.     CallChar 3, "C3812400002499C3", Yellow, White
153.     CallChar 4, "C38124000018A5C3", Yellow, White
154.  
155.     ' \/\/\/\/\/\/\/\/\/\/\/\/\/
156.     '   Make Faces transparent
157.     ' /\/\/\/\/\/\/\/\/\/\/\/\/\
158.     FOR i = 1 TO 4
159.         _CLEARCOLOR White, Sprite(i)
160.     NEXT
161.  
162.     ' \/\/\/\/\/\/
163.     '   Climber
164.     ' /\/\/\/\/\/\
165.     CallChar 5, "3838107C1038286C", Cyan, White
166.     CallChar 6, "3838927C10382C60", Cyan, White
167.     CallChar 7, "3838927C1038680C", Cyan, White
168.  
169.     ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/
170.     '   Make Climber transparent
171.     ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\
172.     FOR i = 5 TO 7
173.         _CLEARCOLOR White, Sprite(i)
174.     NEXT
175.  
176.     ' \/\/\/\/\/\/\/
177.     '   Brick Wall
178.     ' /\/\/\/\/\/\/\
179.     CallChar 8, "7FFF92FFA4FF92FF", Black, Red
180.     CallChar 9, "FFFF49FF92FF49FF", Black, Red
181.     CallChar 10, "FEFF25FF49FF25FF", Black, Red
182.  
183.     CallChar 11, "A4FF92FFA4FF92FF", Black, Red
184.     CallChar 12, "92FF49FF92FF49FF", Black, Red
185.     CallChar 13, "49FF25FF49FF25FF", Black, Red
186.  
187.     ' \/\/\/\/\/\/\/\/\/\/\/
188.     '   Numbers ( 0 - 9 )
189.     ' /\/\/\/\/\/\/\/\/\/\/\
190.     CallChar 14, "0038444444444438", Black, Blue
191.     CallChar 15, "0010301010101038", Black, Blue
192.     CallChar 16, "003844040810207C", Black, Blue
193.     CallChar 17, "0038440418044438", Black, Blue
194.     CallChar 18, "00081828487C0808", Black, Blue
195.     CallChar 19, "007C407804044438", Black, Blue
196.     CallChar 20, "0018204078444438", Black, Blue
197.     CallChar 21, "007C040810202020", Black, Blue
198.     CallChar 22, "0038444438444438", Black, Blue
199.     CallChar 23, "003844443C040830", Black, Blue
200.  
201.     ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
202.     '   Math Symbols ( + - * / . )
203.     ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
204.     CallChar 24, "000010107C101000", Black, Blue
205.     CallChar 25, "000000007C000000", Black, Blue
206.     CallChar 26, "0000221408142200", Black, Blue
207.     CallChar 27, "1818007E7E001818", Black, Blue
208.     CallChar 28, "0000000000003030", Black, Blue
209.     CallChar 29, "000000000000007C", Black, Blue
210.  
211.     ' \/\/\/\/\/\/\/\/\/\/\/
212.     '   Letters ( A - Z )
213.     ' /\/\/\/\/\/\/\/\/\/\/\
214.     CallChar 30, "003844447C444444", Black, Blue
215.     CallChar 31, "0078242438242478", Black, Blue
216.     CallChar 32, "0038444040404438", Black, Blue
217.     CallChar 33, "0078242424242478", Black, Blue
218.     CallChar 34, "007C40407840407C", Black, Blue
219.     CallChar 35, "007C404078404040", Black, Blue
220.     CallChar 36, "003C40405C444438", Black, Blue
221.     CallChar 37, "004444447C444444", Black, Blue
222.     CallChar 38, "0038101010101038", Black, Blue
223.     CallChar 39, "0004040404044438", Black, Blue
224.     CallChar 40, "0044485060504844", Black, Blue
225.     CallChar 41, "004040404040407C", Black, Blue
226.     CallChar 42, "00446C5454444444", Black, Blue
227.     CallChar 43, "00446464544C4C44", Black, Blue
228.     CallChar 44, "007C44444444447C", Black, Blue
229.     CallChar 45, "0078444478404040", Black, Blue
230.     CallChar 46, "0038444444544834", Black, Blue
231.     CallChar 47, "0078444478504844", Black, Blue
232.     CallChar 48, "0038444038044438", Black, Blue
233.     CallChar 49, "007C101010101010", Black, Blue
234.     CallChar 50, "0044444444444438", Black, Blue
235.     CallChar 51, "0044444428281010", Black, Blue
236.     CallChar 52, "0044444454545428", Black, Blue
237.     CallChar 53, "0044442810284444", Black, Blue
238.     CallChar 54, "0044442810101010", Black, Blue
239.     CallChar 55, "007C04081020407C", Black, Blue
240.  
241.     ' \/\/\/\/\/\/\/\/\/\/\/
242.     '   Symbols ( , ' ? )
243.     ' /\/\/\/\/\/\/\/\/\/\/\
244.     CallChar 56, "0000000000301020", Black, Blue
245.     CallChar 57, "0008081000000000", Black, Blue
246.     CallChar 58, "0038440408100010", Black, Blue
247.  
248.     CallChar 64, "007C7C7C7C7C7C7C", Black, Black
249.  
250.     IF _FILEEXISTS("UhOh.mp3") THEN
251.         UhOh = _SNDOPEN("UhOh.mp3")
252.     END IF
253.  
254.     IF _FILEEXISTS("WellDone.mp3") THEN
255.         WellDone = _SNDOPEN("WellDone.mp3")
256.     END IF
257. END SUB
258.  
259. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
260. '   ( Character Definition )
261. '   CALL CHAR (char-code, "pattern-identifier")
262. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
263. SUB CallChar (Char AS INTEGER, Code AS STRING, Fore AS _UNSIGNED LONG, Back AS _UNSIGNED LONG)
264.     DIM temp AS STRING
265.  
266.     Sprite(Char) = _NEWIMAGE(8, 8, 32)
267.     _DEST Sprite(Char)
268.  
269.     FOR v = 0 TO 7
270.         temp = BinValue(VAL("&H" + MID$(Code, 2 * v + 1, 2)), 8)
271.  
272.         FOR h = 0 TO 7
273.             IF MID$(temp, h + 1, 1) = "0" THEN
274.                 PSET (h, v), Back
275.             ELSE
276.                 PSET (h, v), Fore
277.             END IF
278.         NEXT
279.     NEXT
280.  
281.     _DEST 0
282. END SUB
283.  
284. FUNCTION CharInput$ (Row AS INTEGER, Col AS INTEGER)
285.     DIM touch AS STRING
286.  
287.     Cursor = True
288.     WHILE INKEY$ <> "": WEND
289.  
290.     x1 = Mag * Col - 1: x2 = x1 + Mag - 1
291.     y1 = Mag * Row - 1: y2 = y1 + Mag - 1
292.  
293.     WHILE NOT Done
294.         _LIMIT 60
295.  
296.         touch = INKEY$
297.         IF touch <> "" THEN
298.             IF touch = CHR$(8) THEN Done = True
299.             IF touch = CHR$(13) OR touch = " " THEN Done = True
300.  
301.             IF INSTR("0123456789-.", touch) THEN Done = True
302.         END IF
303.  
304.         IF Frames = 0 THEN
305.             LINE (x1, y1)-(x2, y2), Blue, BF
306.  
307.             IF Cursor THEN
308.                 Cursor = False
309.                 _PUTIMAGE (x1, y1)-(x2, y2), Sprite(1)
310.             ELSE
311.                 Cursor = True
312.                 _PUTIMAGE (x1, y1)-(x2, y2), Sprite(3)
313.             END IF
314.  
315.             _DISPLAY
316.         END IF
317.  
318.         Frames = Frames + 1
319.         IF Frames = Limit THEN Frames = 0
320.     WEND
321.  
322.     CharInput = touch
323. END FUNCTION
324.  
325. SUB Intro
326.     DIM touch AS STRING
327.  
328.     IF zoom = 3 THEN
329.         text = "  Daring Dan likes to climb, and he has the challenge of climbing up a tall"
330.         text = text + " brick wall." + SPACE$(28) + " Can you help him?"
331.         text = text + SPACE$(30) + " Every right answer to a math question will help"
332.         text = text + " him get higher on the wall and closer to his goal."
333.         WordWrap text: touch = CharInput(11, 15)
334.  
335.         text = "  Watch out, though, one wrong answer and poor 'ole Dan will fall to the"
336.         text = text + " ground." + SPACE$(34)
337.         text = text + "  Don't worry, Dan will survive the fall and you can try again."
338.         WordWrap text: touch = CharInput(11, 15)
339.  
340.         text = "  Do you want to?" + SPACE$(32)
341.         text = text + " 1. Easy Numbers" + SPACE$(12) + "* 1, 2, 3 *" + SPACE$(34)
342.         text = text + "2. Advanced Numbers        * 1.2, 2.4, 3.6 *"
343.         WordWrap text
344.     ELSE
345.         text = "  Daring Dan likes to climb, and he has the challenge of climbing up a tall"
346.         text = text + " brick wall." + SPACE$(36) + "Can you help him?" + SPACE$(46)
347.         text = text + " Every right answer to a math question will help him get higher on"
348.         text = text + " the wall and closer to his goal." + SPACE$(52)
349.         text = text + "  Watch out, though, one wrong answer and poor 'ole Dan will fall to the"
350.         text = text + " ground." + SPACE$(46)
351.         text = text + " Don't worry, Dan will survive the fall and you can try again."
352.         WordWrap text: touch = CharInput(11, 15)
353.  
354.         text = "  Do you want to?" + SPACE$(32)
355.         text = text + " 1. Easy Numbers" + SPACE$(12) + "* 1, 2, 3 *" + SPACE$(34)
356.         text = text + "2. Advanced Numbers        * 1.2, 2.4, 3.6 *"
357.         WordWrap text
358.     END IF
359.  
360.     Done = False
361.     WHILE NOT Done
362.         Level = CharInput(11, 15)
363.         IF Level = "1" OR Level = "2" THEN Done = True
364.     WEND
365. END SUB
366.  
367. SUB WordWrap (text AS STRING)
368.     LINE (0, 0)-(xScreen - 1, yScreen - 1), Blue, BF
369.     GameTitle -1
370.  
371.     IF zoom = 2 THEN Mag = 8: Row = 5
372.     IF zoom = 3 THEN Mag = 16: Row = 4
373.     IF zoom > 3 THEN Mag = 16: Row = 5
374.  
375.     length = xScreen \ Mag
376.     WHILE LEN(text) > length
377.         t = length
378.         WHILE MID$(text, t, 1) <> " ": t = t - 1: WEND
379.         CharPrint Row, 0, LEFT$(text, t), 0
380.  
381.         Row = Row + 1
382.         text = RIGHT$(text, LEN(text) - t)
383.     WEND
384.  
385.     CharPrint Row, 0, text, 0
386.  
387.     Mag = 8 * zoom
388. END SUB
389.  
390. SUB GameTitle (Flag AS INTEGER)
391.     DIM text AS STRING
392.  
393.     Mag = 8 * zoom
394.  
395.     text = "Math Climber"
396.     CharPrint 0, 0, text, -1
397.  
398.     IF Flag THEN
399.         text = "by [banned user]"
400.         CharPrint 1, 0, text, -1
401.     END IF
402. END SUB
403.  
404. SUB Background
405.     DIM text AS STRING
406.  
407.     LINE (0, 0)-(xScreen - 1, yScreen - 1), Blue, BF
408.  
409.     'text = "The Wall of Math"
410.     'CharPrint 0, 0, text, -1
411.     text = "TRUMP'S WALL"
412.     CharPrint 0, 0, text, -1
413.     y1 = Mag * 2: y2 = y1 + Mag - 1
414.     x1 = xScreen \ 2 - 21: x2 = x1 + Mag - 1
415.  
416.     _PUTIMAGE (x1, y1)-(x2, y2), Sprite(8)
417.     _PUTIMAGE (x1 + 8, y1)-(x2 + 8, y2), Sprite(9)
418.     _PUTIMAGE (x1 + 16, y1)-(x2 + 16, y2), Sprite(10)
419.  
420.     FOR v = 3 TO 21
421.         y1 = Mag * v: y2 = y1 + Mag - 1
422.  
423.         _PUTIMAGE (x1, y1)-(x2, y2), Sprite(11)
424.         _PUTIMAGE (x1 + 8, y1)-(x2 + 8, y2), Sprite(12)
425.         _PUTIMAGE (x1 + 16, y1)-(x2 + 16, y2), Sprite(13)
426.     NEXT
427. END SUB
428.  
429. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/
430. '   Print text to the screen
431. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\
432. SUB CharPrint (row AS INTEGER, col AS INTEGER, text AS STRING, flag AS _BYTE)
433.     DIM temp AS STRING
434.  
435.     IF flag = -1 THEN col = 8 - LEN(text) \ 2
436.  
437.     text = UCASE$(text)
438.     y1 = Mag * row: y2 = y1 + Mag - 1
439.     temp = "0123456789+-*/._ABCDEFGHIJKLMNOPQRSTUVWXYZ,'?"
440.  
441.     FOR c = 0 TO LEN(text) - 1
442.         f = INSTR(temp, MID$(text, c + 1, 1))
443.  
444.         IF f > 0 THEN
445.             x1 = Mag * (col + c): x2 = x1 + Mag - 1
446.             _PUTIMAGE (x1, y1)-(x2, y2), Sprite(13 + f)
447.         END IF
448.     NEXT
449. END SUB
450.  
451. SUB MathProblem
452.     DIM Ans AS STRING
453.     DIM Exp1 AS STRING
454.     DIM Exp2 AS STRING
455.     DIM temp AS STRING
456.     DIM touch AS STRING
457.  
458.     Math.sym = INT(4 * RND) + 1
459.     temp = MID$("+-*/", Math.sym, 1)
460.  
461.     WHILE NOT Ready
462.         Math.exp1 = INT(11 * RND)
463.         Math.exp2 = INT(11 * RND)
464.  
465.         IF Math.sym = 4 THEN
466.             IF Math.exp1 = 0 THEN Math.exp1 = INT(10 * RND) + 1
467.             IF Math.exp2 = 0 THEN Math.exp2 = INT(10 * RND) + 1
468.  
469.             IF Level = "1" THEN
470.                 IF Math.exp1 / Math.exp2 <> Math.exp1 \ Math.exp2 THEN
471.                     WHILE NOT Safe
472.                         Math.exp1 = INT(10 * RND) + 1
473.                         Math.exp2 = INT(10 * RND) + 1
474.  
475.                         IF Math.exp1 / Math.exp2 = Math.exp1 \ Math.exp2 THEN Safe = -1
476.                     WEND
477.                 END IF
478.             END IF
479.         END IF
480.  
481.         SELECT CASE Math.sym
482.             CASE 1: Math.ans = Math.exp1 + Math.exp2
483.             CASE 2: Math.ans = Math.exp1 - Math.exp2
484.             CASE 3: Math.ans = Math.exp1 * Math.exp2
485.             CASE 4: Math.ans = Math.exp1 / Math.exp2
486.         END SELECT
487.  
488.         Ready = -1
489.     WEND
490.  
491.     IF Math.exp1 = 10 THEN
492.         Exp1 = _TRIM$(STR$(Math.exp1))
493.     ELSE
494.         Exp1 = STR$(Math.exp1)
495.     END IF
496.  
497.     IF Math.exp2 = 10 THEN
498.         Exp2 = temp + _TRIM$(STR$(Math.exp2)): ea2 = LEN(Exp2)
499.     ELSE
500.         Exp2 = temp + STR$(Math.exp2)
501.     END IF
502.  
503.     ea1 = LEN(Exp1): ea2 = LEN(Exp2)
504.  
505.     Ans = _TRIM$(STR$(Math.ans)): sa = LEN(Ans)
506.     IF sa > 4 THEN Ans = LEFT$(Ans, 4): sa = 4
507.  
508.     IF Math.side = 0 THEN x = 5 ELSE x = 14
509.  
510.     CharPrint 2, x - ea1, Exp1, 0
511.     CharPrint 3, x - ea2, Exp2, 0
512.     CharPrint 4, x - 4, STRING$(5, "_"), 0
513.     CharPrint 5, x - sa, STRING$(sa, "?"), 0
514.  
515.     temp = ""
516.     WHILE sa <> 0
517.         touch = CharInput(11, 15)
518.  
519.         IF touch = CHR$(8) THEN
520.             temp = "": sa = LEN(Math.ans)
521.             CharPrint 5, x - sa, STRING$(sa, "?"), 0
522.         ELSE
523.             CharPrint 5, x - sa, touch, 0
524.             _DISPLAY
525.             _DELAY 0.25
526.  
527.             temp = temp + touch: sa = sa - 1
528.         END IF
529.     WEND
530.  
531.     IF VAL(temp) = Math.ans THEN Climb ELSE Fall
532. END SUB
533.  
534. SUB Climb
535.     IF WellDone THEN _SNDPLAY WellDone
536.  
537.     Background
538.     yClimb = yClimb - Mag \ 2
539.  
540.     IF uClimb = 0 THEN
541.         _PUTIMAGE (xClimb, yClimb)-(xClimb + Mag - 1, yClimb + Mag - 1), Sprite(6)
542.     ELSE
543.         _PUTIMAGE (xClimb, yClimb)-(xClimb + Mag - 1, yClimb + Mag - 1), Sprite(7)
544.     END IF
545.  
546.     _DISPLAY
547.     _DELAY 0.25
548.  
549.     Background
550.     yClimb = yClimb - Mag \ 2
551.     _PUTIMAGE (xClimb, yClimb)-(xClimb + Mag - 1, yClimb + Mag - 1), Sprite(5)
552.     _DISPLAY
553.     _DELAY 0.25
554.  
555.     uClimb = (uClimb + 1) MOD 2
556. END SUB
557.  
558. SUB HappyDance
559.     IF WellDone THEN _SNDPLAY WellDone
560.  
561.     FOR dance = 0 TO 11
562.         Background
563.         IF dance MOD 2 = 0 THEN
564.             _PUTIMAGE (xClimb, yClimb)-(xClimb + Mag - 1, yClimb + Mag - 1), Sprite(6)
565.         ELSE
566.             _PUTIMAGE (xClimb, yClimb)-(xClimb + Mag - 1, yClimb + Mag - 1), Sprite(7)
567.         END IF
568.  
569.         _DISPLAY
570.         _DELAY 0.15
571.  
572.         Background
573.         _PUTIMAGE (xClimb, yClimb)-(xClimb + Mag - 1, yClimb + Mag - 1), Sprite(5)
574.         _DISPLAY
575.         _DELAY 0.15
576.     NEXT
577. END SUB
578.  
579. SUB Fall
580.     IF UhOh THEN _SNDPLAY UhOh
581.  
582.     FOR y = yClimb TO 20 * Mag STEP 3
583.         Background
584.         'IF y MOD 2 = 0 THEN
585.         _PUTIMAGE (xClimb, y)-(xClimb + Mag - 1, y + Mag - 1), Sprite(6)
586.         'ELSE
587.         '_PUTIMAGE (xClimb, y)-(xClimb + Mag - 1, y + Mag - 1), Sprite(7)
588.         'END IF
589.         _PUTIMAGE (xClimb, y)-(xClimb + Mag - 1, y + Mag - 1), Sprite(7)
590.         _DISPLAY
591.         _DELAY 0.005
592.     NEXT
593.     text = "BOOM"
594.     _DELAY .25
595.     CharPrint 18, 6, text, 0
596.     _DISPLAY
597.     _DELAY 3
598.     GameOver 0
599. END SUB
600.  
601. SUB Main
602.     yScreen = 156 * zoom
603.     SCREEN _NEWIMAGE(xScreen, yScreen, 32)
604.  
605.     yClimb = 11 * Mag
606.     xClimb = xScreen \ 2 - 12
607.     Math.side = INT(2 * RND)
608.  
609.     WHILE NOT Done
610.         WHILE yClimb <> 24
611.             _LIMIT 60
612.  
613.             Background
614.             _PUTIMAGE (xClimb, yClimb)-(xClimb + Mag - 1, yClimb + Mag - 1), Sprite(5)
615.             _DISPLAY
616.  
617.             MathProblem
618.         WEND
619.  
620.         HappyDance
621.         Done = True
622.     WEND
623. END SUB
624.  
625. SUB GameOver (Flag AS SINGLE)
626.     DIM text AS STRING
627.     DIM touch AS STRING
628.  
629.     IF Flag THEN
630.         text = "  Congratulations.  You helped that daring Dan make it to the to of the Wall of Math."
631.         text = text + SPACE$(32) + " Would you like to play again?" + SPACE$(38) + " 1. Yes        2. No"
632.     ELSE
633.         text = "  Awe,  You tried, but failed to help daring Dan make it to the top.   Don't be sad though."
634.         text = text + SPACE$(26) + "  Would you like to play again?" + SPACE$(38) + " 1. Yes        2. No"
635.     END IF
636.  
637.     LINE (0, 0)-(xScreen - 1, yScreen - 1), Blue, BF
638.     GameTitle -1
639.     WordWrap text
640.  
641.     touch = CharInput(12, 15)
642.     IF touch = "1" THEN Main ELSE SYSTEM
643. END SUB
644.  

Pete :D