Rain Storm Screensaver coding.

[Phlashlite]

A multi monitor screensaver I have been working on as my first coding project.  I started by translating this coding challenge:

https://www.youtube.com/watch?v=KkyIDI6rQJI

Algorithms are algorithms!

Enjoy,
Phlashlite

Code: QB64: [Select]

1. 'A work in progress...
2.  
3. ' - Adding better lightnig affects.
4. '   - Maybe adding screen flash?
5. ' - Working on colors.
6. ' - Add a ground plane
7. '   - Maybe Add splash effects?
8. ' - Add cloud layer
9. ' - Always working on code efficiency.
10.  
11. 'Author: Phlashlite, Jan 2022
12.  
13. ' NOTES: If you see code enclosed in "++++" there are adjustable setting to play with in there.
14.  
15. '        The original code was translated from watching this Coding Challenge Video:
16. '        [youtube]https://www.youtube.com/watch?v=KkyIDI6rQJI[/youtube]
17.  
18.  
19. 'Most of the adjustable settings+++++++++++++++++++++++++++++++++++++++++++++++
20.  
21. 'Screen________________________________________________________________________
22.  
23. 'Your screen width
24. CONST SCRWDTH = 5760
25.  
26. 'Your screen height
27. CONST SCRHGHT = 1200
28.  
29. 'Virtual depth of the scene
30. CONST SCRDPTH = 15
31.  
32.  
33. 'Rain__________________________________________________________________________
34.  
35. 'Number of raindrops to draw
36. CONST NUMDROPS = 5000
37.  
38. 'Lower limit of raindrop (drp) speed
39. CONST LDRPSPEED = 17
40.  
41. 'Upper limit of drp speed
42. CONST UDRPSPEED = 30
43.  
44. 'Lower limit of drp length
45. CONST LDRPLENGTH = 3
46.  
47. 'Upper limit of drp length
48. CONST UDRPLENGTH = 40
49.  
50. 'Lower limit of drp width
51. CONST LDRPWDTH = 1
52.  
53. 'Upper limit of drp width
54. CONST UDRPWDTH = 5
55.  
56.  
57. 'Lightning_____________________________________________________________________
58.  
59. 'Bolt detail, smaller is more detailed, 7 is default
60. CONST BLTDETAIL = 1
61.  
62. 'How crazy the bolt path is (angle displacement) 500 is default
63. CONST BLTDISP = 500
64.  
65. 'Bolt width
66. CONST BLTWDTH = 1
67.  
68. 'Bolt Glow width
69. CONST BLTGLOW = 50
70.  
71. 'Ticks Bolt is on screen
72. CONST BLTTIME = 2
73.  
74. 'Frequency of Bolts.  Range is 1 to 1000. > = less frequency.
75. CONST BLTFFREQ = 995
76. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
77.  
78. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
79. _MOUSEHIDE 'hide the mouse if you want (use if you are going to use as a screensaver
80. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
81.  
82. SCREEN _NEWIMAGE(SCRWDTH, SCRHGHT, 32) ' set the drawing screen
83.  
84. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
85. _SCREENMOVE (-SCRWDTH / 3) - 3, -26 'Moves the screen to hide widows title bars and frames
86. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
87.  
88. 'this is a drp
89. TYPE Drop
90.     x AS SINGLE '   x coordinate
91.     y AS SINGLE '   y coordinate
92.     z AS SINGLE '   z virtual coordinate
93.     wth AS SINGLE ' drp width
94.     lng AS SINGLE ' drp length
95.     spd AS SINGLE ' drp speed
96. END TYPE
97.  
98. RANDOMIZE TIMER
99.  
100. 'GroundY = SCRHGHT * 0.75
101.  
102. 'Initialize and fill the array that holds all the drops________________________
103. DIM SHARED Rain(NUMDROPS) AS Drop
104.  
105. FOR i% = 0 TO NUMDROPS
106.     fillDropArray (i%)
107. NEXT
108.  
109. 'Main loop to draw each Drop and call the lightning bolts______________________
110. DO
111.     FOR i% = 0 TO NUMDROPS
112.  
113.         'Fall
114.         Rain(i%).y = Rain(i%).y + Rain(i%).spd
115.  
116.         'Draw
117.         LINE (Rain(i%).x, Rain(i%).y)-(Rain(i%).x + Rain(i%).wth, Rain(i%).y + Rain(i%).lng), _RGBA(161, 166, 172, 100), BF
118.  
119.         'Fill
120.         'Restart each Drop in the array if it's y value passes the bottom of the screen (SCRHGHT)
121.         IF Rain(i%).y > SCRHGHT THEN
122.             fillDropArray (i%)
123.         END IF
124.  
125.     NEXT
126.  
127.     'Call the lightning bolt (blt)_____________________________________________
128.  
129.     'How far the bolt wanders++++++++++++++++++++++++++++++++++++++++++++++++++
130.     x1! = Rndm!(-10, SCRWDTH + 10) 'Sets blts x axis starting point range
131.  
132.     x2! = Rndm!(x1! - 500, x1! + 500) 'Sets how much a blts end x axis point
133.     '                                  varies from its starting x axis point
134.  
135.     y1! = 0 ' Rndm!(0, SCRHGHT - 1000) 'Sets blts y axis starting point range
136.  
137.     y2! = Rndm!(1000, SCRHGHT) 'Sets blts y axis ending point range
138.  
139.     'Adjust how often bolts strike+++++++++++++++++++++++++++++++++++++++++++++
140.     k% = Rndm(1, 1000)
141.     IF k% > BLTFFREQ THEN drawLightning x1!, y1!, x2!, y2!, BLTDISP
142.     '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
143.  
144.     '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
145.     _LIMIT 40
146.     '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
147.  
148.     _DISPLAY
149.     CLS
150.  
151. LOOP UNTIL _KEYDOWN(27)
152. SYSTEM
153.  
154. '______________________________________________________________________________
155.  
156. 'Does all the drop calculations and fills the array.
157.  
158. SUB fillDropArray (i%)
159.  
160.     Rain(i%).x = Rndm(0, SCRWDTH)
161.     Rain(i%).y = Rndm(-SCRHGHT, 0) 'start drops off screen on the y axis
162.  
163.     'bias rnd# gen for  more drops farther away (shorter, slower, narrower)___
164.     j! = Rndm(1, SCRDPTH * 2.5)
165.     IF j! > SCRDPTH THEN j! = Rndm(1, SCRDPTH * .25)
166.  
167.     Rain(i%).z = j! 'Rndm(1, SCRDPTH)
168.     Rain(i%).wth = map(Rain(i%).z, 0, SCRDPTH, LDRPWDTH, UDRPWDTH)
169.     Rain(i%).lng = map(Rain(i%).z, 0, SCRDPTH, LDRPLENGTH, UDRPLENGTH)
170.     Rain(i%).spd = map(Rain(i%).z, 0, SCRDPTH, LDRPSPEED, UDRPSPEED)
171.  
172. END SUB
173.  
174. '______________________________________________________________________________
175.  
176. 'Does all the lightning calculations usimg a "midpoint displacement alrorithm".
177.  
178. SUB drawLightning (x1!, y1!, x2!, y2!, BLTDISP)
179.  
180.     DIM midX!, midY!
181.  
182.     IF BLTDISP < BLTDETAIL THEN
183.  
184.         FOR l% = 1 TO BLTTIME
185.             LINE (x1!, y1!)-(x2! + BLTWDTH, y2!), _RGBA(255, 255, 255, 255), BF
186.         NEXT
187.  
188.     ELSE
189.         midX = (x1! + x2!) / 2
190.         midY = (y1! + y2!) / 2
191.         midX! = midX! + (RND - .5) * BLTDISP
192.         midY! = midY! + (RND - .5) * BLTDISP
193.  
194.         drawLightning x1!, y1!, midX!, midY!, BLTDISP / 2
195.         drawLightning x2!, y2!, midX!, midY!, BLTDISP / 2
196.  
197.     END IF
198.  
199. END SUB
200.  
201. '______________________________________________________________________________
202.  
203. 'Standard random numbers in a range of mn! (min) to mx! (max)
204.  
205. FUNCTION Rndm! (mn!, mx!)
206.     IF mn! > mx! THEN
207.         SWAP mn!, mx!
208.     END IF
209.     Rndm! = RND * (mx! - mn!) + mn!
210. END FUNCTION
211.  
212. '______________________________________________________________________________
213.  
214. ' Map function I found or translated from somewhere.
215. ' The Coding Train" guy on youtube, where I translated the rain code from explained it in one of his videos.
216.  
217. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
218.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
219. END FUNCTION
220.  
221.  
222.  
223.  

[bplus]

Hey another lightning fan! :)

Welcome to forum @Phlashlite

[Phlashlite]

@bplus

Thanks!  I've been lurking forever... lol!

[johnno56]

Fascinating.

[bplus]

@bplus

Thanks!  I've been lurking forever... lol!

Glad you came out of the closet, we could always use more graphics code. Got any strange clocks?

[Phlashlite]

Glad you came out of the closet, we could always use more graphics code. Got any strange clocks?

Only in my mind...

I honestly haven't done any graphics coding before and only any other coding out of necessity.

I'm a technical writer by trade, if you didn't catch that by all the code comments :)

[bplus]

@Phlashlite

You might like this:

Code: QB64: [Select]

1. 'Rain Drain.bas started 2017-09-13
2. 'translated from
3. 'Rain Drain.bas  SmallBASIC 0.12.9 [B+=MGA] 2017-04-26
4.  
5. _Define A-Z As SINGLE
6. Randomize Timer
7. Const xmax = 1100
8. Const ymax = 700
9.  
10. Screen _NewImage(xmax, ymax, 32)
11. _Delay .25
12. _ScreenMove _Middle
13. _Title "Rain Drain by bplus,    spacebar for new arrangement,    esc to quit"
14.  
15. Type ball
16.     x As Single
17.     y As Single
18.     speed As Single
19.     r As Single
20.     c As Long
21. End Type
22.  
23. Type bLine
24.     x1 As Integer
25.     y1 As Integer
26.     x2 As Integer
27.     y2 As Integer
28.     a As Double
29. End Type
30.  
31. While 1
32.     balls = 2500
33.     ReDim b(balls) As ball
34.     For i = 1 To balls
35.         b(i).x = Rnd * xmax
36.         b(i).y = Rnd * ymax
37.         b(i).speed = 9.85
38.         b(i).r = 5
39.         b(i).c = _RGB(0, rand%(200, 255), rand%(200, 255))
40.     Next
41.  
42.     m = 10
43.     nbl = 12
44.     ReDim bl(nbl) As bLine
45.     For i = 1 To nbl
46.         d = rand%(50, 200)
47.         bl(i).x1 = rand%(m, xmax - d - m)
48.         bl(i).y1 = i * ymax / nbl - 10
49.         bl(i).a = Rnd * _Pi(1 / 32) - _Pi(1 / 64)
50.         bl(i).x2 = bl(i).x1 + d * Cos(bl(i).a)
51.         bl(i).y2 = bl(i).y1 + d * Sin(bl(i).a)
52.     Next
53.  
54.     While 1
55.         Cls
56.         If 32 = _KeyHit Then
57.             Exit While
58.         ElseIf 27 = _KeyHit Then
59.             End
60.         End If
61.         For j = 1 To balls
62.             If b(j).y - b(j).r > ymax Or b(j).x + b(j).r < 0 Or b(j).x - b(j).r > xmax Then
63.                 b(j).x = rand%(0, xmax): b(j).y = 0
64.             End If
65.             Color b(j).c
66.             fcirc b(j).x, b(j).y, b(j).r
67.             testx = b(j).x + b(j).speed * Cos(_Pi(.5))
68.             testy = b(j).y + b(j).speed * Sin(_Pi(.5))
69.             cFlag = 0
70.             For i = 1 To nbl
71.                 Color _RGB(255, 0, 0)
72.                 lien bl(i).x1, bl(i).y1, bl(i).x2, bl(i).y2
73.                 If cFlag = 0 Then
74.                     If hitLine(testx, testy, b(j).r, bl(i).x1, bl(i).y1, bl(i).x2, bl(i).y2) Then
75.                         bx1 = b(j).x + b(j).speed * Cos(bl(i).a)
76.                         bx2 = b(j).x + b(j).speed * Cos(_Pi(1) - bl(i).a)
77.                         by1 = yy(bx1, bl(i).x1, bl(i).y1, bl(i).x2, bl(i).y2) - b(j).r - 1
78.                         by2 = yy(bx2, bl(i).x1, bl(i).y1, bl(i).x2, bl(i).y2) - b(j).r - 1
79.                         If by1 = (-9999 - b(j).r - 1) Or by2 = (-9999 - b(j).r - 1) Then
80.                             cFlag = 0: Exit For
81.                         End If
82.                         If by1 >= by2 Then b(j).y = by1: b(j).x = bx1 Else b(j).y = by2: b(j).x = bx2
83.                         cFlag = 1
84.                     End If
85.                 End If
86.             Next
87.             If cFlag = 0 Then b(j).x = testx: b(j).y = testy
88.         Next
89.         _Display
90.     Wend
91. Wend
92.  
93. Sub lien (x1, y1, x2, y2)
94.     Line (x1, y1)-(x2, y2)
95. End Sub
96.  
97. Function hitLine (x, y, r, xx1, yy1, xx2, yy2)
98.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2
99.     If x1 > x2 Then Swap x1, x2: Swap y1, y2
100.     If x < x1 Or x > x2 Then hitLine = 0: Exit Function
101.     If ((y2 - y1) / (x2 - x1)) * (x - x1) + y1 - r < y And y < ((y2 - y1) / (x2 - x1)) * (x - x1) + y1 + r Then
102.         hitLine = 1
103.     Else
104.         hitLine = 0
105.     End If
106. End Function
107.  
108. Function yy (x, xx1, yy1, xx2, yy2) 'this puts drop on line
109.     'copy parameters that are changed
110.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2
111.     If x1 > x2 Then Swap x1, x2: Swap y1, y2
112.     If x1 <= x And x <= x2 Then
113.         yy = ((y2 - y1) / (x2 - x1)) * (x - x1) + y1
114.     Else
115.         yy = -9999
116.     End If
117. End Function
118.  
119. Function rand% (lo%, hi%)
120.     rand% = (Rnd * (hi% - lo% + 1)) \ 1 + lo%
121. End Function
122.  
123. Function rdir% ()
124.     If Rnd < .5 Then rdir% = -1 Else rdir% = 1
125. End Function
126.  
127. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
128. Sub fcirc (CX As Long, CY As Long, R As Long)
129.     Dim subRadius As Long, RadiusError As Long
130.     Dim X As Long, Y As Long
131.  
132.     subRadius = Abs(R)
133.     RadiusError = -subRadius
134.     X = subRadius
135.     Y = 0
136.  
137.     If subRadius = 0 Then PSet (CX, CY): Exit Sub
138.  
139.     ' Draw the middle span here so we don't draw it twice in the main loop,
140.     ' which would be a problem with blending turned on.
141.     Line (CX - X, CY)-(CX + X, CY), , BF
142.  
143.     While X > Y
144.         RadiusError = RadiusError + Y * 2 + 1
145.         If RadiusError >= 0 Then
146.             If X <> Y + 1 Then
147.                 Line (CX - Y, CY - X)-(CX + Y, CY - X), , BF
148.                 Line (CX - Y, CY + X)-(CX + Y, CY + X), , BF
149.             End If
150.             X = X - 1
151.             RadiusError = RadiusError - X * 2
152.         End If
153.         Y = Y + 1
154.         Line (CX - X, CY - Y)-(CX + X, CY - Y), , BF
155.         Line (CX - X, CY + Y)-(CX + X, CY + Y), , BF
156.     Wend
157. End Sub
158.  
159.  

Maybe make a rain gage? Very handy fcirc = Circle Fill in that code, QB64 doesn't have that.

[Phlashlite]

@bplus

I do like that!

I once saw one similar that had the platforms tilting in oscillation.

[bplus]

Yeah that was Rain Drain 2, tilted but not oscillating, that would be Rain Drain 3  :)

[Phlashlite]

Yep,  I knew I had seen it!

Code: QB64: [Select]

1. 'Rain Drain.bas started 2017-09-13
2. 'translated from
3. 'Rain Drain.bas  SmallBASIC 0.12.9 [B+=MGA] 2017-04-26
4. '2020-08-29 Rain Drain 2: What if we move one side of every line up and down?
5.  
6. _DEFINE A-Z AS SINGLE
7. RANDOMIZE TIMER
8. CONST xmax = 1024 'SCREEN WIDTH
9. CONST ymax = 768 'SCREEN HEIGHT
10.  
11. SCREEN _NEWIMAGE(xmax, ymax, 32)
12. _DELAY 1 '.25
13. _SCREENMOVE _MIDDLE
14. _TITLE "Rain Drain 2:   spacebar for new arrangement,    esc to quit"
15.  
16. TYPE ball
17.     x AS SINGLE 'X COORDINATE
18.     y AS SINGLE 'Y COORDINATE
19.     speed AS SINGLE 'SPEED
20.     r AS SINGLE 'RADIUS
21.     c AS LONG 'COLOR
22. END TYPE
23.  
24. TYPE bLine
25.     x1 AS SINGLE
26.     y1 AS SINGLE
27.     x2 AS SINGLE
28.     y2 AS SINGLE
29.     a AS DOUBLE
30. END TYPE
31.  
32. WHILE 1
33.  
34.     'init ball array
35.     balls = 1000
36.     REDIM b(balls) AS ball
37.     FOR i = 1 TO balls
38.         b(i).x = RND * xmax 'RANDOM STARTING LOCATION
39.         b(i).y = RND * ymax '^
40.         b(i).speed = 5 '9.85 'SPEED
41.         b(i).r = 5 'RADIUS
42.         b(i).c = _RGB(0, rand%(200, 255), rand%(200, 255)) 'COLOR
43.     NEXT
44.  
45.     'intit bLine array
46.     m = 10
47.     nbl = 7 'NUMBER OF BLINES
48.     REDIM bl(nbl) AS bLine
49.     FOR i = 1 TO nbl
50.         d = rand%(50, 200)
51.         bl(i).x1 = rand%(m, xmax - d - m)
52.         bl(i).y1 = i * ymax / nbl - 10
53.         bl(i).a = RND * _PI(1 / 4) - _PI(1 / 8)
54.         bl(i).x2 = bl(i).x1 + d * COS(bl(i).a)
55.         bl(i).y2 = bl(i).y1 + d * SIN(bl(i).a)
56.     NEXT
57.  
58.     dir = .5
59.     lp = 0
60.     WHILE 1
61.         CLS
62.         IF 32 = _KEYHIT THEN
63.             EXIT WHILE
64.         ELSEIF 27 = _KEYHIT THEN
65.             END
66.         END IF
67.         lp = lp + dir
68.         IF lp > 50 THEN dir = -dir
69.         IF lp < -50 THEN dir = -dir
70.  
71.         FOR j = 1 TO balls
72.  
73.             IF b(j).y - b(j).r > ymax OR b(j).x + b(j).r < 0 OR b(j).x - b(j).r > xmax THEN
74.                 b(j).x = rand%(0, xmax): b(j).y = 0
75.             END IF
76.  
77.             fcirc b(j).x, b(j).y, b(j).r, b(j).c
78.             testx = b(j).x + b(j).speed * COS(_PI(.5))
79.             testy = b(j).y + b(j).speed * SIN(_PI(.5))
80.             cFlag = 0
81.  
82.             FOR i = 1 TO nbl
83.                 COLOR _RGB(255, 0, 0)
84.                 IF j = 1 THEN bl(i).y1 = bl(i).y1 + dir
85.                 LINE (bl(i).x1, bl(i).y1)-(bl(i).x2, bl(i).y2)
86.                 IF cFlag = 0 THEN
87.                     IF hitLine(testx, testy, b(j).r, bl(i).x1, bl(i).y1, bl(i).x2, bl(i).y2) THEN
88.                         bx1 = b(j).x + b(j).speed * COS(bl(i).a)
89.                         bx2 = b(j).x + b(j).speed * COS(_PI(1) - bl(i).a)
90.                         by1 = yy(bx1, bl(i).x1, bl(i).y1, bl(i).x2, bl(i).y2) - b(j).r - 1
91.                         by2 = yy(bx2, bl(i).x1, bl(i).y1, bl(i).x2, bl(i).y2) - b(j).r - 1
92.                         IF by1 = (-9999 - b(j).r - 1) OR by2 = (-9999 - b(j).r - 1) THEN
93.                             cFlag = 0: EXIT FOR
94.                         END IF
95.                         IF by1 >= by2 THEN b(j).y = by1: b(j).x = bx1 ELSE b(j).y = by2: b(j).x = bx2
96.                         cFlag = 1
97.                     END IF
98.                 END IF
99.             NEXT
100.             IF cFlag = 0 THEN b(j).x = testx: b(j).y = testy
101.         NEXT
102.         '_Limit 20
103.         _DISPLAY
104.     WEND
105. WEND
106.  
107. FUNCTION hitLine (x, y, r, xx1, yy1, xx2, yy2)
108.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2
109.     IF x1 > x2 THEN SWAP x1, x2: SWAP y1, y2
110.     IF x < x1 OR x > x2 THEN hitLine = 0: EXIT FUNCTION
111.     IF ((y2 - y1) / (x2 - x1)) * (x - x1) + y1 - r < y AND y < ((y2 - y1) / (x2 - x1)) * (x - x1) + y1 + r THEN
112.         hitLine = 1
113.     ELSE
114.         hitLine = 0
115.     END IF
116. END FUNCTION
117.  
118. FUNCTION yy (x, xx1, yy1, xx2, yy2) 'this puts drop on line
119.     'copy parameters that are changed
120.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2
121.     IF x1 > x2 THEN SWAP x1, x2: SWAP y1, y2
122.     IF x1 <= x AND x <= x2 THEN
123.         yy = ((y2 - y1) / (x2 - x1)) * (x - x1) + y1
124.     ELSE
125.         yy = -9999
126.     END IF
127. END FUNCTION
128.  
129. FUNCTION rand% (lo%, hi%)
130.     rand% = (RND * (hi% - lo% + 1)) \ 1 + lo%
131. END FUNCTION
132.  
133. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
134.     DIM Radius AS INTEGER, RadiusError AS INTEGER
135.     DIM X AS INTEGER, Y AS INTEGER
136.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
137.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
138.     LINE (CX - X, CY)-(CX + X, CY), C, BF
139.     WHILE X > Y
140.         RadiusError = RadiusError + Y * 2 + 1
141.         IF RadiusError >= 0 THEN
142.             IF X <> Y + 1 THEN
143.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
144.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
145.             END IF
146.             X = X - 1
147.             RadiusError = RadiusError - X * 2
148.         END IF
149.         Y = Y + 1
150.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
151.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
152.     WEND
153. END SUB
154.  
155.  

[Phlashlite]

*** WARNING! *** If you suffer from epilepsy, you may not want to run this.  It is quite flashy!

Same code as the screensaver code uploaded earlier except with improved lightning effects, modified colors and reduced to demo sized application.

~Phlashlite

Code: QB64: [Select]

1.  
2. 'A work in progress...
3.  
4. ' - Added better lightnig affects.
5. '   - Added screen flash
6. ' - Worked on colors.
7. ' - Add a ground plane
8. '   - Maybe Add splash effects?
9. ' - Add cloud layer
10. ' - Always working on code efficiency.
11.  
12. 'Author: Phlashlite, Jan 2022
13.  
14. ' NOTES: If you see code enclosed in "++++" there are adjustable setting to play with in there.
15.  
16. '        The original code was translated from watching this Coding Challenge Video:
17. '        [youtube]https://www.youtube.com/watch?v=KkyIDI6rQJI[/youtube]
18.  
19.  
20. 'Most of the adjustable settings+++++++++++++++++++++++++++++++++++++++++++++++
21.  
22. 'Screen________________________________________________________________________
23.  
24. 'Your screen width
25. CONST SCR_WDTH = 1536
26.  
27. 'Your screen height
28. CONST SCR_HGHT = SCR_WDTH * .5625
29.  
30. 'Virtual depth of the scene
31. CONST SCR_DPTH = 15
32.  
33.  
34. 'Rain__________________________________________________________________________
35.  
36. 'Number of raindrops to draw
37. CONST NUM_DROPS = 5000
38.  
39. 'Lower limit of raindrop (drp) speed
40. CONST MIN_DRP_SPEED = 13
41.  
42. 'Upper limit of drp speed
43. CONST MAX_DRP_SPEED = 60
44.  
45. 'Lower limit of drp length
46. CONST MIN_DRP_LNGTH = 3
47.  
48. 'Upper limit of drp length
49. CONST MAX_DRP_LNGTH = 60
50.  
51. 'Lower limit of drp width
52. CONST MIN_DRP_WDTH = 1
53.  
54. 'Upper limit of drp width
55. CONST MAX_DRP_WDTH = 5
56.  
57.  
58. 'Lightning_____________________________________________________________________
59.  
60. 'Bolt detail, smaller is more detailed, 1 is default
61. CONST BLT_DETAIL = 1
62.  
63. 'How crazy the bolt path is (angle displacement) 650 is default
64. CONST BLT_DISP = 650
65.  
66. 'Bolt width
67. CONST BLT_HLF_WDTH = 1.5
68.  
69. 'Ticks Bolt is on screen
70. CONST BLT_TIME = 15
71.  
72. 'Frequency of Bolts.  Range is 1 to 1000. > = less frequency.
73. CONST BLT_FREQ = 990
74.  
75. 'Lightning Bolt glow___________________________________________________________
76.  
77. 'One side gradient width
78. CONST BLT_GRD_HLF_WDTH = 17
79.  
80. 'Intensity of the gradient
81. CONST BLT_GRD_INTENSTY = 168
82.  
83. 'Map gradient to 255 color scale
84. CONST BLT_GRD_CALC = BLT_GRD_INTENSTY / BLT_GRD_HLF_WDTH
85.  
86.  
87. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
88.  
89. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
90. _MOUSEHIDE 'hide the mouse if you want (use if you are going to use as a screensaver
91. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
92.  
93. SCREEN _NEWIMAGE(SCR_WDTH, SCR_HGHT, 32) ' set the drawing screen
94.  
95. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
96. _SCREENMOVE _MIDDLE '(-SCR_WDTH / 3) - 3, -26 'Moves the screen to hide widows title bars and frames
97. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
98.  
99. 'This is a drp
100. TYPE Drop
101.     x AS SINGLE '   x coordinate
102.     y AS SINGLE '   y coordinate
103.     z AS SINGLE '   z virtual coordinate
104.     wth AS SINGLE ' drp width
105.     lng AS SINGLE ' drp length
106.     spd AS SINGLE ' drp speed
107. END TYPE
108.  
109. RANDOMIZE TIMER
110.  
111. 'GroundY = SCR_HGHT * 0.75
112.  
113. 'Initialize and fill the rain array____________________________________________
114. DIM SHARED Rain(NUM_DROPS) AS Drop
115.  
116. FOR i! = 0 TO NUM_DROPS
117.     fillDropArray (i!)
118. NEXT
119.  
120.  
121. 'Initialize and fill the glow array____________________________________________
122. DIM SHARED gradtable(BLT_GRD_HLF_WDTH) AS INTEGER
123.  
124. FOR g! = BLT_GRD_HLF_WDTH TO 1 STEP -1
125.     gradtable(g!) = BLT_GRD_INTENSTY - BLT_GRD_CALC * g!
126. NEXT
127.  
128. 'Main loop to draw each Drop and call the lightning bolts______________________
129. DO
130.     FOR i! = 0 TO NUM_DROPS
131.  
132.         'Fall
133.         Rain(i!).y = Rain(i!).y + Rain(i!).spd
134.  
135.         'Draw
136.         LINE (Rain(i!).x, Rain(i!).y)-(Rain(i!).x + Rain(i!).wth, Rain(i!).y + Rain(i!).lng), _RGBA(205, 205, 205, 21), BF
137.  
138.         'Fill
139.         'Restart each Drop in the array if it's y value passes the bottom of the screen (SCR_HGHT)
140.         IF Rain(i!).y > SCR_HGHT THEN
141.             fillDropArray (i!)
142.         END IF
143.  
144.     NEXT
145.  
146.     'Call the lightning bolt (blt)_____________________________________________
147.  
148.     'How far the bolt wanders++++++++++++++++++++++++++++++++++++++++++++++++++
149.     x1! = Rndm!(-10, SCR_WDTH + 10) 'Sets blts x axis starting point range
150.  
151.     x2! = Rndm!(x1! - SCR_WDTH / 2, x1! + SCR_WDTH / 2) 'Sets how much a blt's end x axis point
152.     '                                  varies from its starting x axis point
153.  
154.     y1! = 0 ' Rndm!(0, SCR_HGHT - 1000) 'Sets blts y axis starting point range
155.  
156.     y2! = Rndm!(1100, SCR_HGHT) 'Sets blts y axis ending point range
157.  
158.     'Adjust how often bolts strike_____________________________________________
159.     k! = Rndm(1, 1000)
160.     IF k! > BLT_FREQ THEN
161.         CLS , _RGBA(61, 72, 155, 100)
162.         drawLightning x1!, y1!, x2!, y2!, BLT_DISP
163.  
164.         '_DISPLAY
165.         'DO
166.         'LOOP UNTIL INKEY$ <> ""
167.  
168.     END IF
169.     '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
170.     _LIMIT 30
171.     '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
172.    0
173.     _DISPLAY
174.  
175.     CLS , _RGB(0, 0, 13)
176.  
177. LOOP UNTIL _KEYDOWN(27)
178. SYSTEM
179.  
180. '______________________________________________________________________________
181.  
182. 'Does all the drop calculations and fills the array.
183.  
184. SUB fillDropArray (i!)
185.  
186.     Rain(i!).x = Rndm(0, SCR_WDTH)
187.     Rain(i!).y = Rndm(-SCR_HGHT, 0) 'start drops off screen on the y axis
188.  
189.     'bias rnd# gen for  more drops farther away (shorter, slower, narrower)___
190.     j! = Rndm(1, SCR_DPTH * 2.5)
191.     IF j! > SCR_DPTH THEN j! = Rndm(1, SCR_DPTH * .25)
192.  
193.     Rain(i!).z = j! 'Rndm(1, SCR_DPTH)
194.     Rain(i!).wth = map(Rain(i!).z, 0, SCR_DPTH, MIN_DRP_WDTH, MAX_DRP_WDTH)
195.     Rain(i!).lng = map(Rain(i!).z, 0, SCR_DPTH, MIN_DRP_LNGTH, MAX_DRP_LNGTH)
196.     Rain(i!).spd = map(Rain(i!).z, 0, SCR_DPTH, MIN_DRP_SPEED, MAX_DRP_SPEED)
197.  
198. END SUB
199.  
200. '______________________________________________________________________________
201.  
202. 'Does all the lightning calculations usimg a "midpoint displacement alrorithm".
203.  
204. SUB drawLightning (x1!, y1!, x2!, y2!, BLT_DISP)
205.  
206.     x3! = x1! - BLT_HLF_WDTH 'start x1 adjusted for width
207.     x4! = x1! + BLTWHLFDTH 'end x1 adjusted for width
208.     x5! = x2! - BLT_HLF_WDTH 'start x2 adjusted for width
209.     x6! = x2! - BLT_HLF_WDTH 'end x2 adjusted for width
210.  
211.     DIM midX!, midY!
212.  
213.     IF BLT_DISP < BLT_DETAIL THEN
214.  
215.         FOR l! = 1 TO BLT_TIME
216.  
217.             FOR bw! = 1 TO BLT_HLF_WDTH
218.                 LINE (x1!, y1!)-(x2!, y2!), _RGBA(255, 255, 255, 200)
219.                 LINE (x1! + bw!, y1!)-(x2! + bw!, y2!), _RGBA(255, 255, 255, 200)
220.                 LINE (x1! - bw!, y1!)-(x2! - bw!, y2!), _RGBA(255, 255, 255, 200)
221.             NEXT
222.  
223.             FOR bgw! = 1 TO BLT_GRD_HLF_WDTH
224.                 LINE (x3! + bgw!, y1!)-(x4! + bgw!, y2!), _RGBA(gradtable(bgw!), gradtable(bgw!), gradtable(bgw!), gradtable(bgw!))
225.                 LINE (x3! - bgw!, y1!)-(x4! - bgw!, y2!), _RGBA(gradtable(bgw!), gradtable(bgw!), gradtable(bgw!), gradtable(bgw!))
226.             NEXT
227.  
228.         NEXT
229.  
230.     ELSE
231.         midX = (x1! + x2!) / 2
232.         midY = (y1! + y2!) / 2
233.         midX! = midX! + (RND - .5) * BLT_DISP
234.         midY! = midY! + (RND - .5) * BLT_DISP
235.  
236.         drawLightning x1!, y1!, midX!, midY!, BLT_DISP / 2
237.         drawLightning x2!, y2!, midX!, midY!, BLT_DISP / 2
238.  
239.     END IF
240.  
241. END SUB
242.  
243. '______________________________________________________________________________
244.  
245. 'Standard random numbers in a range of mn! (min) to mx! (max)
246.  
247. FUNCTION Rndm! (mn!, mx!)
248.     IF mn! > mx! THEN
249.         SWAP mn!, mx!
250.     END IF
251.     Rndm! = RND * (mx! - mn!) + mn!
252. END FUNCTION
253.  
254. '______________________________________________________________________________
255.  
256. ' Map function I found or translated from somewhere.
257. ' The Coding Train" guy on youtube, where I translated the rain code from explained it in one of his videos.
258.  
259. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
260.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
261. END FUNCTION
262.  
263.  

[Phlashlite]

Very handy fcirc = Circle Fill in that code, QB64 doesn't have that.

Funny you bring that up... I made these awhile back when I was thinking about making an "A-LIFE" sim.

Code: QB64: [Select]

1. SUB CircleFillDia2 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
2.  
3.     ' CX = offset x coordinate
4.     ' CY = offset y coordinate
5.     '  C = fill color
6.     '
7.     ' Output: A fast filled circle of diameter 2
8.     ' *** Only included for OCD completeness :) ***
9.     '
10.     '          ±Û
11.     '          ÛÛ
12.  
13.  
14.     PSET (CX, CY), C
15.  
16. END SUB
17.  
18. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
19.  
20. SUB CircleFillDia3 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
21.  
22.     ' CX = center x coordinate
23.     ' CY = center y coordinate
24.     '  C = fill color
25.     '
26.     ' Output: A fast filled circle of diameter 3
27.     '
28.     '          ÛÛÛ
29.     '          Û±Û
30.     '          ÛÛÛ
31.  
32.  
33.     LINE (CX - 1, CY - 1)-(CX + 1, CY + 1), C, BF
34.  
35. END SUB
36.  
37. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
38.  
39. SUB CircleFillDia4 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
40.  
41.     ' CX = offset x coordinate
42.     ' CY = offset y coordinate
43.     '  C = fill color
44.     '
45.     ' Output: A fast filled circle of diameter 4
46.     '
47.     '           ÛÛ
48.     '          Û±ÛÛ
49.     '          ÛÛÛÛ
50.     '           ÛÛ
51.  
52.  
53.     LINE (CX, CY - 1)-(CX + 1, CY - 1), C
54.     LINE (CX - 1, CY)-(CX + 2, CY + 1), C, BF
55.     LINE (CX, CY + 2)-(CX + 1, CY + 2), C
56.  
57. END SUB
58.  
59. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
60.  
61. SUB CircleFillDia5 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
62.  
63.     ' CX = center x coordinate
64.     ' CY = center y coordinate
65.     '  C = fill color
66.     '
67.     ' Output: A fast filled circle of diameter 5
68.     '
69.     '          ÛÛÛ
70.     '         ÛÛÛÛÛ
71.     '         ÛÛ±ÛÛ
72.     '         ÛÛÛÛÛ
73.     '          ÛÛÛ
74.  
75.  
76.     LINE (CX - 1, CY - 2)-(CX + 1, CY - 2), C
77.     LINE (CX - 2, CY - 1)-(CX + 2, CY + 1), C, BF
78.     LINE (CX - 1, CY + 2)-(CX + 1, CY + 2), C
79.  
80. END SUB
81.  
82. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
83.  
84. SUB CircleFillDia6 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
85.  
86.     ' CX = offset x coordinate
87.     ' CY = offset y coordinate
88.     '  C = fill color
89.     '
90.     ' Output: A fast filled circle of diameter 6
91.     '
92.     '          ÛÛÛÛ
93.     '         ÛÛÛÛÛÛ
94.     '         ÛÛ±ÛÛÛ
95.     '         ÛÛÛÛÛÛ
96.     '         ÛÛÛÛÛÛ
97.     '          ÛÛÛÛ
98.  
99.  
100.     LINE (CX - 1, CY - 2)-(CX + 2, CY - 2), C
101.     LINE (CX - 2, CY - 1)-(CX + 3, CY + 2), C, BF
102.     LINE (CX - 1, CY + 3)-(CX + 2, CY + 3), C
103.  
104. END SUB
105.  
106. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
107.  
108. SUB CircleFillDia7 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
109.  
110.     ' CX = center x coordinate
111.     ' CY = center y coordinate
112.     '  C = fill color
113.     '
114.     ' Output: A fast filled circle of diameter 7
115.     '
116.     '           ÛÛÛ
117.     '          ÛÛÛÛÛ
118.     '         ÛÛÛÛÛÛÛ
119.     '         ÛÛÛ±ÛÛÛ
120.     '         ÛÛÛÛÛÛÛ
121.     '          ÛÛÛÛÛ
122.     '           ÛÛÛ
123.  
124.  
125.     LINE (CX - 1, CY - 3)-(CX + 1, CY - 3), C
126.     LINE (CX - 2, CY - 2)-(CX + 2, CY - 2), C
127.     LINE (CX - 3, CY - 1)-(CX + 3, CY + 1), C, BF
128.     LINE (CX - 2, CY + 2)-(CX + 2, CY + 2), C
129.     LINE (CX - 1, CY + 3)-(CX + 1, CY + 3), C
130.  
131. END SUB
132.  
133. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
134.  
135. SUB CircleFillDia8 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
136.  
137.     ' CX = center x coordinate
138.     ' CY = center y coordinate
139.     '  C = fill color
140.     '
141.     ' Output: A fast filled circle of diameter 8
142.     '
143.     '         ÛÛÛÛ
144.     '        ÛÛÛÛÛÛ
145.     '       ÛÛÛÛÛÛÛÛ
146.     '       ÛÛÛ±ÛÛÛÛ
147.     '       ÛÛÛÛÛÛÛÛ
148.     '       ÛÛÛÛÛÛÛÛ
149.     '        ÛÛÛÛÛÛ
150.     '         ÛÛÛÛ
151.     '
152.  
153.     LINE (CX - 2, CY - 4)-(CX + 2, CY - 4), C
154.     LINE (CX - 3, CY - 3)-(CX + 3, CY - 3), C
155.     LINE (CX - 4, CY - 2)-(CX + 4, CY + 2), C, BF
156.     LINE (CX - 3, CY + 3)-(CX + 3, CY + 3), C
157.     LINE (CX - 2, CY + 4)-(CX + 2, CY + 4), C
158.  
159. END SUB
160.  
161. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
162.  
163. SUB CircleFillDia9 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
164.  
165.     ' CX = center x coordinate
166.     ' CY = center y coordinate
167.     '  C = fill color
168.     '
169.     ' Output: A fast filled circle of diameter 9
170.     '
171.     '         ÛÛÛÛÛ
172.     '        ÛÛÛÛÛÛÛ
173.     '       ÛÛÛÛÛÛÛÛÛ
174.     '       ÛÛÛÛÛÛÛÛÛ
175.     '       ÛÛÛÛ±ÛÛÛÛ
176.     '       ÛÛÛÛÛÛÛÛÛ
177.     '       ÛÛÛÛÛÛÛÛÛ
178.     '        ÛÛÛÛÛÛÛ
179.     '         ÛÛÛÛÛ
180.  
181.  
182.     LINE (CX - 2, CY - 4)-(CX + 2, CY - 4), C
183.     LINE (CX - 3, CY - 3)-(CX + 3, CY - 3), C
184.     LINE (CX - 4, CY - 2)-(CX + 4, CY + 2), C, BF
185.     LINE (CX - 3, CY + 3)-(CX + 3, CY + 3), C
186.     LINE (CX - 2, CY + 4)-(CX + 2, CY + 4), C
187.  
188. END SUB
189.  
190. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
191.  
192. SUB CircleFillDia10 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
193.  
194.     ' CX = center x coordinate
195.     ' CY = center y coordinate
196.     '  C = fill color
197.     '
198.     ' Output: A fast filled circle of diameter 10
199.     '
200.     '          ÛÛÛÛ
201.     '        ÛÛÛÛÛÛÛÛ
202.     '        ÛÛÛÛÛÛÛÛ
203.     '       ÛÛÛÛÛÛÛÛÛÛ
204.     '       ÛÛÛÛ±ÛÛÛÛÛ
205.     '       ÛÛÛÛÛÛÛÛÛÛ
206.     '       ÛÛÛÛÛÛÛÛÛÛ
207.     '        ÛÛÛÛÛÛÛÛ
208.     '        ÛÛÛÛÛÛÛÛ
209.     '          ÛÛÛÛ
210.  
211.     LINE (CX - 1, CY - 4)-(CX + 2, CY - 4), C
212.     LINE (CX - 3, CY - 3)-(CX + 4, CY - 2), C, BF
213.     LINE (CX - 4, CY - 1)-(CX + 5, CY + 2), C, BF
214.     LINE (CX - 3, CY + 3)-(CX + 4, CY + 4), C, BF
215.     LINE (CX - 1, CY + 5)-(CX + 2, CY + 5), C
216.  
217. END SUB
218.  
219. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
220.  
221. SUB CircleFillDia11 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
222.  
223.     ' CX = center x coordinate
224.     ' CY = center y coordinate
225.     '  C = fill color
226.     '
227.     ' Output: A fast filled circle of diameter 11
228.     '
229.     '         ÛÛÛÛÛ
230.     '        ÛÛÛÛÛÛÛ
231.     '       ÛÛÛÛÛÛÛÛÛ
232.     '      ÛÛÛÛÛÛÛÛÛÛÛ
233.     '      ÛÛÛÛÛÛÛÛÛÛÛ
234.     '      ÛÛÛÛÛ±ÛÛÛÛÛ
235.     '      ÛÛÛÛÛÛÛÛÛÛÛ
236.     '      ÛÛÛÛÛÛÛÛÛÛÛ
237.     '       ÛÛÛÛÛÛÛÛÛ
238.     '        ÛÛÛÛÛÛÛ
239.     '         ÛÛÛÛÛ
240.  
241.  
242.     LINE (CX - 2, CY - 5)-(CX + 2, CY - 5), C
243.     LINE (CX - 3, CY - 4)-(CX + 3, CY - 4), C
244.     LINE (CX - 4, CY - 3)-(CX + 4, CY - 3), C
245.     LINE (CX - 5, CY - 2)-(CX + 5, CY + 2), C, BF
246.     LINE (CX - 4, CY + 3)-(CX + 4, CY + 3), C
247.     LINE (CX - 3, CY + 4)-(CX + 3, CY + 4), C
248.     LINE (CX - 2, CY + 5)-(CX + 2, CY + 5), C
249.  
250. END SUB
251.  
252. 'ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
253.  
254. SUB CircleFillDia12 (CX AS INTEGER, CY AS INTEGER, C AS _UNSIGNED LONG)
255.  
256.     ' CX = center x coordinate
257.     ' CY = center y coordinate
258.     '  C = fill color
259.     '
260.     ' Output: A fast filled circle of diameter 12
261.     '
262.     '          ÛÛÛÛ
263.     '        ÛÛÛÛÛÛÛÛ
264.     '       ÛÛÛÛÛÛÛÛÛÛ
265.     '       ÛÛÛÛÛÛÛÛÛÛ
266.     '      ÛÛÛÛÛÛÛÛÛÛÛÛ
267.     '      ÛÛÛÛÛ±ÛÛÛÛÛÛ
268.     '      ÛÛÛÛÛÛÛÛÛÛÛÛ
269.     '      ÛÛÛÛÛÛÛÛÛÛÛÛ
270.     '       ÛÛÛÛÛÛÛÛÛÛ
271.     '       ÛÛÛÛÛÛÛÛÛÛ
272.     '        ÛÛÛÛÛÛÛÛ
273.     '          ÛÛÛÛ
274.  
275.     LINE (CX - 1, CY - 5)-(CX + 2, CY - 5), C
276.     LINE (CX - 3, CY - 4)-(CX + 4, CY - 4), C
277.     LINE (CX - 4, CY - 3)-(CX + 5, CY - 2), C, BF
278.     LINE (CX - 5, CY - 1)-(CX + 6, CY + 2), C, BF
279.     LINE (CX - 4, CY + 3)-(CX + 5, CY + 4), C, BF
280.     LINE (CX - 3, CY + 5)-(CX + 4, CY + 5), C
281.     LINE (CX - 1, CY + 6)-(CX + 2, CY + 6), C
282.  
283. END SUB
284.  
285.  
286.  

[bplus]

Yeah I remember trying circle fills with a square fill in middle and doing 1 hump calc and repeating the lines across the other 3 tips of axis cross.