Helicopter blades

[TerryRitchie]

I was working on an idea for helicopter blades tonight for a game similar to: http://www.helicopter-game.org/

I thought instead of using a sprite sheet why not mathematically draw them and then store them in images instead of using a sprite sheet. Below is the result which I though I would share because the routine may be useful to others. Right now it looks like a ceiling fan spinning casting a shadow, LOL.

Code: QB64: [Select]

1. '
2. ' Helicopter blades idea
3.  
4. CONST PI = 3.1415926
5.  
6. start = -.00000001
7. finish = -2 * PI / 16
8. steps = finish / 20
9. inc = -.0981726875
10.  
11. SCREEN _NEWIMAGE(640, 480, 32)
12. CLS
13.  
14. DO
15.     FOR j = 0 TO 15
16.         _LIMIT 30
17.         CIRCLE (319, 239), 35, _RGB(25, 76, 127), , , .35
18.         PAINT (319, 239), _RGB(25, 76, 127), _RGB(25, 76, 127)
19.         FOR i = start + (inc * j) TO finish + (inc * j) STEP steps
20.             FOR k = 0 TO 3
21.                 radian = i + k * -1.5707963
22.                 IF radian < -2 * PI THEN radian = radian + 2 * PI
23.                 CIRCLE (319, 239), 35, _RGB(12, 38, 88), radian, radian, .35
24.                 CIRCLE (319, 209), 35, _RGB(12, 38, 88), radian, radian, .35
25.             NEXT k
26.         NEXT i
27.         _DISPLAY
28.         CLS
29.     NEXT j
30. LOOP

[bplus]

Nice!

[johnno56]

Very nicely done... and I even like the colour...

J

[bplus]

I made blades rectangular and then played with code some more. :)

Code: QB64: [Select]

1. '
2. ' Helicopter blades idea started by Terry Ritchie mods by B+ 2018-08-31
3.  
4. CONST PI = 3.1415926
5.  
6. start = -.00000001
7. finish = -2 * PI / 16
8. steps = finish / 20
9. inc = -.0981726875
10.  
11. SCREEN _NEWIMAGE(640, 480, 32)
12. CLS
13.  
14. 'DO
15. _MOUSEHIDE
16. WHILE _KEYDOWN(27) = 0
17.     a = a + _PI(1.111)
18.     IF a > _PI(2) THEN a = a - _PI(2)
19.     CLS
20.     CIRCLE (mx, 380), 150, _RGB(25, 76, 127), , , .35
21.     PAINT (mx, 380), _RGB(25, 76, 127), _RGB(25, 76, 127)
22.     'FOR i = start + (inc * j) TO finish + (inc * j) STEP steps
23.     FOR k = 0 TO 3
24.         radian = a + k * -1.5707963
25.         IF radian < -2 * PI THEN radian = radian + 2 * PI
26.         x1 = mx + 15 * COS(radian)
27.         y1 = my + .35 * 15 * SIN(radian)
28.         y3 = 380 + .35 * 15 * SIN(radian)
29.         x2 = mx + 135 * COS(radian)
30.         y2 = my + .35 * 135 * SIN(radian)
31.         y4 = 380 + .35 * 135 * SIN(radian)
32.         'CIRCLE (319, 239), 35, _RGB(12, 38, 88), radian, radian, .35
33.         'CIRCLE (319, 209), 35, _RGB(12, 38, 88), radian, radian, .35
34.         thic x1, y1, x2, y2, 5, _RGB32(25, 76, 127)
35.         thic x1, y3, x2, y4, 5, _RGB32(0, 0, 0)
36.     NEXT k
37.     'NEXT i
38.     PRINT speed
39.     _DISPLAY
40.     WHILE _MOUSEINPUT: WEND
41.     my = _MOUSEY: mx = _MOUSEX
42.     IF my <> 0 THEN speed = 60 * (480 - my) / 480 ELSE speed = 30
43.     _LIMIT speed
44.     '_DELAY speed
45. WEND
46. 'LOOP
47.  
48. SUB thic (x1, y1, x2, y2, thick, K AS _UNSIGNED LONG)
49.     t2 = thick / 2
50.     IF t2 < 1 THEN t2 = 1
51.     a = _ATAN2(y2 - y1, x2 - x1)
52.     x3 = x1 + t2 * COS(a + _PI(.5))
53.     y3 = y1 + t2 * SIN(a + _PI(.5))
54.     x4 = x1 + t2 * COS(a - _PI(.5))
55.     y4 = y1 + t2 * SIN(a - _PI(.5))
56.     x5 = x2 + t2 * COS(a + _PI(.5))
57.     y5 = y2 + t2 * SIN(a + _PI(.5))
58.     x6 = x2 + t2 * COS(a - _PI(.5))
59.     y6 = y2 + t2 * SIN(a - _PI(.5))
60.     ftri x6, y6, x4, y4, x3, y3, K
61.     ftri x3, y3, x5, y5, x6, y6, K
62. END SUB
63.  
64. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
65. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
66.     a& = _NEWIMAGE(1, 1, 32)
67.     _DEST a&
68.     PSET (0, 0), K
69.     _DEST 0
70.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
71.     _FREEIMAGE a& '<<< this is important!
72. END SUB
73.  
74.  

[FellippeHeitor]

Looking really good, gentlemen.

[bplus]

Thanks, I though about changing the aspect of the ellipse and blade width according my relation to horizon but decided to have lunch instead. :)

[TerryRitchie]

I made blades rectangular and then played with code some more. :)

Cool!

[bplus]

Here is my post lunch launch post:

Code: QB64: [Select]

1. '
2. ' Mod 2  Helicopter blades idea started by Terry Ritchie mods by B+ 2018-08-31
3.  
4. CONST PI = 3.1415926
5. CONST horizon = 300
6. CONST WW = 800
7. CONST WH = 600
8. start = -.00000001
9. finish = -2 * PI / 16
10. steps = finish / 20
11. inc = -.0981726875
12.  
13. SCREEN _NEWIMAGE(WW, WH, 32)
14. _SCREENMOVE 250, 50
15. CLS
16.  
17.  
18. _MOUSEHIDE
19. WHILE _KEYDOWN(27) = 0
20.     a = a + _PI(1.111)
21.     IF a > _PI(2) THEN a = a - _PI(2)
22.     aspect = ABS(horizon - my) / (WH * .5)
23.     IF aspect > .35 THEN aspect = .35
24.     bladeWidth = 20 * aspect
25.     CLS
26.     FOR i = 0 TO horizon
27.         midInk 0, 0, 128, 200, 200, 255, i / horizon
28.         LINE (0, i)-(WW, i)
29.     NEXT
30.     FOR i = horizon% TO WH
31.         midInk 50, 200, 50, 50, 128, 50, (i - horizon) / (WH - horizon)
32.         LINE (0, i)-(WW, i)
33.     NEXT
34.     FOR k = 0 TO 3
35.         radian = a + k * -1.5707963
36.         IF radian < -2 * PI THEN radian = radian + 2 * PI
37.         x1 = mx + 15 * COS(radian)
38.         y1 = my + aspect * 15 * SIN(radian)
39.         y3 = WH - .35 * 150 + .35 * 15 * SIN(radian)
40.         x2 = mx + 135 * COS(radian)
41.         y2 = my + aspect * 135 * SIN(radian)
42.         y4 = WH - .35 * 150 + .35 * 135 * SIN(radian)
43.         IF my > horizon THEN c~& = _RGB32(255, 255, 255) ELSE c~& = _RGB32(60, 60, 60)
44.         thic x1, y1, x2, y2, bladeWidth, c~&
45.         thic x1, y3, x2, y4, 20 * .35, _RGB32(0, 0, 0)
46.         _DISPLAY
47.     NEXT k
48.     PRINT speed
49.     _DISPLAY
50.     WHILE _MOUSEINPUT: WEND
51.     my = _MOUSEY: mx = _MOUSEX
52.     IF my <> 0 THEN speed = 60 * (WH - my) / WH ELSE speed = 30
53.     _LIMIT speed
54. WEND
55.  
56.  
57. SUB thic (x1, y1, x2, y2, thick, K AS _UNSIGNED LONG)
58.     t2 = thick / 2
59.     IF t2 < 1 THEN t2 = 1
60.     a = _ATAN2(y2 - y1, x2 - x1)
61.     x3 = x1 + t2 * COS(a + _PI(.5))
62.     y3 = y1 + t2 * SIN(a + _PI(.5))
63.     x4 = x1 + t2 * COS(a - _PI(.5))
64.     y4 = y1 + t2 * SIN(a - _PI(.5))
65.     x5 = x2 + t2 * COS(a + _PI(.5))
66.     y5 = y2 + t2 * SIN(a + _PI(.5))
67.     x6 = x2 + t2 * COS(a - _PI(.5))
68.     y6 = y2 + t2 * SIN(a - _PI(.5))
69.     ftri x6, y6, x4, y4, x3, y3, K
70.     ftri x3, y3, x5, y5, x6, y6, K
71. END SUB
72.  
73. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
74. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
75.     a& = _NEWIMAGE(1, 1, 32)
76.     _DEST a&
77.     PSET (0, 0), K
78.     _DEST 0
79.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
80.     _FREEIMAGE a& '<<< this is important!
81. END SUB
82.  
83. SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
84.     COLOR _RGB(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
85. END SUB
86.  
87.  

[TerryRitchie]

Your math-fu astounds me. I wish I had your mathematical chops.

[bplus]

Your math-fu astounds me. I wish I had your mathematical chops.

Yes, math can be fun, so is inspiring others. I admire your tutorial efforts.

[STxAxTIC]

Your math-fu astounds me. I wish I had your mathematical chops.

Pun intended?

[TerryRitchie]

Your math-fu astounds me. I wish I had your mathematical chops.

Pun intended?

No, lol, the cut-elimination theorem is beyond my chops. :)