Mouse demo using _DEVICE commands

[SMcNeill]

Code: QB64: [Select]

1. DIM SHARED MouseX AS INTEGER, MouseY AS INTEGER
2. DIM SHARED MouseWheel AS INTEGER
3. DIM SHARED LeftMouse AS INTEGER, RightMouse AS INTEGER, MiddleMouse AS INTEGER
4. DIM SHARED ClickThreshold AS SINGLE
5. ClickThreshold = 0.2 'down and up in threshold of a second to count as a click.  If down for more then threshold, we just have a hold event.
6.  
7.  
8. SCREEN _NEWIMAGE(640, 480, 32)
9. _SCREENMOVE _MIDDLE
10.  
11.  
12.  
13. DO
14.     _LIMIT 60
15.  
16.     UpdateMouseInfo
17.     LOCATE 1, 1
18.     PRINT MouseX, MouseY
19.     PRINT MouseWheel
20.     PRINT LeftMouse, MiddleMouse, RightMouse
21.     IF LeftMouse AND 2 THEN leftclick = leftclick + 1
22.     IF MiddleMouse AND 2 THEN middleclick = middleclick + 1
23.     IF RightMouse AND 2 THEN rightclick = rightclick + 1
24.     PRINT leftclick, middleclick, rightclick
25.  
26. LOOP UNTIL INKEY$ = CHR$(27) 'escape key exit
27.  
28. SUB UpdateMouseInfo
29.     DIM SW AS INTEGER, SH AS INTEGER
30.     DIM LM AS INTEGER, MM AS INTEGER, RM AS INTEGER
31.  
32.     STATIC leftdown AS SINGLE, middledown AS SINGLE, rightdown AS SINGLE
33.  
34.     WHILE _DEVICEINPUT(2): MouseWheel = MouseWheel + _WHEEL(3): WEND 'clear and update the mouse buffer
35.  
36.     SW = _WIDTH \ 2: SH = _HEIGHT \ 2
37.     MouseX = _AXIS(1) * SW + SW: MouseY = _AXIS(2) * SH + SH
38.  
39.  
40.  
41.     LM = _BUTTON(1): MM = _BUTTON(2): RM = _BUTTON(3)
42.  
43.     IF leftdown THEN 'if it was down
44.         IF LM = 0 THEN 'and is now up
45.             IF TIMER - leftdown < ClickThreshold THEN
46.                 LeftMouse = 2 'clicked
47.             ELSE 'if it's still down
48.                 LeftMouse = 0 'the mouse was just released
49.             END IF
50.             leftdown = 0 'timer is cleared either way
51.         ELSE
52.             LeftMouse = 1 'the left mouse is down , timer should have already been set
53.         END IF
54.     ELSE
55.         IF LM THEN
56.             leftdown = TIMER 'set the timer to see if we have click or hold events
57.             LeftMouse = 1 'the left mouse is down
58.         ELSE
59.             LeftMouse = 0
60.         END IF
61.     END IF
62.  
63.     IF middledown THEN 'if it was down
64.         IF MM = 0 THEN 'and is now up
65.             IF TIMER - middledown < ClickThreshold THEN
66.                 MiddleMouse = 2 'clicked
67.             ELSE 'if it's still down
68.                 MiddleMouse = 0 'the mouse was just released
69.             END IF
70.             middledown = 0 'timer is cleared either way
71.         ELSE
72.             MiddleMouse = 1 'the middle mouse is down , timer should have already been set
73.         END IF
74.     ELSE
75.         IF MM THEN
76.             middledown = TIMER 'set the timer to see if we have click or hold events
77.             MiddleMouse = 1 'the middle mouse is down
78.         ELSE
79.             MiddleMouse = 0
80.         END IF
81.     END IF
82.  
83.     IF rightdown THEN 'if it was down
84.         IF RM = 0 THEN 'and is now up
85.             IF TIMER - rightdown < ClickThreshold THEN
86.                 RightMouse = 2 'clicked
87.             ELSE 'if it's still down
88.                 RightMouse = 0 'the mouse was just released
89.             END IF
90.             rightdown = 0 'timer is cleared either way
91.         ELSE
92.             RightMouse = 1 'the right mouse is down , timer should have already been set
93.         END IF
94.     ELSE
95.         IF RM THEN
96.             rightdown = TIMER 'set the timer to see if we have click or hold events
97.             RightMouse = 1 'the right mouse is down
98.         ELSE
99.             RightMouse = 0
100.         END IF
101.     END IF
102.  
103.  
104. END SUB
105.  

A simple little set of code which can be easily plugged into any other program to give us a set of working mouse values without any hassles.   ;)

This tracks both "click" events and just "down" (or hold) events for us, as well as giving us x/y coordinates and wheel status.  A value of 1 for LeftMouse, RightMouse, MiddleMouse tells us the button is down; a value of 2 tells us the button was actually clicked with an up, down, then up in time, action.