qXed: linked list text editor

[STxAxTIC]

OBSOLETE POST


Hi folks,

In the interest of keeping the top most most relevant, I bumped the original text downward to make space for today's update. This code has crystallized enough so I can post somewhat of a "clean" milestone. (Still deciding on some internal and external behaviors - what you see might not be final.)

What makes this update different however, is I've decided to a explain a little on how to use it.

Startup and File IO
The code you see below can run as stand-alone. No external files needed for this showing. The auxiliary text files attached are samples that you can drag+drop onto the compiled *.exe file once you throw it through your QB64 compiler. That is, unlike earlier prototypes, it now loads blank like a real editor, and the psychedelic rant has to be loaded separately. To save a file along the way, press F6 and a snapshot will be dumped into the directory alongside the exe.

Cursors
So there are seemingly three cursors on screen. You'll notice the grey single-character highlight just follows that mouse - it's a completely benign pointer (not really a cursor). There are two relevant cursors though. Cursor 1 (the main one) is blue, and causes the character under it to blink. Cursor 2 is a brown, and only has a function/appearance when it is downstream of cursor 1. That is, cursor 2 is always to the right, else it disappears. The one exception is when the cursors overlap, in which the color blends to purple. The ESC key sill send cursor 2 to either (i) the end of the text file, or (ii) onto cursor 1, depending on initial position.

Typing text
In "normal" mode, i.e., with cursor 1 appearing as blue, any typed or inserted characters appear *after* the cursor position. However, when cursors are aligned and appear as purple, typed or inserted characters appear *before* the cursor.

Mouse Buttons
Mouse button 1 moves the position of cursor 1. Observe it can't be moved anywhere - only within the topology of the existing text file. Mouse button 2 moves the position of cursor 2, and is rendered provided it occurs downstream of cursor 1. *Any* qualified movement of cursor 2 invokes a clipboard copy of all characters between cursors. Mouse button 3 pastes the contents of the clipboard at the position of cursor 1.

Navigation and Scrolling
The normal ways of getting around a text file work here: arrow keys, home/end, pgup/pgdn, auto-scrolling when your text insertions reach the bottom... most of the expected behaviors are there. The scrollbar on the right indicates not what page or line we're on, but the position of cursor 1 with respect to the whole file. That is, you can "scroll" with the mouse by clicking the right edge through a file of any length, even two characters. Of course, clicking on the right edge is the only fast way to get to the bottom of a big file. There are so far no dialog windows, jump-to-line options, or search. Mouse scrollwheel does what you think.

Wrapping Modes
That "gotcha" part of text editors... There are three wrapping modes in this editor. By default it loads "fluid" mode, which makes all efforts to never chop words in half. It breaks on spaces and hyphens. Next there is "square" mode, which makes zero effort to never chop words in half. The text appears as a big rectangle. Finally, there is the "none" case, in where lines never break, and horizontal scrolling must be used to see the end (like the IDE). In the special cases where a single word is too long for any of the first two modes, it spills onto the next line without incident. Press F12 to cycle through these modes.

Formatting Option
Because I am in the cult of Doug Crockford and agree with most of what he thinks, I hate using TABS for spacing. What a horrible throwback to the typewriter that is... So we use spaces for spacing in qXed. Break returns are all converted to CHR$(13). To see the hidden characters that slice up the text file, press F11. This solves the problem (for me) of opening text files and being thrown off by white space that renders as invisible. This option was inspired by the VI editor.

...

Okay, all that said, the code is below. Compile to an exe, and then drag+drop reasonably-size text files onto there. The downloads include some fun reading and demonstrations, so please do have a look.

Code: QB64: [Select]

1. _TITLE "qXed"
2. _DELAY .15
3. SCREEN _NEWIMAGE(90, 30, 0)
4.  
5. ' Define fundamental structures.
6. TYPE Vector
7.     X AS INTEGER
8.     Y AS INTEGER
9. END TYPE
10.  
11. TYPE Cell
12.     Identity AS LONG
13.     Pointer AS LONG
14.     Lagger AS LONG
15.     Content AS STRING * 1
16. END TYPE
17.  
18. DIM SHARED ChainLimit AS LONG
19. DIM SHARED BOC AS LONG ' Beginning of chain.
20. DIM SHARED EOC AS LONG ' End of chain.
21. ChainLimit = 128000
22. BOC = -1
23. EOC = ChainLimit
24.  
25. ' Define text window properties.
26. DIM SHARED VisibleLines
27. DIM SHARED TopIndent
28. DIM SHARED LeftIndent
29. DIM SHARED TextHeight
30. DIM SHARED TextWidth
31. DIM SHARED HScroll
32. DIM SHARED TextWrapping
33. DIM SHARED TextFormatting
34. DIM SHARED InsertKey
35. TopIndent = 1
36. LeftIndent = 1
37. TextHeight = _HEIGHT - 2 * TopIndent + 1
38. TextWidth = _WIDTH - 2 * LeftIndent
39. HScroll = 1
40. TextWrapping = 1
41. TextFormatting = -1
42. InsertKey = -1
43.  
44. ' Initiate text inside window.
45. DIM SHARED StartIndex ' First visible character address.
46. DIM SHARED LineAsMapped(TextHeight) AS STRING
47. DIM SHARED Cursor1 AS Vector
48. DIM SHARED Cursor2 AS Vector
49. DIM SHARED ID1
50. DIM SHARED ID2
51.  
52. DIM SHARED AuxGrid(TextWidth, TextHeight, 2) AS STRING
53.  
54. ' Load text file into memory if applicable, use example string if not.
55. DIM SHARED FileName$
56. c$ = COMMAND$
57. IF (c$ <> "") THEN
58.     q$ = ""
59.     OPEN c$ FOR INPUT AS #1
60.     DO WHILE NOT EOF(1)
61.         LINE INPUT #1, r$
62.         q$ = q$ + r$ + CHR$(13)
63.     LOOP
64.     CLOSE #1
65.     i = INSTR(c$, ".")
66.     IF (i <> 0) THEN j = i - 1 ELSE j = LEN(c$)
67.     FileName$ = LEFT$(c$, j) + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
68. ELSE
69.     FileName$ = "Newfile" + "-" + DATE$ + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
70.     'q$ = "I sank to the floor. I [experienced] this hallucination of tumbling forward into these fractal geometric spaces made of light and then I found myself in the equivalent of the Pope's private chapel and there were insect elf machines proffering strange little tablets with strange writing on them, and I was aghast, completely appalled, because [in] a matter of seconds . . . my entire expectation of the nature of the world was just being shredded in front of me. I've never actually gotten over it. These self-transforming machine elf creatures were speaking in a colored language which condensed into rotating machines that were like Faberge eggs but crafted out of luminescent superconducting ceramics and liquid crystal gels. All this stuff was just so weird and so alien and so un-English-able that it was a complete shock - I mean, the literal turning inside out of [my] intellectual universe!" + CHR$(13) + CHR$(13) + "This went on for two or three minutes, this situation of [discontinuous] orthogonal dimensions to reality just engulfing me. As I came out of it and the room reassembled itself, I said, " + CHR$(34) + "I can't believe it, it's impossible." + CHR$(34) + " To call that a drug is ridiculous; that just means that you just don't have a word for it and so you putter around and you come upon this sloppy concept [that] something goes into your body and there's a change. It's not like that; it's like being struck by noetic lightning. [Note: " + CHR$(34) + "Noetic" + CHR$(34) + " derives from the theologian Pierre Teilhard de Chardin's " + CHR$(34) + "noosphere" + CHR$(34) + " - the collective consciousness of humankind conceived of as a sort of philosophical virtuality.]" + CHR$(13) + CHR$(13) + "[What] astonished me was [that] . . . in the carpets of Central Asia, in the myths of the Maya, in the visions of an Arcimboldi or a Fra Angelico or a Bosch, there is not a hint, not a clue, not an atom of the presence of this thing, This was more [multiplex] than the universe that we share with each other. It was the victory of Neo-Platonic metaphysics; everything [was] made out of a fourth-dimensional mosaic of energy. I was knocked off my feet, and set myself the goal of understanding this. There was really no choice, you see."
71.     'q$ = "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                         **         **    " + CHR$(13) + "                        * *         **    " + CHR$(13) + "  **       **           **                " + CHR$(13) + "  **      * *                             " + CHR$(13) + "          **      **                      " + CHR$(13) + "                  * *                     " + CHR$(13) + "                  *                       " + CHR$(13) + "                                     **   " + CHR$(13) + "                                     * *  " + CHR$(13) + "                                     *    " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                          ***             " + CHR$(13) + "                          *               " + CHR$(13) + "                           *              " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13) + "                                          " + CHR$(13)
72.     q$ = " "
73. END IF
74.  
75. ' Create memory space for string.
76. DIM SHARED TheChain(ChainLimit) AS Cell
77.  
78. ' Create character list.
79. CALL Assimilate(q$)
80.  
81. ' Prime main loop.
82. CALL MapText
83. CALL CalibrateCursor(ID1)
84. CALL CalibrateCursor(ID2)
85. CALL PrintEverything
86.  
87. DIM SHARED DEBUG$
88.  
89. ' Main loop.
90. DO
91.     CALL StateChange
92.     CALL PrintEverything
93.  
94.     _DISPLAY
95.     _LIMIT 120
96. LOOP
97. SYSTEM
98.  
99. SUB PrintEverything
100.     CLS
101.  
102.     COLOR 11, 0
103.     c$ = "qXed" + DEBUG$
104.     _PRINTSTRING (1, 1), c$
105.  
106.     COLOR 7, 1
107.     FOR i = 1 TO VisibleLines
108.         c$ = LineAsMapped(i)
109.         IF ((TextFormatting = 1) AND (TextWrapping <> 2)) THEN
110.             FOR j = 1 TO TextWidth - LEN(c$)
111.                 c$ = c$ + "_"
112.             NEXT
113.         END IF
114.         _PRINTSTRING (LeftIndent + 1, TopIndent + i), MID$(c$, HScroll, TextWidth)
115.     NEXT
116.  
117.     IF ((Cursor2.X > 0 AND Cursor2.X < _WIDTH) AND ((Cursor2.Y > 0) AND (Cursor2.Y < _HEIGHT))) THEN
118.         p1 = LinearCount(StartIndex, ID1)
119.         p2 = LinearCount(StartIndex, ID2)
120.         pe = LinearCount(StartIndex, EOC)
121.         IF ((p2 > p1) AND (p2 < pe)) THEN
122.             c$ = TheChain(ID2).Content
123.             IF (c$ = " ") THEN c$ = "_"
124.             IF (c$ = CHR$(13)) THEN c$ = "~"
125.             COLOR 0, 6
126.             _PRINTSTRING (Cursor2.X, Cursor2.Y), c$
127.         END IF
128.     END IF
129.  
130.     IF ((Cursor1.X > 0 AND Cursor1.X < _WIDTH) AND ((Cursor1.Y > 0) AND (Cursor1.Y < _HEIGHT))) THEN
131.         IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN COLOR 16, 5 ELSE COLOR 16, 3
132.         c$ = TheChain(ID1).Content
133.         IF (c$ = " ") THEN c$ = "_"
134.         IF (c$ = CHR$(13)) THEN c$ = "~"
135.         _PRINTSTRING (Cursor1.X, Cursor1.Y), c$
136.     END IF
137.  
138.     d$ = TheChain(ID1).Content
139.     e$ = TheChain(ID2).Content
140.     IF ((ASC(d$) = 10) OR (ASC(d$) = 13)) THEN d$ = "~"
141.     IF ((ASC(e$) = 10) OR (ASC(e$) = 13)) THEN e$ = "~"
142.     IF (ASC(d$) = 32) THEN d$ = "_"
143.     IF (ASC(e$) = 32) THEN e$ = "_"
144.  
145.     IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN COLOR 0, 5 ELSE COLOR 0, 3
146.     c$ = "(" + LTRIM$(RTRIM$(STR$(Cursor1.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor1.Y - TopIndent))) + ":" + " " + LTRIM$(RTRIM$(d$)) + " " + LTRIM$(RTRIM$(STR$(ID1))) + ")"
147.     _PRINTSTRING (2, _HEIGHT), c$
148.     IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
149.         COLOR 0, 6
150.         _PRINTSTRING (3 + LEN(c$), _HEIGHT), "(" + LTRIM$(RTRIM$(STR$(Cursor2.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor2.Y - TopIndent))) + ":" + " " + LTRIM$(RTRIM$(e$)) + " " + LTRIM$(RTRIM$(STR$(ID2))) + ")"
151.     END IF
152.  
153.     p = LinearCount(ID1, NthP(ID1, ChainLimit + 1))
154.     q = LinearCount(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
155.     IF (q = 0) THEN r = 1 ELSE r = 1 - p / q
156.     COLOR 8, 7
157.     _PRINTSTRING (_WIDTH, 1 + INT(r * (_HEIGHT - 1))), "*"
158.  
159.     COLOR 15, 0
160.     SELECT CASE TextWrapping
161.         CASE 0: d$ = "Square"
162.         CASE 1: d$ = "Fluid"
163.         CASE 2: d$ = "None"
164.     END SELECT
165.     c$ = "[F6=Save] [F11=Formatting] [F12=Wrapping: " + d$ + "]"
166.     IF (TextWrapping = 2) THEN c$ = "[F1/2=HScroll] " + c$
167.     c$ = c$ + STR$(INT(100 * r)) + "%"
168.     _PRINTSTRING (_WIDTH - LEN(c$), 1), c$
169.  
170.     c$ = "[Esc=Sync] [Mouse2=Copy] [Mouse3=Paste]"
171.     IF (InsertKey = 1) THEN c$ = "[Ins] " + c$
172.     _PRINTSTRING (_WIDTH - LEN(c$), _HEIGHT), c$
173.  
174.     IF ((_MOUSEX >= 1) AND (_MOUSEX <= _WIDTH) AND (_MOUSEY >= 1) AND (_MOUSEY <= _HEIGHT)) THEN
175.         a$ = CHR$(SCREEN(_MOUSEY, _MOUSEX))
176.         COLOR 0, 15
177.         _PRINTSTRING (_MOUSEX, _MOUSEY), a$
178.     END IF
179.  
180.     COLOR 15, 0
181. END SUB
182.  
183. SUB Assimilate (a AS STRING)
184.     ' Load a string to initialize chain.
185.     FOR k = 1 TO ChainLimit
186.         TheChain(k).Identity = 0
187.     NEXT
188.     StartIndex = 1
189.     PreviousIdentity = BOC
190.     NextIdentity = NextOpenIdentity(StartIndex)
191.     FOR k = 1 TO LEN(a)
192.         j = NextIdentity
193.         TheChain(j).Identity = j
194.         TheChain(j).Content = ReFormat$(MID$(a, k, 1))
195.         TheChain(j).Lagger = PreviousIdentity
196.         PreviousIdentity = j
197.         IF (k < LEN(a)) THEN
198.             NextIdentity = NextOpenIdentity(j)
199.             TheChain(j).Pointer = NextIdentity
200.         ELSE
201.             TheChain(j).Pointer = EOC
202.         END IF
203.         PRINT TheChain(j).Content
204.     NEXT
205.     ID1 = StartIndex
206.     ID2 = ID1
207. END SUB
208.  
209. FUNCTION ReFormat$ (a AS STRING)
210.     c$ = a
211.     IF c$ = CHR$(10) THEN c$ = CHR$(13)
212.     IF c$ = CHR$(9) THEN c$ = "    "
213.     ReFormat = c$
214. END FUNCTION
215.  
216. FUNCTION NthP (a AS LONG, b AS LONG)
217.     ' Returns the address that is b jumps ahead of address a.
218.     i = a
219.     IF (i <> EOC) THEN
220.         k = 0
221.         j = 0
222.         DO WHILE (k < b)
223.             k = k + 1
224.             j = TheChain(i).Identity
225.             i = TheChain(j).Pointer
226.             IF (i = EOC) THEN EXIT DO
227.         LOOP
228.     END IF
229.     NthP = j
230. END FUNCTION
231.  
232. FUNCTION NthPC (a AS LONG, b AS STRING)
233.     ' Returns the address holding b first enLinearCountered from a.
234.     i = a
235.     DO
236.         j = TheChain(i).Identity
237.         i = TheChain(j).Pointer
238.         IF (TheChain(j).Content = b) THEN EXIT DO
239.         IF (i = EOC) THEN
240.             j = BOC
241.             EXIT DO
242.         END IF
243.     LOOP
244.     NthPC = j
245. END FUNCTION
246.  
247. FUNCTION NthL (a AS LONG, b AS LONG)
248.     ' Returns the address that is b jumps behind address a.
249.     i = a
250.     k = 0
251.     DO WHILE k < b
252.         k = k + 1
253.         j = TheChain(i).Identity
254.         i = TheChain(j).Lagger
255.         IF (i = BOC) THEN EXIT DO
256.     LOOP
257.     NthL = j
258. END FUNCTION
259.  
260. FUNCTION NextOpenIdentity (a AS LONG)
261.     ' Returns first nonzero identity.
262.     FOR j = a TO ChainLimit
263.         IF (TheChain(j).Identity = 0) THEN EXIT FOR
264.     NEXT
265.     IF (j > ChainLimit) THEN
266.         PRINT "Out of memory: "; ChainLimit
267.         SLEEP
268.         SYSTEM
269.     END IF
270.     NextOpenIdentity = j
271. END FUNCTION
272.  
273. FUNCTION BackBreak (a AS LONG)
274.     ' Function for scrolling up.
275.     j = a
276.     lastbreak = 0
277.     c$ = ""
278.     DO
279.         IF (j = BOC) THEN EXIT DO
280.         k = TheChain(j).Lagger
281.         IF (k = BOC) THEN
282.             lastbreak = j
283.             EXIT DO
284.         END IF
285.         j = k
286.         d$ = TheChain(j).Content
287.         IF ((TextWrapping = 1) AND (d$ = " ")) THEN lastbreak = j
288.         c$ = d$ + c$
289.         IF (TextWrapping <> 2) AND (LEN(c$) = TextWidth) THEN EXIT DO
290.         IF (d$ = CHR$(13)) THEN EXIT DO
291.     LOOP
292.     IF (lastbreak <> 0) THEN j = TheChain(lastbreak).Identity
293.     BackBreak = j
294. END FUNCTION
295.  
296. SUB InsertBefore (a AS LONG, b AS STRING)
297.     ' Inserts a single cell before address a in the chain.
298.     j = NextOpenIdentity(a)
299.     al = TheChain(a).Lagger
300.     TheChain(j).Identity = j
301.     TheChain(j).Pointer = a
302.     TheChain(j).Lagger = al
303.     TheChain(j).Content = ReFormat$(b)
304.     TheChain(a).Lagger = j
305.     IF (al = BOC) THEN StartIndex = j ELSE TheChain(al).Pointer = j
306. END SUB
307.  
308. SUB InsertAfter (a AS LONG, b AS STRING)
309.     ' Inserts a single cell after address a in the chain.
310.     j = NextOpenIdentity(a)
311.     ap = TheChain(a).Pointer
312.     TheChain(j).Identity = j
313.     TheChain(j).Pointer = ap
314.     TheChain(j).Lagger = a
315.     TheChain(j).Content = ReFormat$(b)
316.     TheChain(a).Pointer = j
317.     IF (ap <> EOC) THEN TheChain(ap).Lagger = j
318. END SUB
319.  
320. SUB InsertRange (a AS LONG, b AS STRING)
321.     ' Inserts a sub-chain anywhere.
322.     FOR k = 1 TO LEN(b)
323.         c$ = MID$(b, k, 1)
324.         CALL InsertBefore(a, c$)
325.     NEXT
326. END SUB
327.  
328. SUB UnlinkCell (a AS LONG)
329.     ' Remove single cell from chain and clear identity.
330.     ap = TheChain(a).Pointer
331.     al = TheChain(a).Lagger
332.     IF ((ap = EOC) AND (al = BOC)) THEN
333.         TheChain(a).Content = " "
334.         'ID1 = a
335.         'ID2 = ID1
336.     ELSE
337.         TheChain(a).Identity = 0
338.         IF ((ap <> EOC) AND (al <> BOC)) THEN
339.             TheChain(al).Pointer = ap
340.             TheChain(ap).Lagger = al
341.         END IF
342.         IF (ap = EOC) THEN TheChain(al).Pointer = EOC
343.         IF (al = BOC) THEN
344.             StartIndex = ap
345.             TheChain(ap).Lagger = BOC
346.         END IF
347.     END IF
348. END SUB
349.  
350. SUB UnlinkRange (a AS LONG, b AS LONG)
351.     ' Remove sub-chain and clear identity of each cell.
352.     bp = TheChain(b).Pointer
353.     al = TheChain(a).Lagger
354.     IF ((al = BOC) AND (bp = EOC)) THEN
355.         CALL UnlinkRange(NthP(a, 2), b)
356.         TheChain(a).Content = " "
357.         TheChain(a).Pointer = bp
358.     ELSE
359.         k = a
360.         DO WHILE ((k <> b) AND (k <> EOC))
361.             TheChain(k).Identity = 0
362.             k = TheChain(k).Pointer
363.         LOOP
364.         TheChain(b).Identity = 0
365.         TheChain(bp).Lagger = al
366.         IF (al = BOC) THEN StartIndex = bp ELSE TheChain(al).Pointer = bp
367.     END IF
368. END SUB
369.  
370. FUNCTION LinearCount (a AS LONG, b AS LONG)
371.     ' Returns number of links between two addresses.
372.     i = a
373.     k = 0
374.     DO WHILE (i <> b)
375.         k = k + 1
376.         j = TheChain(i).Identity
377.         i = TheChain(j).Pointer
378.         IF (i = EOC) THEN EXIT DO
379.     LOOP
380.     LinearCount = k
381. END FUNCTION
382.  
383. FUNCTION LinearCount2 (a AS LONG, b AS LONG, c AS LONG)
384.     ' Returns number of links between two addresses.
385.     i = a
386.     k = 0
387.     DO WHILE (i <> b)
388.         k = k + 1
389.         j = TheChain(i).Identity
390.         i = TheChain(j).Pointer
391.         IF (i = EOC) THEN EXIT DO
392.         IF (k = c) THEN EXIT DO
393.     LOOP
394.     LinearCount2 = k
395. END FUNCTION
396.  
397. FUNCTION Projection$ (a AS LONG, b AS LONG)
398.     ' Returns the linear content for all address between a and b, inclusive.
399.     DIM TheReturn AS STRING
400.     TheReturn = ""
401.     IF (a = b) THEN
402.         TheReturn = TheChain(a).Content
403.     ELSE
404.         j = a
405.         DO
406.             c$ = TheChain(j).Content
407.             TheReturn = TheReturn + c$
408.             k = TheChain(j).Pointer
409.             IF (j = b) THEN EXIT DO
410.             IF (k = EOC) THEN EXIT DO
411.             j = k
412.         LOOP
413.     END IF
414.     Projection$ = TheReturn
415. END SUB
416.  
417. SUB MapText
418.     IF (TextFormatting = 1) THEN br$ = "~" ELSE br$ = " "
419.     j = StartIndex
420.     i = 1
421.     q$ = ""
422.     d$ = ""
423.     DO ' Begin with any left-over text from previous iteration.
424.         q$ = d$
425.         d$ = ""
426.         r = TextWidth - LEN(q$)
427.         IF (TextWrapping <> 2) THEN k1 = NthP(j, r) ELSE k1 = EOC
428.         k2 = NthPC(j, CHR$(13))
429.         IF (TextWrapping <> 2) THEN c1 = LinearCount(j, k1) ELSE c1 = LinearCount2(j, k1, TextWidth * TextHeight)
430.         c2 = LinearCount(j, k2)
431.         IF (c2 = 0) THEN ' Line is blank-returned.
432.             k = k2
433.             q$ = q$ + br$
434.             j = NthP(k, 2)
435.         ELSE
436.             IF (c1 = c2) THEN ' Possible end of chain.
437.                 k = TheChain(k1).Lagger
438.                 q$ = q$ + Projection$(j, k)
439.                 j = NthP(k, 2)
440.             END IF
441.             IF (c1 < c2) THEN ' Width limit case (not always maximum).
442.                 k = k1
443.                 q$ = q$ + Projection$(j, k)
444.                 j = NthP(k, 2)
445.             END IF
446.             IF (c1 > c2) THEN ' Break return somewhere in line (not first).
447.                 k = k2
448.                 q$ = q$ + Projection$(j, TheChain(k).Lagger) + br$
449.                 n = TheChain(k).Pointer
450.                 IF (n <> EOC) THEN j = n
451.             END IF
452.         END IF
453.         IF (TextWrapping = 1) THEN ' Wrap text at first space from right, send remainder to next line.
454.             IF (LEN(q$) >= TextWidth) THEN
455.                 FOR m = LEN(q$) TO 1 STEP -1
456.                     c$ = MID$(q$, m, 1)
457.                     IF (c$ = " ") OR (c$ = "-") THEN
458.                         q$ = LEFT$(q$, m)
459.                         EXIT FOR
460.                     END IF
461.                     d$ = c$ + d$
462.                     IF (m = 1) THEN ' Line is too long for allowed space and contains no wrapping characters.
463.                         q$ = LEFT$(q$, TextWidth)
464.                         d$ = ""
465.                         EXIT FOR
466.                     END IF
467.                 NEXT
468.             END IF
469.         END IF
470.         LineAsMapped(i) = q$
471.         i = i + 1
472.         IF (i >= TextHeight) THEN EXIT DO
473.         IF (j = k) THEN EXIT DO
474.     LOOP
475.     VisibleLines = i - 1
476. END SUB
477.  
478. SUB StateChange
479.     MH = 0
480.     MW = 0
481.     MT = 0
482.     DO WHILE _MOUSEINPUT
483.         MH1 = _MOUSEBUTTON(1)
484.         MH2 = _MOUSEBUTTON(2)
485.         MH3 = _MOUSEBUTTON(3)
486.         MW = _MOUSEWHEEL
487.         IF (MW <> 0) THEN MT = MW
488.     LOOP
489.     MW = MT
490.  
491.     IF (MH1 = -1) THEN
492.         ' Move Cursor1 among text.
493.         MH = 1
494.         IF (_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight + 1) THEN
495.             Cursor1.X = _MOUSEX
496.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent))
497.             IF (Cursor1.X > q) THEN Cursor1.X = q
498.             Cursor1.Y = _MOUSEY
499.             CALL ReassignID1
500.         END IF
501.         ' Move by scrollbar.
502.         IF (_MOUSEX = _WIDTH) THEN
503.             i = NthL(ID1, ChainLimit + 1)
504.             j = NthP(ID1, ChainLimit + 1)
505.             IF (_MOUSEY = _HEIGHT) THEN i = j
506.             IF (_MOUSEY > 1) AND (_MOUSEY < _HEIGHT) THEN
507.                 t = LinearCount(i, j)
508.                 f = _MOUSEY / _HEIGHT
509.                 FOR k = 1 TO t
510.                     IF (k / t) >= f THEN EXIT FOR
511.                     i = TheChain(i).Pointer
512.                 NEXT
513.             END IF
514.             StartIndex = i
515.             ID1 = i
516.         END IF
517.     END IF
518.     IF (MH2 = -1) THEN
519.         ' Move Cursor2 and copy anything between Cursor1 and Cursor2 to clipboard.
520.         MH = 1
521.         IF (_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight + 1) THEN
522.             Cursor2.X = _MOUSEX
523.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent))
524.             IF (Cursor2.X > q) THEN Cursor2.X = q
525.             Cursor2.Y = _MOUSEY
526.             CALL ReassignID2
527.             IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN _CLIPBOARD$ = Projection$(ID1, ID2)
528.         END IF
529.     END IF
530.     IF (MH3 = -1) THEN
531.         ' Paste at Cursor1 position.
532.         MH = 1
533.         IF (LinearCount(StartIndex, ID2) >= LinearCount(StartIndex, ID1)) THEN CALL InsertRange(ID1, _CLIPBOARD$)
534.     END IF
535.     IF (MW = -1) THEN
536.         ' Wheel up
537.         MH = 1
538.         StartIndex = BackBreak(StartIndex)
539.         CALL ReassignID1
540.     END IF
541.     IF (MW = 1) THEN
542.         ' Wheel down
543.         MH = 1
544.         IF (VisibleLines > 1) THEN
545.             StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
546.             CALL MapText
547.         END IF
548.         CALL ReassignID1
549.     END IF
550.  
551.     KH = 0
552.     KH = _KEYHIT
553.  
554.     ' Bksp
555.     IF (KH = 8) THEN
556.         r = TheChain(ID1).Pointer
557.         q = TheChain(ID1).Lagger
558.         CALL UnlinkCell(ID1)
559.         IF ((r = EOC) AND (q = BOC)) THEN
560.         ELSE
561.             IF (q <> BOC) THEN ID1 = q ELSE ID1 = r
562.             IF (r = EOC) THEN ID2 = ID1
563.         END IF
564.     END IF
565.     ' Tab
566.     IF (KH = 9) THEN CALL InsertRange(ID1, "    ")
567.     ' Esc
568.     IF (KH = 27) THEN
569.         IF (ID2 <> ID1) THEN ID2 = ID1 ELSE ID2 = NthP(ID2, ChainLimit + 1)
570.     END IF
571.     ' Enter, Alphanumerics
572.     IF (KH = 13) OR ((KH >= 32) AND (KH <= 126)) THEN
573.         IF (InsertKey = -1) THEN
574.             IF (ID1 = ID2) THEN
575.                 CALL InsertBefore(ID1, LTRIM$(RTRIM$(CHR$(KH))))
576.             ELSE
577.                 CALL InsertAfter(ID1, LTRIM$(RTRIM$(CHR$(KH))))
578.                 ID1 = NthP(ID1, 2)
579.             END IF
580.         ELSE
581.             TheChain(ID1).Content = LTRIM$(RTRIM$(CHR$(KH)))
582.             IF (ID1 = ID2) THEN
583.                 ID1 = NthP(ID1, 2)
584.                 ID2 = ID1
585.             ELSE
586.                 ID1 = NthP(ID1, 2)
587.             END IF
588.         END IF
589.     END IF
590.     ' F1
591.     IF (KH = 15104) THEN
592.         IF (TextWrapping = 2) THEN
593.             HScroll = HScroll - 1
594.             IF (HScroll < 1) THEN HScroll = 1
595.             CALL ReassignID1
596.             CALL ReassignID2
597.         END IF
598.     END IF
599.     ' F2
600.     IF (KH = 15360) THEN
601.         IF (TextWrapping = 2) THEN
602.             HScroll = HScroll + 1
603.             CALL ReassignID1
604.             CALL ReassignID2
605.         END IF
606.     END IF
607.     ' F5
608.     IF (KH = 16128) THEN
609.         q$ = Projection$(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
610.         Assimilate q$
611.     END IF
612.     ' F4
613.     IF (KH = 15872) THEN
614.         'CALL InsertRange(NthP(ID2, 2), "=" + SxriptEval$(Projection(ID1, ID2)))
615.     END IF
616.     ' F6
617.     IF (KH = 16384) THEN
618.         OPEN FileName$ FOR OUTPUT AS #1
619.         q$ = Projection$(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
620.         PRINT #1, q$
621.         CLOSE #1
622.     END IF
623.     ' F7
624.     IF (KH = 16640) THEN
625.         CALL ConvertToGrid
626.         CALL GOL
627.         CALL ConvertFromGrid
628.     END IF
629.     ' F8
630.     'IF (KH = 16896) THEN
631.     ' Home
632.     IF (KH = 18176) THEN
633.         IF (TextWrapping = 2) THEN HScroll = 1
634.         Cursor1.X = LeftIndent + 1
635.         CALL ReassignID1
636.     END IF
637.     ' UpArrow
638.     IF (KH = 18432) THEN
639.         IF (Cursor1.Y > TopIndent + 1) THEN
640.             Cursor1.Y = Cursor1.Y - 1
641.         ELSE
642.             StartIndex = BackBreak(StartIndex)
643.         END IF
644.         q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) + 1
645.         IF (Cursor1.X > q) THEN Cursor1.X = q
646.         CALL ReassignID1
647.     END IF
648.     ' PgUp
649.     IF (KH = 18688) THEN
650.         FOR k = 1 TO INT(TextHeight / 2)
651.             StartIndex = BackBreak(StartIndex)
652.         NEXT
653.         CALL ReassignID1
654.     END IF
655.     ' LeftArrow
656.     IF (KH = 19200) THEN
657.         ID1 = NthL(ID1, 2)
658.         IF (TextWrapping = 2) THEN
659.             IF (Cursor1.X = LeftIndent + 1) THEN
660.                 IF (HScroll > 1) THEN
661.                     HScroll = HScroll - 1
662.                 ELSE
663.                     j = Cursor1.Y - TopIndent - 1
664.                     IF (j >= 1) THEN
665.                         k = LEN(LineAsMapped(j)) - TextWidth + 1
666.                         IF (k >= 1) THEN
667.                             HScroll = k
668.                         END IF
669.                     END IF
670.                 END IF
671.             END IF
672.         ELSE
673.             IF ((Cursor1.X - LeftIndent = 1) AND Cursor1.Y - TopIndent = 1) THEN
674.                 StartIndex = BackBreak(StartIndex)
675.             END IF
676.         END IF
677.     END IF
678.     ' RightArrow
679.     IF (KH = 19712) THEN
680.         ID1 = NthP(ID1, 2)
681.         m = Cursor1.X - LeftIndent
682.         n = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - HScroll + 1
683.         IF (TextWrapping = 2) THEN
684.             IF (m >= TextWidth) THEN
685.                 HScroll = HScroll + 1
686.                 CALL ReassignID1
687.             END IF
688.             IF (m >= n) THEN
689.                 j = Cursor1.Y - TopIndent + 1
690.                 IF (j <= TextHeight) THEN HScroll = 1
691.             END IF
692.         ELSE
693.             IF ((m >= n) AND (Cursor1.Y - TopIndent = VisibleLines)) THEN
694.                 IF (VisibleLines > 1) THEN StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
695.             END IF
696.         END IF
697.     END IF
698.     ' End
699.     IF (KH = 20224) THEN
700.         Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
701.         CALL ReassignID1
702.         IF (TextWrapping = 2) THEN
703.             q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - TextWidth + 1
704.             IF (q >= 1) THEN HScroll = q
705.         END IF
706.     END IF
707.     ' DownArrow
708.     IF (KH = 20480) THEN
709.         IF (Cursor1.Y = TopIndent + VisibleLines) THEN
710.             IF (VisibleLines > 1) THEN
711.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
712.                 CALL MapText
713.             END IF
714.         ELSE
715.             Cursor1.Y = Cursor1.Y + 1
716.         END IF
717.         q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) + 1
718.         IF (Cursor1.X > q) THEN
719.             Cursor1.X = q
720.         END IF
721.         CALL ReassignID1
722.     END IF
723.     ' PgDn
724.     IF (KH = 20736) THEN
725.         FOR k = 1 TO INT(TextHeight / 2)
726.             IF (VisibleLines > 1) THEN
727.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
728.                 CALL MapText
729.             END IF
730.         NEXT
731.         CALL ReassignID1
732.     END IF
733.     ' Insert
734.     IF (KH = 20992) THEN
735.         InsertKey = -InsertKey
736.     END IF
737.     ' Del
738.     IF (KH = 21248) THEN
739.         IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
740.             r = TheChain(ID2).Pointer
741.             q = TheChain(ID1).Lagger
742.             p = ID1
743.             CALL UnlinkRange(ID1, ID2)
744.             IF ((r = EOC) AND (q = BOC)) THEN
745.                 ID1 = p
746.                 ID2 = ID1
747.                 StartIndex = p
748.             ELSE
749.                 IF (q <> BOC) THEN ID1 = q ELSE ID1 = r
750.                 ID2 = NthP(ID1, 2)
751.             END IF
752.         END IF
753.     END IF
754.     ' F11
755.     IF (KH = 34048) THEN TextFormatting = -TextFormatting
756.     ' F12
757.     IF (KH = 34304) THEN
758.         TextWrapping = TextWrapping + 1
759.         IF (TextWrapping > 2) THEN TextWrapping = 0
760.         ID1 = StartIndex
761.         ID2 = ID1
762.         HScroll = 1
763.     END IF
764.     ' Cursor sync and autoscrolling.
765.     IF ((MH <> 0) OR (KH > 0)) THEN
766.         CALL MapText
767.         CALL CalibrateCursor(ID1)
768.         CALL CalibrateCursor(ID2)
769.         IF (Cursor1.Y > TopIndent + TextHeight - 1) THEN StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
770.     END IF
771.     _KEYCLEAR
772. END SUB
773.  
774. SUB CalibrateCursor (a AS LONG)
775.     ' Place Cursor under ID on rendered line.
776.     s = StartIndex
777.     IF ((TextWrapping = 2) AND (HScroll > 1)) THEN s = NthP(s, HScroll)
778.     c = LinearCount(s, a)
779.     k = 0
780.     i = -1
781.     FOR j = 1 TO VisibleLines
782.         n = LEN(LineAsMapped(j))
783.         IF (k + n < c) THEN
784.             k = k + n
785.         ELSE
786.             i = c - k + 1
787.             EXIT FOR
788.         END IF
789.     NEXT
790.     IF (i >= LeftIndent + LEN(LineAsMapped(j))) THEN
791.         IF (j <= VisibleLines) THEN
792.             i = 1 ' LeftIndent
793.             j = j + 1
794.             'ELSE
795.             '    i = 1 ' LeftIndent '+ LEN(LineAsMapped(j))
796.             '    j = j + 1
797.         END IF
798.     END IF
799.     IF (a = ID1) THEN
800.         Cursor1.X = LeftIndent + i
801.         Cursor1.Y = TopIndent + j
802.     END IF
803.     IF (a = ID2) THEN
804.         Cursor2.X = LeftIndent + i
805.         Cursor2.Y = TopIndent + j
806.     END IF
807. END SUB
808.  
809. FUNCTION FindID (a AS INTEGER, b AS LONG)
810.     ' Find identity under a map location.
811.     RelX = a - LeftIndent
812.     RelY = b - TopIndent
813.     FOR k = 1 TO RelY - 1
814.         t = t + LEN(LineAsMapped(k))
815.     NEXT
816.     t = t + RelX
817.     FindID = t
818. END FUNCTION
819.  
820. SUB ReassignID1
821.     ' Reassign identity under Cursor1.
822.     ID1 = NthP(StartIndex, FindID(Cursor1.X, Cursor1.Y) + (HScroll - 1))
823. END SUB
824.  
825. SUB ReassignID2
826.     ' Reassign identity under Cursor2.
827.     ID2 = NthP(StartIndex, FindID(Cursor2.X, Cursor2.Y) + (HScroll - 1))
828. END SUB
829.  
830. SUB ConvertToGrid
831.     FOR j = 1 TO VisibleLines
832.         c$ = LineAsMapped(j)
833.         FOR i = 1 TO LEN(c$) - 1 ' BR offset to exclude break return at line end.
834.             AuxGrid(i, j, 1) = MID$(c$, i, 1)
835.         NEXT
836.     NEXT
837. END SUB
838.  
839. SUB ConvertFromGrid
840.     q$ = ""
841.     FOR j = 1 TO VisibleLines
842.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
843.             q$ = q$ + AuxGrid(i, j, 1)
844.         NEXT
845.         q$ = q$ + CHR$(13) ' Undoes BR offset.
846.     NEXT
847.     Assimilate q$
848. END SUB
849.  
850. SUB GOL
851.     FOR j = 1 TO VisibleLines
852.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
853.             c$ = AuxGrid(i, j, 1)
854.             IF (c$ = " ") THEN c$ = "0" ELSE c$ = "1"
855.             AuxGrid(i, j, 1) = c$
856.             AuxGrid(i, j, 2) = c$
857.         NEXT
858.     NEXT
859.     FOR j = 2 TO VisibleLines - 2 ' BR offset.
860.         FOR i = 2 TO LEN(LineAsMapped(j)) - 2 ' BR offset.
861.             c$ = AuxGrid(i, j, 1)
862.             a1 = VAL(AuxGrid(i - 1, j + 1, 1))
863.             a2 = VAL(AuxGrid(i, j + 1, 1))
864.             a3 = VAL(AuxGrid(i + 1, j + 1, 1))
865.             a4 = VAL(AuxGrid(i - 1, j, 1))
866.             a6 = VAL(AuxGrid(i + 1, j, 1))
867.             a7 = VAL(AuxGrid(i - 1, j - 1, 1))
868.             a8 = VAL(AuxGrid(i, j - 1, 1))
869.             a9 = VAL(AuxGrid(i + 1, j - 1, 1))
870.             t = a1 + a2 + a3 + a4 + a6 + a7 + a8 + a9
871.             IF (c$ = "1") THEN
872.                 SELECT CASE t
873.                     CASE IS < 2
874.                         AuxGrid(i, j, 2) = "0"
875.                     CASE 2
876.                         AuxGrid(i, j, 2) = "1"
877.                     CASE 3
878.                         AuxGrid(i, j, 2) = "1"
879.                     CASE IS > 3
880.                         AuxGrid(i, j, 2) = "0"
881.                 END SELECT
882.             ELSE
883.                 IF (t = 3) THEN AuxGrid(i, j, 2) = "1"
884.             END IF
885.         NEXT
886.     NEXT
887.     FOR j = 1 TO VisibleLines
888.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
889.             c$ = AuxGrid(i, j, 2)
890.             IF (c$ = "0") THEN c$ = " " ELSE c$ = CHR$(219)
891.             AuxGrid(i, j, 1) = c$
892.             AuxGrid(i, j, 2) = c$
893.         NEXT
894.     NEXT
895. END SUB
896.  
897.  

------------ Old Post ----------

So I'm not sure what any of you would do in your 6th month of having no Internet access at home, occasionally clinging to the underbelly of the digital world via mobile hot spot. I can only compare this to the coder's equivalent to a silent mediation retreat. Out of the silence echoed an idea though that's about ready to share.

This post is about a new text editor - I needed a way to avoid all the foreseeable pitfalls ahead of time, which required a little thinking outside the (text) box. First is a topological comment: text is fundamentally one dimensional. The fact that we blob text into rectangles is completely a human interest - the information is really linear. We tend to forget this fact at step 1 though (without mentioning names, people tend to start with the box and work backwards to the text, amirite?)

So this is a completely different approach. There is not one big 1D array, or a screen-fitted 2D array to hang the characters on. That will get stupidly slow when your text is 50,000 characters large and you decide to paste something in the middle. This approach must completely avoid looping through arrays all the time - even some of the time.

What I do is define a type "cell" that has an address (addresses are not in linear order, or any order whatsoever, this is the key!), the content (just a single character), and then two bits of information: a "pointer", which contains the address of the next character, and a "lagger", which is the address of the previous character. To loop through the text, start at any identity and follow the pointer. This means you can insert and delete arbitrary blobs of text into the main body without bumping all the content up or down an array. It's more like adding or subtracting frames from an old movie strip.

So this program is somewhat polished and I can explain it all day, there are a ton of features engineered in: wrapping, handling absurdly long lines with no breaks, jumping around, copy+paste, etc. It uses two cursors to do everything - I've learned to be really handy with this as a general tool. A few more tweaks and I can delete Notepad. One thing I will admit is the mechanism component is probably bug free after all this testing, but there is at least one shallow off-by-one policy bug I just noticed but ran out of time to smooth out.

The program loads a default text blob, or you can click+drag other files onto the exe. For no good reason whatsoever, the character limit is 64000. I'll bump that up to infinity in the next version.

(Btw Fellippe, this is a candidate mechanism for InForm's textbox if you want it. It doesn't need to be monospace font forever either. This whole thing is less than 500 lines and half of that is policy junk you would strip off.)[/s]

[Pete]

Well it's a bit buggy but text editors are a real challenge. I had one I did not finish that was about 1600 lines in SCREEN 0. Wow, that was back in January, time flies. I know the blinking cursor needs to be programmed for other screens, so nice job there! Delete needs work for some reason. I wish I could be more specific but I just fiddled around with it a bit before shutting down and now off to put what's left of my aging intellect to bed.

Pete

[freetrav]

It's an interesting approach, and should work in theory, but its memory efficiency... well, let's just say that that phrase doesn't apply.  You might do better to acknowledge some human perception of file structure, and go with larger chunks in your linked list - if this is strictly a text editor, then chunking at the line level (Newline/CRLF as delimiter) might be the way to go; if you're planning on making it a general-purpose file editor, with separate text and binary modes, the binary mode might do better with 16- or 32-byte chunking.

[bplus]

Oh yeah! That is an interesting idea.

I knew array(s) of strings don't work but I seem to remember 20+ years ago the giant string approach working even for selecting text. Alas, code gone with the DOS. Reading someone else's beautiful monster, no fun, but 500 lines might be doable!

Nice meditation.

[STxAxTIC]

Hi guys, thanks for your hasty replies.

Pete - I didnt bother explaining the behaviors, so it wont be acting like Wordpad any time time soon. There are several "smart" cursor behaviors that will probably be confusing until you game it enough or I explain how things go. There is one actual tiny bug that I know of.

Trav - something tells me you didnt test it, or at least test its limits. Its lightning fast out of the box even with 50k characters- in this design, memory management is done on the fly, junk data does not linger. Certain hardcoded values will change once I sit down and make it handle arbitrary text sizes.

[STxAxTIC]

Thanks bplus-

Just FYI, this does not deal in giant strings. It can churn a big string into cells, and sometimes boots that way, but doesnt stay there.

(Using phone to write replies so pardon my terseness.)

[FellippeHeitor]

This is cool! A different approach, nonetheless.

I just ran it but didn't read through it yet. One of the greatest struggles I found with my preliminary multiline text box control for InForm was to handle variable-width characters, as that must be taken into account when deciding what part of the text is being displayed at what part of the screen so a click has the cursor properly placed.

I'll get back to you once I've done my homework with this.

[bplus]

Thanks bplus-

Just FYI, this does not deal in giant strings. It can churn a big string into cells, and sometimes boots that way, but doesnt stay there.

(Using phone to write replies so pardon my terseness.)

Yes, I understand not giant string, this qXed works like snake in Snake Game and Pathfinding, each cell of snake or path only knows the one before (or after) it, and yet the whole thing can be assembled as one. Great idea to apply it to strings.

On occasion, a giant string could be reassembled but what would occasion the need? Don't even need to do it for filing.

Hi Fellippe,

I wondered what the holdup was with EditBox control. Now I know, the variable width Fonts. Certainly was tricky for ListBox control getting even MONOSPACE in a predictable cell size.

[STxAxTIC]

Thanks Fellippe-

You'll see that most of the time, cursor positions are not a function of X,Y on the screen, but they follow the topology of the text. This engineers out any width calculations in that ballbark.

At other moments, you do in fact need to reverse-calculate the position under a cursor. Anticipating this from the git go, I assure its not that big a leap.

[Petr]

Nice work, Stxaxtic!

One of the greatest struggles I found with my preliminary multiline text box control for InForm was to handle variable-width characters, as that must be taken into account when deciding what part of the text is being displayed at what part of the screen so a click has the cursor properly placed.

 Invalid value _FONTWIDTH 0 is sometimes returned when it comes to working with variable characters, if you mean fonts, and the MONOSPACE type. It can be calculated as _PRINTWIDTH / LEN (Text $). Well, some fonts are displayed poorly, cut at the top and some on the right. It's just one or two pixels, but it's visible.

[FellippeHeitor]

Invalid value _FONTWIDTH 0 is sometimes returned when it comes to working with variable characters, if you mean fonts, and the MONOSPACE type. It can be calculated as _PRINTWIDTH / LEN (Text $).

InForm uses a custom text rendering set of routines (that falcon.h file that must be present in QB64's folder is the rendering library provided by Luke) and these provide an array of width data for each character printed.

Besides having that advantage, using falcon also solves the font rendering issues you mentioned:

Well, some fonts are displayed poorly, cut at the top and some on the right. It's just one or two pixels, but it's visible.

[Petr]

I see. Thank you for the information. Will the repair not be in the foreseeable future?

[FellippeHeitor]

It's deep in the C++ level, not my area. Let's wait and see if it gets incorporated eventually.

[Pete]

Started playing around with it this morning and it locked up using delete and F12 with some cursors. I could not replicate it, as I'm not keeping track of exact keystrokes at this moment. It also locked up again playing with the delete key. I had almost all of the text deleted. I see what you did using delete to remove text between the white and orange cursor. It was going great until I had only three letters left on the screen. At that point, I couldn't get any key responses. Cursor wouldn't work and I could no longer delete or type other characters.

This is generally how I go about testing my own WP creations, willy-nilly at first. I figure if it can't handle hard random typing it's buggy in more than one place. That usually gets the worst mistakes taken out but there are usually small unusual bugs that need to be addressed later. Of course I've seen irregularities in even professional programs like Notepad and Word. Some situations in WP are simply the Kobayashi Maru with how some word wrap situation get handled. I'm not the type that documents. Why? Because I hate the time it takes away from coding. If I liked documentation, I'd probably have a book of all the conditions that need to be met and the various ways to go about designing a WP by now. I've played around with single strings when QB64 came out. QB45 couldn't handle that. I have also used RA files and arrays. They all have there pluses and minuses but require different coding approaches, which makes it fun to try different approaches.

I would disagree on how you position your cursor for backspace. In Open Office you can press INSERT to make the | cursor a square. Now you can overwrite characters. So if you place the cursor square over a letter and use backspace, it eliminates the letter behind the cursor and the cursor moves back one space. Your WP actually eliminates the letter under the cursor and then drags the remains back one space. Your method works, but I'd call it unusual.

I just got an error 5 at line 128 when playing around with the right scroll bar. I was using the mouse to move it up and down and mouse and it threw the error at one of the many times I had the scroll bar pulled all the way to the bottom of the screen.

Why is cursor down so random between paragraphs? Put the cursor at the end of line one and continuously cursor all the way down through the paragraphs. I expected it to either stay in the column, stay at the left edge, or go to the right margin when it moved down to the new paragraph. Conversely, cursor up is refuses to jump up to the above paragraph immediately. Instead when the cursor is somewhere in the middle of the start of a paragraph, pressing cursor up acts as if cursor left was pressed. This continues until it reaches the right margin, then another cursor up press finally gets the cursor to go up. If that's the way you intended it to act, why did you not make the cursor down key work in the reverse fashion?

Here's more unexpected behavior. Start the program and mouse click to the "]" in "multiplex" near the right bottom of the screen. Now either cursor down or mouse click directly down under the "]" (which is a black blank space). Anyway, the cursor re-appears not on the next line, but two lines down and not on the first letter, but on the second, the "e" in metaphysics.

One final thing, programming a WP should come with a warning label. Caution, may cause significant hair loss and Transient Tourette Syndrome. If you can handle the ******* baldness, you will eventually have it ready for prime time.

Pete

[TerryRitchie]

One final thing, programming a WP should come with a warning label. Caution, may cause significant hair loss and Transient Tourette Syndrome. If you can handle the ******* baldness, you will eventually have it ready for prime time.

Pete

I've always found processing text to be a hair-raising experience.

I find it to be a paradox in programming. Text "looks" easy to manipulate while graphics "looks" difficult. I find it to be the exact opposite.