Multiple Panels

[johnno56]

Quick question.

I am thinking of modifying an old text game. I am toying with the idea of having multiple 'windows/panels' to view the main game display; games stats and user/computer feedback.

Are there any tutorials/examples that I can help?

J

[SMcNeill]

Absolute easiest way is the use multiple screens and then putimage them onto a main display.

LeftFrame = _NEWIMAGE(200, 720, 32)
RightFrame = _NEWIMAGE(200, 720, 32)
CenterFrame = _NEWIMAGE(624, 720, 32)
DisplayScreen = _NEWIMAGE(1024, 720, 32)

SCREEN DisplayScreen

With the above setup, you now have three panels to work with.  Use _DEST with LeftFrame, for example, to put your list of commands.  (Status, Skill, Equip, Quest, Save...)  Use _DEST with _RightFrame to place information like Day, Hour, Map Location, whatever..   With CenterFrame, you can display your map, or text, or whatever you need...

Then just _PUTIMAGE those frames onto your DisplayScreen and _DISPLAY them.

[johnno56]

Thanks, Steve. I'm not sure if anything will come of this game yet. I'm still trying to figure out how to do it. But, with the examples you have provided, it should help out with the display. Cool.

J

[bplus]

Hey @johnno56

Would this happen to be about a certain Star Trek Game that I've been expecting from you for awhile? ;-))

What Steve describes is really nice you can work on each image independent of the others and as he said just _putimage (x, y)-step(imgWidth * scale, imgHeight * scale), img#, 0 (0=screen) when needed. x, y screen coord of top left corner, scale allows zoom in or out.

[SMcNeill]

A working style example for you, just to showcase the display using the above method:

Code: QB64: [Select]

1. LF = _NewImage(200, 720, 32)
2. RF = _NewImage(200, 720, 32)
3. CF = _NewImage(600, 720, 32)
4. DisplayScreen = _NewImage(1024, 720, 32)
5.  
6. Screen DisplayScreen
7.  
8. 'Stuff to print ot left side
9. _Dest LF
10. Cls , &HFF0000AA
11. Color , 0
12. Print "Joe Blow"
13. Print
14. Print "Age: 18"
15. Print "Sex: M"
16. Print
17. Print "ATK: 18:" 'attack
18. Print "DEF: 12" 'deffense
19. Print "MAT: 08" 'magic attack
20. Print "MDF: 05" 'magic defense
21. Print
22. Print "Health: 102 / 126"
23. Print "Mana  : 12  / 12"
24.  
25. 'Stuff to print to the right side
26. _Dest RF
27. Cls , &HFF0000AA
28. Color , 0
29. Print "Day: 01"
30. Print "Location: Home"
31. Print "Time: 07:00 AM"
32. Print
33. Print "Directions Available:"
34. Print "North"
35. Print "Bed"
36.  
37. 'Stuff to print to the center area
38. _Dest CF
39. Print "You wake up in your bed, in your home, with a hangover.  The sun is high in the sky and your alarm either failed to go off this morning, or else you were simply too drunk and hungover to respond to it.  Yesterday you were fired at work, and last night you spent drinking away your worries and concerns until into the wee hours of the morning."
40. Print ""
41. Print "In the room is your dirty clothes which are scattered all across the floor, your closet where you keep your clothes and extra blankets and such for the bed, and a small nightside table where you keep your loaded 45, in case of home invasion while you sleep.  You live in a rough neighborhood after all!"
42. Print
43. Print "What do you want to do now? "
44. Print
45.  
46. _Dest DisplayScreen
47. Do
48.     Cls
49.     _PutImage (0, 0), LF, DisplayScreen
50.     _PutImage (824, 0), RF, DisplayScreen
51.     _PutImage (210, 0), CF, DisplayScreen
52.     _PrintString (210, 700), "=>" + user$
53.     _Limit 30
54.     _Display
55. Loop Until _KeyHit
56.  

[madscijr]

A working style example for you, just to showcase the display using the above method:

Wow, this should really simplify a lot of things I have been doing the hard way. Thanks for sharing!

[johnno56]

Thanks, Steve. Much appreciated. I realize the use of coloured panels (to clearly display the individual areas) but most of all, I like the colour.
Another related question. How would I create panels like: two panels across the screen and a third panel below both but is the full width of the main screen... I hope I have described that correctly...

[johnno56]

bplus,

Based on my latest post, you may be lead to believe that the layout may be 'Star Trek' related... but in this case, even thought the overall layout will be similar, it will be used to cobble together David Ahl's "Seabat". I have no idea if this is going to work. The mongrel of a game uses line numbers. I would prefer no line numbers. But my lack of skill dictates, for me anyway, that kind of conversion is "not on the table"....

There was a far superior version (seatbat 2.0) that was made in 14-Jun-2011 by Vincent Erickson using freebasic?
Graphics, sound etc... Very cool. I have the source codes for all three versions if you are interested? (original, V1.0 and V2.03)

I suppose a study of how V2 was written might help in bypassing all those line numbers from the original version... lol

ps: I have been expecting a 'certain game' as well... I suppose it would be a good idea to get it done... before I "shuffle off"... lol

[SMcNeill]

Thanks, Steve. Much appreciated. I realize the use of coloured panels (to clearly display the individual areas) but most of all, I like the colour.
Another related question. How would I create panels like: two panels across the screen and a third panel below both but is the full width of the main screen... I hope I have described that correctly...

Do you mean something like the following?

Code: [Select]

LF = _NewImage(512, 300, 32)
RF = _NewImage(512, 300, 32)
CF = _NewImage(1024, 420, 32)
DisplayScreen = _NewImage(1024, 720, 32)

Screen DisplayScreen

'Stuff to print ot left side
_Dest LF
Cls , &HFF0000AA
Color , 0
Print "Joe Blow"
Print
Print "Age: 18"
Print "Sex: M"
Print
Print "ATK: 18:" 'attack
Print "DEF: 12" 'deffense
Print "MAT: 08" 'magic attack
Print "MDF: 05" 'magic defense
Print
Print "Health: 102 / 126"
Print "Mana  : 12  / 12"

'Stuff to print to the right side
_Dest RF
Cls , &HFF7700AA
Color , 0
Print "Day: 01"
Print "Location: Home"
Print "Time: 07:00 AM"
Print
Print "Directions Available:"
Print "North"
Print "Bed"

'Stuff to print to the center area
_Dest CF
Print "You wake up in your bed, in your home, with a hangover.  The sun is high in the sky and your alarm either failed to go off this morning, or else you were simply too drunk and hungover to respond to it.  Yesterday you were fired at work, and last night you spent drinking away your worries and concerns until into the wee hours of the morning."
Print ""
Print "In the room is your dirty clothes which are scattered all across the floor, your closet where you keep your clothes and extra blankets and such for the bed, and a small nightside table where you keep your loaded 45, in case of home invasion while you sleep.  You live in a rough neighborhood after all!"
Print
Print "What do you want to do now? "
Print

_Dest DisplayScreen
Do
    Cls
    _PutImage (0, 0), LF, DisplayScreen
    _PutImage (512, 0), RF, DisplayScreen
    _PutImage (0, 300), CF, DisplayScreen
    _PrintString (0, 700), "=>" + user$
    _Limit 30
    _Display
Loop Until _KeyHit


[bplus]

bplus,

Based on my latest post, you may be lead to believe that the layout may be 'Star Trek' related... but in this case, even thought the overall layout will be similar, it will be used to cobble together David Ahl's "Seabat". I have no idea if this is going to work. The mongrel of a game uses line numbers. I would prefer no line numbers. But my lack of skill dictates, for me anyway, that kind of conversion is "not on the table"....

There was a far superior version (seatbat 2.0) that was made in 14-Jun-2011 by Vincent Erickson using freebasic?
Graphics, sound etc... Very cool. I have the source codes for all three versions if you are interested? (original, V1.0 and V2.03)

I suppose a study of how V2 was written might help in bypassing all those line numbers from the original version... lol

ps: I have been expecting a 'certain game' as well... I suppose it would be a good idea to get it done... before I "shuffle off"... lol

I think I found it:

Code: QB64: [Select]

1. 10 Print Tab(33); "SEABAT"
2. 20 Print Tab(15); "CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
3. 30 Print: Print: Print
4. 40 Rem
5. 50 Rem  PROGRAM BY VINCENT ERIKSON
6. 60 Rem   ORIGINALLY IN H.P. BASIC
7. 70 Rem   CONVERTED TO MICROSOFT BASIC BY S.N.
8. 80 Rem
9. 90 Rem  NOTE THE FOLLOWING ABOUT CONVERSIONS:
10. 100 Rem   1) RESTORE <LINE NUMBER> MEANS TO SET THE DATA
11. 110 Rem      POINTER TO THE SPECIFIED LINE. THIS IS ONLY
12. 120 Rem      PRESENT IN TRS-80 LEVEL II AND CP/M BASIC.
13. 130 Rem      FOR OTHERS, IMPROVISE BY USING A RESTORE, AND
14. 140 Rem      FOR...NEXT WITH READ STATEMENTS TO SKIP OVER
15. 150 Rem      THE DATA THAT SHOULD BE IGNORED.
16. 160 Rem
17. 170 Rem   2) LOGICAL EXPRESSIONS ARE USED OFTEN.  A TRUE
18. 180 Rem      EXPRESSION EVALUATES AS A (-1) AND A FALSE EXPRESSION
19. 190 Rem      EVALUATES AS A (0).  THUS IF THE PROGRAM SAYS:
20. 200 Rem          X = (D<50)
21. 210 Rem      IT MEANS, LET X=0 IF D>=50, AND LET X=-1 IF D<50.
22. 220 Rem      AGAIN, IMPROVISE IF YOUR BASIC DOESN'T HAVE THIS
23. 230 Rem      (BUT ALL MICROSOFT BASICS DO.)
24. 240 Rem
25. 245 Rem   The real name of this program is, "Underwater Pie Lob"
26. 250 Rem *** PROGRAM FOLLOWS ***
27. 260 Rem ***
28. 270 Dim A(20, 20), D(9)
29. 280 Print "WHAT IS YOUR NAME";
30. 290 Input N$
31. 300 Print
32. 310 Rem *** SET UP AREA ***
33. 320 For I = 1 To 20
34.    322 For J = 1 To 20
35.        324 A(I, J) = 0
36.    326 Next J
37. 328 Next I
38. 330 Rem *** ISLAND ***
39. 340 Restore 6300
40. 350 For X = 7 To 13
41.    360 For Y = 7 To 12
42.        370 Read A(X, Y)
43.    380 Next Y
44. 390 Next X
45. 400 Rem *** SUB ***
46. 410 S1 = 10: S2 = 10
47. 420 A(S1, S2) = 2
48. 430 Rem *** ENEMY SHIPS ***
49. 440 S = Int(Rnd(1) * 16) + 15
50. 450 Restore 6090
51. 460 For X = 1 To (Int(Rnd(1) * 4) + 1) * 2 - 1
52.    470 Read D8, D9
53. 480 Next X
54. 490 For X = 1 To S
55.    500 X1 = Int(Rnd(1) * 20) + 1
56.    510 X2 = Int(Rnd(1) * 20) + 1
57.    520 If A(X1, X2) <> 0 Then 500
58.    530 A(X1, X2) = 3
59. 540 Next X
60. 550 Print "YOU MUST DESTROY"; S; "ENEMY SHIPS TO WIN "; N$; "."
61. 560 Rem *** HEADQUARTERS ***
62. 570 S3 = Int(Rnd(1) * 20) + 1
63. 580 S4 = Int(Rnd(1) * 20) + 1
64. 590 If A(S3, S4) <> 0 Then 570
65. 600 A(S3, S4) = 4
66. 610 Rem *** UNDERWATER MINES ***
67. 620 For X = 1 To Int(Rnd(1) * 8) + 8
68.    630 X1 = Int(Rnd(1) * 20) + 1
69.    640 X2 = Int(Rnd(1) * 20) + 1
70.    650 If A(X1, X2) <> 0 Then 630
71.    660 A(X1, X2) = 5
72. 670 Next X
73. 680 Rem *** SEA MONSTERS ***
74. 690 For X = 1 To 4
75.    700 X1 = Int(Rnd(1) * 18) + 2
76.    710 X2 = Int(Rnd(1) * 18) + 2
77.    720 If A(X1, X2) <> 0 Then 700
78.    730 A(X1, X2) = 6
79.    740 Restore 6090
80.    750 For Y = 1 To Int(Rnd(1) * 8) + 1
81.        760 Read M1, M2
82.    770 Next Y
83. 780 Next X
84. 790 Rem *** SET STARTING VALUES ***
85. 800 For I = 1 To 9
86.    802 D(I) = 0
87. 804 Next I
88. 810 C = 30
89. 820 P = 6000
90. 830 F = 2500
91. 840 T = 10
92. 850 M = 3
93. 860 D = 100
94. 870 D2 = 2
95. 880 Rem *** COMMAND SECTION ***
96. 890 Print: Print: Print "WHAT ARE YOUR ORDERS "; N$;
97. 900 Input O
98. 910 On Int(O + 1) GOTO 1040, 1680, 2220, 2680, 3250, 3410, 3700, 3880, 4400, 4660
99. 920 Print "THE COMMANDS ARE:"
100. 930 Print "     #0: NAVIGATION"
101. 940 Print "     #1: SONAR"
102. 950 Print "     #2: TORPEDO CONTROL"
103. 960 Print "     #3: POLARIS MISSILE CONTROL"
104. 970 Print "     #4: MANUEVERING"
105. 980 Print "     #5: STATUS/DAMAGE REPORT"
106. 990 Print "     #6: HEADQUARTERS"
107. 1000 Print "     #7: SABOTAGE"
108. 1010 Print "     #8: POWER CONVERSION"
109. 1020 Print "     #9: SURRENDER"
110. 1030 GoTo 890
111. 1040 Rem *** #0: NAVIGATION ***
112. 1050 If D(1) >= 0 Then 1080
113. 1060 Print "ENGINES ARE UNDER REPAIR "; N$; "."
114. 1070 GoTo 890
115. 1080 If C > 8 Then 1110
116. 1090 Print "NOT ENOUGH CREW TO MAN THE ENGINES "; N$; "."
117. 1100 GoTo 890
118. 1110 D1 = 1 - ((.23 + Rnd(1) / 10) * (-(D <= 50)))
119. 1120 GoSub 6090
120. 1130 Print "POWER AVAILABLE="; P; ". POWER TO USE";
121. 1140 Input P1
122. 1150 If P1 < 0 Or P1 > P Then 1130
123. 1160 If P1 <= 1000 Then 1210
124. 1170 If Rnd(1) < .43 Then 1210
125. 1180 Print "ATOMIC PILE GOES SUPERCRITICAL "; N$; "!!! HEADQUARTERS"
126. 1190 Print "WILL WARN ALL SUBS TO STAY AWAY FROM RADIOACTIVE AREA!!!"
127. 1200 GoTo 6180
128. 1210 X = S1
129. 1220 Y = S2
130. 1230 Q1 = 1
131. 1240 For X2 = 1 To Int(Int(P1 / 100 + .5) * D1 + .5)
132.    1250 If X + X1 > 0 And X + X1 < 21 And Y + Y1 > 0 And Y + Y1 < 21 Then 1280
133.    1260 Print "YOU CAN'T LEAVE THE AREA "; N$; "!!"
134.    1270 GoTo 1340
135.    1280 On A(X + X1, Y + Y1) + 1 GOTO 1290, 1330, 1630, 1390, 1440, 1470, 1490
136.    1290 X = X + X1
137.    1300 Y = Y + Y1
138.    1310 P = P - 100
139.    1320 GoTo 1520
140.    1330 Print "YOU ALMOST RAN AGROUND "; N$; "!!"
141.    1340 A(X, Y) = 2
142.    1350 A(S1, S2) = 0
143.    1360 S1 = X
144.    1370 S2 = Y
145.    1380 GoTo 4690
146.    1390 If D > 50 Then 1290
147.    1400 Print "YOU RAMMED A SHIP!!! YOU'RE BOTH SUNK!!"; N$; "!!"
148.    1410 S = S - 1
149.    1420 If S = 0 Then 6260
150.    1430 GoTo 6180
151.    1440 If D > 50 Then 1290
152.    1450 Print "YOU RAMMED HEADQUARTERS!! YOU'RE SUNK!!"
153.    1460 GoTo 6180
154.    1470 Print "YOU'VE BEEN BLOWN UP BY A MINE "; N$; "!!"
155.    1480 GoTo 6180
156.    1490 If Rnd(1) < .21 Then 1630
157.    1500 Print "YOU WERE EATEN BY A SEA MONSTER, "; N$; "!!"
158.    1510 GoTo 6180
159.    1520 Rem *** CHECK FOR NEARBY SEA MONSTERS ***
160.    1530 For X3 = X - 2 To X + 2
161.        1540 For Y3 = Y - 2 To Y + 2
162.            1550 If X3 < 1 Or X3 > 20 Or Y3 < 1 Or Y3 > 20 Then 1610
163.            1560 If A(X, Y) <> 6 Then 1610
164.            1570 If Rnd(1) < .25 Then 1500
165.            1580 If Q1 = 0 Then 1610
166.            1590 Print "YOU JUST HAD A NARROW ESCAPE WITH A SEA MONSTER "; N$; "!!"
167.            1600 Q1 = 0
168.        1610 Next Y3
169.    1620 Next X3
170. 1630 Next X2
171. 1640 Print "NAVIGATION COMPLETE. POWER LEFT="; P; "."
172. 1650 If P > 0 Then 1340
173. 1660 Print "ATOMIC PILE HAS GONE DEAD!!! SUB SINKS, CREW SUFFOCATES"
174. 1670 GoTo 6180
175. 1680 Rem *** #1: SONAR ***
176. 1690 If D(2) >= 0 Then 1720
177. 1700 Print "SONAR IS UNDER REPAIR "; N$; "."
178. 1710 GoTo 880
179. 1720 If C > 5 Then 1750
180. 1730 Print "NOT ENOUGH CREW TO WORK SONAR "; N$; "."
181. 1740 GoTo 880
182. 1750 Print "OPTION #";
183. 1760 Input O
184. 1770 On Int(O + 1) GOTO 1790, 2010
185. 1780 GoTo 1750
186. 1790 Rem *** PRINT OUT MAP ***
187. 1800 Print
188. 1810 For X = 1 To 20
189.    1820 For Y = 1 To 20
190.        1830 Data "   ","***","(X)","\S/","!H!"," $ ","-#-"
191.        1840 If A(X, Y) <> 0 Then 1880
192.        1850 If X <> 1 And X <> 20 And Y <> 1 And Y <> 20 Then 1880
193.        1860 Print " . ";
194.        1870 GoTo 1950
195.        1880 Restore 1830
196.        1890 For X1 = 1 To A(X, Y) + 1
197.            1900 Read A$
198.        1910 Next X1
199.        1920 If D < 50 And Rnd(1) < .23 And A(X, Y) <> 1 And A(A, Y) <> 2 Then 1860
200.        1930 If Rnd(1) < .15 And A(X, Y) > 2 Then 1860
201.        1940 Print A$;
202.    1950 Next Y
203.    1960 Print
204. 1970 Next X
205. 1980 P = P - 50
206. 1990 If P > 0 Then 880
207. 2000 GoTo 1660
208. 2010 Rem *** DIRECTIONAL INFORMATION ***
209. 2020 For I = 1 To 5
210.    2022 B(I) = 0
211. 2024 Next I
212. 2030 Print "DIRECTION   # OF SHIPS    DISTANCES"
213. 2040 Restore 6090
214. 2050 For X = 1 To 8
215.    2060 Read X1, Y1
216.    2070 X3 = 0
217.    2080 For X4 = 1 To 20
218.        2090 If S1 + X1 * X4 < 1 Or S1 + X1 * X4 > 20 Or S2 + Y1 * X4 < 1 Or S2 + Y1 * X4 > 20 Then 2140
219.        2100 If A(S1 + X1 * X4, S2 + Y1 * X4) <> 3 Then 2130
220.        2110 X3 = X3 + 1
221.        2120 B(X3) = X4
222.    2130 Next X4
223.    2140 If X3 = 0 Then 2200
224.    2150 Print "   "; X, X3,
225.    2160 For X4 = 1 To X3
226.        2170 Print B(X4);
227.    2180 Next X4
228.    2190 Print
229. 2200 Next X
230. 2210 GoTo 1980
231. 2220 Rem *** #2: TORPEDO CONTROL ***
232. 2230 If D(3) >= 0 Then 2260
233. 2240 Print "TORPEDO TUBES ARE UNDER REPAIR "; N$; "."
234. 2250 GoTo 880
235. 2260 If C >= 10 Then 2290
236. 2270 Print "NOT ENOUGH CREW TO FIRE TORPEDO "; N$; "."
237. 2280 GoTo 880
238. 2290 If T Then 2320
239. 2300 Print "NO TORPEDOS LEFT "; N$; "."
240. 2310 GoTo 880
241. 2320 If D < 2000 Then 2360
242. 2330 If Rnd(1) > .5 Then 2360
243. 2340 Print "PRESSURE IMPLODES UPON FIRING...YOU'RE CRUSHED!!"
244. 2350 GoTo 6180
245. 2360 GoSub 6080
246. 2370 X = S1
247. 2380 Y = S2
248. 2390 For X2 = 1 To Int(7 + 5 * (-(D > 50)) - Rnd(1) * 4 + .5)
249.    2400 If X + X1 > 0 And X + X1 < 21 And Y + Y1 > 0 And Y + Y1 < 21 Then 2460
250.    2410 Print "TORPEDO OUT OF SONAR RANGE...INEFFECTUAL "; N$; "."
251.    2420 T = T - 1
252.    2430 P = P - 150
253.    2440 If P > 0 Then 4690
254.    2450 GoTo 1660
255.    2460 On A(X + X1, Y + Y1) + 1 GOTO 2470, 2510, 2650, 2540, 2580, 2610, 2630
256.    2470 X = X + X1
257.    2480 Y = Y + Y1
258.    2490 Print "..!..";
259.    2500 GoTo 2650
260.    2510 Print "YOU TOOK OUT SOME ISLAND "; N$; "!"
261.    2520 A(X + X1, Y + Y1) = 0
262.    2530 GoTo 2420
263.    2540 Print "OUCH!!! YOU GOT ONE "; N$; "!!"
264.    2550 S = S - 1
265.    2560 If S <> 0 Then 2520
266.    2570 GoTo 6260
267.    2580 Print "YOU BLEW UP YOUR HEADQUARTERS "; N$; "!!!"
268.    2590 S3 = 0: S4 = 0: D2 = 0
269.    2600 GoTo 2520
270.    2610 Print "BLAM!! SHOT WASTED ON A MINE "; N$; "!!"
271.    2620 GoTo 2520
272.    2630 Print "A SEA MONSTER HAD A TORPEDO FOR LUNCH "; N$; "!!"
273.    2640 GoTo 2420
274. 2650 Next X2
275. 2660 Print "DUD."
276. 2670 GoTo 2420
277. 2680 Rem #3: POLARIS MISSILE CONTROL ***
278. 2690 If D(4) >= 0 Then 2720
279. 2700 Print "MISSILE SILOS ARE UNDER REPAIR "; N$; "."
280. 2710 GoTo 880
281. 2720 If C > 23 Then 2750
282. 2730 Print "NOT ENOUGH CREW TO LAUNCH A MISSILE "; N$; "."
283. 2740 GoTo 880
284. 2750 If M <> 0 Then 2780
285. 2760 Print "NO MISSILES LEFT "; N$; "."
286. 2770 GoTo 880
287. 2780 If D > 50 And D < 2000 Then 2850
288. 2790 Print "RECOMMEND THAT YOU DO NOT FIRE AT THIS DEPTH...PROCEED";
289. 2800 Input A$
290. 2810 If Left$(A$, 1) = "N" Then 880
291. 2820 If Rnd(1) < .5 Then 2850
292. 2830 Print "MISSILE EXPLODES UPON FIRING "; N$; "!! YOU'RE DEAD!!"
293. 2840 GoTo 6180
294. 2850 GoSub 6080
295. 2860 Print "FUEL (LBS.)";
296. 2870 Input F1
297. 2880 If F1 > 0 And F1 <= F Then 2910
298. 2890 Print "YOU HAVE"; F; "LBS. LEFT "; N$; "."
299. 2900 GoTo 2860
300. 2910 F2 = Int(F1 / 75 + .5)
301. 2920 If S1 + X1 * F2 > 0 And S1 + X1 * F2 < 21 And S2 + Y1 * F2 > 0 And S2 + Y1 * F2 < 21 Then 2980
302. 2930 Print "MISSILE OUT OF SONAR TRACKING "; N$; ". MISSILE LOST."
303. 2940 M = M - 1
304. 2950 F = F - F1
305. 2960 P = P - 300
306. 2970 GoTo 2440
307. 2980 D3 = 0: D4 = 0: D5 = 0: D6 = 0
308. 2990 For X = S1 + X1 * F2 - 1 To S1 + X1 * F2 + 1
309.    3000 For Y = S2 + Y1 * F2 - 1 To S2 + Y1 * F2 + 1
310.        3010 If X < 1 Or X > 20 Or Y < 1 Or Y > 20 Then 3140
311.        3020 D3 = D3 - (A(X, Y) = 3)
312.        3030 D4 = D4 - (A(X, Y) = 6)
313.        3040 D5 = D5 - (A(X, Y) = 5)
314.        3050 D6 = D6 - (A(X, Y) = 1)
315.        3060 If A(X, Y) <> 4 Then 3100
316.        3070 Print "YOU'VE JUST DESTROYED YOUR HEADQUARTERS "; N$; "!!!"
317.        3080 D3 = 0: S4 = 0: D2 = 0
318.        3090 GoTo 3130
319.        3100 If A(X, Y) <> 2 Then 3130
320.        3110 Print "YOU'VE JUST DESTROYED YOURSELF "; N$; "!!!    DUMMY!!"
321.        3120 GoTo 6180
322.        3130 A(X, Y) = 0
323.    3140 Next Y
324. 3150 Next X
325. 3160 If D6 = 0 Then 3180
326. 3170 Print "YOU BLEW OUT SOME ISLAND "; N$; "."
327. 3180 If D5 = 0 Then 3200
328. 3190 Print "YOU DESTROYED"; D5; "MINES "; N$; "."
329. 3200 If D4 = 0 Then 3220
330. 3210 Print "YOU GOT"; D4; "SEA MONSTERS "; N$; "!!!   GOOD WORK!!"
331. 3220 Print "YOU DESTROYED"; D3; "ENEMY SHIPS "; N$; "!!!"
332. 3230 S = S - D3
333. 3240 GoTo 2940
334. 3250 Rem *** MANUEVERING ***
335. 3260 If D(5) >= 0 Then 3290
336. 3270 Print "BALLAST CONTROLS ARE BEING REPAIRED "; N$; "."
337. 3280 GoTo 890
338. 3290 If C > 12 Then 3320
339. 3300 Print "THERE ARE NOT ENOUGH CREW TO WORK THE CONTROLS "; N$; "."
340. 3310 GoTo 880
341. 3320 Print "NEW DEPTH";
342. 3330 Input D1
343. 3340 If D1 >= 0 And D1 < 3000 Then 3370
344. 3350 Print "HULL CRUSHED BY PRESSURE "; N$; "!!"
345. 3360 GoTo 6180
346. 3370 P = P - Int(Abs((D - D1) / 2 + .5))
347. 3380 Print "MANUEVER COMPLETE. POWER LOSS="; Int(Abs((D - D1) / 2 + .5))
348. 3390 D = D1
349. 3400 GoTo 4690
350. 3410 Rem *** #5: STATUS / DAMAGE REPORT ***
351. 3420 If D(6) >= 0 Then 3450
352. 3430 Print "NO REPORTS ARE ABLE TO GET THROUGH "; N$; "."
353. 3440 GoTo 880
354. 3450 If C > 3 Then 3480
355. 3460 Print "NO ONE LEFT TO GIVE THE REPORT "; N$; "."
356. 3470 GoTo 880
357. 3480 Print "# OF ENEMY SHIPS LEFT......."; S
358. 3490 Print "# OF POWER UNITS LEFT......."; P
359. 3500 Print "# OF TORPEDOS LEFT.........."; T
360. 3510 Print "# OF MISSILES LEFT.........."; M
361. 3520 Print "# OF CREWMEN LEFT..........."; C
362. 3530 Print "LBS. OF FUEL LEFT..........."; F
363. 3540 Print
364. 3550 Print "WANT A DAMAGE REPORT";
365. 3560 Input A$
366. 3570 If Left$(A$, 1) = "N" Then 3670
367. 3580 Print "   ITEM            DAMAGE  (+ GOOD, 0 NEUTRAL, - BAD)"
368. 3590 Print "   ----            ------"
369. 3600 Data "ENGINES","SONAR","TORPEDOS","MISSILES","MANUEVERING"
370. 3610 Data "STATUS","HEADQUARTERS","SABOTAGE","CONVERTER"
371. 3620 Restore 3600
372. 3630 For X = 1 To 9
373.    3640 Read A$
374.    3650 Print A$, D(X)
375. 3660 Next X
376. 3670 Print "YOU ARE AT LOCATION ("; S1; ","; S2; ")."
377. 3680 Print
378. 3690 GoTo 880
379. 3700 Rem #6: HEADQUARTERS ***
380. 3710 If D(7) >= 0 Then 3740
381. 3720 Print "HEADQUARTERS IS DAMAGED.  UNABLE TO HELP "; N$; "."
382. 3730 GoTo 880
383. 3740 If D2 <> 0 Then 3770
384. 3750 Print "HEADQUARTERS IS DESERTED "; N$; "."
385. 3760 GoTo 880
386. 3770 If Sqr((S1 - S3) ^ 2 + (S2 - S4) ^ 2) <= 2 And D < 51 Then 3800
387. 3780 Print "UNABLE TO COMPLY WITH DOCKING ORDERS "; N$; "."
388. 3790 GoTo 880
389. 3800 Print "DIVERS FROM HEAD QUARTERS BRING OUT SUPPLYS AND MEN."
390. 3810 P = 4000
391. 3820 T = 8
392. 3830 M = 2
393. 3840 F = 1500
394. 3850 C = 25
395. 3860 D2 = D2 - 1
396. 3870 GoTo 4690
397. 3880 Rem *** #7: SABOTAGE ***
398. 3890 If D(8) >= 0 Then 3920
399. 3900 Print "HATCHES INACCESSIBLE "; N$; ".  NO SABOTAGES POSSIBLE."
400. 3910 GoTo 880
401. 3920 If C > 10 Then 3950
402. 3930 Print "NOT ENOUGH CREW TO GO ON MISSION "; N$; "."
403. 3940 GoTo 880
404. 3950 D3 = 0: D4 = 0
405. 3960 For X = S1 - 2 To S1 + 2
406.    3970 For Y = S2 - 2 To S2 + 2
407.        3980 If X < 1 Or X > 20 Or Y < 1 Or Y > 20 Then 4010
408.        3990 D3 = D3 - (A(X, Y) = 3)
409.        4000 D4 = D4 - (A(X, Y) = 6)
410.    4010 Next Y
411. 4020 Next X
412. 4030 If D3 <> 0 Then 4060
413. 4040 Print "NO SHIPS IN RANGE "; N$; "."
414. 4050 GoTo 880
415. 4060 Print "THERE ARE"; D3; "SHIPS IN RANGE "; N$; "."
416. 4070 Print "HOW MANY MEN ARE GOING "; N$;
417. 4080 Input Q1
418. 4090 If C - Q1 >= 10 Then 4120
419. 4100 Print "YOU MUST LEAVE AT LEAST 10 MEN ON BOARD "; N$; "."
420. 4110 GoTo 4070
421. 4120 D5 = Int(D3 / Q1 + .5)
422. 4130 D6 = 0
423. 4140 For X = S1 - 2 To S1 + 2
424.    4150 For Y = S2 - 2 To S2 + 2
425.        4160 If D3 / Q1 > 1 - Rnd(1) And Rnd(1) + D3 / Q1 < .9 Then 4220
426.        4170 If A(X, Y) <> 3 Then 4220
427.        4180 D6 = D6 + 1
428.        4190 A(X, Y) = 0
429.        4200 S = S - 1
430.        4210 If S = 0 Then 6260
431.    4220 Next Y
432. 4230 Next X
433. 4240 Print D6; "SHIPS WERE DESTROYED "; N$; "."
434. 4250 D6 = 0: D7 = 0
435. 4260 For X = 1 To Q1
436.    4270 D7 = D7 - (Rnd(1) > .6)
437. 4280 Next X
438. 4290 For X = 1 To Q1 - D7
439.    4300 D6 = D6 - (Rnd(1) < .15)
440. 4310 Next X
441. 4320 If D4 = 0 Then 4360
442. 4330 Print "A SEA MONSTER SMELLS THE MEN ON THE WAY BACK!!!"
443. 4340 Print D7; "MEN WERE EATEN "; N$; "!!"
444. 4350 C = C - D7
445. 4360 Print D6; "MEN WERE LOST THROUGH ACCIDENTS "; N$; "."
446. 4370 C = C - D6
447. 4380 P = P - Int(10 * Q1 + Rnd(1) * 10)
448. 4390 GoTo 4700
449. 4400 Rem *** #8: POWER CONVERTER ***
450. 4410 If D(9) >= 0 Then 4440
451. 4420 Print "POWER CONVERTER IS DAMAGED "; N$; "."
452. 4430 GoTo 880
453. 4440 If C > 5 Then 4470
454. 4450 Print "NOT ENOUGH MEN TO WORK THE CONVERTER "; N$; "."
455. 4460 GoTo 880
456. 4470 Print "OPTION? (1=FUEL TO POWER, 2=POWER TO FUEL)";
457. 4480 Input O
458. 4490 On O GOTO 4520, 4590
459. 4500 GoTo 4470
460. 4510 Rem *** FUEL TO POWER CONVERSION ***
461. 4520 Print "FUEL AVAILABLE="; F; ". CONVERT";
462. 4530 Input C1
463. 4540 If C1 > F Or C1 < 0 Then 4520
464. 4550 F = F - C1
465. 4560 P = P + Int(C1 / 3)
466. 4570 GoTo 4640
467. 4590 Print "POWER AVAILABLE="; P - 1; ". CONVERT";
468. 4600 Input C1
469. 4610 If C1 > P - 1 Or C1 < 0 Then 4590
470. 4620 P = P - C1
471. 4630 F = F + Int(C1 * 3)
472. 4640 Print "CONVERSION COMPLETE. POWER="; P; ". FUEL="; F; "."
473. 4650 GoTo 4690
474. 4660 Rem *** #9: SURRENDER ***
475. 4670 Print "COWARD!! YOU'RE NOT VERY PATRIOTIC "; N$; "!!!"
476. 4680 GoTo 6180
477. 4690 Rem *** RETALIATION SECTION ***
478. 4700 Q = 0
479. 4710 For X = S1 - 4 To S1 + 4
480.    4720 For Y = S2 - 4 To S2 + 4
481.        4730 If X < 1 Or X > 20 Or Y < 1 Or Y > 20 Then 4760
482.        4740 If A(X, Y) <> 3 Then 4760
483.        4750 Q = Q + (Rnd(1) / Sqr((S1 - X) ^ 2 + (S2 - Y) ^ 2))
484.    4760 Next Y
485. 4770 Next X
486. 4780 If Q Then 4810
487. 4790 Print "NO SHIPS IN RANGE TO DEPTH CHARGE YOU "; N$; "!!"
488. 4800 GoTo 5210
489. 4810 Print "DEPTH CHARGES OFF ";
490. 4820 If Rnd(1) > .5 Then 4850
491. 4830 Print "PORT SIDE "; N$; "!!!"
492. 4840 GoTo 4860
493. 4850 Print "STARBOARD SIDE "; N$; "!!!"
494. 4860 If Q3 > .13 Or Rnd(1) > .92 Then 4890
495. 4870 Print "NO REAL DAMAGE SUSTAINED "; N$; "."
496. 4880 GoTo 5220
497. 4890 If Q > .36 Or Rnd(1) > .96 Then 4940
498. 4900 Print "LIGHT, SUPERFICAL DAMAGE "; N$; "."
499. 4910 P = P - 50
500. 4920 D(Int(Rnd(1) * 9) + 1) = -Rnd(1) * 2
501. 4930 GoTo 5210
502. 4940 If Q > .6 Or Rnd(1) > .975 Then 5020
503. 4950 Print "MODERATE DAMAGE. REPAIRS NEEDED."
504. 4960 P = P - 75 + Int(Rnd(1) * 30)
505. 4970 For Y = 1 To 2
506.    4980 X = Int(Rnd(1) * 9) + 1
507.    4990 D(X) = D(X) - Rnd(1) * 8
508. 5000 Next Y
509. 5010 GoTo 5210
510. 5020 If Q > .9 Or Rnd(1) > .983 Then 5100
511. 5030 Print "HEAVY DAMAGE!! REPAIRS IMMEDIATE "; N$; "!!!"
512. 5040 P = P - (200 + Int(Rnd(1) * 76))
513. 5050 For X = 1 To 4 + Int(Rnd(1) * 2)
514.    5060 Y = Int(Rnd(1) * 9) + 1
515.    5070 D(Y) = D(Y) - Rnd(1) * 11
516. 5080 Next X
517. 5090 GoTo 5210
518. 5100 Print "DAMAGE CRITICAL!!!!   WE NEED HELP!!!"
519. 5110 A$ = "VRAVUKXCNVPCRHFDRSAXQURLQTRHXYACVFZYITLCBSSYYKDQIPCAEGQGPCNOTSIO"
520. 5120 X = Int(Rnd(1) * 16) + 1
521. 5130 Print "SEND 'HELP' IN CODE. HERE IS THE CODE:"; Mid$(A$, X, 4);
522. 5134 For I = 1 To 500: Next I
523. 5136 Print Chr$(13); Tab(38); "XXXX"; Chr$(13); Tab(38); "****"
524. 5140 Input "ENTER CODE"; B$
525. 5150 Print
526. 5160 If B$ <> Mid$(A$, X, 4) Then 5190
527. 5170 Print "FAST WORK "; N$; "!! HELP ARRIVES IN TIME TO SAVE YOU!!!"
528. 5180 GoTo 5040
529. 5190 Print "MESSAGE GARBLED "; N$; "...NO HELP ARRIVES!!!"
530. 5200 GoTo 6180
531. 5210 Rem *** MOVE SHIPS / SEA MONSTERS ***
532. 5220 If D(1) >= 0 Or D(3) >= 0 Or D(4) >= 0 Or D(5) >= 0 Or D(6) >= 0 Or D(7) >= 0 Then 5260
533. 5230 If D(8) >= 0 Or D(9) >= 0 Then 5270
534. 5240 Print "DAMAGE TOO MUCH "; N$; "!!!   YOU'RE SUNK!!"
535. 5250 GoTo 6180
536. 5260 Rem *** MOVE SHIPS / SEA MONSTERS ***
537. 5270 Print: Print: Print "---*** RESULT OF LAST ENEMY MANUEVER ***---"
538. 5280 For X = 1 To 20
539.    5290 For Y = 1 To 20
540.        5300 If A(X, Y) <> 3 Then 5690
541.        5310 Rem *** MOVE A SHIP ***
542.        5320 W = D8
543.        5330 V = D9
544.        5340 If X + W > 0 And X + W < 21 And Y + V > 0 And Y + V < 21 Then 5420
545.        5350 For X0 = 19 To 1 Step -1
546.            5360 If A(X - W * X0, Y - V * X0) <> 0 Then 5400
547.            5370 A(X - W * X0, Y - V * X0) = 3
548.            5380 A(X, Y) = 0
549.            5390 GoTo 6000
550.        5400 Next X0
551.        5410 Stop
552.        5420 On A(X + W, Y + V) + 1 GOTO 5430, 5460, 5530, 5460, 5560, 5600, 5650
553.        5430 A(X + W, Y + V) = 3
554.        5440 A(X, Y) = 0
555.        5450 GoTo 6000
556.        5460 Rem *** CHANGE DIRECTION ***
557.        5470 Restore 6090
558.        5480 For X0 = 1 To Int(Rnd(1) * 8) + 1
559.            5490 Read W, V
560.        5500 Next X0
561.        5510 If X + W < 1 Or X + W > 20 Or Y + V < 1 Or Y + V > 20 Then 5470
562.        5520 GoTo 5420
563.        5530 If D > 50 Then 5460
564.        5540 Print "*** YOU'VE BEEN RAMMED BY A SHIP "; N$; "!!! ***"
565.        5550 GoTo 6180
566.        5560 If Rnd(1) < .15 Then 5460
567.        5570 Print "*** YOUR HEADQUARTERS WAS RAMMED "; N$; "!!! ***"
568.        5580 S3 = 0: S4 = 0: D2 = 0: A(X + W, Y + V) = 0
569.        5590 GoTo 5620
570.        5600 If Rnd(1) < .7 Then 5460
571.        5610 Print "*** SHIP DESTROYED BY A MINE "; N$; "!!! ***"
572.        5620 S = S - 1
573.        5630 If S <> 0 Then 5440
574.        5640 GoTo 6260
575.        5650 If Rnd(1) < .8 Then 5460
576.        5660 Print "*** SHIP EATEN BY A SEA MONSTER "; N$; "!! ***"
577.        5670 S = S - 1
578.        5680 GoTo 5630
579.        5690 Rem *** MOVE A SEA MONSTER ***
580.        5700 If A(X, Y) <> 6 Then 6000
581.        5710 If X + M1 < 1 Or X + M1 > 20 Or Y + M2 < 1 Or Y + M2 > 20 Then 5760
582.        5720 On A(X + M1, Y + M2) + 1 GOTO 5730, 5760, 5830, 5850, 5900, 5730, 5930
583.        5730 A(X + M1, Y + M2) = 6
584.        5740 A(X, Y) = 0
585.        5750 GoTo 6000
586.        5760 Rem *** CHANGE DIRECTION ***
587.        5770 Restore 6090
588.        5780 For X0 = 1 To Int(Rnd(1) * 8) + 1
589.            5790 Read M1, M2
590.        5800 Next X0
591.        5810 If X + M1 < 1 Or X + M1 > 20 Or Y + M2 < 1 Or Y + M2 > 20 Then 5760
592.        5820 GoTo 5720
593.        5830 Print "*** YOU'VE BEEN EATEN BY A SEA MONSTER "; N$; "!! ***"
594.        5840 GoTo 6180
595.        5850 If Rnd(1) > .2 Then 5760
596.        5860 Print "*** SHIP EATEN BY A SEA MONSTER "; N$; "!! ***"
597.        5870 S = S - 1
598.        5880 If S <> 0 Then 5730
599.        5890 GoTo 6260
600.        5900 Print "*** A SEA MONSTER ATE YOU HEADQUARTERS "; N$; "!! ***"
601.        5910 S3 = 0: S4 = 0: D2 = 0
602.        5920 GoTo 5730
603.        5930 If Rnd(1) < .75 Then 5760
604.        5940 Print "*** A SEA MONSTER FIGHT "; N$; "!!! ";
605.        5950 If Rnd(1) < .8 Then 5980
606.        5960 Print "AND ONE DIES!! ***"
607.        5970 GoTo 5730
608.        5980 Print "IT'S A TIE!! ***"
609.        5990 GoTo 5760
610.    6000 Next Y
611. 6010 Next X
612. 6020 Rem *** MAKE REPAIRS ***
613. 6030 For Y = 1 To 9
614.    6040 X = Int(Rnd(1) * 9) + 1
615.    6050 D(X) = D(X) + (Rnd(1) * (2 + Rnd(1) * 2)) * (1 + (-(D < 51) Or -(D > 2000))) * (-(D(X) < 3))
616. 6060 Next Y
617. 6070 GoTo 880
618. 6080 Rem *** GOSUB FOR COURSE / DIRECTION ***
619. 6090 Data -1,0,-1,1,0,1,1,1,1,0,1,-1,0,-1,-1,-1
620. 6100 Print "COURSE (1-8)";
621. 6110 Input C1
622. 6120 If C1 < 1 Or C1 > 8 Then 6100
623. 6130 Restore 6090
624. 6140 For X9 = 1 To Int(C1 + .5)
625.    6150 Read X1, Y1
626. 6160 Next X9
627. 6170 Return
628. 6180 Rem *** DESTROYED ? ***
629. 6190 Print "THERE ARE STILL"; S; "ENEMY SHIPS LEFT "; N$; "."
630. 6200 Print "YOU WILL BE DEMOTED TO THE RANK OF DECK SCRUBBER!!!"
631. 6210 Print "WANT ANOTHER GAME";
632. 6220 Input A$
633. 6230 If Left$(A$, 1) <> "Y" Then 6250
634. 6240 GoTo 310
635. 6250 Stop
636. 6260 Print "GOOD WORK "; N$; "!!!  YOU GOT THEM ALL!!!"
637. 6270 Print "PROMOTION AND COMMENDATIONS WILL BE GIVEN IMMEDIATELY!!!"
638. 6280 GoTo 6210
639. 6300 Data 0,1,1,1,0,0,0,1,1,1,1,0,1,1,1,0,1,1,1,1,0,0,0,1
640. 6310 Data 1,1,0,0,1,1,0,1,1,0,1,0,0,0,1,0,0,0
641. 6320 End
642.  
643.  

[johnno56]

That's the one!  I plan to use three panels, instead of having the text scroll off the screen... Top left will be the main ocean map. Top right will show ammunition and other submarine stats. The third panel (letter box style) will sit beneath the top two panels and will use the full width of the screen. I may go with Screen 12.

The Star Trek game (based on the same book) will use 5 panels... I hope...

[Cobalt]

Perhaps find an old game called EGA TREK for inspiration on the "panel" layout.

[SMcNeill]

If you need a little more power than just printing to a panel area, you might want to try out my Frame Library.  https://qb64forum.alephc.xyz/index.php?topic=718.0

The idea behind it is rather simple:

First, define a frame area with:

LeftFrame = NewTextArea(0, 0, 400, _Height - 1, False)
RightFrame = NewTextArea(401, 0, _Width - 1, _Height - 1, False)

Based off the FUNCTION NewTextArea% (tx1 AS INTEGER, ty1 AS INTEGER, tx2 AS INTEGER, ty2 AS INTEGER, SaveBackground AS INTEGER)

So, in the two above examples, LeftFrame goes from (0,0)-(400, _height-1) and we don't save the background.  RightFrame goes from (400,0)-(_width-1, _height-1) and doesn't save the background.


After that, we PrintOut to the frames, with a simple little call to:

SUB PrintOut (WhichHandle AS INTEGER, What AS STRING) 

Which we use as simple as:

PrintOut LeftFrame, "Whatever I want to print to the left side."
PrintOut RightFrame, "Whatever I want to print to the right side."

And the library has a lot more functions included with it so you can justify your printing inside a frame (left, right, center), change colors, hide backgrounds, use the frame as a pop-up and then close it and restore your screen when finished, ect, ect...


It's a little bit more complicated than the simple method I showed you above, but it's a whole lot more powerful as well, with a lot of nice features built in which might reduce your development time considerably.  (Especially if you want to justify words or implement word wrap into your text adventure, as it can do those things for you automatically.)

[OldMoses]

I did one a while back for taking a picture and superimposing a square or hex grid over a loaded picture. It then saves the resulting image with Steve's SaveImage utility. It displays a smaller navigation image on the left side.

The heart of that aspect of the program is SUB Image_Resize, which will put any size image in any other size area of another image or screen. It will justify up/down/left/right/center within the defined space and maintain the original images aspect ratio.

Maybe you can find it of some utility in slapping up image panels on a screen, the images should be of similar aspect ratio to the space if there are not to be some rather large waste areas.

Code: QB64: [Select]

1. '$INCLUDE:'SaveImage.BI'
2. 'Grid-a-Pic version 0.2
3. 'Thanks go to:  Steve McNeill for SaveImage
4. '               Galleon/Bplus for Rotozoom3
5.  
6. TYPE object
7.     x AS INTEGER
8.     y AS INTEGER
9. END TYPE
10.  
11. 'GLOBAL VARIABLES
12. DIM SHARED camera AS object
13. DIM dWidth AS INTEGER
14. DIM dHeight AS INTEGER
15. DIM mWidth AS INTEGER
16. DIM mHeight AS INTEGER
17. DIM SHARED wWidth AS INTEGER
18. DIM SHARED wHeight AS INTEGER
19. DIM SHARED navrat AS SINGLE '                                   nav map reduction ratio
20. DIM SHARED gsiz AS INTEGER
21. DIM SHARED hOff AS INTEGER
22. DIM SHARED vOff AS INTEGER
23. DIM SHARED gtog AS _BYTE '                                      Grid state toggle
24. '                                                               bit 0 = Hex(1) Box(0)
25. '                                                               bit 1 = 1 on 0 off
26.  
27. DIM SHARED mp AS LONG '                                         working image handle
28. DIM SHARED mpt& '                                               temp working image
29. DIM SHARED main& '                                              main display handle
30. DIM SHARED grid& '                                              grid image handle
31. DIM SHARED arw& '                                               offset arrow handle
32. DIM SHARED abyt AS _UNSIGNED _BYTE '                            Alpha
33. DIM SHARED rbyt AS _UNSIGNED _BYTE '                            Red
34. DIM SHARED gbyt AS _UNSIGNED _BYTE '                            Green
35. DIM SHARED bbyt AS _UNSIGNED _BYTE '                            Blue
36.  
37. 'INITIAL PARAMETERS
38. dWidth = _DESKTOPWIDTH '                                        Desktop size
39. dHeight = _DESKTOPHEIGHT - 80 '                                 leave room for task bar
40. wWidth = dWidth - 401 '                                         Window size
41. wHeight = dHeight
42. mp = _NEWIMAGE(wWidth, wHeight, 32)
43. mWidth = _WIDTH(mp) '                                           Map/pic size
44. mHeight = _HEIGHT(mp)
45. gsiz = 35: hOff = 0: vOff = 0 '                                 grid size 35 pixels, no offsets
46. abyt = 127: rbyt = 127: gbyt = 127: bbyt = 127
47. main& = _NEWIMAGE(dWidth, dHeight, 32) '                        Complete display screen
48. grid& = _NEWIMAGE(mWidth, mHeight, 32) '                        grid handle
49. arw& = _NEWIMAGE(30, 30, 32) '                                  grid positioning arrow
50. Make_Arrow
51. SCREEN main&
52. DO UNTIL _SCREENEXISTS
53. LOOP
54. _TITLE "GridPic (esc to quit, arrows to pan, +/- to resize grid, 'h' for hex grid, 'b' for box grid)"
55. _SCREENMOVE 0, 0
56. IF _CAPSLOCK THEN _CAPSLOCK OFF
57.  
58. 'Main program loop
59. in = -1 '                                                       short around the input loop on startup
60. DO
61.     DO 'begin input loop
62.         IF _KEYDOWN(98) THEN '                                  Box grid has been toggled "b"
63.             IF _READBIT(gtog, 1) THEN '                         If grid is on
64.                 IF _READBIT(gtog, 0) THEN '                     and it is a hex
65.                     gtog = _RESETBIT(gtog, 0) '                 then make it a box
66.                 ELSE '                                          if it's already a box
67.                     gtog = _TOGGLEBIT(gtog, 1) '                then turn it off
68.                 END IF
69.             ELSE '                                              if grid is off
70.                 gtog = _RESETBIT(gtog, 0) '                     set for box and,
71.                 gtog = _TOGGLEBIT(gtog, 1) '                    turn the grid on
72.             END IF
73.             _DELAY .2
74.             : in = -1
75.         END IF
76.         IF _KEYDOWN(104) THEN '                                 Hex grid has been toggled "h"
77.             IF _READBIT(gtog, 1) THEN '                         If the grid is on
78.                 IF NOT _READBIT(gtog, 0) THEN '                 and it is a box
79.                     gtog = _SETBIT(gtog, 0) '                   then make it a hex
80.                 ELSE '                                          if it's already a hex
81.                     gtog = _TOGGLEBIT(gtog, 1) '                then turn it off
82.                 END IF
83.             ELSE '                                              if the grid is off
84.                 gtog = _SETBIT(gtog, 0) '                       set for hex and,
85.                 gtog = _TOGGLEBIT(gtog, 1) '                    turn the grid on
86.             END IF
87.             _DELAY .2
88.             : in = -1
89.         END IF
90.         IF _KEYDOWN(115) THEN Save_Gridpic: in = -1
91.         IF _KEYDOWN(111) THEN Load_Image: in = -1
92.         IF _KEYDOWN(43) THEN gsiz = gsiz + 1: in = -1 '         increase grid size
93.         IF _KEYDOWN(45) THEN gsiz = gsiz - 1 - (gsiz = 6): in = -1 'decrease grid size, limit to 6 or more
94.         IF _KEYDOWN(18432) THEN camera.y = camera.y - 10 - ((camera.y = 0) * 10): in = -1
95.         IF _KEYDOWN(20480) THEN camera.y = camera.y + 10 + ((camera.y > (_HEIGHT(mp) - wHeight)) * 10): in = -1
96.         IF _KEYDOWN(19200) THEN camera.x = camera.x - 10 - ((camera.x = 0) * 10): in = -1
97.         IF _KEYDOWN(19712) THEN camera.x = camera.x + 10 + ((camera.x > (_WIDTH(mp) - wWidth)) * 10): in = -1
98.         IF _KEYDOWN(27) THEN SYSTEM
99.         IF _KEYDOWN(113) THEN SYSTEM
100.         IF _KEYDOWN(97) AND hOff > -gsiz / 2 THEN hOff = hOff - 1: in = -1
101.         IF _KEYDOWN(100) AND hOff < gsiz / 2 THEN hOff = hOff + 1: in = -1
102.         IF _KEYDOWN(119) AND vOff > -gsiz / 2 THEN vOff = vOff - 1: in = -1
103.         IF _KEYDOWN(122) AND vOff < gsiz / 2 THEN vOff = vOff + 1: in = -1
104.  
105.         WHILE _MOUSEINPUT
106.         WEND
107.         IF _MOUSEBUTTON(1) THEN
108.             Mouse_Ops _MOUSEX, _MOUSEY
109.             in = -1
110.         END IF
111.         _LIMIT 30
112.     LOOP UNTIL in 'end of input loop
113.     in = 0
114.  
115.     'Create grid overlay
116.     _DEST grid&
117.     CLS
118.     IF _READBIT(gtog, 1) THEN '                                 if grid is enabled
119.         IF _READBIT(gtog, 0) THEN '                             if hex enabled
120.             Hex_Grid gsiz, hOff, vOff
121.         ELSE '                                                  if box enabled
122.             Box_Grid gsiz, hOff, vOff
123.         END IF
124.     END IF
125.     _CLEARCOLOR _RGB32(0, 0, 0)
126.     _DEST main&
127.  
128.     'place finished images in screen window
129.     CLS
130.     IF _WIDTH(mp) < wWidth THEN b = wWidth / _WIDTH(mp) ELSE b = 1
131.     _PUTIMAGE , mp, mpt& '                                      put map onto temp map
132.     _PUTIMAGE , grid&, mpt& '                                   overlay grid onto temp map
133.     _PUTIMAGE (400, 0), mpt&, main&, (camera.x, camera.y)-(camera.x + wWidth, camera.y + wHeight) 'temp map to main display
134.     LINE (0, 200)-(399, _HEIGHT(main&) - 1), &HFF0000FF, B
135.     Image_Resize 0, 200, 399, _HEIGHT(main&) - 1, mp, main&, "l", "u" 'Place nav map in navmap window
136.     navrat = navrat / b
137.     LINE (camera.x * navrat, 200 + camera.y * navrat)-((camera.x + wWidth) * navrat, 200 + (camera.y + wHeight) * navrat), &HFFFF0000, B
138.     LINE (camera.x * navrat + 1, 201 + camera.y * navrat)-((camera.x + wWidth) * navrat - 1, 199 + (camera.y + wHeight) * navrat), &HFFFF0000, B
139.  
140.     Para_Disp
141.  
142.     _LIMIT 30
143.     _DISPLAY
144. LOOP
145. 'End main program loop
146.  
147. '                                                               END: MAIN MODULE / BEGIN SUBROUTINES
148.  
149.  
150. SUB Box_Grid (siz AS INTEGER, h AS INTEGER, v AS INTEGER)
151.  
152.     DIM s, ho, vo
153.     COLOR _RGBA32(rbyt, gbyt, bbyt, abyt)
154.     s = siz
155.     ho = 0
156.     DO 'vertical lines
157.         LINE (ho * s + h, 0)-(ho * s + h, _HEIGHT(grid&) - 1)
158.         ho = ho + 1
159.     LOOP UNTIL ho * s > _WIDTH(grid&)
160.     vo = 0
161.     DO 'horizontal lines
162.         LINE (0, vo * s + v)-(_WIDTH(grid&) - 1, vo * s + v)
163.         vo = vo + 1
164.     LOOP UNTIL vo * s + v > _HEIGHT(grid&)
165.  
166. END SUB 'Box_Grid
167.  
168.  
169. SUB Con_Blok (xpos AS INTEGER, ypos AS INTEGER, xsiz AS INTEGER, ysiz AS INTEGER, label AS STRING, high AS INTEGER, col AS _UNSIGNED LONG)
170.  
171.     'Create control block
172.     DIM CN&, x, p, sx, sy
173.     CN& = _NEWIMAGE(xsiz, ysiz, 32)
174.     _DEST CN&
175.     COLOR , col
176.     CLS
177.     _PRINTMODE _KEEPBACKGROUND
178.     x = LEN(label)
179.     sx = xsiz / 2 - x * 4: sy = ysiz / 2 - 8
180.     FOR p = 1 TO x '                                            iterate through label characters
181.         IF p = high THEN '                                      print hotkey highlight color (red) else (black)
182.             IF col = &HFFFF0000 THEN
183.                 COLOR &HFFFFFFFF
184.             ELSE
185.                 COLOR &HFFFF0000
186.             END IF
187.         ELSE
188.             COLOR &HFF000000
189.         END IF
190.         _PRINTSTRING (sx + (p - 1) * 8, sy), MID$(label, p, 1)
191.     NEXT p
192.     _PUTIMAGE (xpos, ypos), CN&, main&
193.     _FREEIMAGE CN&
194.  
195. END SUB 'Con_Blok
196.  
197.  
198. SUB DialogBox (heading AS STRING, xsiz AS INTEGER, ysiz AS INTEGER, ypos AS INTEGER, bcol AS _UNSIGNED LONG, tcol AS _UNSIGNED LONG)
199.  
200.     'superimpose a screen centered input box for various input routines
201.     cr& = _DEST '                                               save calling destination
202.     dbox& = _NEWIMAGE(xsiz, ysiz, 32) '                         define box
203.     _DEST dbox&
204.     COLOR tcol, &HFF000000 '                                    set text color with black background
205.     CLS
206.     FOR x% = 0 TO 5 '                                           draw bounding box 6 pixels thick
207.         b~& = -Black * (x% < 2) - bcol * (x% >= 2) '             color=outer two black, balance bcol
208.         LINE (0 + x%, 0 + x%)-(xsiz - 1 - x%, ysiz - 1 - x%), b~&, B 'draw color border
209.     NEXT x%
210.     _PRINTSTRING (_SHR(xsiz, 1) - _SHL(LEN(heading), 2), 31), heading 'print heading two rows below top
211.     _DEST cr& '                                                 reset to calling destination
212.     _PUTIMAGE (_SHR(_WIDTH, 1) - _SHR(xsiz, 1), ypos), dbox& '  display box centered over calling destination image
213.     _FREEIMAGE dbox& '                                          clean up
214.  
215. END SUB 'DialogBox
216.  
217.  
218. SUB Hex_Grid (siz AS INTEGER, h AS INTEGER, v AS INTEGER)
219.  
220.     'siz= size in pixels across hex flats
221.     'h= horizontal bias
222.     'v= vertical bias
223.     DIM s, sb, ho, vo, vo2, ro, col, of, roho, colvo
224.     CLS
225.     s = siz / (2 * SIN(_PI / 3)) '                              side length
226.     sb = s / 2 '                                                slope apex horzontal distance
227.     ho = s + sb '                                               horizontal offset
228.     vo = siz '                                                  vertical offset
229.     vo2 = vo / 2 '                                              1/2 vertical offset
230.     COLOR _RGBA32(rbyt, gbyt, bbyt, abyt)
231.     ro = -1 '                                                   starting row position
232.     DO '                                                        x row loop
233.         col = -1 '                                              starting column position
234.         roho = ro * ho + h '                                    row position x horizontal offset + horizontal bias
235.         of = -(vo2) * (ro MOD 2 = 0) '                          even/odd bias, branchless for: IF ro MOD 2 = 0 THEN of = vo2 ELSE of = 0
236.         DO '                                                    y column loop
237.             colvo = col * vo + v + of '                         column position x vertical offset + vertical bias + even/odd row bias
238.             LINE (roho - sb, colvo)-(roho + sb, colvo) '        hex horizontal
239.             LINE (roho + sb, colvo)-(roho + s, colvo - vo2) '   hex up leg
240.             LINE (roho + sb, colvo)-(roho + s, colvo + vo2) '   hex down leg
241.             col = col + 1 '                                     advance column
242.         LOOP UNTIL (col - 1) * vo > _HEIGHT(grid&)
243.         ro = ro + 1 '                                           advance row
244.     LOOP UNTIL (ro - 1) * ho > _WIDTH(grid&)
245.  
246. END SUB 'Hex_Grid
247.  
248.  
249. '²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²²
250. SUB Image_Resize (xpos AS INTEGER, ypos AS INTEGER, xlim AS INTEGER, ylim AS INTEGER, i AS LONG, d AS LONG, xj AS STRING, yj AS STRING)
251.  
252.     DIM AS INTEGER xs, ys, xp, yp, xl, yl
253.     DIM AS SINGLE rt, xrt, yrt
254.     xrt = (xlim - xpos) / _WIDTH(i) '                           width of area divided by width of image
255.     yrt = (ylim - ypos) / _HEIGHT(i) '                          height of area divided by height of image
256.     rt = -xrt * (xrt < yrt) - yrt * (yrt <= xrt) '             pick the smaller of the two ratios to fit area
257.     navrat = rt '                                               for global use-can be removed in other programs that don't need it
258.     xs = _WIDTH(i) * rt '                                       final image size ratio in x
259.     ys = _HEIGHT(i) * rt '                                      final image size ratio in y
260.  
261.     xp = -xpos * (xj = "l") - (_SHR(xlim - xpos, 1) + xpos - _SHR(xs, 1)) * (xj = "c") - (xlim - xs) * (xj = "r")
262.     xl = xp + xs
263.     yp = -ypos * (yj = "u") - (_SHR(ylim - ypos, 1) + ypos - _SHR(ys, 1)) * (yj = "c") - (ylim - ys) * (yj = "d")
264.     yl = yp + ys
265.     _PUTIMAGE (xp, yp)-(xl, yl), i, d
266.  
267. END SUB 'Image_Resize
268.  
269.  
270. SUB Load_Image
271.  
272.     DialogBox "Load Image", 600, 400, 50, &HFF00FF00, &HFFFFFFFF
273.     _PRINTSTRING (_WIDTH(main&) / 2 - 140, 116), "Input path \ filename and extension", 0
274.     _DISPLAY
275.     _KEYCLEAR
276.     LOCATE 148 \ 16, (_WIDTH(main&) / 2 - 120) \ 8
277.     INPUT ": ", fn$: fn$ = _TRIM$(fn$)
278.     IF _FILEEXISTS(fn$) THEN
279.         _FREEIMAGE (mp)
280.         IF mpt& < -1 THEN _FREEIMAGE (mpt&)
281.         _FREEIMAGE (grid&)
282.         mp = _LOADIMAGE(fn$, 32)
283.         IF mp = -1 THEN mp = _LOADIMAGE(fn$)
284.         mwidth = _WIDTH(mp)
285.         mheight = _HEIGHT(mp)
286.         grid& = _NEWIMAGE(mwidth, mheight, 32)
287.         IF _WIDTH(mp) < wWidth THEN b = wWidth / _WIDTH(mp) ELSE b = 1
288.         mpt& = _NEWIMAGE(_WIDTH(mp) * b, _HEIGHT(mp) * b, 32)
289.         camera.x = 0: camera.y = 0
290.     ELSE
291.     END IF
292.  
293. END SUB 'Load_Image
294.  
295.  
296. SUB Make_Arrow
297.  
298.     _DEST arw&
299.     CLS
300.     _CLEARCOLOR &HF000000
301.     COLOR &HFF00FF00
302.     LINE (15, 5)-(25, 25)
303.     LINE (25, 25)-(15, 16)
304.     LINE (15, 16)-(5, 25)
305.     LINE (5, 25)-(15, 5)
306.     _DEST 0
307.  
308. END SUB 'Make_Arrow
309.  
310.  
311. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
312.  
313.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
314.  
315. END FUNCTION 'map!
316.  
317.  
318. SUB Mouse_Ops (xpos AS INTEGER, ypos AS INTEGER)
319.  
320.     SELECT CASE xpos
321.         CASE IS < 400 '                                         left screen cases
322.             SELECT CASE ypos
323.                 CASE IS < 25
324.                     SELECT CASE xpos
325.                         CASE 0 TO 39 '                          open
326.                             Load_Image
327.                         CASE 50 TO 89 '                         save
328.                             Save_Gridpic
329.                         CASE 100 TO 139: SYSTEM
330.                         CASE 200 TO 239 '                       hex button click
331.                             IF _READBIT(gtog, 1) THEN '         if grid active
332.                                 IF NOT _READBIT(gtog, 0) THEN ' and box
333.                                     gtog = _SETBIT(gtog, 0) '   change to hex
334.                                 ELSE '                          otherwise
335.                                     gtog = _RESETBIT(gtog, 1) ' make grid inactive
336.                                 END IF
337.                             ELSE '                              otherwise if grid inactive
338.                                 gtog = _SETBIT(gtog, 1) '       activate it
339.                                 gtog = _SETBIT(gtog, 0) '       as a hex
340.                             END IF
341.                             _DELAY .2
342.                         CASE 250 TO 289 '                       box button click
343.                             IF _READBIT(gtog, 1) THEN '         if grid active
344.                                 IF _READBIT(gtog, 0) THEN '     and hex
345.                                     gtog = _RESETBIT(gtog, 0) ' change to box
346.                                 ELSE
347.                                     gtog = _RESETBIT(gtog, 1) ' make grid inactive
348.                                 END IF
349.                             ELSE '                              otherwise
350.                                 gtog = _SETBIT(gtog, 1) '       activate it
351.                                 gtog = _RESETBIT(gtog, 0) '     as a box
352.                             END IF
353.                             _DELAY .2
354.                     END SELECT
355.                 CASE 24 TO 199 '                                color, size & offset
356.                     SELECT CASE xpos
357.                         CASE 5 TO 200 '                         color block
358.                             SELECT CASE ypos
359.                                 CASE 50 TO 60 '                 alpha
360.                                     abyt = map!(xpos, 5, 200, 1, 255)
361.                                 CASE 90 TO 100 '                red
362.                                     rbyt = map!(xpos, 5, 200, 1, 255)
363.                                 CASE 130 TO 140 '               green
364.                                     gbyt = map!(xpos, 5, 200, 1, 255)
365.                                 CASE 170 TO 180 '               blue
366.                                     bbyt = map!(xpos, 5, 200, 1, 255)
367.                             END SELECT
368.                         CASE IS > 200 '                         size & offset cross
369.                             SELECT CASE ypos
370.                                 CASE 46 TO 70
371.                                     SELECT CASE xpos
372.                                         CASE 225 TO 257
373.                                             gsiz = gsiz - 1
374.                                         CASE 343 TO 375
375.                                             gsiz = gsiz + 1
376.                                     END SELECT
377.                                 CASE 90 TO 120
378.                                     SELECT CASE xpos
379.                                         CASE 286 TO 314 '       offset up
380.                                             IF vOff > -gsiz / 2 THEN vOff = vOff - 1
381.                                     END SELECT
382.                                 CASE 121 TO 149
383.                                     SELECT CASE xpos
384.                                         CASE 255 TO 285 '       offset left
385.                                             IF hOff > -gsiz / 2 THEN hOff = hOff - 1
386.                                         CASE 286 TO 314 '       offset to (0, 0)
387.                                             hOff = 0: vOff = 0
388.                                         CASE 315 TO 345 '       offset right
389.                                             IF hOff < gsiz / 2 THEN hOff = hOff + 1
390.                                     END SELECT
391.                                 CASE 150 TO 180
392.                                     SELECT CASE xpos
393.                                         CASE 286 TO 314 '       offset down
394.                                             IF vOff < gsiz / 2 THEN vOff = vOff + 1
395.                                     END SELECT
396.                             END SELECT
397.  
398.                     END SELECT
399.                 CASE IS > 199
400.                     'move the camera box in the navmap
401.                     'LINE (camera.x * navrat, 200 + camera.y * navrat)-((camera.x + wWidth) * navrat, 200 + (camera.y + wHeight) * navrat), &HFFFF0000, B
402.                     'LINE (camera.x * navrat + 1, 201 + camera.y * navrat)-((camera.x + wWidth) * navrat - 1, 199 + (camera.y + wHeight) * navrat), &HFFFF0000, B
403.  
404.                     ''This works at the upper left corner
405.                     camera.x = xpos / navrat
406.                     camera.y = (ypos - 200) / navrat
407.  
408.                     ''Trying to get it centered
409.                     'camera.x = (xpos - ((wWidth / 2) / navrat)) / navrat ' - wWidth * navrat
410.                     'camera.y = (ypos - 200) / navrat
411.                     'camera.x = map!(xpos, 0, 400, 0, _WIDTH(mp) - 1)
412.                     'camera.y = map!(ypos,200,_height(main&)-1,0, )
413.             END SELECT '                                        end: left screen ypos cases
414.         CASE ELSE
415.             _MOUSEMOVE 400 + wWidth / 2, wHeight / 2
416.             camera.x = camera.x - (xpos - 400 - wWidth / 2)
417.             camera.y = camera.y - (ypos - wHeight / 2)
418.     END SELECT
419.  
420. END SUB 'Mouse_Ops
421.  
422.  
423. SUB Panel_Blank (xpos AS INTEGER, ypos AS INTEGER, xsiz AS INTEGER, ysiz AS INTEGER, col AS LONG)
424.  
425.     'Background blank to mark and mask button use and/or changes
426.     DIM CN&
427.     CN& = _NEWIMAGE(xsiz, ysiz, 32) '                           active button overlay
428.     _DEST CN&
429.     COLOR , col '                                               set overlay background color
430.     CLS
431.     _PUTIMAGE (xpos, ypos), CN&, main& '                        cover button
432.     _FREEIMAGE CN&
433.  
434. END SUB 'Panel_Blank
435.  
436.  
437. SUB Para_Disp
438.  
439.     'Display available parameters and controls
440.     Con_Blok 0, 0, 40, 24, "Open", 1, &HFF00FF00
441.     Con_Blok 50, 0, 40, 24, "Save", 1, &HFF0000FF
442.     Con_Blok 100, 0, 40, 24, "Quit", 1, &HFFFF0000
443.     Con_Blok 200, 0, 40, 24, "Hex", 1, &HFFF0F0F0
444.     Con_Blok 250, 0, 40, 24, "Box", 1, &HFFF0F0F0
445.     IF _READBIT(gtog, 1) THEN
446.         IF _READBIT(gtog, 0) THEN
447.             Panel_Blank 250, 0, 40, 24, &H9F000000
448.         ELSE
449.             Panel_Blank 200, 0, 40, 24, &H9F000000
450.         END IF
451.     ELSE
452.         Panel_Blank 200, 0, 40, 24, &H9F000000
453.         Panel_Blank 250, 0, 40, 24, &H9F000000
454.     END IF
455.  
456.     _PRINTSTRING (5, 30), "Alpha " + STR$(abyt) '               color bars
457.     LINE (5, 50)-(200, 60), &HFF7F7F7F, B
458.     LINE (5, 50)-(map!(abyt, 1, 255, 5, 200), 60), &HFF7F7F7F, BF
459.     _PRINTSTRING (5, 70), "Red " + STR$(rbyt)
460.     LINE (5, 90)-(200, 100), &HFF7F0000, B
461.     LINE (5, 90)-(map!(rbyt, 1, 255, 5, 200), 100), &HFF7F0000, BF
462.     _PRINTSTRING (5, 110), "Green " + STR$(gbyt)
463.     LINE (5, 130)-(200, 140), &HFF007F00, B
464.     LINE (5, 130)-(map!(gbyt, 1, 255, 5, 200), 140), &HFF007F00, BF
465.     _PRINTSTRING (5, 150), "Blue " + STR$(bbyt)
466.     LINE (5, 170)-(200, 180), &HFF0000FF, B
467.     LINE (5, 170)-(map!(bbyt, 1, 255, 5, 200), 180), &HFF0000FF, BF
468.  
469.     _PRINTSTRING (284, 30), "Size" '                            size buttons
470.     Con_Blok 225, 46, 32, 24, "-", 1, &HFF00007F
471.     Con_Blok 343, 46, 32, 24, "+", 1, &HFF00007F
472.     _PRINTSTRING (284, 48), STR$(gsiz)
473.  
474.     LINE (285, 90)-(315, 180), &HFFFFFFFF, B '                  offset cross
475.     LINE (255, 120)-(345, 150), &HFFFFFFFF, B
476.     CIRCLE (300, 135), 8, &HFFFF0000
477.     LINE (290, 135)-(310, 135), &HFFFF0000
478.     LINE (300, 125)-(300, 145), &HFFFF0000
479.     RotoZoom3 285 + _WIDTH(arw&) / 2, 90 + _HEIGHT(arw&) / 2, arw&, 1, 1, 0
480.     RotoZoom3 255 + _WIDTH(arw&) / 2, 120 + _HEIGHT(arw&) / 2, arw&, 1, 1, _PI * 3 / 2
481.     RotoZoom3 315 + _WIDTH(arw&) / 2, 120 + _HEIGHT(arw&) / 2, arw&, 1, 1, _PI / 2
482.     RotoZoom3 285 + _WIDTH(arw&) / 2, 150 + _HEIGHT(arw&) / 2, arw&, 1, 1, _PI
483.  
484. END SUB 'Para_Disp
485.  
486.  
487. SUB RotoZoom3 (X AS LONG, Y AS LONG, Image AS LONG, xScale AS SINGLE, yScale AS SINGLE, radianRotation AS SINGLE)
488.  
489.     ' Thanks be to Galleon and Bplus for this SUB, wish I was this good...
490.     ' This assumes you have set your drawing location with _DEST or default to screen.
491.     ' X, Y - is where you want to put the middle of the image
492.     ' Image - is the handle assigned to the image to be rotated
493.     ' xScale, yScale - are shrinkage < 1 or magnification > 1 on the given axis, 1 just uses image size.
494.     ' These are multipliers so .5 will create image .5 size on given axis and 2 for twice image size.
495.     ' radianRotation is the Angle in Radian units to rotate the image
496.     ' note: Radian units for rotation because it matches angle units of other Basic Trig functions
497.     '       and saves a little time converting from degree.
498.     '       Use the _D2R() function if you prefer to work in degree units for angles.
499.  
500.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE '                  simple arrays for x, y to hold the 4 corners of image
501.     DIM W&, H&, sinr!, cosr!, i&, x2&, y2& '                    variables for image manipulation
502.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
503.     px(0) = -W& / 2: py(0) = -H& / 2 '                          left top corner
504.     px(1) = -W& / 2: py(1) = H& / 2 '                           left bottom corner
505.     px(2) = W& / 2: py(2) = H& / 2 '                            right bottom
506.     px(3) = W& / 2: py(3) = -H& / 2 '                           right top
507.     sinr! = SIN(-radianRotation): cosr! = COS(-radianRotation) 'rotation helpers
508.     FOR i& = 0 TO 3 '                                           calc new point locations with rotation and zoom
509.         x2& = xScale * (px(i&) * cosr! + sinr! * py(i&)) + X: y2& = yScale * (py(i&) * cosr! - px(i&) * sinr!) + Y
510.         px(i&) = x2&: py(i&) = y2&
511.     NEXT
512.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
513.     _MAPTRIANGLE _SEAMLESS(0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
514.  
515. END SUB 'RotoZoom3
516.  
517.  
518. SUB Save_Gridpic
519.  
520.     DIM si&, fn$, fn1$, r
521.     DialogBox "Save Image", 600, 400, 50, &HFF0000FF, &HFFFFFFFF
522.     si& = _COPYIMAGE(mp&, 32)
523.     _PUTIMAGE , grid&, si&
524.     _PRINTSTRING (_WIDTH(main&) / 2 - 140, 116), "Input path \ filename and extension", 0
525.     _DISPLAY
526.     LOCATE 148 \ 16, (_WIDTH(main&) / 2 - 120) \ 8
527.     INPUT ": ", fn$: fn$ = _TRIM$(fn$)
528.     r = SaveImage(fn$, si&, 0, 0, _WIDTH(si&) - 1, _HEIGHT(si&) - 1)
529.     IF r = 1 THEN
530.         fn1$ = "grid_" + fn$
531.         r = SaveImage(fn1$, si&, 0, 0, _WIDTH(si&) - 1, _HEIGHT(si&) - 1)
532.     END IF
533.     IF r < 0 THEN
534.         _PRINTSTRING (_WIDTH(main&) / 2 - 68, 300), "successful export", 0
535.         _DISPLAY
536.         SLEEP 2
537.     END IF
538.     _FREEIMAGE si&
539.  
540. END SUB 'Save_Gridpic
541.  
542. '$INCLUDE:'SaveImage.BM'
543.  
544.  

[johnno56]

Do you mean something like the following?

Code: [Select]

LF = _NewImage(512, 300, 32)
RF = _NewImage(512, 300, 32)
CF = _NewImage(1024, 420, 32)
DisplayScreen = _NewImage(1024, 720, 32)

Screen DisplayScreen

'Stuff to print ot left side
_Dest LF
Cls , &HFF0000AA
Color , 0
Print "Joe Blow"
Print
Print "Age: 18"
Print "Sex: M"
Print
Print "ATK: 18:" 'attack
Print "DEF: 12" 'deffense
Print "MAT: 08" 'magic attack
Print "MDF: 05" 'magic defense
Print
Print "Health: 102 / 126"
Print "Mana  : 12  / 12"

'Stuff to print to the right side
_Dest RF
Cls , &HFF7700AA
Color , 0
Print "Day: 01"
Print "Location: Home"
Print "Time: 07:00 AM"
Print
Print "Directions Available:"
Print "North"
Print "Bed"

'Stuff to print to the center area
_Dest CF
Print "You wake up in your bed, in your home, with a hangover.  The sun is high in the sky and your alarm either failed to go off this morning, or else you were simply too drunk and hungover to respond to it.  Yesterday you were fired at work, and last night you spent drinking away your worries and concerns until into the wee hours of the morning."
Print ""
Print "In the room is your dirty clothes which are scattered all across the floor, your closet where you keep your clothes and extra blankets and such for the bed, and a small nightside table where you keep your loaded 45, in case of home invasion while you sleep.  You live in a rough neighborhood after all!"
Print
Print "What do you want to do now? "
Print

_Dest DisplayScreen
Do
    Cls
    _PutImage (0, 0), LF, DisplayScreen
    _PutImage (512, 0), RF, DisplayScreen
    _PutImage (0, 300), CF, DisplayScreen
    _PrintString (0, 700), "=>" + user$
    _Limit 30
    _Display
Loop Until _KeyHit


Cool... That's the kind of layout That I am aiming for... I will take a look at your 'framework'. Many thanks for the tips.

J