External ASCII Chart

[SMcNeill]

Since a lot of folks here didn't seem to know about QB64's in-built ASCII chart, I can only assume that they also don't know the history of the chart...   

When I was working on my IDE several years back, I tried to think of all the features that I'd like for it to have that QB64 didn't have.  The ASCII chart was one of those features, as well as the Math Calculator which is currently used for both CONST evaluation and the Math function available under Help.

Once I'd gotten them working in StevesIDE, I made certain to make them as portable as I possibly could, and then I worked around with adding them into QB64 for everyone.  At first, both routines used external calls to stand-alone programs, which QB64 shelled out to, and then used the SHELL return value inside QB64 itself.  You can still see the comment where this happened if you look inside the QB64 source at the current version of ideASCIIchart:

    'IF INSTR(_OS$, "WIN") THEN ret% = SHELL("internal\ASCII-Picker.exe") ELSE ret% = SHELL("internal/ASCII-Picker")

This worked fine back in the SDL days, but somehow it got broken for Linux users once we swapped to over to the GL version.  You could select SPACE (value 32) in Linux, and sometimes it'd give a return value of 214, or something equally odd.  That glitch was never sorted out properly, as it seemed OS specific to certain versions of Linux only, and instead the ASCII chart was modified to work directly with QB64's internal strings -- which is how it currently exists today.  (Whether SHELL's return values are still broken for Linux, I couldn't tell you.  Somebody else, with a Linux machine, would have to test that out to see.)

Personally, I like the in-built ASCII chart QB64 has.  Gives values as well as being clickable and selectable!  Found happily enough under the Help tab, on the top right of the IDE.

Oh my goodness, I did not even see this, LOL. Yes, it is handy. Is there a way it can be made to appear without losing the code window though?

Since folks have been asking about making it appear without losing the code window, that's a simple enough request which I can easily give a response to: SURE IT CAN!!  WOOT!!WOOT!!

After all, it was an external program, completely independent to QB64 itself, to begin with....

Code: QB64: [Select]

1. _TITLE "External ASCII Picker"
2. SCREEN _NEWIMAGE(640, 480, 32)
3. f = _LOADFONT("cour.ttf", 128) 'a nice large display font, not a 100% match to QB64's inbuilt version,
4. _FONT f '                       but it works easily here for a demo highlight character
5.  
6.  
7.  
8. _CONTROLCHR OFF
9. DO
10.     _CLIPBOARD$ = ASCIIbox$ 'get an ASCII character
11.     CLS
12.     PRINT _CLIPBOARD$ 'preview it
13.     SLEEP: _KEYCLEAR 'hit a key to select another
14. LOOP UNTIL RIGHT$(out$, 1) = CHR$(27)
15.  
16. FUNCTION ASCIIbox$
17.     STATIC temp AS LONG, temp1 AS LONG, ws AS LONG
18.     d = _DEST
19.     font = _FONT
20.     IF temp = 0 THEN 'static backgrounds so we don't have to make them over and over, or worry about freeing them
21.         temp = _NEWIMAGE(640, 480, 32)
22.         temp1 = _NEWIMAGE(640, 480, 32)
23.         ws = _NEWIMAGE(640, 480, 32)
24.     END IF
25.     SCREEN temp
26.     DIM CurrentASC(1 TO 16, 1 TO 16)
27.     DIM CurrentOne AS INTEGER
28.     CLS , _RGB(0, 0, 170)
29.     COLOR , _RGB(0, 0, 170)
30.     FOR y = 1 TO 16
31.         FOR x = 1 TO 16
32.             LINE (x * 40, 0)-(x * 40, 480), _RGB32(255, 255, 0)
33.             LINE (0, y * 30)-(640, y * 30), _RGB32(255, 255, 0)
34.             IF counter THEN _PRINTSTRING (x * 40 - 28, y * 30 - 23), CHR$(counter)
35.             counter = counter + 1
36.         NEXT
37.     NEXT
38.  
39.     _DEST temp1
40.     CLS , _RGB(0, 0, 170)
41.     COLOR , _RGB(0, 0, 170)
42.     counter = 0
43.     FOR y = 1 TO 16
44.         FOR x = 1 TO 16
45.             LINE (x * 40, 0)-(x * 40, 480), _RGB32(255, 255, 0)
46.             LINE (0, y * 30)-(640, y * 30), _RGB32(255, 255, 0)
47.             text$ = LTRIM$(STR$(counter))
48.             IF counter THEN _PRINTSTRING (x * 40 - 24 - (LEN(text$)) * 4, y * 30 - 23), text$
49.             counter = counter + 1
50.         NEXT
51.     NEXT
52.     _DEST temp
53.  
54.     x = 1: y = 1
55.     _PUTIMAGE , temp, ws
56.     DO: LOOP WHILE _MOUSEINPUT 'clear the mouse input buffer
57.     oldmousex = _MOUSEX: oldmousey = _MOUSEY
58.  
59.     DO
60.         _LIMIT 60
61.         DO: LOOP WHILE _MOUSEINPUT
62.         IF oldx <> _MOUSEX AND oldy <> _MOUSEY THEN
63.             x = _MOUSEX \ 40 + 1 'If mouse moved, where are we now?
64.             y = _MOUSEY \ 30 + 1
65.         END IF
66.         oldx = _MOUSEX: oldy = _MOUSEY
67.  
68.         num = (y - 1) * 16 + x - 1
69.         IF num = 0 THEN
70.             text$ = ""
71.         ELSE
72.             flashcounter = flashcounter + 1
73.             IF flashcounter > 30 THEN
74.                 COLOR _RGB32(255, 255, 255), _RGB(0, 0, 170)
75.                 text$ = CHR$(num)
76.                 IF LEN(text$) = 1 THEN text$ = " " + text$ + " "
77.             ELSE
78.                 COLOR _RGB32(255, 255, 255), _RGB(0, 0, 170)
79.                 text$ = RTRIM$(LTRIM$(STR$(num)))
80.             END IF
81.         END IF
82.         IF flashcounter = 60 THEN flashcounter = 1
83.         CLS
84.         IF toggle THEN _PUTIMAGE , temp1, temp ELSE _PUTIMAGE , ws, temp
85.         _PRINTSTRING (x * 40 - 24 - (LEN(text$)) * 4, y * 30 - 23), text$
86.         LINE (x * 40 - 40, y * 30 - 30)-(x * 40, y * 30), _RGBA32(255, 255, 255, 150), BF
87.  
88.         k1 = _KEYHIT
89.         MouseClick = 0: MouseExit = 0
90.         IF MouseButtonSwapped THEN
91.             MouseClick = _MOUSEBUTTON(2): MouseExit = _MOUSEBUTTON(1)
92.         ELSE
93.             MouseClick = _MOUSEBUTTON(1): MouseExit = _MOUSEBUTTON(2)
94.         END IF
95.         SELECT CASE k1
96.             CASE 13: EXIT DO
97.             CASE 27
98.                 GOTO cleanexit
99.             CASE 32: toggle = NOT toggle
100.             CASE 18432: y = y - 1
101.             CASE 19200: x = x - 1
102.             CASE 20480: y = y + 1
103.             CASE 19712: x = x + 1
104.         END SELECT
105.  
106.         IF x < 1 THEN x = 1
107.         IF x > 16 THEN x = 16
108.         IF y < 1 THEN y = 1
109.         IF y > 16 THEN y = 16
110.         _DISPLAY
111.         IF MouseExit GOTO cleanexit
112.     LOOP UNTIL MouseClick
113.  
114.     ret% = (y - 1) * 16 + x - 1
115.     IF ret% > 0 AND ret% < 255 THEN
116.         ASCIIbox$ = CHR$(ret%)
117.     END IF
118.     cleanexit:
119.     _AUTODISPLAY
120.  
121.     SCREEN d
122.     _FONT font
123.     _DEST 0: _DELAY .2
124.  
125. END FUNCTION
126.  

Run the above and we get the ASCII Chart we all know and love.  (And if someone didn't know it, they do now, and I'm certain they'll love it...)  Choose a character, it'll copy to your clipboard, where it should paste into whichever program you need it to -- including QB64.

It's not quite as simple as Click-To-Insert, as it's Click-To-Clipboard, but it does have the added advantage of staying up for those times when you simply need to know what character corresponds to what value.  Feel free to save it and use it for all you ASCII needs.  :)

Edit: Cleaned up the code just a bit since it doesn't have to work just for SCREEN 0, like with QB64's IDE.  Also loaded a larger font for display purposes, just for the heck of it.  :P

[TerryRitchie]

Woot! Woot!

Now have ASCII_Chart.exe on my desktop whenever I need it.

[Dav]

Hey Steve!  I remember your IDE and chart.  I still have them on my old laptop.  Handy chart.  I'll be using it.

- Dav