Turn page 90 degrees

[Juanjogomez]

Hi guys,
I want to print a page in landscape format but I do not know how to turn the page 90 degrees.
What I do is create a page with the width of the A4 length and the width of the A4 length. I write the corresponding text, but to send it to the printer I have to rotate it.
With _PUTIMAGE I can reverse it, but I do not think I can rotate it. Could someone tell me how to do it?
Thank you

[Petr]

Hi. Try ROTOZOOM way (with this you can rotating images for all angles, this demo show 45)

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
2. CLS , _RGB32(255, 255, 255)
3.  
4. image& = _SCREENIMAGE 'or LOADIMAGE....
5. RotoZoom _WIDTH / 2, _HEIGHT / 2, image&, _WIDTH, _HEIGHT, 1, 1, 1, 45
6. _PRINTIMAGE 0 'print current screen
7.  
8.  
9. SUB RotoZoom (X AS INTEGER, Y AS INTEGER, Image AS LONG, startx AS INTEGER, starty AS INTEGER, xoffset AS INTEGER, yoffset AS INTEGER, Scale AS SINGLE, Rotation AS SINGLE)
10.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE
11.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
12.     px(0) = (-xoffset + startx) / 2: py(0) = (-yoffset + starty) / 2: px(1) = (-xoffset + startx) / 2: py(1) = (yoffset - starty) / 2
13.     px(2) = (xoffset - startx) / 2: py(2) = (yoffset - starty) / 2: px(3) = (xoffset - startx) / 2: py(3) = (-yoffset + starty) / 2
14.     sinr! = SIN(-Rotation / 57.2957795131): cosr! = COS(-Rotation / 57.2957795131)
15.     FOR i& = 0 TO 3
16.         x2& = Scale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = Scale * (py(i&) * cosr! - px(i&) * sinr!) + Y
17.         px(i&) = x2&: py(i&) = y2&
18.     NEXT
19.     _MAPTRIANGLE (startx, starty)-(startx, yoffset - 1)-(xoffset - 1, yoffset - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
20.     _MAPTRIANGLE (startx, starty)-(xoffset - 1, starty)-(xoffset - 1, yoffset - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
21. END SUB
22.  

[Pete]

I don't work with graphics and I don't know enough about the orientation of color, hue, pixel 0 or 1, etc., to make a real gif, png example, etc. If this was SCREEN 0, you would find the color and character and use loops to re-orient the object. Anyway, just to demonstrate the concept. Maybe something like this could be implemented to work with _PRINTSTRING. Of course, the other elements in an image, hue, etc., would have to be mapped and the algorithms adjusted accordingly, but this was fun...

Code: QB64: [Select]

1. ' Portrait to Landscape pseudosimulation.
2. DATA This is a phony gif header
3. DATA 1A1B1C1D1E
4. DATA 2F2G2H2I2J
5. DATA 3K3L3M3N3O
6. DATA EOF
7.  
8. ' Get height and width
9. DO UNTIL a$ = "EOF"
10.     i = i + 1
11.     READ a$
12.     IF i > 1 THEN
13.         IF i = 2 THEN ' Get width
14.             gifwidth = LEN(a$)
15.         END IF
16.     END IF
17. LOOP
18. gifheight = i - 2 ' Subtract 2 for header and EOF
19.  
20. ' Draw a portrait orientation pic.
21. i = 0
22. RESTORE
23. DO
24.     i = i + 1
25.     READ a$
26.     IF a$ = "EOF" THEN EXIT DO
27.     IF i > 1 THEN
28.         pic$ = pic$ + a$
29.     END IF
30. LOOP
31. RESTORE
32.  
33. PRINT "Portrait Orientation": PRINT
34. FOR i = 1 TO LEN(pic$) / 2
35.     a = VAL(MID$(pic$, i * 2 - 1, 1))
36.     a$ = MID$(pic$, i * 2, 1)
37.     COLOR a
38.     PRINT CHR$((ASC(UCASE$(a$)) - 65 + 127));
39.     IF i MOD gifwidth / 2 = 0 THEN PRINT
40. NEXT
41. COLOR 7, 0
42. PRINT
43.  
44. REDIM a$(gifwidth) ' This will be the new height when rotated.
45. i = 0
46. RESTORE
47.  
48. DO
49.     h = h + 1
50.     READ a$
51.     IF a$ = "EOF" THEN EXIT DO
52.     IF h > 1 THEN
53.         j = j + 1
54.         FOR i = 1 TO gifwidth / 2
55.             x$ = MID$(a$, i * 2 - 1, 2)
56.             a$(i) = x$ + a$(i)
57.         NEXT
58.     END IF
59. LOOP
60.  
61. 'PRINT
62. 'FOR i = 1 TO gifwidth
63. 'PRINT i, a$(i)
64. 'NEXT
65.  
66. FOR i = 1 TO gifwidth
67.     newpic$ = newpic$ + a$(i)
68. NEXT
69.  
70. PRINT: PRINT "Landscape Orientation": PRINT
71. FOR i = 1 TO LEN(newpic$) / 2
72.     a = VAL(MID$(newpic$, i * 2 - 1, 1))
73.     a$ = MID$(newpic$, i * 2, 1)
74.     COLOR a
75.     PRINT CHR$((ASC(UCASE$(a$)) - 65 + 127));
76.     IF i MOD gifheight = 0 THEN PRINT
77. NEXT
78. COLOR 7, 0

Pete

[doppler]

If you are still using a CRT monitor it's possible to turn the yoke on the monitor neck to achieve the effect you want.
If you are using a led monitor just flip it on it's side.

K.I.S.S. no need for complex programs.

[Pete]

Yeah, but he wants to PRINT it. Oh that's right, just turn the printer on its side, right? I'm guilty of making this same joke on a similar QBasic thread, some 15 years ago. I think back then I recommended using printer escape codes, to tell the printer to switch the orientation to landscape, but I'm pretty sure that was for a text document, not a graphic.

Pete

[Juanjogomez]

Thanks Petr, I did not know the function _MAPTRIANGLE
I have already been able to do it.

[Pete]

What values did you use to get it to go from 45% to 90%? Also, it looked to me like Rotozoom when taking a full screen image let the corners get chopped off, instead of truncating the image to fit on the screen.

Pete

[TempodiBasic]

Well
QB64 let use the default printer that results from settings of OS.
But is there some statement to access to the settings of default printer?

Try just Galleon example in the wiki about printing and making a preview.
It is not clear how to change direction of the output in printing.... yes you can workaround
rotating the  image to print but how it fits on the paper?
Mixing RotoZoom with the above talked example in the wiki I get no good results.

[Pete]

Well the ESC sequence for landscape printing would be...

LPRINT CHR$(27)&l1O ' Which is sending the sequence [ESC] & l 1O (el one Oh) to the printer. I hope I have that coded right, it's been 12 years since I used this with QB45. By coded right, I mean I can't recall if a "+" sign is needed after the CHR$(27) or not. i think the "&" sign combines it properly, but I just can no longer recall.

As far as how to access the default printer with QB64, I believe someone once pointed out you needed to make a library to access the Windows API in Windows. I don't even want to guess about how to do it in Linux or Mac.

Pete

[Juanjogomez]

With this sentences works perfectly. A4 landscape to A4 in printer.

Page& = _NEWIMAGE(2970, 2100, 32) '---A4 landscape
NewPage& = _NEWIMAGE(2100, 2970, 32) '---A4 normal
_DEST NewPage&
 CLS , _RGB(255, 255, 255)'make background white to save ink!
_DEST Page&
 CLS , _RGB(255, 255, 255) 'make background white to save ink!
_DEST 0

´´´´´´print text in Page&

_MAPTRIANGLE (2970, 2100)-(2970, 0)-(0, 0), Page& TO(0, 2970)-(2100, 2970)-(2100, 0), NewPage&
_MAPTRIANGLE (2970, 2100)-(0, 2100)-(0, 0), Page& TO(0, 2970)-(0, 0)-(2100, 0), NewPage&
_PRINTIMAGE NewPage&

[Petr]

Juanjogomez:

Thanks Petr, I did not know the function _MAPTRIANGLE
I have already been able to do it.

I am glad, it helped you

Pete:

Well the ESC sequence for landscape printing would be...

LPRINT CHR$(27)&l1O ' Which is sending the sequence [ESC] & l 1O (el one Oh) to the printer. I hope I have that coded right, it's been 12 years since I used this with QB45. By coded right, I mean I can't recall if a "+" sign is needed after the CHR$(27) or not. i think the "&" sign combines it properly, but I just can no longer recall.

As far as how to access the default printer with QB64, I believe someone once pointed out you needed to make a library to access the Windows API in Windows. I don't even want to guess about how to do it in Linux or Mac.

Pete

I'm afraid I've read somewhere that QB64 does not support these print control codes.

[Pete]

I haven't used LPRINT in years so I checked the Wiki and...

"Note: Printer escape codes starting with CHR$(27) will not work with LPRINT and may produce text printing errors."

That's a shame. I'm going to read up a bit on Windows print settings, next.

OK, I modified this, from the Wiki article, to find the default printer...

Code: QB64: [Select]

1. ' WARNING: Be sure you don't already have "default.txt" as a text file in your directory or running this will overwrite that file.
2. SHELL _HIDE "CMD /C" + "wmic printer get name,default > default.txt"
3. OPEN "default.txt" FOR INPUT AS #1
4. DO UNTIL EOF(1)
5.     LINE INPUT #1, a$
6.     PRINT a$
7. LOOP
8. CLOSE

The word "True" will appear before the default printer device. There is another example that allows you to change the default printer in a similar manner, which leads me to wonder if the command window has a sequence that would change the orientation setting to landscape and back.

Well, I suppose it depends on the printers. Some helpful articles online to send escape codes via the command line:

https://stackoverflow.com/questions/30255647/print-a-file-in-landscape-from-windows-command-line-or-powershell

https://groups.google.com/forum/#!topic/microsoft.public.word.pagelayout/wXJoer4u1Eg


Pete

[SMcNeill]

For Windows, you can change printer settings with powershell:  https://docs.microsoft.com/en-us/powershell/module/printmanagement/set-printconfiguration?view=win10-ps

[Pete]

I read that Powershell does not effect orientation settings.

https://powershell.org/forums/topic/changing-printer-output-to-landscape/

Pete

[SMcNeill]

I read that Powershell does not effect orientation settings.

https://powershell.org/forums/topic/changing-printer-output-to-landscape/

Pete

Try this command and see if it doesn't work for you:

Code: QB64: [Select]

1. SetPrinter "” 8 pDevMode=dmOrientation=1

The "" basically says to apply orientation changes to ALL your printers.  Feel free to use the specific name of one, if you don't want to change them all.  (Such as "EPSON1BF169 (WF-3640 Series)" on my machine.)

dmOrientation is 1 for Landscape, 2 for Portrait.  (If I remember correctly...)

There's a boatload of things that SetPrinter can change for you, so my advice would be to go to your command line and just type:   SetPrinter /?

Once you get a basic list of things, give the inbuilt examples a go:   
SetPrinter /examples 0
SetPrinter /examples 8

Code: QB64: [Select]

1. SetPrinter -show "" 8

The above will give you a list of all the level 8 options which you can change with SetPrinter.  Not all printers/devices allow changes to orientation, so make certain that the device you want to work with allows that.