Compliation fail using DECLARE LIBRARY

[Cobalt]

Trying to pull things off beyond my skill set.
I know where the error is but not how to fix it.
I'm 95% sure its in the DECLARE LIBRARY but not sure how to correct it.

Code: QB64: [Select]

1. 'Master Control Program (MCP)
2. '2019/01/06
3. 'Monitor for and Shut down Youtube access
4. _DELAY .025
5. _TITLE "MCP"
6. _DELAY .25
7.  
8. TYPE LPpoint
9.  Mx AS LONG
10.  My AS LONG
11. END TYPE
12.  
13. TYPE Rectangle
14.  left AS LONG
15.  top AS LONG
16.  right AS LONG
17.  bottom AS LONG
18. END TYPE
19.  
20. DIM Rec AS Rectangle, Mp AS LPpoint
21. DIM SHARED RF AS Rectangle, Dx&, Dy&
22.  
23. _SCREENHIDE 'makes the program invisible to the user. Escape key displays log!
24. DECLARE LIBRARY 'function is already used by QB64 so "User32" is not required
25.  FUNCTION GetAsyncKeyState% (BYVAL vkey AS LONG)
26.  FUNCTION GetWindowRect% (BYVAL Hwnd AS LONG, Rect AS Rectangle)
27.  FUNCTION GetCursorPos% (Mpoint AS LPpoint)
28. END DECLARE
29.  
30. CONST TRUE = -1, FALSE = NOT TRUE
31. Dx& = _DESKTOPWIDTH
32. Dy& = _DESKTOPHEIGHT
33. Test& = _SCREENIMAGE 'get desktop screen
34. temp& = _NEWIMAGE(640, 480, 32)
35. _SOURCE Test&
36.  
37. DO
38.  Test& = _SCREENIMAGE 'get desktop screen
39.  _LIMIT 60
40.  IF Find_Red(Test&) THEN
41.  
42.   RF.top = Shift_UP(RF.top) 'correct start search pos
43.   RF.left = Shift_LEFT(RF.left)
44.  
45.   Tube_Found% = Check_Tube(Test&)
46.  END IF
47.  
48.  IF Tube_Found% > 80 AND Tube_Found% < 95 THEN
49.   IF Tube_Found% = 92 THEN Exact%% = TRUE ELSE Exact%% = FALSE
50.  
51.  IF GetCursorPos(Mp) THEN 'get current mouse Position to restore when finished
52.    tempX% = Mp.Mx: tempY% = Mp.My
53.   END IF
54.  
55.   _SCREENCLICK RF.left, RF.top, 2
56.   _DELAY .05
57.   _SCREENPRINT "c"
58.   '  _MOUSEMOVE temp_X%, temp_Y%
59.   exitflag%% = TRUE
60.   _DELAY .15
61.  END IF
62.  IF GetAsyncKeyState(&H1B) THEN
63.   theitem$(a) = theitem$(a) + "{ESC}"
64.   exitflag%% = TRUE 'ESC key exits loop
65.  END IF
66. LOOP UNTIL exitflag%%
67.  
68. _SCREENSHOW
69. 'SYSTEM
70. 'SCREEN temp&
71. '_PUTIMAGE (0, 0)-(320, 200), Test&, _DISPLAY, (0, 0)-(320, 200)
72. 'LINE (RF.left, RF.top)-(RF.left + 10, RF.top + 10), _RGB32(255, 255, 0), B
73. PRINT Tube_Found%, Exact%%; tempX%, tempX%
74.  
75. FUNCTION Find_Red%% (Handle&)
76.  Result%% = FALSE
77.  FOR y% = 1 TO Dy& STEP 3
78.   FOR x% = 1 TO Dx& STEP 3
79.    Colr~& = POINT(x%, y%)
80.    IF _RED32(Colr~&) > 250 AND _BLUE32(Colr~&) < 16 AND _GREEN32(Colr~&) < 16 THEN
81.     Result%% = TRUE: RF.top = y%: RF.left = x% 'store where the red was found
82.     x% = Dx& + 1: y% = Dy& + 1 'exit loops upon a find
83.    END IF
84.   NEXT x%
85.  NEXT y%
86.  Find_Red = Result%%
87. END FUNCTION
88.  
89. FUNCTION Shift_UP (start%)
90.  FOR adj% = RF.top TO RF.top - 3 STEP -1 'make sure we find top of YouTube Icon
91.   Colr~& = POINT(RF.left, adj%)
92.   IF _RED32(Colr~&) > 250 AND _BLUE32(Colr~&) < 16 AND _GREEN32(Colr~&) < 16 THEN shftY%% = shftY%% + 1
93.  NEXT adj%
94.  Result% = start% - shftY%%
95.  Shift_UP = Result%
96. END FUNCTION
97.  
98. FUNCTION Shift_LEFT (start%)
99.  FOR adj% = RF.left TO RF.left - 3 STEP -1 'make sure we shift left some, get better centering match
100.   Colr~& = POINT(adj%, RF.top)
101.   IF _RED32(Colr~&) > 250 AND _BLUE32(Colr~&) < 16 AND _GREEN32(Colr~&) < 16 THEN shftX%% = shftX%% + 1
102.  NEXT adj%
103.  Result% = start% - shftX%%
104.  Shift_LEFT = Result%
105. END FUNCTION
106.  
107. FUNCTION Check_Tube (Handle&)
108.  FOR y% = RF.top TO RF.top + 10 'adjust Y to top of icon
109.   FOR x% = RF.left TO RF.left + 10
110.    checking~& = POINT(x%, y%)
111.    IF _RED32(checking~&) > 250 AND _BLUE32(checking~&) < 16 AND _GREEN32(checking~&) < 16 THEN hit% = hit% + 1
112.   NEXT x%
113.  NEXT y%
114.  Result% = hit%
115.  Check_Tube = Result%
116. END FUNCTION
117.  
118.  

the compile log is

In file included from qbx.cpp:2165:0:
..\\temp\\main.txt: In function 'void QBMAIN(void*)':
..\\temp\\main.txt:74:66: error: invalid conversion from 'void*' to 'LPPOINT {aka tagPOINT*}' [-fpermissive]
compilation terminated due to -Wfatal-errors.

not sure what I need to do to fix this.

[Pete]

Change your declare library statement to...

DECLARE DYNAMIC LIBRARY "user32"

That will get it to compile.

Pete

[Cobalt]

Awesome, Thanks Pete.

[Cobalt]

now if I could figure out why I'm getting constant false positives after it closes the first tab.

[Petr]

Please, add _FREEIMAGE test& to your program DO LOOP loop. Your program devoured all my memory and I had to restart computer. That's not nice at all! :-D For really  current screen screenshot add to program _SCREENICON for minimalizing your program.  MAYBE it help you.

[Pete]

Ha! Good recommendation. My computer crashed shortly after running his code, too.

Lucky for me, I'm always backed up. That's probably why I so cranky!

Pete

[Cobalt]

yeah, had not progressed far enough to into testing to catch that, opps.  though as I was putting the image into the same handle it didn't occur to me it was making a new one each time rather than just over writing the old one.

By the way Pete that second function in the DECLARE, GetWindowRect, should allow for retrieval of the Position and Size of the active window, not sure if that would help you in your management program you were working on. I haven't made it to the point of testing that but that is what it is supposed to do. I believe we have a function for returning the active windows handle anyway.

[Pete]

From what little I have read, it seems trickier than it should be to that function to get the coordinates of the titled window. For instance, this code gives a 1  for the windows coordinates, which I think means it is just acknowledging the call but not returning their respective values. It does return the window's handle (hwnd).

Code: QB64: [Select]

1. fwp$ = "Find Windows Position"
2. _TITLE fwp$
3. _DELAY .1
4.  
5. TYPE Rectangle
6.     left AS LONG
7.     top AS LONG
8.     right AS LONG
9.     bottom AS LONG
10. END TYPE
11.  
12. DIM Rec AS Rectangle
13. DIM SHARED win AS Rectangle
14.  
15. DECLARE DYNAMIC LIBRARY "user32"
16.     FUNCTION FindWindowA& (BYVAL ClassName AS LONG, WindowName$) 'handle by title
17.     FUNCTION GetWindowRect& (BYVAL Hwnd AS LONG, Rec AS Rectangle)
18. END DECLARE
19.  
20. hwnd = FindWindowA&(0, fwp$ + CHR$(0))
21. _DELAY .1
22. win.left = GetWindowRect&(hwnd, Rec)
23. _DELAY .1
24. win.bottom = GetWindowRect&(hwnd, Rec)
25. _DELAY .1
26. PRINT win.left, win.bottom, hwnd
27.  

My guess is you're not going for "Grandfather of the Year" with that code of yours. :D

Pete

[Petr]

I believe we have a function for returning the active windows handle anyway.

You think about _WINDOWHANDLE function?

[Pete]

_WINDOWHANDLE returns the exact same results as the WINDOW API function in my code posted. It's nice to have it in the keywords, though. There is a desktop windows api example in the Windows Library section of the Wiki, but that is a different function call, apparently just for the desktop coordinates. It would be nice to find an active window's coordinates, and beyond that, moving it to a different area of the screen, or resizing it.

I'll have to try and look through that whole API library list to be certain there isn't something in there, already. This isn't something I'm still actively working on presently, but the more you know, the more you grow... although smart guys don't usually end up as porn stars, but hey, no analogy (excuse the pun) is completely bullet proof.

Pete

[Cobalt]

when ODIN doesn't like your title selection! took me a minute to find this again. :)
[maybe he thought I was being too modest by admitting my lack of skill with DECLARE LIBRARY]

I Think _WINDOWHANDLE only returns your programs window handle. and I think HASFOCUS only pertains to 'your' program as well. I thought there was a way to get the handle of the active window but I can't find it by searching the forum, possible it was back on .NET.

But GETFOREGROUNDWINDOW should return the current ACTIVE window. granted this is all for WINDOWs users.
there is also GETACTIVEWINDOW.

now If I could find a way to retrieve what is typed in the address bar that would be killer! Would super simplify my work.

[odin]

Post titles should not be misleading or vague, or else the search feature becomes useless for people looking for help.

Yours was vague.

[Pete]

Check the code I posted a few comments above to get the active window handle.

FUNCTION FindWindowA& (BYVAL ClassName AS LONG, WindowName$) 'handle by title

My Firefox management program  demonstrates how to use it: https://www.qb64.org/forum/index.php?topic=860.msg100590#msg100590

To get the ontents of the address bar, it uses...

_SCREENCLICK  on the address bar.
_SCREENPRINT CHR$(1) ' Select All
_SCREENPRINT CHR$(3) ' Copy URL
URL$ = _CLIPBOARD$

I'd use some brief delays between the statements, too.

Pete

[Cobalt]

Yours was vague.

My titles reflect myself, oh wait, maybe I should go Vogue instead? :)

To get the ontents of the address bar, it uses...

_SCREENCLICK  on the address bar.
_SCREENPRINT CHR$(1) ' Select All
_SCREENPRINT CHR$(3) ' Copy URL
URL$ = _CLIPBOARD$

I thought about that, but how to know when to use it, as if you try that while someone is typing it will cause issues. and constantly running that would be impractical, even restoring the mouse position would cause usage issues. I would have to find a way of knowing when to run it.
I guess with IE its crazy easy to do, and Chrome isn't bad but because the way FireFox is made its nigh upon impossible. have to use DDE ,Dynamic Data something or other, and its not the easiest to implement either.

[Pete]

Try this...

Code: QB64: [Select]

1. WIDTH 100, 4
2. _SCREENMOVE 0, 0
3. _CLIPBOARD$ = ""
4. PRINT: PRINT " Put Firefox anywhere. Click here to start and quickly click Firefox to focus it."
5. DO
6.     i = _MOUSEINPUT
7.     lb% = _MOUSEBUTTON(1)
8.     IF lb% THEN ' Button release
9.         WHILE _MOUSEBUTTON(1)
10.             i = _MOUSEINPUT
11.         WEND
12.         EXIT DO
13.     END IF
14. LOOP
15. _SCREENHIDE
16. _DELAY 2 ' You have 2-seconds to click firefox.
17.  
18. DECLARE DYNAMIC LIBRARY "user32"
19.     SUB SENDKEYS ALIAS keybd_event (BYVAL bVk AS LONG, BYVAL bScan AS LONG, BYVAL dwFlags AS LONG, BYVAL dwExtraInfo AS LONG)
20. END DECLARE
21.  
22. CONST KEYEVENTF_KEYUP = &H2
23. CONST VK_CONTROL = &H11 'Ctrl key
24. CONST VK_L = &H4C ' "L"
25.  
26. _DELAY .1
27.  
28. SENDKEYS VK_CONTROL, 0, 0, 0
29. SENDKEYS VK_L, 0, 0, 0
30. SENDKEYS VK_L, 0, KEYEVENTF_KEYUP, 0
31. SENDKEYS VK_CONTROL, 0, KEYEVENTF_KEYUP, 0
32. _DELAY .1
33. _SCREENPRINT CHR$(3)
34. _DELAY .1
35. _SCREENSHOW
36. CLS
37. PRINT: PRINT " URL = "; _CLIPBOARD$
38.  

Now focus is a problem because the title for firefox is actually the title of the given tab in the browser. In my programs, I just open Bing home page and use that as the title. SO if Firefox is not in focus, this routine will do a Ctrl + L key send on whatever window is in focus. I suspect it won't affect too many programs but I have no idea what hotkeys are used for every program, game, etc. Still, this is a way to get the contents of the address bar, no matter where firefox is and the API allows Ctrl + L, which would be _SCREENCLICK CHR$(12) but that one is not supported in QB64. CHR$(12) was used to eject printer paper, back in the day, if I recall correctly.

Pete