Problem with OPEN in SUB

[RobinGravel]

I'm making a game and I need SUBs instead using GOSUBs.

Code: QB64: [Select]

1. TYPE testing
2.  t1 AS STRING * 12
3.  t2 AS STRING * 12
4.  t3 AS STRING * 12
5. END TYPE
6. DIM ttt AS testing
7. DECLARE SUB text (g, tt, testing, t1, t2, t3)
8. CLS
9. text 1, tt, testing, t1, t2, t3
10. END
11.  
12. SUB text (g, ttt, testing, t1, t2, t3)
13. OPEN "test.txt" FOR RANDOM AS 1 LEN = 36
14. max = LOF(1) / LEN(ttt)
15. GET #1, g, ttt
16. PRINT ttt.t1
17. PRINT ttt.t2
18. PRINT ttt.t3
19. k$ = INPUT$(1): CLOSE
20. END SUB
21.  

No message error but it doesn't give the right results.


Without SUB, the program works as intended.

Code: QB64: [Select]

1. Type testing
2.     t1 As String * 12
3.     t2 As String * 12
4.     t3 As String * 12
5. End Type
6.  
7. Dim ttt As testing: Cls
8. Open "test.txt" For Random As 1 Len = 36
9. max = LOF(1) / Len(ttt)
10. For z = 1 To 2
11.     Get #1, z, ttt
12.     Print ttt.t1
13.     Print ttt.t2
14.     Print ttt.t3
15.     Print
16. Next z
17. k$ = Input$(1): Close
18.  

Here the code to create TEST.TXT

Code: QB64: [Select]

1. 'Ftexte
2.  
3. TYPE testing
4.    t1 AS STRING * 12
5.    t2 AS STRING * 12
6.    t3 AS STRING * 12
7. END TYPE
8.  
9. DIM ttt AS testing
10. CLS
11. K$ = INPUT$(1)
12. '
13.  OPEN "test.txt" FOR RANDOM AS 1 LEN = LEN(ttt): limit = LEN(ttt)
14.  FOR z = 1 TO 2
15.  READ m1$, m2$, m3$
16.  ttt.t1 = m1$: ttt.t2 = m2$: ttt.t3 = m3$
17.  PUT #1, z, ttt
18.  NEXT z
19.  CLOSE
20.  CLS : PRINT "Saved": K$ = INPUT$(1)
21. '
22. END
23.  
24. DATA "123456789012"
25. DATA "Hello World!"
26. DATA " Good day.  "
27.  
28. DATA "ABCDEFGHIJKL"
29. DATA "Chichen.    "
30. DATA "Pizza  Hotel"
31.  

[bplus]

Code: QB64: [Select]

1. Type testing
2.     t1 As String * 12
3.     t2 As String * 12
4.     t3 As String * 12
5. End Type
6. Dim ttt As testing
7.  
8. GetRec 1, ttt
9. Print ttt.t1
10. Print ttt.t2
11. Print ttt.t3
12.  
13. Sub GetRec (recNum As Long, ttt As testing)
14.     lenRec% = Len(ttt) ' <<<<<<<<<<<<< I had to do this to get the crazy thing to work
15.     Open "test.txt" For Random As #1 Len = lenRec%
16.     Get #1, recNum, ttt
17.     Close
18. End Sub
19.  
20.  
21.  

I cut to the chase.

An alternate way to show you don't need to match ttt in the sub definition:

Code: QB64: [Select]

1. Type testing
2.     t1 As String * 12
3.     t2 As String * 12
4.     t3 As String * 12
5. End Type
6. Dim rec As testing
7.  
8. GetRec 1, rec
9. Print rec.t1
10. Print rec.t2
11. Print rec.t3
12.  
13. Sub GetRec (recNum As Long, ttt As testing)
14.     lenRec% = Len(ttt) ' <<<<<<<<<<<<< I had to do this to get the crazy thing to work
15.     Open "test.txt" For Random As #1 Len = lenRec%
16.     Get #1, recNum, ttt
17.     Close
18. End Sub
19.  

[bplus]

Oh sure! Now it works as I thought I tried originally. The secret is to save the file before Running I bet.

Code: QB64: [Select]

1. Type testing
2.     t1 As String * 12
3.     t2 As String * 12
4.     t3 As String * 12
5. End Type
6. Dim rec As testing
7.  
8. GetRec 1, rec
9. Print rec.t1
10. Print rec.t2
11. Print rec.t3
12.  
13. Sub GetRec (recNum As Long, ttt As testing)
14.     'lenRec% = Len(ttt) ' >>> commented out <<<<<<<<<<<<< I had to do this to get the crazy thing to work
15.     Open "test.txt" For Random As #1 Len = Len(ttt)
16.     Get #1, recNum, ttt
17.     Close
18. End Sub
19.  

[SMcNeill]

You should toss an error check in the @bplus.

If record num < 1 OR record num > file length \ record length THEN ERROR!  Out of bounds record.

[bplus]

Yeah e had this in sub originally which was a start of one, I think:

Code: QB64: [Select]

1. max = LOF(1) / Len(ttt)
2.  

[bplus]

Here's a proper write up then

Code: QB64: [Select]

1. Type testing
2.     t1 As String * 12
3.     t2 As String * 12
4.     t3 As String * 12
5. End Type
6. Dim rec As testing
7.  
8. GetRec 0, rec ' try this with 1 should get record, at 10 or 0 should see error message.
9. Print rec.t1
10. Print rec.t2
11. Print rec.t3
12.  
13. Sub GetRec (recNum As Long, ttt As testing)
14.     Dim As Long max
15.     Open "test.txt" For Random As #1 Len = Len(ttt)
16.     max = LOF(1) \ Len(ttt)
17.     If recNum > 0 And recNum <= max Then
18.         Get #1, recNum, ttt
19.     Else
20.         Print "Error, recNum is too high or 0."
21.     End If
22.     Close
23. End Sub
24.  

[RobinGravel]

I manage to make PRINTs to work inside the SUB. So I don't need to overuse PRINT all the time.

Code: QB64: [Select]

1. Type testing
2.     t1 As String * 12
3.     t2 As String * 12
4.     t3 As String * 12
5. End Type
6. Dim rec As testing
7.  
8. GetRec 1, rec: GetRec 2, rec
9. k$ = Input$(1)
10. End
11. Sub GetRec (recNum, rec As testing)
12.     'Dim As Long max
13.     Open "test.txt" For Random As #1 Len = Len(rec)
14.     max = LOF(1) / Len(rec)
15.     If recNum > 0 And recNum <= max Then
16.         Get #1, recNum, rec
17.     Else
18.         Print "Error, recNum is too high or 0.": End
19.     End If
20.     Close
21.     Print rec.t1: Print rec.t2: Print rec.t3: Print
22. End Sub
23.  

Thanks for help.

[Pete]

In these last two examples, it doesn't matter where the PRINT statements are at all. You can have them in the sub or in the main, but my point is it's just a coding style choice. Subs are just ways to better organize program flow and allow for a single routine to be used instead or coding repeated routines in a main. I saw your initial post contained a FOR/NEXT loop. If you need to call both the sub with a print routine or the sub with the print routine n the main, yuo would simply include that call in the FOR/NEXT loop..

Code: QB64: [Select]

1. FOR pete = 1 TO 2
2.     CALL mysubroutine(a$)
3. NEXT pete
4.  
5. SUB mysubroutine (a$)
6.     a = a + 1
7.     PRINT "Next Pete? You mean another one is out there? :O"
8. END SUB

or...

Code: QB64: [Select]

1. FOR pete = 1 TO 2
2.     CALL mysubroutine(a$)
3.     PRINT "Next Pete? You mean another one is out there? :O"
4. NEXT pete
5.  
6. SUB mysubroutine (a$)
7.     a = a + 1
8. END SUB

My coding style preference would also be to place the print statement in the sub, but again, that's just a preference. There is no "overuse" that i see, in either of the two examples above.

Happy coding!

Pete

[Cobalt]

Would have been nice if somebody would have pointed out what you did wrong, though you might of garnered it from the example replies.

This was your original issue;

SUB text (g, ttt, testing, t1, t2, t3)

If you wanted to pass a UDT you needed to use the AS statement just like in a DIM line

SUB text (g, ttt AS testing)
called with
text 1, ttt

in your original line, each of those variables being passed were passed as the SINGLE data type, by default since you did not specify.

That is why you were not seeing the results you expected.

Now you didn't receive any kind of error because you didn't write one bit of code wrong! Every thing you typed was valid code. Just not the code that would produce the results you wanted.  ttt.t1 is a valid variable even without UDT.

and GET #1, g, ttt
worked correctly too it loaded 4bytes (length of a SINGLE) into ttt, but instead of as a STRING it loaded it as a SINGLE(numeric) value. so no error

and of course PRINT ttt.t1 would have printed 0 as ttt.t1 was a SINGLE value that had nothing assigned to it.(same with the other 2 print lines) so still no error

max = LOF(1) / LEN(ttt)
here LEN(ttt) would have been 4, again because ttt is a SINGLE value which is 4 bytes long. again no error on the compiler side.

Hopefully that explains what occurred, and you can avoid (or make) some problems in the future with this knowledge.

[Pete]

@Cobalt makes a good point.

Personally I find the use of UDT's useful for large apps with many parameter to pass to many subs. It saves a ton of typing and dramatically reduces line sizes. For smaller apps or non-sub snippets, I tend not to use them. I suppose some people, in either case, may prefer UDT's for better variable naming, especially grouping of variable names to assignments.

Pete

[RobinGravel]

Would have been nice if somebody would have pointed out what you did wrong, though you might of garnered it from the example replies.

This was your original issue;

SUB text (g, ttt, testing, t1, t2, t3)

If you wanted to pass a UDT you needed to use the AS statement just like in a DIM line

SUB text (g, ttt AS testing)
called with
text 1, ttt

in your original line, each of those variables being passed were passed as the SINGLE data type, by default since you did not specify.

That is why you were not seeing the results you expected.

Now you didn't receive any kind of error because you didn't write one bit of code wrong! Every thing you typed was valid code. Just not the code that would produce the results you wanted.  ttt.t1 is a valid variable even without UDT.

and GET #1, g, ttt
worked correctly too it loaded 4bytes (length of a SINGLE) into ttt, but instead of as a STRING it loaded it as a SINGLE(numeric) value. so no error

and of course PRINT ttt.t1 would have printed 0 as ttt.t1 was a SINGLE value that had nothing assigned to it.(same with the other 2 print lines) so still no error

max = LOF(1) / LEN(ttt)
here LEN(ttt) would have been 4, again because ttt is a SINGLE value which is 4 bytes long. again no error on the compiler side.

Hopefully that explains what occurred, and you can avoid (or make) some problems in the future with this knowledge.

Understood.