Some info regarding $IF precompiler directives

[FellippeHeitor]

Code: QB64: [Select]

1. $IF WIN THEN
2.         DECLARE LIBRARY
3.         FUNCTION MessageBox (BYVAL ignore&, message$, title$, BYVAL type&)
4.         END DECLARE
5. $ELSE
6.     DECLARE LIBRARY ""
7.         FUNCTION MessageBox (BYVAL ignore&, message$, title$, BYVAL type&)
8.     END DECLARE
9. $END IF
10.  
11. answer = MessageBox(0, "Hi, bplus. You can do this.", "This is platform-agnostic", 0)
12.  

[bplus]

Perfect! Thanks I will give it a go!

[bplus]

@FellippeHeitor

Would that work in a library BM or BI?

[SMcNeill]

Code: QB64: [Select]

1. $IF WIN THEN
2.         DECLARE LIBRARY
3.         FUNCTION MessageBox (BYVAL ignore&, message$, title$, BYVAL type&)
4.         END DECLARE
5. $ELSE
6.     DECLARE LIBRARY ""
7.         FUNCTION MessageBox (BYVAL ignore&, message$, title$, BYVAL type&)
8.     END DECLARE
9. $END IF
10.  
11. answer = MessageBox(0, "Hi, bplus. You can do this.", "This is platform-agnostic", 0)
12.  

What's the difference in those two DECLARE LIBRARY statements?  Is the blank quotes necessary for Linux/Mac, but not Windows?  It's something I've never noticed before.

[bplus]

@SMcNeill  curious my IDE is coloring the two things different.

Maybe you would know if that would work in BI?

I am thinking of starting include code library, it would have this messageBox and circleFill code for sure!

[FellippeHeitor]

Yes, empty quotes are required for non-Windows systems in this case.

[FellippeHeitor]

Maybe you would know if that would work in BI?

Yes, no problems.

[SMcNeill]

@SMcNeill  curious my IDE is coloring the two things different.

Try anything in an $IF ...  $ELSE... set of blocks.  The code that's evaluated as valid is colored and syntax spaced like normal; the code that's excluded isn't.  It's an easy visual way to see what's actually included in your code and what isn't, before you hit the f5 button and compile it.

$LET CHEESE = 2

$IF CHEESE = 1 THEN
    ? "One Cheese!"
$END IF

$IF CHEESE = 2 THEN
    ? "Two Cheese!"
$END IF

Try the above in the IDE and see how it formats and colors the two different $IF blocks.

[bplus]

Alright! so it's doing a little interpreter work. Thanks

[mdijkens]

And it also determines if it gets compiled/linked in your executable and thus (not) include certain libraries

Code: QB64: [Select]

1. $Let MYLOG = 1
2.  
3. Sub log (l$)
4.   $If MYLOG = DEFINED Then
5.  
6.   $End If
7. end sub
8.  

[bplus]

Well I thought the messageBox thing would be great but it likes to hide under the 2nd window button of QB64 on the tool bar, not even visible to the QB64 app sitting in the window. I thought my program was hanging until I found it when the top right X button wasn't working for QB64 app.

Code: QB64: [Select]

1. _Title " MessageBox test - look behind the QB64 app on tool bar if not seen on top. Lean on esc to quit... "
2.  
3. ' Thank you FellippeHeitor!
4. $If WIN Then
5.     Declare Library
6.         Function MessageBox (ByVal ignore&, message$, title$, Byval type&)
7.     End Declare
8. $Else
9.     DECLARE LIBRARY ""
10.     FUNCTION MessageBox (BYVAL ignore&, message$, title$, BYVAL type&)
11.     END DECLARE
12. $End If
13.  
14. Const xmax = 800, ymax = 600, PI = 3.141592653589793
15. Screen _NewImage(xmax, ymax, 32)
16. _ScreenMove 300, 40
17. Randomize Timer
18.  
19. Do
20.     Cls
21.     drawLandscape
22.     Color &HFFFFFFFF, &HFF000000
23.     kind = 1 ' 0 is just OK, 1 is OK & Cancel
24.     Print "Warning a Modal Message Box may come up off screen, you program is waiting for that!."
25.     answer = MessageBox(0, "You might have to look for me off screen. Lean on escape button to quit. Now you should quit seeing me with Cancel.", "Test MessageBox", kind)
26.     Print answer
27.  
28.     'cant mess with first parameter?
29.     _Delay 2
30.     If answer = 2 Then End
31.     k$ = InKey$ ' curious if key press in messageBox will interfere with inkey$
32.     If k$ = "q" Then End
33.     _Limit 1
34. Loop Until _KeyDown(27)
35.  
36. Sub drawLandscape
37.     'needs midInk, irnd
38.  
39.     Dim i As Long, startH As Single, rr As Long, gg As Long, bb As Long
40.     Dim mountain As Long, Xright As Single, y As Single, upDown As Single, range As Single
41.     Dim lastx As Single, X As Long
42.     'the sky
43.     For i = 0 To ymax
44.         midInk 0, 0, 128, 128, 128, 200, i / ymax
45.         Line (0, i)-(xmax, i)
46.     Next
47.     'the land
48.     startH = ymax - 200
49.     rr = 70: gg = 70: bb = 90
50.     For mountain = 1 To 6
51.         Xright = 0
52.         y = startH
53.         While Xright < xmax
54.             ' upDown = local up / down over range, change along Y
55.             ' range = how far up / down, along X
56.             upDown = (Rnd * .8 - .35) * (mountain * .5)
57.             range = Xright + irnd&(15, 25) * 2.5 / mountain
58.             lastx = Xright - 1
59.             For X = Xright To range
60.                 y = y + upDown
61.                 Color _RGB(rr, gg, bb)
62.                 Line (lastx, y)-(X, ymax), , BF 'just lines weren't filling right
63.                 lastx = X
64.             Next
65.             Xright = range
66.         Wend
67.         rr = irnd&(rr - 15, rr): gg = irnd&(gg - 15, gg): bb = irnd&(bb - 25, bb)
68.         If rr < 0 Then rr = 0
69.         If gg < 0 Then gg = 0
70.         If bb < 0 Then bb = 0
71.         startH = startH + irnd&(5, 20)
72.     Next
73. End Sub
74.  
75. Sub midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
76.     Color _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
77. End Sub
78.  
79. Function irnd& (n1, n2) 'return an integer between 2 numbers
80.     Dim l%, h%
81.     If n1 > n2 Then l% = n2: h% = n1 Else l% = n1: h% = n2
82.     irnd& = Int(Rnd * (h% - l% + 1)) + l%
83. End Function
84.  
85.  
86.  

So is there anyway to force the MessageBox to make an appearance on top of the QB64 app specially the first time, it often works as expected after that but not always.

What is nice is esc works as alt or short cut to Cancel Click.

[Dav]

It's  been a while since I dabbled with API, but I remember that there is a message box flag that lets you keep it on top of everything.  Perhaps our API guru @SpriggsySpriggs can jump in for percise info, but for now I changed this and it seemed to work for me on Windows.

kind = 1 OR 4096   '4096 is the number for MB_SYSTEMMODAL flag

- Dav

[SMcNeill]

It's  been a while since I dabbled with API, but I remember that there is a message box flag that lets you keep it on top of everything.  Perhaps our API guru @SpriggsySpriggs can jump in for percise info, but for now I changed this and it seemed to work for me on Windows.

kind = 1 OR 4096   '4096 is the number for MB_SYSTEMMODAL flag

- Dav

MB_TOPMOST = 0x00040000L

[bplus]

Thanks guys, I will try and let you know.

Does that go in the first argument? or what / where to use that number?

I plan to use it mostly for debugging and Windows only is fine for me, even if Fellippe was offering cross-platform box.

[SMcNeill]

Last argument for the type of box.  Just add or OR the value to whatever the existing number was you were passing.