Exploding logo

[Petr]

Hi, I was just playing with QB64 in particle style...

Code: QB64: [Select]

1. Img = -11 'ico image file
2. Screen _NewImage(300, 300, 32)
3. _FullScreen
4. CenterX = 150: CenterY = 150
5. S = _Width(Img) * _Height(Img)
6. Type P
7.     A As Single
8.     L As Integer
9.     C As _Unsigned Long
10.     LG As Integer
11.     oLG As Integer
12. End Type
13. Dim P(S) As P
14. PS = _Source
15. _Source Img
16. i = 0
17. For Y = 0 To _Height(Img) - 1
18.     For X = 0 To _Width(Img) - 1
19.         P(i).A = _Atan2(X - _Width(Img) \ 2, Y - _Height(Img) \ 2)
20.         P(i).L = _Hypot(Y - _Height(Img) \ 2, X - _Width(Img) \ 2)
21.         P(i).C = Point(X, Y)
22.         P(i).LG = (10 + Rnd * 300) * Sgn(P(i).A)
23.         P(i).oLG = P(i).LG
24.         i = i + 1
25. Next X, Y
26. _Source PS
27. Do Until k& = 27
28.     k& = _KeyHit
29.     Do Until vsak = 2
30.         i = 0
31.         vsak = 0
32.         For X = 0 To _Width(Img) - 1
33.             For Y = 0 To _Height(Img) - 1
34.                 If Abs(P(i).LG) > 0 Then
35.                     If P(i).LG > 0 Then P(i).LG = P(i).LG - 1 Else P(i).LG = P(i).LG + 1
36.                     vsak = 1
37.                 End If
38.                 If Sgn(P(i).A) = 1 Then DX = CenterX + Sin(P(i).A) * (P(i).L + P(i).LG) Else DX = CenterX + Sin(P(i).A) * (P(i).L - P(i).LG)
39.                 If Sgn(P(i).A) = 1 Then DY = CenterY + Cos(P(i).A) * (P(i).L + P(i).LG) Else DY = CenterY + Cos(P(i).A) * (P(i).L - P(i).LG)
40.                 PSet (DX, DY), P(i).C
41.                 i = i + 1
42.         Next Y, X
43.         If vsak = 0 Then vsak = 2
44.         _Display
45.         _Limit 60
46.         Cls
47.     Loop
48.     vsak = 0
49.     Do Until vsak = 2
50.         i = 0
51.         vsak = 0
52.         For X = 0 To _Width(Img) - 1
53.             For Y = 0 To _Height(Img) - 1
54.  
55.                 If Abs(P(i).LG) < Abs(P(i).oLG) Then
56.                     If P(i).oLG > 0 Then P(i).LG = P(i).LG + 1 Else P(i).LG = P(i).LG - 1
57.                     vsak = 1
58.                 End If
59.  
60.                 If Sgn(P(i).A) = 1 Then DX = CenterX + Sin(P(i).A) * (P(i).L + P(i).LG) Else DX = CenterX + Sin(P(i).A) * (P(i).L - P(i).LG)
61.                 If Sgn(P(i).A) = 1 Then DY = CenterY + Cos(P(i).A) * (P(i).L + P(i).LG) Else DY = CenterY + Cos(P(i).A) * (P(i).L - P(i).LG)
62.                 PSet (DX, DY), P(i).C
63.                 i = i + 1
64.         Next Y, X
65.         If vsak = 0 Then vsak = 2
66.         _Display
67.         _Limit 60
68.         Cls
69.     Loop
70.     vsak = 0
71. Loop
72.  

[johnno56]

Cool effect..!  I like it...

[Colonel_Panic]

you got me thinking particle trace; GIMP filter... ?

[Petr]

@Colonel_Panic

Filter GIMP...?

Hi. This is not a filter per se. They are just vectors. The position of a point is determined by the angle of the point's coordinates relative to the center of the screen and their distance from the center of the screen. Just a 2D vector. By changing the distance from the center, you determine the "explosive" position of the point. In practice, you can create even more complex effects, such as rotation after an explosion (just calculate the angle increment so that it is at the correct value at the destination). Maybe I'll try later, I got new toys yesterday, so now I'm sitting and soldering the circuit boards :)

[bplus]

I try exploding Christmas message:

Code: QB64: [Select]

1. Option _Explicit
2. _Title "Merry Christmas 2021"
3. Const back = _RGB32(0, 200, 100), cx = 249, cy = 249
4. Type pt
5.     As Single x, y, dx, dy, tx, ty, tw
6.     As _Unsigned Long c
7. End Type
8.  
9. Screen _NewImage(500, 500, 32)
10. _ScreenMove 450, 200
11. _PrintMode _KeepBackground
12.  
13. ReDim p(1 To 20000) As pt 'track particles
14. Dim As Long np, i, pmax, psave, f
15. Dim As Single x, y, speed, a
16. Dim s$
17.  
18. f = _LoadFont("arial.ttf", 48) ' everyone has arial correct?
19. 'Print f   'check font loaded
20. 'End
21. _Font f
22.  
23. Color _RGB32(255, 0, 48), back
24. Cls
25. Color _RGB32(255, 255, 255)
26. _PrintString (13, 223), "Merry Christmas 2021"
27.  
28. Color _RGB32(0, 0, 0)
29. _PrintString (17, 227), "Merry Christmas 2021"
30.  
31. Color _RGB32(255, 0, 48)
32. _PrintString (15, 225), "Merry Christmas 2021"
33.  
34. speed = 15
35. np = np + 1
36. For y = 0 To _Width - 1 '                   gather data of text points
37.     For x = 0 To _Height - 1
38.         If x = cx And y = cy Then psave = np
39.         If Point(x, y) <> back Then
40.             p(np).tx = x: p(np).ty = y '  save original location  target x, y
41.             p(np).x = x: p(np).y = y '    current location of particle
42.             a = _Atan2(y - cy, x - cx)
43.             p(np).dx = speed * Cos(a): p(np).dy = speed * Sin(a) ' setup move vectors
44.             p(np).c = Point(x, y)
45.             np = np + 1
46.         End If
47.     Next
48. Next
49. pmax = np - 1
50.  
51. 'check we got our data right, OK!
52. 'Sleep
53. 'Cls
54. 'Sleep
55. 'For i = 1 To pmax
56. '    PSet (p(i).x, p(i).y), p(i).c
57. 'Next
58.  
59. While _KeyDown(27) = 0
60.     _Delay 2
61.     ' Explode
62.     While p(psave).x > -_Width * Sqr(2) And p(psave).x < _Width * Sqr(2) ' center point is still visible
63.         Cls
64.         For i = 1 To pmax
65.             p(i).x = p(i).x + p(i).dx: p(i).y = p(i).y + p(i).dy
66.             PSet (p(i).x, p(i).y), p(i).c
67.         Next
68.         _Display
69.         _Limit 30
70.     Wend
71.  
72.     While p(psave).x <> p(psave).tx ' back in place
73.         Cls
74.         For i = 1 To pmax
75.             p(i).x = p(i).x - p(i).dx: p(i).y = p(i).y - p(i).dy
76.             PSet (p(i).x, p(i).y), p(i).c
77.         Next
78.         _Display
79.         _Limit 30
80.     Wend
81. Wend
82.  

[Colonel_Panic]

Well, I never was in love with GIMP calling them "filters" anyways.
But, now its the word i use for it, "filter".

I assume you have seen "ALPHA TO LOGO" set of filters in GIMP?
some versions have the alpha to logo filter collection, some dont.

anyways, from your description of your "particle trace" routine...
I had the idea of... someone else makes a "different filter" and it gets added to a list...
a routine for editing TEXT and controlling text attributes...

and BING, we would have a "alpha to logo"  little IDE going on. We could slowly assemble extra filters, as people took it upon themselves to write a new filter...

In GIMP? I can only do ONE alpha-to-logo FILTER at all... if i want to go and do a "frozen" over top of the "sparkle" filter? It undoes it, and re-does the new one... I want to run BOTH one after the other...

the whole thing SOUNDS way more complicated than it actually is.
(if YOU dont want to play with this idea? i will try it in my spare time)

[bplus]

@Colonel_Panic  Oh yeah, alpha trails sounds cool!

Update with trails:

Code: QB64: [Select]

1. Option _Explicit
2. _Title "Merry Christmas 2021"
3. Const back = _RGB32(0, 200, 100), cx = 249, cy = 249
4. Type pt
5.     As Single x, y, dx, dy, tx, ty, tw
6.     As _Unsigned Long c
7. End Type
8.  
9. Screen _NewImage(500, 500, 32)
10. _ScreenMove 450, 200
11. _PrintMode _KeepBackground
12.  
13. ReDim p(1 To 20000) As pt 'track particles
14. Dim As Long np, i, pmax, psave, f, j
15. Dim As Single x, y, speed, a
16. Dim s$
17.  
18. f = _LoadFont("arial.ttf", 48) ' everyone has arial correct?
19. 'Print f   'check font loaded
20. 'End
21. _Font f
22.  
23. Color _RGB32(255, 0, 48), back
24. Cls
25. Color _RGB32(255, 255, 255)
26. _PrintString (13, 223), "Merry Christmas 2021"
27.  
28. Color _RGB32(0, 0, 0)
29. _PrintString (17, 227), "Merry Christmas 2021"
30.  
31. Color _RGB32(255, 0, 48)
32. _PrintString (15, 225), "Merry Christmas 2021"
33.  
34. speed = 10
35. np = np + 1
36. For y = 0 To _Width - 1 '                   gather data of text points
37.     For x = 0 To _Height - 1
38.         If x = cx And y = cy Then psave = np
39.         If Point(x, y) <> back Then
40.             p(np).tx = x: p(np).ty = y '  save original location  target x, y
41.             p(np).x = x: p(np).y = y '    current location of particle
42.             a = _Atan2(y - cy, x - cx)
43.             p(np).dx = speed * Cos(a): p(np).dy = speed * Sin(a) ' setup move vectors
44.             p(np).c = Point(x, y)
45.             np = np + 1
46.         End If
47.     Next
48. Next
49. pmax = np - 1
50.  
51. 'check we got our data right, OK!
52. 'Sleep
53. 'Cls
54. 'Sleep
55. 'For i = 1 To pmax
56. '    PSet (p(i).x, p(i).y), p(i).c
57. 'Next
58.  
59. While _KeyDown(27) = 0
60.     _Delay 2
61.     ' Explode
62.     While p(psave).x > -_Width * Sqr(2) And p(psave).x < _Width * Sqr(2) ' center point is still visible
63.         Line (0, 0)-(500, 500), _RGBA32(0, 200, 100, 30), BF
64.         For i = 1 To pmax
65.             p(i).x = p(i).x + p(i).dx: p(i).y = p(i).y + p(i).dy
66.             PSet (p(i).x, p(i).y), p(i).c
67.         Next
68.         _Display
69.         _Limit 30
70.     Wend
71.     Cls
72.     While p(psave).x <> p(psave).tx ' back in place
73.         Line (0, 0)-(500, 500), _RGBA32(0, 200, 100, 30), BF
74.         For i = 1 To pmax
75.             p(i).x = p(i).x - p(i).dx: p(i).y = p(i).y - p(i).dy
76.             PSet (p(i).x, p(i).y), p(i).c
77.         Next
78.         _Display
79.         _Limit 30
80.     Wend
81.     For j = 1 To 100
82.         Line (0, 0)-(500, 500), _RGBA32(0, 200, 100, 100), BF
83.         For i = 1 To pmax
84.             PSet (p(i).x, p(i).y), p(i).c
85.         Next
86.         _Display
87.         _Limit 30
88.     Next
89. Wend
90.