Peace Sign

[SierraKen]

This is a peace sign I just threw together. The colors of the sign change and then go back and start over.

Code: QB64: [Select]

1. _Title "Peace - press Esc to quit app."
2. Screen _NewImage(800, 600, 32)
3. r = 50: g = 1: b = 1
4. _Limit 100
5. Do
6.     If r < 256 Then r = r + .005
7.     If r > 255 Then r2 = 1
8.     If b < 256 And r2 = 1 Then b = b + .005
9.     If b > 255 Then b2 = 1
10.     If g < 256 And r2 = 1 And b2 = 1 Then g = g + .005
11.     If g > 255 Then r2 = 0: b2 = 0: r = 1: b = 1: g = 1
12.  
13.     x = x + .01
14.     y = y + .01
15.     Line (0, y)-(x, 0), _RGB32(r, g, b)
16.     If y > 2000 Then GoTo design:
17. Loop
18. design:
19.  
20. For cir = .1 To 100 Step .1
21.     Circle (400, 300), cir, _RGB32(127 - cir, 255 / cir, 255 / cir)
22. Next cir
23. Do
24.     bl = bl + 1
25.     If bl > 254 Then bl = 1
26.     gr = gr + 1
27.     If gr > 254 Then gr = 1
28.     re = red + 1
29.     If re > 254 Then re = 1
30.     For thick = .1 To 10 Step .1
31.         Circle (400, 300), 90 + thick, _RGB32(re, gr, bl)
32.     Next thick
33.  
34.     seconds = 29.99
35.     s = (60 - seconds) * 6 + 180
36.     x2 = Int(Sin(s / 180 * 3.141592) * 100) + 400
37.     y2 = Int(Cos(s / 180 * 3.141592) * 100) + 300
38.     Line (400, 300)-(x2, y2), _RGB32(re, gr, bl)
39.     seconds = 60
40.     s = (60 - seconds) * 6 + 180
41.     x2 = Int(Sin(s / 180 * 3.141592) * 100) + 400
42.     y2 = Int(Cos(s / 180 * 3.141592) * 100) + 300
43.     Line (400, 300)-(x2, y2), _RGB32(re, gr, bl)
44.     seconds = 20
45.     s = (60 - seconds) * 6 + 180
46.     x2 = Int(Sin(s / 180 * 3.141592) * 100) + 400
47.     y2 = Int(Cos(s / 180 * 3.141592) * 100) + 300
48.     Line (400, 300)-(x2, y2), _RGB32(re, gr, bl)
49.     seconds = 40
50.     s = (60 - seconds) * 6 + 180
51.     x2 = Int(Sin(s / 180 * 3.141592) * 100) + 400
52.     y2 = Int(Cos(s / 180 * 3.141592) * 100) + 300
53.     Line (400, 300)-(x2, y2), _RGB32(re, gr, bl)
54.  
55.     _Delay .02
56.     If bl = 254 Then _Delay 1
57. Loop While InKey$ <> Chr$(27)
58.  

[bplus]

Hey Ken nice background!

Here's some help with ThickLine:

Code: QB64: [Select]

1. Screen _NewImage(800, 600, 32)
2.  
3. ThickLine 400, 20, 400, 580, 50, _RGB32(255, 255, 255)
4. ThickLine 400, 300, 400 + 280 * Cos(_Pi / 2 + _Pi / 4), 300 + 280 * Sin(_Pi / 2 + _Pi / 4), 50, _RGB32(255, 255, 255)
5. ThickLine 400, 300, 400 + 280 * Cos(_Pi / 2 - _Pi / 4), 300 + 280 * Sin(_Pi / 2 - _Pi / 4), 50, _RGB32(255, 255, 255)
6. Circle (400, 300), 280
7. Sleep
8.  
9. Sub ThickLine (x1, y1, x2, y2, rThick, colr~&)
10.     'x1, y1 is one endpoint of line
11.     'x2, y2 is the other endpoint of the line
12.     'rThick is the radius of the tiny circles that will be drawn
13.     '   from one end point to the other to create the thick line
14.  
15.     'Yes, the line will then extend beyond the endpoints with circular ends.
16.  
17.     cThick = Int(rThick / 2) ' << dont change value, copy it
18.     stepx = x2 - x1: stepy = y2 - y1
19.     lngth = Int((stepx ^ 2 + stepy ^ 2) ^ .5)
20.     If lngth Then
21.         dx = stepx / lngth: dy = stepy / lngth
22.         For i = 0 To lngth
23.             For r = 0 To cThick Step .25
24.                 Circle (x1 + dx * i, y1 + dy * i), r
25.             Next
26.         Next
27.     Else
28.         For r = 0 To cThick Step .25
29.             Circle (x1, y1), r
30.         Next
31.     End If
32. End Sub
33.  
34.  
35.  
36.  

Edit: Thickness is 1 unit to 5.5 unit (radius) 280/5.5 ~ 50

[SierraKen]

Thanks B+! I just had to add the color variable inside of the SUB's CIRCLE command and it works great! I love it! I left the tips rounded to make it almost like a paintbrush look to it, or spray paint. Thanks again :).

Here is the code and a new picture:

Code: QB64: [Select]

1. _Title "Peace - press Esc to quit app."
2.  
3. Screen _NewImage(800, 600, 32)
4. r = 50: g = 1: b = 1
5. _Limit 100
6. Do
7.     If r < 256 Then r = r + .005
8.     If r > 255 Then r2 = 1
9.     If b < 256 And r2 = 1 Then b = b + .005
10.     If b > 255 Then b2 = 1
11.     If g < 256 And r2 = 1 And b2 = 1 Then g = g + .005
12.     If g > 255 Then r2 = 0: b2 = 0: r = 1: b = 1: g = 1
13.  
14.     x = x + .01
15.     y = y + .01
16.     Line (0, y)-(x, 0), _RGB32(r, g, b)
17.     If y > 2000 Then GoTo design:
18. Loop
19. design:
20.  
21. For cir = .1 To 100 Step .1
22.     Circle (400, 300), cir, _RGB32(127 - cir, 255 / cir, 255 / cir)
23. Next cir
24. Do
25.     bl = bl + 1
26.     If bl > 254 Then bl = 1
27.     gr = gr + 1
28.     If gr > 254 Then gr = 1
29.     re = red + 1
30.     If re > 254 Then re = 1
31.     For thick = .1 To 10 Step .1
32.         Circle (400, 300), 90 + thick, _RGB32(re, gr, bl)
33.     Next thick
34.  
35.     colr~& = _RGB32(re, gr, bl)
36.     ThickLine 400, 220, 400, 300 + 80, 20, colr~&
37.     ThickLine 400, 300, 400 + 80 * Cos(_Pi / 2 + _Pi / 4), 300 + 80 * Sin(_Pi / 2 + _Pi / 4), 20, colr~&
38.     ThickLine 400, 300, 400 + 80 * Cos(_Pi / 2 - _Pi / 4), 300 + 80 * Sin(_Pi / 2 - _Pi / 4), 20, colr~&
39.  
40.     _Delay .02
41.     If bl = 254 Then _Delay 1
42. Loop While InKey$ <> Chr$(27)
43.  
44. Sub ThickLine (x1, y1, x2, y2, rThick, colr~&)
45.     'x1, y1 is one endpoint of line
46.     'x2, y2 is the other endpoint of the line
47.     'rThick is the radius of the tiny circles that will be drawn
48.     '   from one end point to the other to create the thick line
49.  
50.     'Yes, the line will then extend beyond the endpoints with circular ends.
51.  
52.     cThick = Int(rThick / 2) ' << dont change value, copy it
53.     stepx = x2 - x1: stepy = y2 - y1
54.     lngth = Int((stepx ^ 2 + stepy ^ 2) ^ .5)
55.     If lngth Then
56.         dx = stepx / lngth: dy = stepy / lngth
57.         For i = 0 To lngth
58.             For r = 0 To cThick Step .25
59.                 Circle (x1 + dx * i, y1 + dy * i), r, colr~&
60.             Next
61.         Next
62.     Else
63.         For r = 0 To cThick Step .25
64.             Circle (x1, y1), r
65.         Next
66.     End If
67. End Sub
68.  

[SierraKen]

If anyone wishes to make their own peace signs, feel free to post them here.

[bplus]

Changed Thick line to Lyne:

Code: QB64: [Select]

1. _Title "Now" 'B+ 2022-03-10 Mod Smooth Clock #3
2. Const sq = 320 '<<<<<<<<<<<<<< everything is scaled to this
3. Const xy0 = sq / 2, dr = .88 * xy0, br = .1 * xy0, hh = .65 * xy0, mh = .88 * xy0, sh = .88 * xy0, thk = .01 * xy0
4. Const pi = 3.141592653589793, pm2 = 2 * pi, pd2 = pi / 2, pm2d12 = 2 * pi / 12, pm2d60 = 2 * pi / 60 ' pi stuff
5. Screen _NewImage(sq, sq, 32)
6. _ScreenMove (1200 - sq) / 2, 10
7. Do
8.     t# = Timer(.001)
9.     hour% = Int(t# / 3600)
10.     If hour% > 12 Then showHr# = t# / 3600 - 12 Else showHr# = t# / 3600
11.     min# = t# / 60 - hour% * 60
12.     sec# = t# - hour% * 3600 - Int(min#) * 60
13.     Color , &HFF002868: Cls
14.     For r = dr - dr / 11 To dr + dr / 11 Step .25
15.         Circle (xy0, xy0), r
16.     Next
17.     lyne xy0, xy0 - dr, 2 * dr, pd2, dr / 5.5, &HFFFFFFFF
18.     lyne xy0, xy0, dr, pi * .25, dr / 5.5, &HFFFFFFFF
19.     lyne xy0, xy0, dr, pi * .75, dr / 5.5, &HFFFFFFFF
20.     For i = 0 To 59
21.         If i Mod 5 = 0 Then r = 3 Else r = 1
22.         Circle (xy0 + dr * Cos(i * pm2d60), xy0 + dr * Sin(i * pm2d60)), r * thk, &HFFBF0A30
23.     Next
24.     lyne xy0, xy0, hh, pm2d12 * showHr# - pd2, 8 * thk, &HFFBF0A30
25.     lyne xy0, xy0, mh, pm2d60 * min# - pd2, 6 * thk, &HFFBF0A30
26.     lyne xy0, xy0, sh, pm2d60 * sec# - pd2, 2 * thk, &HFFBF0A30
27.     Circle (xy0, xy0), 3, &HFF000000
28.     _Limit 60
29.     _Display
30. Loop Until _KeyDown(27)
31.  
32. Sub lyne (x0, y0, lngth, ra, thic, c As _Unsigned Long)
33.     Dim x As Integer, y As Integer, l As Integer
34.     While l < lngth
35.         l = l + 1: x = x0 + l * Cos(ra): y = y0 + l * Sin(ra)
36.         For radius = 0 To thic / 2
37.             Circle (x, y), radius, c, BF
38.         Next
39.     Wend
40. End Sub
41.  

 

[Dimster]

Does it come in Blue and Yellow?

[bplus]

Does it come in Blue and Yellow?

Sure a simple mod I leave to you!

[SierraKen]

Cool clock B+!

[bplus]

Code: QB64: [Select]

1. _Title "Peace Train" ' 2022-03-10 Mod of old post 2019-03-24 mod B+ 2019-03-26
2.  
3.  
4.  
5. '      play this: [youtube]https://www.youtube.com/watch?v=UkTQri3a4Gg[/youtube]
6. '      Cat Stevens: Peace Train
7.  
8.  
9.  
10. Randomize Timer
11. Screen _NewImage(800, 600, 32)
12. _ScreenMove 200, 20
13.  
14. 'background B+ mod
15. Dim Shared scape&
16. LoadLandscape
17. scapeWidth = _Width(scape&)
18. scapeHeight = _Height(scape&)
19. 'PRINT scapeWidth, scapeHeight
20.  
21. 'train stuff [banned user] and Fellippe?
22. Dim temp As String
23. Dim Shared Pattern As String
24.  
25. Dim Shared Train(7, 10) As String
26. Dim Shared Coal(10) As String
27.  
28. Dim Smoke1 As String
29. Dim Smoke2 As String
30. Dim Smoke3 As String
31. Dim Smoke4 As String
32. Smoke1 = Space$(16) + "@@@@"
33. Smoke2 = Space$(16) + "          @ @ "
34. Smoke3 = Space$(16) + "    @@     @@     @     @     @    "
35. Smoke4 = Space$(16) + "       @@     @@     @     @     @ "
36. LoadTrain
37. col = 1
38. row = 7
39. p = 6
40.  
41. le = scapeWidth - 800
42. While 1
43.     Cls
44.  
45.     '    background stuff
46.     If le + 800 > scapeWidth Then
47.         te = scapeWidth - le
48.         _PutImage (0, 0)-(te, scapeHeight), scape&, 0, (scapeWidth - te, 0)-(scapeWidth, scapeHeight)
49.         _PutImage (te, 0)-(800, scapeHeight), scape&, 0, (0, 0)-(800 - te, scapeHeight)
50.     Else
51.         _PutImage (0, 0)-(800, scapeHeight), scape&, 0, (le, 0)-(le + 800, scapeHeight)
52.     End If
53.     '_PRINTSTRING (5, 5), STR$(le)
54.     le = le - 1
55.     If le < 0 Then le = scapeWidth
56.  
57.  
58.     'train stuff
59.     Color _RGBA32(255, 255, 255, 200), _RGBA32(0, 0, 0, 0)
60.     For j = 0 To 9
61.         '_PRINTSTRING (0, 16 * j + 112), MID$(Train(p, j + 1), i, 80)
62.         _PrintString (64, 16 * j + 442), Mid$(Train(p, j + 1), 1, 84)
63.     Next
64.     'If i < Len(Smoke4) Then
65.     '    If fcount Mod 30 < 15 Then
66.     '        _PrintString (0, 96 + 300), Mid$(Smoke1, i, 80)
67.     '        _PrintString (0, 64 + 300), Space$(8) + Mid$(Smoke1, i, 80)
68.     '        _PrintString (0, 32 + 300), Space$(24) + Mid$(Smoke3, i, 80)
69.     '    Else
70.     '        _PrintString (0, 80 + 280), Space$(4) + Mid$(Smoke1, i, 80)
71.     '        _PrintString (0, 48 + 280), Space$(12) + Mid$(Smoke2, i, 80)
72.     '        _PrintString (0, 32 + 280), Space$(24) + Mid$(Smoke4, i, 80)
73.     '    End If
74.     'End If
75.  
76.     fcount = fcount + 1
77.     If fcount = 60 Then fcount = 0
78.     If fcount Mod 6 = 0 Then
79.         col = col + 1: i = i + 1
80.         If col = Len(Pattern) + 1 Then col = 1
81.         If i > Len(Train(1, 1)) - 80 Then i = 1
82.         p = Val(Mid$(Pattern, col, 1))
83.     End If
84.     peace 167, 579, 18, a
85.     peace 215, 579, 18, a + _Pi / 2
86.     peace 263, 579, 18, a + _Pi
87.     peace 311, 579, 18, a + _Pi * 1.5
88.  
89.     peace 530, 591, 6, a + _Pi * .25
90.     peace 578, 591, 6, a + _Pi * .75
91.     peace 634, 591, 6, a + _Pi * 1.25
92.     peace 682, 591, 6, a + _Pi * 1.75
93.  
94.     peace 90, 585, 12, a + _Pi * .66
95.     peace 386, 585, 12, a + _Pi * 1.66
96.  
97.     peace 128, 419, 12, -a + _Pi * .1
98.     peace 175, 386, 10, -a - _Pi * .3
99.     peace 281, 351, 9, -a + _Pi * .5
100.     peace 328, 321, 10, -a + _Pi * .7
101.     peace 401, 318, 7, -a + _Pi * .9
102.     peace 477, 307, 9, -a + _Pi * 1.1
103.     peace 562, 317, 6, -a + _Pi * 1.5
104.  
105.     a = a - _Pi / 36
106.     For i = 1 To 5
107.         peace 608, 518, 28, 0
108.     Next
109.  
110.     _Display
111.     _Limit 90 '<<< EDIT
112. Wend
113.  
114. Sub LoadLandscape
115.     cur& = _Dest
116.     xmax = 800 * 6: ymax = 600
117.     scape& = _NewImage(xmax, ymax, 32)
118.     _Dest scape&
119.  
120.     For i = 0 To ymax
121.         midInk 0, 0, 128, 128, 128, 200, i / ymax
122.         Line (0, i)-(xmax, i)
123.     Next
124.     'the land
125.     startH = ymax - 200
126.     rr = 70: gg = 70: bb = 90
127.     For mountain = 1 To 6
128.         Xright = 0
129.         y = startH
130.         Color _RGB(rr, gg, bb)
131.         While Xright < xmax - 50
132.             ' upDown = local up / down over range, change along Y
133.             ' range = how far up / down, along X
134.             upDown = (Rnd * .8 - .4) * (mountain * .5)
135.             range = Xright + rand%(15, 25) * 2.5 / mountain
136.             If range > xmax - 50 Then range = xmax - 50
137.             lastx = Xright - 1
138.             For x = Xright To range
139.                 test = y + upDown
140.                 If Abs(test - startH) < .1 * startH Then y = test
141.                 Line (lastx, y)-(x, ymax), , BF 'just lines weren't filling right
142.                 lastx = x
143.             Next
144.             Xright = range
145.         Wend
146.         x = lastx + 1
147.         While x <= xmax
148.             y = y + (startH - y) / 40
149.             Line (lastx, y)-(x, ymax), , BF 'just lines weren't filling right
150.             lastx = x
151.             x = x + 1
152.         Wend
153.         rr = rand%(rr - 15, rr): gg = rand%(gg - 15, gg): bb = rand%(bb - 25, bb)
154.         If rr < 0 Then rr = 0
155.         If gg < 0 Then gg = 0
156.         If bb < 0 Then bb = 0
157.         startH = startH + rand%(5, 20)
158.     Next
159.     _Dest cur&
160. End Sub
161.  
162. Function rand% (lo%, hi%)
163.     rand% = Int(Rnd * (hi% - lo% + 1)) + lo%
164. End Function
165.  
166. Sub midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
167.     Color _RGB(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
168. End Sub
169.  
170. Sub LoadTrain
171.     Dim t As String
172.  
173.     For j = 1 To 10
174.         Read t: Coal(j) = t
175.     Next
176.  
177.     For i = 1 To 6
178.         For j = 1 To 10
179.             Read t: Train(i, j) = t + Coal(j)
180.         Next
181.     Next
182.  
183.     For i = 1 To Len(t)
184.         ' Reverse: "312465"
185.         t = Mid$("564213", i, 1)
186.         Pattern = Pattern + t + t
187.     Next
188.     Exit Sub
189.  
190.     Data "                             "
191.     Data "                             "
192.     Data "    _________________        "
193.     Data "   _|                \_____A "
194.     Data " =|                        | "
195.     Data " -|                        | "
196.     Data "__|________________________|_"
197.     Data "|__________________________|_"
198.     Data "   |_D__D__D_|  |_D__D__D_|  "
199.     Data "    \_/   \_/    \_/   \_/   "
200.  
201.     Data "      ====        ________                ___________"
202.     Data "  _D _|  |_______/        \__I_I_____===__|_________|"
203.     Data "   |(_)---  |   H\________/ |   |        =|___ ___|  "
204.     Data "   /     |  |   H  |  |     |   |         ||_| |_||  "
205.     Data "  |      |  |   H  |__--------------------| [___] |  "
206.     Data "  | ________|___H__/__|_____/[][]~\_______|       |  "
207.     Data "  |/ |   |-----------I_____I [][] []  D   |=======|__"
208.     Data "__/ =| o |=-O=====O=====O=====O \ ____Y___________|__"
209.     Data " |/-=|___|=    ||    ||    ||    |_____/~\___/       "
210.     Data "  \_/      \__/  \__/  \__/  \__/      \_/           "
211.  
212.     Data "      ====        ________                ___________"
213.     Data "  _D _|  |_______/        \__I_I_____===__|_________|"
214.     Data "   |(_)---  |   H\________/ |   |        =|___ ___|  "
215.     Data "   /     |  |   H  |  |     |   |         ||_| |_||  "
216.     Data "  |      |  |   H  |__--------------------| [___] |  "
217.     Data "  | ________|___H__/__|_____/[][]~\_______|       |  "
218.     Data "  |/ |   |-----------I_____I [][] []  D   |=======|__"
219.     Data "__/ =| o |=-~O=====O=====O=====O\ ____Y___________|__"
220.     Data " |/-=|___|=    ||    ||    ||    |_____/~\___/       "
221.     Data "  \_/      \__/  \__/  \__/  \__/      \_/           "
222.  
223.     Data "      ====        ________                ___________"
224.     Data "  _D _|  |_______/        \__I_I_____===__|_________|"
225.     Data "   |(_)---  |   H\________/ |   |        =|___ ___|  "
226.     Data "   /     |  |   H  |  |     |   |         ||_| |_||  "
227.     Data "  |      |  |   H  |__--------------------| [___] |  "
228.     Data "  | ________|___H__/__|_____/[][]~\_______|       |  "
229.     Data "  |/ |   |-----------I_____I [][] []  D   |=======|__"
230.     Data "__/ =| o |=-~~\  /~~\  /~~\  /~~\ ____Y___________|__"
231.     Data " |/-=|___|=O=====O=====O=====O   |_____/~\___/       "
232.     Data "  \_/      \__/  \__/  \__/  \__/      \_/           "
233.  
234.     Data "      ====        ________                ___________"
235.     Data "  _D _|  |_______/        \__I_I_____===__|_________|"
236.     Data "   |(_)---  |   H\________/ |   |        =|___ ___|  "
237.     Data "   /     |  |   H  |  |     |   |         ||_| |_||  "
238.     Data "  |      |  |   H  |__--------------------| [___] |  "
239.     Data "  | ________|___H__/__|_____/[][]~\_______|       |  "
240.     Data "  |/ |   |-----------I_____I [][] []  D   |=======|__"
241.     Data "__/ =| o |=-~~\  /~~\  /~~\  /~~\ ____Y___________|__"
242.     Data " |/-=|___|=   O=====O=====O=====O|_____/~\___/       "
243.     Data "  \_/      \__/  \__/  \__/  \__/      \_/           "
244.  
245.     Data "      ====        ________                ___________"
246.     Data "  _D _|  |_______/        \__I_I_____===__|_________|"
247.     Data "   |(_)---  |   H\________/ |   |        =|___ ___|  "
248.     Data "   /     |  |   H  |  |     |   |         ||_| |_||  "
249.     Data "  |      |  |   H  |__--------------------| [___] |  "
250.     Data "  | ________|___H__/__|_____/[][]~\_______|       |  "
251.     Data "  |/ |   |-----------I_____I [][] []  D   |=======|__"
252.     Data "__/ =| o |=-~~\  /~~\  /~~\  /~~\ ____Y___________|__"
253.     Data " |/-=|___|=    ||    ||    ||    |_____/~\___/       "
254.     Data "  \_/      \O=====O=====O=====O_/      \_/           "
255.  
256.     Data "      ====        ________                ___________"
257.     Data "  _D _|  |_______/        \__I_I_____===__|_________|"
258.     Data "   |(_)---  |   H\________/ |   |        =|___ ___|  "
259.     Data "   /     |  |   H  |  |     |   |         ||_| |_||  "
260.     Data "  |      |  |   H  |__--------------------| [___] |  "
261.     Data "  | ________|___H__/__|_____/[][]~\_______|       |  "
262.     Data "  |/ |   |-----------I_____I [][] []  D   |=======|__"
263.     Data "__/ =| o |=-~~\  /~~\  /~~\  /~~\ ____Y___________|__"
264.     Data " |/-=|___|=    ||    ||    ||    |_____/~\___/       "
265.     Data "  \_/      \_O=====O=====O=====O/      \_/           "
266. End Sub
267.  
268. Sub lyne (x0, y0, lngth, ra, thic, c As _Unsigned Long)
269.     Dim x As Integer, y As Integer, l As Integer
270.     While l < lngth
271.         l = l + 1: x = x0 + l * Cos(ra): y = y0 + l * Sin(ra)
272.         For radius = 0 To thic / 2
273.             Circle (x, y), radius, c, BF
274.         Next
275.     Wend
276. End Sub
277.  
278. Sub peace (x0, y0, r, raRot) ' 12 is about smallest
279.     thic = r / 5.5
280.     For rr = r - thic To r Step 1
281.         Circle (x0, y0), rr
282.     Next
283.     lyne x0, y0, r - .5 * thic, _Pi * 1.5 + raRot, thic, &H11FFFFFF
284.     lyne x0, y0, r - .5 * thic, _Pi * .5 + raRot, thic, &H11FFFFFF
285.     lyne x0, y0, r - .5 * thic, _Pi * .25 + raRot, thic, &H11FFFFFF
286.     lyne x0, y0, r - .5 * thic, _Pi * .75 + raRot, thic, &H11FFFFFF
287. End Sub
288.  
289.  

[SierraKen]

WOW That's way cool! The Peace Train! Good job.

[bplus]

Man! You picked up on that fast! :)

[johnno56]

SierraKen. Nice job!

bplus. Trains. Gotta love 'em.

[SierraKen]

Thanks Johno :). LOL B+. :)