Mastering InForm: method to deal with a continuous loop

[Qwerkey]

Today's Problem - How to do a calculation loop whilst still updating in SUB __UI_BeforeUpdateDisplay

Fellippe, in my Trackword program post, you mentioned that any continuous process initiated by a SUB __UI_Click event would not interfere with the ongoing InForm processing in SUB __UI_BeforeUpdateDisplay, thus giving a kind of multithreading which will be what I require for the Gravitation program.

TIMERs are QB64's way of multithreading if you will, which means that even while the calculations are going on in SUB __UI_Click, which was fired by the __UI_EventsTimer, the interface keeps on being updated because __UI_RefreshTimer keeps being fired at ~30fps (or as otherwise set by the SetFrameRate method).

In the Gravitation program, a Click of the Execute button (event CASE ExecuteBT) will initiate a high CPU usage calculation loop.  In the attached program, which will work with the Form already supplied, when the calculation is triggered (a very simple but continuous loop in this trial) the InForm display goes into a freeze mode.

Is there actually a method to deal with a continuous loop (where I imagine the program will "stay" and not get to antywhere else until the loop is finished)?

Code: QB64: [Select]

1. ': This program uses
2. ': InForm - GUI library for QB64 - Beta version 7
3. ': Fellippe Heitor, 2016-2018 - fellippe@qb64.org - @fellippeheitor
4. ': https://github.com/FellippeHeitor/InForm
5. '-----------------------------------------------------------
6.  
7. ': Controls' IDs: ------------------------------------------------------------------
8. REM NOTICE: THIS FORM HAS BEEN RECENTLY EDITED
9. '>> The controls in the list below may have been added or renamed,
10. '>> and previously existing controls may have been deleted since
11. '>> this program's structure was first generated.
12. '>> Make sure to check your code in the events SUBs so that
13. '>> you can take your recent edits into consideration.
14. ': ---------------------------------------------------------------------------------
15. DIM SHARED GravitationSimulation AS LONG
16. DIM SHARED SimulationTypeFR AS LONG
17. DIM SHARED BodyDataFR AS LONG
18. DIM SHARED GravitationalCollapseFR AS LONG
19. DIM SHARED PictureBox1 AS LONG
20. DIM SHARED ExitBT AS LONG
21. DIM SHARED CauseBT AS LONG
22. DIM SHARED ExecuteBT AS LONG
23. DIM SHARED SolarSystemRB AS LONG
24. DIM SHARED BodyManualRB AS LONG
25. DIM SHARED GravitationalCollapseRB AS LONG
26. DIM SHARED LoadFromFileRB AS LONG
27. DIM SHARED DemonstrationRB AS LONG
28. DIM SHARED GravitationalConstantFR AS LONG
29. DIM SHARED GravitationalConstantLB AS LONG
30. DIM SHARED GravitationalConstantTB AS LONG
31. DIM SHARED Earth&, DispCalc`
32. CONST Thirty%% = 30
33.  
34. ': External modules: ---------------------------------------------------------------
35. '$INCLUDE:'InForm\InForm.ui'
36. '$INCLUDE:'InForm\xp.uitheme'
37. '$INCLUDE:'GravitationSimulation.frm'
38.  
39. ': Event procedures: ---------------------------------------------------------------
40. SUB __UI_BeforeInit
41.     Earth& = _LOADIMAGE("The Earth.png", 32)
42.  
43.     OPEN "temp.txt" FOR OUTPUT AS #1 '!!! Temporary
44.  
45. END SUB
46.  
47. SUB __UI_OnLoad
48.     _SCREENMOVE 0, 0
49.     '!!! Ought to be able to set these in UIEditor
50.     Control(BodyDataFR).Disabled = True
51.     Control(GravitationalCollapseFR).Disabled = True
52.     DispCalc` = True
53.     SetFrameRate Thirty%%
54. END SUB
55.  
56. SUB __UI_BeforeUpdateDisplay
57.     'This event occurs at approximately 30 frames per second.
58.     'You can change the update frequency by calling SetFrameRate DesiredRate%
59.  
60.  
61.     IF DispCalc` THEN
62.         '!!! Temp
63.         NoBodiesLess1% = 11
64.         DIM GlobalArray#(NoBodiesLess1%, 3)
65.         GlobalArray#(0, 3) = 1
66.         GlobalArray#(1, 3) = 2
67.         GlobalArray#(0, 0) = 5
68.  
69.         'Use local array from global to display only >0 mass bodies in z-dimension order
70.         DIM LocalArray!(NoBodiesLess1%, 2)
71.  
72.         NoVisible% = 0
73.         FOR N% = 0 TO NoBodiesLess1%
74.             IF GlobalArray#(N%, 3) <> 0 THEN
75.                 FOR M%% = 0 TO 2
76.                     LocalArray!(NoVisible%, M%%) = GlobalArray#(N%, M%%) '!!! Or whatever index value is correct
77.                 NEXT M%%
78.                 NoVisible% = NoVisible% + 1
79.             END IF
80.         NEXT N%
81.  
82.         'FOR N% = 0 TO NoVisible% - 1
83.         '    PRINT #1, N%, LocalArray!(N%, 0)
84.         'NEXT N%
85.         'PRINT #1, ""
86.  
87.         IF NoVisible% >= 2 THEN
88.  
89.             'Now order visible bodies
90.             'To order based upon z-dimension
91.             '!!! NB Here, x- is out of screen, y- is left to right, z_ is botton to top (old coordinate system)
92.             ' dblA#() is the array used here, not in the calculations routine
93.             Jump% = 1 'fio To order based upon x-distance: this doesn't seem to slowdown calculation too much.
94.             WHILE Jump% <= NoVisible% - 1: Jump% = Jump% * 2: WEND
95.             'Have to do this every time as collisions change NoBodiesLess1%
96.             WHILE Jump% > 1
97.                 Jump% = (Jump% - 1) \ 2
98.                 Finis` = False
99.                 WHILE NOT Finis`
100.                     Finis` = True
101.                     FOR Upper% = 0 TO NoVisible% - 1 - Jump%
102.                         Lower% = Upper% + Jump%
103.                         'IF dblA#(intKeep%(Upper%, 3), 1) > dblA#(intKeep%(Lower%, 3), 1) THEN
104.                         '    SWAP intKeep%(Upper%, 3), intKeep%(Lower%, 3)
105.                         '    Finis` = False
106.                         'END IF
107.                         IF LocalArray!(Upper%, 1) > LocalArray!(Lower%, 1) THEN
108.                             SWAP LocalArray!(Upper%, 1), LocalArray!(Lower%, 1)
109.                             Finis` = False
110.                         END IF
111.                     NEXT Upper%
112.                 WEND
113.             WEND
114.  
115.             BeginDraw PictureBox1 'Replace PictureBox1 with the actual ID of the desired PictureBox
116.             'Drawing code goes here
117.  
118.             CLS '!!! Need this if image is (software)
119.  
120.             '_DISPLAYORDER _HARDWARE '!!! This doesn't work
121.  
122.             IF Caption(CauseBT) = "Cause" THEN
123.                 _PUTIMAGE (200, 200), Earth&
124.                 '_MAPTRIANGLE (0, 0)-(260, 0)-(0, 253), Earth& TO(200, 200, -400)-(460, 0, -400)-(200, 453, -400) '261x254
125.                 '!!! _MAPTRIANGLE(3D) doesn't work in InForm
126.             END IF
127.             EndDraw PictureBox1
128.  
129.         ELSE
130.             '!!! Not enough bodies to carry on
131.             '!!! Or do we do this assessment elsewhere?
132.         END IF
133.  
134.     END IF
135.  
136. END SUB
137.  
138. SUB __UI_BeforeUnload
139.     'If you set __UI_UnloadSignal = False here you can
140.     'cancel the user's request to close.
141.  
142. END SUB
143.  
144. SUB __UI_Click (id AS LONG)
145.     SELECT CASE id
146.         CASE GravitationSimulation
147.  
148.         CASE ExitBT
149.  
150.             CLOSE #1 '!!! Temporary
151.  
152.             SYSTEM
153.         CASE CauseBT
154.             IF Caption(CauseBT) = "Cause" THEN
155.                 Caption(CauseBT) = "Effect"
156.                 Control(SimulationTypeFR).Hidden = False
157.                 Control(SimulationTypeFR).Disabled = False
158.             ELSE
159.                 Caption(CauseBT) = "Cause"
160.             END IF
161.  
162.         CASE ExecuteBT
163.  
164.             Control(SimulationTypeFR).Hidden = True
165.             Control(SimulationTypeFR).Disabled = True
166.             '!!! And other Frames
167.  
168.             DoCalc` = True
169.             WHILE DoCalc`
170.                 _LIMIT 3000
171.                 A# = 2E24 * (3.6 ^ 5)
172.                 B# = 2345.67 * RND
173.                 C# = B# * A# / ATN(1)
174.             WEND
175.  
176.         CASE SolarSystemRB
177.  
178.             'PRINT #1, Control(SolarSystemRB).Value
179.             'PRINT #1, Control(BodyManualRB).Value
180.             'PRINT #1, Control(GravitationalCollapseRB).Value
181.             'PRINT #1, Control(LoadFromFileRB).Value
182.             'PRINT #1, Control(DemonstrationRB).Value
183.  
184.             'Hidden/NotHidden 11-Body, GravitationalCollapse Input Forms
185.             IF Control(BodyManualRB).Value = True THEN
186.                 Control(BodyDataFR).Hidden = False
187.                 Control(BodyDataFR).Disabled = False
188.             ELSE
189.                 Control(BodyDataFR).Hidden = True
190.                 Control(BodyDataFR).Disabled = True
191.             END IF
192.             IF Control(GravitationalCollapseRB).Value = True THEN
193.                 Control(GravitationalCollapseFR).Hidden = False
194.                 Control(GravitationalCollapseFR).Disabled = False
195.             ELSE
196.                 Control(GravitationalCollapseFR).Hidden = True
197.                 Control(GravitationalCollapseFR).Disabled = True
198.             END IF
199.  
200.         CASE BodyManualRB
201.  
202.             IF Control(BodyManualRB).Value = True THEN
203.                 Control(BodyDataFR).Hidden = False
204.                 Control(BodyDataFR).Disabled = False
205.             ELSE
206.                 Control(BodyDataFR).Hidden = True
207.                 Control(BodyDataFR).Disabled = True
208.             END IF
209.             IF Control(GravitationalCollapseRB).Value = True THEN
210.                 Control(GravitationalCollapseFR).Hidden = False
211.                 Control(GravitationalCollapseFR).Disabled = False
212.             ELSE
213.                 Control(GravitationalCollapseFR).Hidden = True
214.                 Control(GravitationalCollapseFR).Disabled = True
215.             END IF
216.  
217.         CASE GravitationalCollapseRB
218.  
219.             IF Control(BodyManualRB).Value = True THEN
220.                 Control(BodyDataFR).Hidden = False
221.                 Control(BodyDataFR).Disabled = False
222.             ELSE
223.                 Control(BodyDataFR).Hidden = True
224.                 Control(BodyDataFR).Disabled = True
225.             END IF
226.             IF Control(GravitationalCollapseRB).Value = True THEN
227.                 Control(GravitationalCollapseFR).Hidden = False
228.                 Control(GravitationalCollapseFR).Disabled = False
229.             ELSE
230.                 Control(GravitationalCollapseFR).Hidden = True
231.                 Control(GravitationalCollapseFR).Disabled = True
232.             END IF
233.  
234.         CASE LoadFromFileRB
235.  
236.             IF Control(BodyManualRB).Value = True THEN
237.                 Control(BodyDataFR).Hidden = False
238.                 Control(BodyDataFR).Disabled = False
239.             ELSE
240.                 Control(BodyDataFR).Hidden = True
241.                 Control(BodyDataFR).Disabled = True
242.             END IF
243.             IF Control(GravitationalCollapseRB).Value = True THEN
244.                 Control(GravitationalCollapseFR).Hidden = False
245.                 Control(GravitationalCollapseFR).Disabled = False
246.             ELSE
247.                 Control(GravitationalCollapseFR).Hidden = True
248.                 Control(GravitationalCollapseFR).Disabled = True
249.             END IF
250.  
251.         CASE DemonstrationRB
252.  
253.             IF Control(BodyManualRB).Value = True THEN
254.                 Control(BodyDataFR).Hidden = False
255.                 Control(BodyDataFR).Disabled = False
256.             ELSE
257.                 Control(BodyDataFR).Hidden = True
258.                 Control(BodyDataFR).Disabled = True
259.             END IF
260.             IF Control(GravitationalCollapseRB).Value = True THEN
261.                 Control(GravitationalCollapseFR).Hidden = False
262.                 Control(GravitationalCollapseFR).Disabled = False
263.             ELSE
264.                 Control(GravitationalCollapseFR).Hidden = True
265.                 Control(GravitationalCollapseFR).Disabled = True
266.             END IF
267.  
268.     END SELECT
269.  
270. END SUB
271.  
272. SUB __UI_MouseEnter (id AS LONG)
273.     SELECT CASE id
274.         CASE GravitationSimulation
275.  
276.     END SELECT
277. END SUB
278.  
279. SUB __UI_MouseLeave (id AS LONG)
280.     SELECT CASE id
281.         CASE GravitationSimulation
282.  
283.     END SELECT
284. END SUB
285.  
286. SUB __UI_FocusIn (id AS LONG)
287.     SELECT CASE id
288.     END SELECT
289. END SUB
290.  
291. SUB __UI_FocusOut (id AS LONG)
292.     'This event occurs right before a control loses focus.
293.     'To prevent a control from losing focus, set __UI_KeepFocus = True below.
294.     SELECT CASE id
295.     END SELECT
296. END SUB
297.  
298. SUB __UI_MouseDown (id AS LONG)
299.     SELECT CASE id
300.         CASE GravitationSimulation
301.  
302.     END SELECT
303. END SUB
304.  
305. SUB __UI_MouseUp (id AS LONG)
306.     SELECT CASE id
307.         CASE GravitationSimulation
308.  
309.     END SELECT
310. END SUB
311.  
312. SUB __UI_KeyPress (id AS LONG)
313.     'When this event is fired, __UI_KeyHit will contain the code of the key hit.
314.     'You can change it and even cancel it by making it = 0
315.     SELECT CASE id
316.     END SELECT
317. END SUB
318.  
319. SUB __UI_TextChanged (id AS LONG)
320.     SELECT CASE id
321.     END SELECT
322. END SUB
323.  
324. SUB __UI_ValueChanged (id AS LONG)
325.     SELECT CASE id
326.         CASE SolarSystemRB
327.  
328.         CASE BodyManualRB
329.  
330.         CASE GravitationalCollapseRB
331.  
332.         CASE LoadFromFileRB
333.  
334.         CASE DemonstrationRB
335.  
336.     END SELECT
337. END SUB
338.  
339. SUB __UI_FormResized
340.  
341. END SUB
342.  
343.  

Richard

[FellippeHeitor]

Hi Richard,

You just add a call to __UI_DoEvents inside the LOOP that will hog your program for a while. I may have forgotten to mention it in InForm's wiki, sorry about that.

A progress bar is highly recommended here.

Another thing: you'll want a flag to allow the ExecuteBT button to remain unresponsive while calculation takes place so that the action doesn't get inadvertently restarted by the user. And also make the button's .Disabled property = True.

Please check out the mock up program I'm attaching to show what I mean in practice.

Fellippe.

[Qwerkey]

Thank you, Fellipppe.  I see that you have renamed the title to be a general Inform learning exercise.  Noting the standard of your principal student, a better title might have been "Making a Dog's Dinner of Inform".

Making a Dog's Dinner of ... -  British English for a general mess

Richard

[Qwerkey]

Hi Richard,

You just add a call to __UI_DoEvents inside the LOOP

Yep, that works.  Thank you.

Another thing: you'll want a flag to allow the ExecuteBT button to remain unresponsive while calculation takes place so that the action doesn't get inadvertently restarted by the user. And also make the button's .Disabled property = True.

I expect that the Execute Button will transform into a Stop Button when the simulation is running.

Richard

[Qwerkey]

I expect that the Execute Button will transform into a Stop Button when the simulation is running.

Ah!  Another Button (in place of the Execute Button) will be required to stop the loop.

[FellippeHeitor]

I expect that the Execute Button will transform into a Stop Button when the simulation is running.

Ah!  Another Button (in place of the Execute Button) will be required to stop the loop.

You most definitely do not need that extra button. I added it in for good measure, but here's the same program above with StartBT serving both to start and cancel the process. This one never even shows CancelBT (just replace event SUB __UI_Click):

Code: QB64: [Select]

1. SUB __UI_Click (id AS LONG)
2.     STATIC DoingIt AS _BYTE 'Flag to indicate a LOOP is being run
3.  
4.     SELECT CASE id
5.         CASE IntenseCalculator
6.  
7.         CASE QuitBT
8.             SYSTEM
9.         CASE StartBT
10.             IF NOT DoingIt THEN
11.                 PrevCaption$ = Caption(StartBT)
12.                 Caption(StartBT) = "Cancel"
13.                 Caption(PB) = "Locating stars in observable universe... \#"
14.                 DoingIt = True
15.                 Control(PB).Hidden = False
16.                 Control(PB).Value = 0
17.                 BeginDraw PictureBox1
18.                 CLS
19.                 EndDraw PictureBox1
20.                 StartTime! = TIMER
21.                 DO
22.                     Control(PB).Value = Control(PB).Value + 1
23.  
24.                     BeginDraw PictureBox1
25.                     PSET (RND * _WIDTH, RND * _HEIGHT), _RGB32(RND * 255, RND * 255, RND * 255)
26.                     EndDraw PictureBox1
27.  
28.                     __UI_DoEvents 'This is what you'll want to have in your main loop
29.  
30.                     _LIMIT 30 'simulate a loop that takes a good while...
31.                 LOOP UNTIL DoingIt = False OR Control(PB).Value >= Control(PB).Max
32.                 Control(PB).Hidden = True
33.                 Control(StartBT).Disabled = False
34.                 Caption(StartBT) = PrevCaption$
35.                 BeginDraw PictureBox1
36.                 IF DoingIt = False THEN PRINT "Canceled."
37.                 DoingIt = False
38.                 PRINT "Seconds since start:"
39.                 PRINT TIMER - StartTime!
40.                 EndDraw PictureBox1
41.             ELSE
42.                 DoingIt = False
43.             END IF
44.         CASE PictureBox1
45.  
46.         CASE PB
47.  
48.     END SELECT
49. END SUB

[Qwerkey]

You most definitely do not need that extra button.

Ah!  Silly Me!  I forgot to make my equivalent of DoingIt STATIC.