Download files

[Juanjogomez]

Hello everyone and Merry Christmas.

I have tried continuing this thread, but I think it is closed. https://qb64forum.alephc.xyz/index.php?topic=4411.msg138383#msg138383

I keep trying how to download files and with the examples that you gave me in the other thread, I still can't get it.


I'm trying to download a file from my dropbox with this code, but nothing is downloading.

Code: QB64: [Select]

1. DEFINT A-Z
2.  
3. CrLf$ = CHR$(13) + CHR$(10) ' carriage return + line feed ASCII characters
4.  
5. Host = _OPENHOST("TCP/IP:319")
6. IF Host THEN
7.     PRINT "> Server started succesfully."
8.  
9.     '// Change this to the file's public link
10.     IP_File$ = "www.dropbox.com/s/t6y91q4yjys35j7/ALTERAN.exe?dl=0" 'a Drop Box link
11.  
12.     URL$ = LEFT$(IP_File$, INSTR(IP_File$, "/") - 1)
13.     Path$ = MID$(IP_File$, INSTR(IP_File$, "/"))
14.     Client& = _OPENCLIENT("TCP/IP:80:" + URL$)
15.     IF Client& THEN
16.         Request$ = "GET " + Path$ + " HTTP/1.1" + CrLf$ + "Host:" + URL$ + CrLf$ + CrLf$
17.         PRINT Request$
18.         PUT #Client&, , Request$
19.         DO: _LIMIT 20 '              load response header
20.             GET #Client&, , Dat$
21.             Header$ = Header$ + Dat$
22.         LOOP UNTIL INSTR(Header$, CrLf$ + CrLf$) ' Loop until 2 CRLFs (end of HTML header) are found
23.         PRINT "Header Done."
24.         PRINT Header$
25.  
26.         ' Get file size from header
27.         SizePos = INSTR(UCASE$(Header$), "CONTENT-LENGTH:") + 16
28.         SizeEnd = INSTR(SizePos, Header$, CrLf$)
29.         FileSize& = VAL(MID$(Header$, SizePos, (SizeEnd - SizePos) + 1))
30.         PRINT "File size is"; FileSize&; "bytes"
31.         EndPos = INSTR(Header$, CrLf$ + CrLf$) + 4
32.         Response$ = MID$(Header$, EndPos) ' get data after header already downloaded
33.  
34.         start = 1 '// Get file name from original URL path if necessary
35.         DO '// Change this to destination local file name and path...
36.             posit = INSTR(start, IP_File$, "/")
37.             IF posit THEN lastpos = posit: start = posit + 1
38.         LOOP UNTIL posit = 0
39.         File$ = MID$(IP_File$, lastpos + 1) 'beware of tag suffixes
40.         OPEN File$ FOR BINARY AS #1
41.         DO: _LIMIT 20
42.             PUT #1, , Response$
43.             GET #Client&, , Response$
44.         LOOP UNTIL LOF(1) >= FileSize&
45.         PRINT "File download completed!"
46.         CLOSE #1
47.     ELSE
48.         PRINT "Failed to connect."
49.     END IF
50. ELSE
51.     PRINT "Failed to create server connection..."
52. END IF

Could someone pass me some code to download that file or another, just renaming?

Thanks in advance.

[SpriggsySpriggs]

This code works for HTTP and HTTPS files. Windows only.

Code: QB64: [Select]

1. Option _Explicit
2.  
3. Const INTERNET_OPEN_TYPE_DIRECT = 1
4.  
5. Const INTERNET_DEFAULT_HTTP_PORT = 80
6. Const INTERNET_DEFAULT_HTTPS_PORT = 443
7.  
8. Const INTERNET_SERVICE_HTTP = 3
9.  
10. 'Flags
11. Const INTERNET_FLAG_SECURE = &H00800000
12. Const INTERNET_FLAG_RELOAD = &H80000000
13.  
14. Const HTTP_QUERY_CONTENT_LENGTH = 5
15.  
16. Const TRUE = 1
17. 'CONST FALSE = 0
18.  
19. Declare Dynamic Library "Wininet"
20.     Function InternetOpen%& Alias "InternetOpenA" (ByVal lpszAgent As _Offset, Byval dwAccessType As Long, Byval lpszProxy As _Offset, Byval lpszProxyBypass As _Offset, Byval dwFlags As Long)
21.     Function InternetConnect%& Alias "InternetConnectA" (ByVal hInternet As _Offset, Byval lpszServerName As _Offset, Byval nServerPort As Integer, Byval lpszUserName As _Offset, Byval lpszPassword As _Offset, Byval dwService As Long, Byval dwFlags As Long, Byval dwContext As _Offset)
22.     Function HTTPOpenRequest%& Alias "HttpOpenRequestA" (ByVal hConnect As _Offset, Byval lpszVerb As _Offset, Byval lpszObjectName As _Offset, Byval lpszVersion As _Offset, Byval lpszReferrer As _Offset, Byval lpszAcceptTypes As _Offset, Byval dwFlags As Long, Byval dwContext As _Offset)
23.     Function HTTPSendRequest%% Alias "HttpSendRequestA" (ByVal hRequest As _Offset, Byval lpszHeaders As _Offset, Byval dwHeadersLength As Long, Byval lpOptional As _Offset, Byval dwOptionalLength As Long)
24.     Sub InternetCloseHandle (ByVal hInternet As _Offset)
25.     Function InternetReadFile%% (ByVal hFile As _Offset, Byval lpBuffer As _Offset, Byval dwNumberOfBytesToRead As Long, Byval lpdwNumberOfBytesRead As _Offset)
26.     Function HTTPQueryInfo%% Alias "HttpQueryInfoA" (ByVal hRequest As _Offset, Byval dwInfoLevel As Long, Byval lpBuffer As _Offset, Byval lpdwBufferLength As _Offset, Byval lpdwIndex As _Offset)
27. End Declare
28.  
29. Declare Dynamic Library "Kernel32"
30.     Function GetLastError& ()
31.     Sub SetLastError (ByVal dwErrCode As Long)
32.     Function FormatMessage& Alias "FormatMessageA" (ByVal dwFlags As Long, Byval lpSource As Long, Byval dwMessageId As Long, Byval dwLanguageId As Long, Byval lpBuffer As _Offset, Byval nSize As Long, Byval Arguments As _Offset)
33. End Declare
34.  
35. Declare Library
36.     Function MAKELANGID& (ByVal p As Long, Byval s As Long)
37. End Declare
38.  
39. Screen _NewImage(480, 80, 32)
40. $ScreenHide
41. _ScreenHide
42. $Console
43. _Dest _Console
44.  
45. _Title "URL Downloader"
46. _ConsoleTitle "Enter Link"
47. Dim link As String
48. Dim filename As String
49.  
50. Do
51.     Cls
52.     Line Input "Link: ", link
53.     Line Input "File Name : ", filename
54. Loop Until link <> "" And filename <> ""
55. _ScreenShow
56. _Title _Title$ + " - " + Mid$(filename, _InStrRev(filename, "\") + 1)
57.  
58. _Console Off
59. _Dest 0
60.  
61. DownloadLink link, filename
62.  
63. Sub DownloadLink (URL As String, File As String)
64.     Dim As String URLFile
65.     URLFile = URL
66.     Dim As _Offset hsession
67.     hsession = InternetOpen(0, INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
68.     If hsession = 0 Then
69.         Cls
70.         Print "Error : InternetOpen", ErrorMessage(GetLastError)
71.         InternetCloseHandle hsession
72.         Exit Sub
73.     End If
74.  
75.     Dim As _Offset httpsession
76.     URL = Mid$(URL, InStr(URL, "/") + 2)
77.     URL = Mid$(URL, 1, InStr(URL, "/") - 1)
78.     Dim As String intURL: intURL = URL + Chr$(0)
79.     httpsession = InternetConnect(hsession, _Offset(intURL), INTERNET_DEFAULT_HTTPS_PORT, 0, 0, INTERNET_SERVICE_HTTP, 0, 0)
80.     If httpsession = 0 Then
81.         Cls
82.         Print "Error : Internet Connect", ErrorMessage(GetLastError)
83.         InternetCloseHandle hsession
84.         Exit Sub
85.     End If
86.  
87.     Dim As _Offset httpRequest
88.     Dim As String sessiontype, location, accepttypes
89.     sessiontype = "GET" + Chr$(0)
90.     location = Mid$(URLFile, InStr(URLFile, URL) + Len(URL)) + Chr$(0)
91.     accepttypes = "*/*" + Chr$(0)
92.     httpRequest = HTTPOpenRequest(httpsession, _Offset(sessiontype), _Offset(location), 0, 0, _Offset(accepttypes), INTERNET_FLAG_RELOAD Or INTERNET_FLAG_SECURE, 0)
93.     If httpRequest = 0 Then
94.         Cls
95.         Print "Error : HTTPOpenRequest", ErrorMessage(GetLastError)
96.         InternetCloseHandle hsession
97.         Exit Sub
98.     End If
99.  
100.     Dim As Long sendrequest
101.     Dim As String headers
102.     headers = ""
103.     sendrequest = HTTPSendRequest(httpRequest, 0, 0, 0, 0)
104.     If sendrequest <> TRUE Then
105.         Cls
106.         Print "Error : HTTPSendRequest", ErrorMessage(GetLastError)
107.         InternetCloseHandle hsession
108.         Exit Sub
109.     End If
110.  
111.  
112.     Dim As _Byte query
113.     Dim As String queryinfo
114.     queryinfo = Space$(1024)
115.     Dim As Long querylen
116.     querylen = Len(queryinfo) - 1
117.  
118.     query = HTTPQueryInfo(httpRequest, HTTP_QUERY_CONTENT_LENGTH, _Offset(queryinfo), _Offset(querylen), 0)
119.     If query <> TRUE Then
120.         Cls
121.         Print "Error : HTTPQueryInfo", ErrorMessage(GetLastError)
122.         InternetCloseHandle hsession
123.     End If
124.  
125.     Dim As _Unsigned _Integer64 bytesToRead
126.     bytesToRead = Val(queryinfo)
127.  
128.     Dim As String szBuffer
129.     szBuffer = Space$(4097)
130.     Dim As _Unsigned _Integer64 dwRead, bytesRead
131.     If _FileExists(File) Then
132.         Kill File
133.     End If
134.     Open File For Binary As #1
135.     Dim As _Byte a
136.     Dim As String filedownload
137.     Dim As Long errr, bytesForRate
138.     Dim x!
139.     Dim y!
140.     Dim Rate!
141.     Dim As Single ratetime
142.     Do
143.         x! = Timer
144.         a = InternetReadFile(httpRequest, _Offset(szBuffer), Len(szBuffer) - 1, _Offset(dwRead))
145.         errr = GetLastError
146.         If dwRead > 0 Then
147.             filedownload = Mid$(szBuffer, 1, dwRead)
148.             Put #1, , filedownload
149.             bytesRead = bytesRead + dwRead
150.             bytesForRate = bytesForRate + dwRead
151.             ratetime = timeElapsedSince(x!)
152.             If _Round(ratetime) >= 1 Then
153.                 Rate! = (bytesForRate / ratetime) / 1024
154.                 bytesForRate = 0
155.             End If
156.             Cls
157.             Print "Downloading to " + File
158.             If bytesToRead <> 0 Then
159.                 Select Case bytesRead
160.                     Case Is < 1024
161.                         Print Using "#### B downloaded of "; bytesRead;
162.                     Case Is < (1024 ^ 2) And bytesRead >= 1024
163.                         Print Using "####.## KB downloaded of "; (bytesRead / 1024);
164.                     Case Is < (1024 ^ 3) And bytesRead >= (1024 ^ 2)
165.                         Print Using "####.## MB downloaded of "; (bytesRead / (1024 ^ 2));
166.                     Case Is < (1024 ^ 4) And bytesRead >= (1024 ^ 3)
167.                         Print Using "####.## GB downloaded of "; (bytesRead / (1024 ^ 3));
168.                 End Select
169.                 Select Case bytesToRead
170.                     Case Is < 1024
171.                         Print Using "#### B"; bytesToRead
172.                     Case Is < (1024 ^ 2) And bytesToRead >= 1024
173.                         Print Using "####.## KB"; (bytesToRead / 1024)
174.                     Case Is < (1024 ^ 3) And bytesToRead >= (1024 ^ 2)
175.                         Print Using "####.## MB"; (bytesToRead / (1024 ^ 2))
176.                     Case Is < (1024 ^ 4) And bytesToRead >= (1024 ^ 3)
177.                         Print Using "####.## GB"; (bytesToRead / (1024 ^ 3))
178.                 End Select
179.                 Print Using "###.##%"; bytesRead / bytesToRead * 100
180.             Else
181.                 Select Case bytesRead
182.                     Case Is < 1024
183.                         Print Using "   ####  B downloaded"; bytesRead
184.                     Case Is < (1024 ^ 2) And bytesRead >= 1024
185.                         Print Using "####.## KB downloaded"; (bytesRead / 1024)
186.                     Case Is < (1024 ^ 3) And bytesRead >= (1024 ^ 2)
187.                         Print Using "####.## MB downloaded"; (bytesRead / (1024 ^ 2))
188.                     Case Is < (1024 ^ 4) And bytesRead >= (1024 ^ 3)
189.                         Print Using "####.## GB downloaded"; (bytesRead / (1024 ^ 3))
190.                 End Select
191.             End If
192.             Select Case Rate!
193.                 Case Is < 1024
194.                     Print Using "Rate: #### Bps"; Rate!
195.                 Case Is < (1024 ^ 2) And Rate! >= 1024
196.                     Print Using "Rate: ####.## KBps"; Rate! / 1024
197.                 Case Is < (1024 ^ 3) And Rate! >= (1024 ^ 2)
198.                     Print Using "Rate: ####.## MBps"; Rate! / (1024 ^ 2)
199.                 Case Is < (1024 ^ 4) And Rate! >= (1024 ^ 3)
200.                     Print Using "Rate: ####.## GBps"; Rate! / (1024 ^ 3)
201.             End Select
202.             'Print "Rate="; _Round(Rate!); "KBps"
203.             _Display
204.         End If
205.     Loop Until bytesRead = bytesToRead Or errr <> 0
206.     If errr Then
207.         Print "Error downloading file:"; errr
208.         Close #1
209.         InternetCloseHandle hsession
210.         Kill File
211.         Exit Sub
212.     Else
213.     End If
214.     Close #1
215.     InternetCloseHandle hsession
216.     Cls
217.     Select Case bytesRead
218.         Case Is < 1024
219.             Print Using "#### B downloaded of "; bytesRead;
220.         Case Is < (1024 ^ 2) And bytesRead >= 1024
221.             Print Using "####.## KB downloaded of "; (bytesRead / 1024);
222.         Case Is < (1024 ^ 3) And bytesRead >= (1024 ^ 2)
223.             Print Using "####.## MB downloaded of "; (bytesRead / (1024 ^ 2));
224.         Case Is < (1024 ^ 4) And bytesRead >= (1024 ^ 3)
225.             Print Using "####.## GB downloaded of "; (bytesRead / (1024 ^ 3));
226.     End Select
227.     Select Case bytesToRead
228.         Case Is < 1024
229.             Print Using "#### B"; bytesToRead
230.         Case Is < (1024 ^ 2) And bytesToRead >= 1024
231.             Print Using "####.## KB"; (bytesToRead / 1024)
232.         Case Is < (1024 ^ 3) And bytesToRead >= (1024 ^ 2)
233.             Print Using "####.## MB"; (bytesToRead / (1024 ^ 2))
234.         Case Is < (1024 ^ 4) And bytesToRead >= (1024 ^ 3)
235.             Print Using "####.## GB"; (bytesToRead / (1024 ^ 3))
236.     End Select
237.     Print Using "###.##%"; bytesRead / bytesToRead * 100
238.     Print "Downloaded to " + File
239. End Sub
240.  
241. Function timeElapsedSince! (startTime!)
242.     If startTime! > Timer Then startTime! = startTime! - 86400
243.     timeElapsedSince! = Timer - startTime!
244. End Function
245.  
246. Function ErrorMessage$ (errCode As Long)
247.     Const FORMAT_MESSAGE_ALLOCATE_BUFFER = &H00000100
248.     Const FORMAT_MESSAGE_FROM_SYSTEM = &H00001000
249.     Const FORMAT_MESSAGE_IGNORE_INSERTS = &H00000200
250.  
251.     Const LANG_NEUTRAL = &H00
252.     Const SUBLANG_DEFAULT = &H01
253.  
254.     Dim As _Offset lpMsgBuf
255.     Dim As Long msg
256.  
257. msg = FormatMessage(FORMAT_MESSAGE_ALLOCATE_BUFFER Or _
258.                     FORMAT_MESSAGE_FROM_SYSTEM Or _
259.                     FORMAT_MESSAGE_IGNORE_INSERTS, _
260.                    0, _
261.                     errCode, _
262.                     MAKELANGID(LANG_NEUTRAL, SUBLANG_DEFAULT), _
263.                     _Offset(lpMsgBuf), _
264.                    0, 0)
265.  
266.  
267.     ErrorMessage = pointerToString(lpMsgBuf)
268. End Function
269.  
270. Function pointerToString$ (pointer As _Offset)
271.     Declare CustomType Library
272.         Function strlen%& (ByVal ptr As _Unsigned _Offset)
273.     End Declare
274.     Dim As _Offset length: length = strlen(pointer)
275.     If length Then
276.         Dim As _MEM pString: pString = _Mem(pointer, length)
277.         Dim As String ret: ret = Space$(length)
278.         _MemGet pString, pString.OFFSET, ret
279.         _MemFree pString
280.     End If
281.     pointerToString = ret
282. End Function

[Juanjogomez]

I just tried it and it only downloaded 58 Kb, when the original has 2,758 Kb, what could be the problem? Thanks

[Juanjogomez]

I have tried it again and I have seen that when the 0 is changed to a 1, the program downloads perfectly.
With this link it does not work:

https://www.dropbox.com/s/t6y91q4yjys35j7/ALTERAN.exe?dl=0

And changing the final figure, it downloads it perfectly:

https://www.dropbox.com/s/t6y91q4yjys35j7/ALTERAN.exe?dl=1

I do not know why

[SMcNeill]

I have tried it again and I have seen that when the 0 is changed to a 1, the program downloads perfectly.
With this link it does not work:

https://www.dropbox.com/s/t6y91q4yjys35j7/ALTERAN.exe?dl=0

And changing the final figure, it downloads it perfectly:

https://www.dropbox.com/s/t6y91q4yjys35j7/ALTERAN.exe?dl=1

I do not know why

The end character with dropbox is a toggle for "Download instantly, or wait for human interaction?"

If dl = 0, you get a series of responses for pop-ups asking you "Are you sure you want to save this file?  Where would you like to save this file?  This file might be dangerous, are you certain? "

If dl=1, you simply download the file.


Two kinds of ‘raw’ file download
Dropbox supports two kinds of downloads. One just does what you’d expect. Click a link, and the file downloads. The other renders a file in the browser. This is like when you click an MP3 link and get a little Quicktime-style music player in the middle of the browser window, or when you right-click an image on any webpage and choose to Open in New Tab, whereupon the image is displayed, alone, in the browser.

Force a Dropbox link to render in the browser
To force a Dropbox link to render in the browser, take the link and change dl=0 to raw=1. That is, it serves the “raw” file to your browser. Dropbox pro users can even serve HTML files, so they can host a simple webpage on Dropbox. The example link would look like this:

https://www.dropbox.com/s/a1b2c3d4ef5gh6/example.docx?raw=1

Force a Dropbox link to download
To force a Dropbox link to download a file direct, take the link and change dl=0 to dl=1. These codes mean “download disabled” and “download enabled.”

https://www.dropbox.com/s/a1b2c3d4ef5gh6/example.docx?dl=1

[Juanjogomez]

Thanks to all

[SpriggsySpriggs]

@Juanjogomez Merry Christmas! Glad it worked for you

[Juanjogomez]

@SpriggsySpriggs MERRY CHRISTMAS!! Thanks for your help

[Colonel_Panic]

I am watching this with heightened interest... one of my "end game"
strategies, is to download "stuff" and have 2 or more applications "exchange bytes"