Russian Circle Diagram

[DANILIN]

Russian Circle Diagram

We build pie charts in 2 ways as Russian Circle Diagram
and it is still possible other way around from edges to center

Code: QB64: [Select]

1. 'diagram.bas  Russian Circle Diagram
2. N = 13: s = 0: DIM d(N),r(N+1): SCREEN 12: RANDOMIZE TIMER
3. FOR i = 1 TO N: d(i) = INT(RND*90+9): s = s+d(i): PRINT d(i): NEXT: PRINT "SUM= "; s
4. FOR i = 2 TO N: r(i) = r(i-1)+d(i)*2*3.1416/s: NEXT: r(N+1) = r(1)
5.  
6. FOR i = 2 TO N+1: FOR j = 1 TO 100: CIRCLE (150,150),j,i,r(i-1),r(i)
7.         CIRCLE (149,149),j,i,r(i-1),r(i): CIRCLE (151,149),j,i,r(i-1),r(i)
8. _DELAY .01: NEXT: NEXT
9.  
10. FOR j = 1 TO 100: FOR i = 2 TO N+1: CIRCLE (350,150),j,i,r(i-1),r(i)
11.         CIRCLE (349,149),j,i,r(i-1),r(i): CIRCLE (351,149),j,i,r(i-1),r(i)
12. NEXT: _DELAY .01: NEXT: END

Necessary: schkolnaya olympiyskaya zadacha

 

Plus it is also possible to build a pattern in corners
connecting all points together

 

Practically: olympic school problem

 

animations all: less than 300 kb

[bplus]

Code: QB64: [Select]

1. _Title "Pie Chart" ' b+ 2021-11-06 fix up Russian Circle Diagram
2. 'ref https://www.qb64.org/forum/index.php?topic=4367.msg137864#msg137864
3. Screen 12
4. Randomize Timer
5. _PrintMode _KeepBackground
6.  
7. N = 13
8. Dim d(1 To N), sumD(1 To N), ra(1 To N)
9. For i = 1 To N
10.     d(i) = Int(Rnd * 90 + 9) ' min 9, max 99.99..
11.     s = s + d(i)
12.     sumD(i) = s
13. Next
14.  
15. For i = 1 To N
16.     ra(i) = sumD(i) * 2 * 3.1416 / s
17.     Color i: Print d(i); ra(i)
18. Next
19. Color 15: Print s; "= SUM "
20.  
21. For i = 1 To N
22.     For radius = 1 To (_Height / 2.5) Step .25
23.         If i = 1 Then
24.             Circle (_Width / 2 + 50, _Height / 2), radius, i, 0, ra(1)
25.         ElseIf i = N Then
26.             Circle (_Width / 2 + 50, _Height / 2), radius, i, ra(i - 1), _Pi(2)
27.         Else
28.             Circle (_Width / 2 + 50, _Height / 2), radius, i, ra(i - 1), ra(i)
29.         End If
30.     Next
31. Next
32.  
33. For i = 1 To N
34.     If i = 1 Then a = ra(1) / 2 Else a = (ra(i) + ra(i - 1)) / 2
35.     x = _Width / 2 + 50 + _Height / 3 * Cos(a)
36.     y = _Height / 2 - _Height / 3 * Sin(a) ' <<<<<<<<<< dang backwards circle function!!!
37.     s$ = _Trim$(Str$(d(i)))
38.     Color 0: _PrintString (x + 2 - 4 * Len(s$), y + 2 - 8), s$
39.     Color 15: _PrintString (x - 3.5 * Len(s$), y - 8), _Trim$(Str$(d(i)))
40. Next
41. Sleep
42.  

 

[DANILIN]

Code: QB64: [Select]

1.         END IF
2.     _DELAY .001: NEXT
3. NEXT

_DELAY .001:

better and implements particularity: animation is visible

[bplus]

Better way to do color fill?

Code: QB64: [Select]

1. _Title "Pie Chart 2" ' b+ 2021-11-06 fix up Russian Circle Diagram
2. 'ref https://www.qb64.org/forum/index.php?topic=4367.msg137864#msg137864
3. Screen 12
4. Randomize Timer
5. _PrintMode _KeepBackground
6.  
7. N = 13
8. Dim d(1 To N), sumD(1 To N), ra(1 To N)
9. For i = 1 To N
10.     d(i) = Int(Rnd * 90 + 9) ' min 9, max 99.99..
11.     s = s + d(i)
12.     sumD(i) = s
13. Next
14.  
15. For i = 1 To N ' better fill method?
16.     ra(i) = sumD(i) * 2 * 3.1416 / s
17.     Color i: Print d(i); ra(i)
18. Next
19.  
20. Color 15: Print s; "= SUM "
21. radius = _Height / 2.5
22. Circle (_Width / 2 + 50, _Height / 2), radius, &HFFFFFFFF
23. For i = 1 To N
24.     x = _Width / 2 + 50 + radius * Cos(ra(i))
25.     Y = _Height / 2 + radius * Sin(ra(i))
26.     Line (_Width / 2 + 50, _Height / 2)-(x, Y), &HFFFFFFFF
27.     Paint (_Width / 2 + 50 + (radius - 10) * Cos(ra(i) - _Pi(1 / 36)), _Height / 2 + (radius - 10) * Sin(ra(i) - _Pi(1 / 36))), i, &HFFFFFFFF
28. Next
29.  
30. For i = 1 To N
31.     If i = 1 Then a = ra(1) / 2 Else a = (ra(i) + ra(i - 1)) / 2
32.     x = _Width / 2 + 50 + _Height / 3 * Cos(a)
33.     Y = _Height / 2 + _Height / 3 * Sin(a) ' <<<<<<<<<< NOT backwards because not using Circle Function for fill
34.     s$ = _Trim$(Str$(d(i)))
35.     Color 0: _PrintString (x + 2 - 4 * Len(s$), Y + 2 - 8), s$
36.     Color 15: _PrintString (x - 3.5 * Len(s$), Y - 8), _Trim$(Str$(d(i)))
37. Next
38. Sleep
39.  

 

[DANILIN]

? animation ? ... animation ... ! animation !

Code: QB64: [Select]

1.     '_DELAY .5: NEXT
2.  
3.     '   FOR i = 1 TO N

Code: QB64: [Select]

1. _DELAY .5: NEXT
2. SLEEP

? animation ? ... animation ... ! animation !

... to be continued ...

 

[bplus]

Animation coming right up!

Code: QB64: [Select]

1. _Title "Pie Chart 2 Animate" ' b+ 2021-11-06 fix up Russian Circle Diagram
2. 'ref https://www.qb64.org/forum/index.php?topic=4367.msg137864#msg137864
3. Screen 12
4. Randomize Timer
5. _PrintMode _KeepBackground
6. N = 13
7. Dim d(1 To N), sumD(1 To N), ra(1 To N)
8. For i = 1 To N
9.     d(i) = Int(Rnd * 90 + 9) ' min 9, max 99.99..
10.     s = s + d(i)
11.     sumD(i) = s
12. Next
13. radius = _Height / 2.5
14. Do
15.     Cls
16.     For i = 1 To N ' better fill method?
17.         ra(i) = sumD(i) * 2 * 3.1416 / s
18.         Color i: Print d(i); ra(i)
19.     Next
20.     Color 15: Print s; "= SUM "
21.     offset = offset + _Pi(1 / 360)
22.     Circle (_Width / 2 + 50, _Height / 2), radius, &HFFFFFFFF
23.     For i = 1 To N
24.         x = _Width / 2 + 50 + radius * Cos(ra(i) + offset)
25.         y = _Height / 2 + radius * Sin(ra(i) + offset)
26.         Line (_Width / 2 + 50, _Height / 2)-(x, y), &HFFFFFFFF
27.         Paint (_Width / 2 + 50 + (radius - 10) * Cos(ra(i) + offset - _Pi(1 / 36)), _Height / 2 + (radius - 10) * Sin(ra(i) + offset - _Pi(1 / 36))), i, &HFFFFFFFF
28.     Next
29.     For i = 1 To N
30.         If i = 1 Then a = ra(1) / 2 + offset Else a = (ra(i) + ra(i - 1)) / 2 + offset
31.         x = _Width / 2 + 50 + _Height / 3 * Cos(a)
32.         y = _Height / 2 + _Height / 3 * Sin(a) ' <<<<<<<<<< NOT backwards circle function!!!
33.         s$ = _Trim$(Str$(d(i)))
34.         Color 0: _PrintString (x + 2 - 3.5 * Len(s$), y + 2 - 8), s$  ' <<< EDIT: from 4 * Len()
35.         Color 15: _PrintString (x - 3.5 * Len(s$), y - 8), _Trim$(Str$(d(i)))
36.     Next
37.     _Display
38.     _Limit 30
39. Loop Until _KeyDown(27)
40.  

Edit: fix number noted in code

[johnno56]

That's pretty cool... But it does remind me of Wheel of Fortune.... lol

[DANILIN]

animation 120 kB

 

Code: QB64: [Select]

1. 'diagout.bas  Russian Circle Diagram
2. N=12: s=0: DIM d(N),r(N+1): SCREEN 12: RANDOMIZE TIMER
3. FOR i=1 TO N: d(i)=INT(RND*90+9): s=s+d(i): PRINT d(i): NEXT: PRINT "SUM= "; s
4. FOR i=2 TO N: r(i)=r(i-1)+d(i)*2*3.1416/s: NEXT: r(N+1)=r(1)
5.  
6. FOR i=2 TO N+1 STEP 2: FOR j=1 TO 100: CIRCLE (150,100),j,i,r(i-1),r(i)
7.         CIRCLE (149,99),j,i,r(i-1),r(i): CIRCLE (151,99),j,i,r(i-1),r(i)
8. _DELAY .003: NEXT: NEXT
9.  
10. FOR i=3 TO N+1 STEP 2: FOR j=100 TO 1 STEP -1: CIRCLE (150,100),j,i,r(i-1),r(i)
11.         CIRCLE (149,99),j,i,r(i-1),r(i): CIRCLE (151,99),j,i,r(i-1),r(i)
12. _DELAY .01: NEXT: NEXT
13.  
14. FOR j=1 TO 100: FOR i=2 TO N+1
15.         IF (i MOD 2)=0 THEN CIRCLE (350,100),j,i,r(i-1),r(i): CIRCLE (349,99),j,i,r(i-1),r(i): CIRCLE (351,99),j,i,r(i-1),r(i)
16.         IF (i MOD 2)=1 THEN CIRCLE (350,100),100-j,i,r(i-1),r(i): CIRCLE (349,99),100-j,i,r(i-1),r(i): CIRCLE (351,99),100-j,i,r(i-1),r(i)
17. NEXT: _DELAY .02: NEXT: END

[johnno56]

Cool effects...

[bplus]

To avoid the ugly holes step even less than 1 through Circle( ), radii
Step .5 gets most Step .25 gets almost all. The extra stepping would slow the fills which might add to the animation by slowing it a bit?

And since the 2nd way of filling is way more interesting than first, just devote whole screen to filling the 2nd way, it is cool enough to stand on it's own! :)

[bplus]

Code: QB64: [Select]

1. 'diagout.bas  Russian Circle Diagram
2. N = 12: s = 0: Dim d(N), r(N + 1): Screen 12: Randomize Timer
3. For i = 1 To N: d(i) = Int(Rnd * 90 + 9): s = s + d(i): Print d(i): Next: Print "SUM= "; s
4. For i = 2 To N: r(i) = r(i - 1) + d(i) * 2 * 3.1416 / s: Next: r(N + 1) = r(1)
5. For j = 0 To 200 Step .25: For i = 1 To N + 1
6.     If (i Mod 2) = 0 Then Circle (320, 240), j, i, r(i - 1), r(i)
7.         If (i Mod 2) = 1 Then Circle (320, 240), 200 - j, i, r(i - 1), r(i)
8. Next: _Delay .016: Next
9.  

[bplus]

Finally I get the colors matched up with the original random amounts:

Code: QB64: [Select]

1. 'diagout.bas  Russian Circle Diagram
2. N = 12: Dim d(N): Screen 12: Randomize Timer
3. For i = 1 To N: r = Int(Rnd * 90 + 9): d(i) = d(i - 1) + r: Color i: Print r: Next: Color 15: Print "SUM= "; d(N)
4. For i = 1 To N: d(i) = d(i) / d(N) * _Pi(2): If d(i) >= _Pi(2) Then d(i) = _Pi(2) - .0001 ' wow circle is really frick'n picky!!!
5.     Next: For j = 0 To 200 Step .25: For i = 1 To N
6.         If (i Mod 2) = 0 Then Circle (320, 240), j, i, d(i - 1), d(i)
7.         If (i Mod 2) = 1 Then Circle (320, 240), 200 - j, i, d(i - 1), d(i)
8. Next: _Delay .016: Next
9.  

[bplus]

In case the above is too dense and obscure, I removed all the double parking with colons and commented statement by statement:

Code: QB64: [Select]

1. 'diagout.bas  Russian Circle Diagram   b+ mod overhaul Danilin's 2021-11-15
2. N = 12 '                    Number of pie slices or data items
3. Dim d(N) '                  Store our random items, d(i) first stores totals that are converted to RadianAngles for arcs.
4. Screen 12 '                 Allows graphics like Circle (x, y), radius, color, startRadianForArc, stopRadianForArc
5. Randomize Timer '           New set each time for 1,000,000 times
6. For i = 1 To N '            For each data item
7.     r = Int(Rnd * 90 + 9) ' Pick random  number 9 to 89, +9 guarantees at least 9, INT(rnd*90) = 0 to 89, so 9 to 98 max
8.     d(i) = d(i - 1) + r '   Add last total to this with new item
9.     Color i '               Color code by i = index number
10.     Print r '               Show each item and it's color
11. Next
12. Color 15 ' White, not used by any other item
13. Print "SUM= "; d(N) '       Sum is last total with all data items
14. For i = 1 To N
15.     d(i) = d(i) / d(N) * _Pi(2) ' convert d(i) to a fraction of a circle and multiply by 2*Pi to convert to angle in radians
16.     If d(i) >= _Pi(2) Then d(i) = _Pi(2) - .0001 ' wow circle is really frick'n picky!!!
17.     ' Circle wont do stop Angle < start angle, that happens with imprecise math and 1 converted to something > 2*Pi
18.     ' This was big headache until I isolated which number was not working in Circle.
19. Next
20. For j = 0 To 200 Step .25 ' .25 to avoid holes between arcs
21.     For i = 1 To N ' drawing arcs from d(i-1) to d(i) at j radii
22.         'ref:               Circle (x,y),radius, color, startRadianForArc, stopRadianForArc
23.         If (i Mod 2) = 0 Then Circle (320, 240), j, i, d(i - 1), d(i) '          inside out
24.         If (i Mod 2) = 1 Then Circle (320, 240), 200 - j, i, d(i - 1), d(i) ' outside in
25.     Next
26.     _Delay .016 '           to show the build either outside in or inside out
27. Next
28.  
29.  

[DANILIN]

Visualization resembles theory:

60kB 

LAYERS of DECEPTION and WE

Pyramid: visualization is convenient in many areas

Belonging to a minority in pyramid does not make it higher

Narrow layers of pyramid can be higher or lower
wide layers of pyramid and it is always possible
to depict any number of them as a trapezoid inside pyramid

Looking at visually multi colored layered pyramids
being in one pyramid above it is possible to be same people
in a different environment in another pyramid in layer below

New visualization: a ball where pyramids are like spikes
where each turn of ball brings up 1 pyramid
and makes maxima of vertices of other pyramids lower

Almost at top of pyramids capable of deceiving
located higher up in a separate pyramid and deception
requires more information than deceived ones

Other visualization: lever and torque

Product of force on shoulder creates a moment and knowing
moment and lever are calculated as an increase in force
and force field is plotted on inverse function graph

Curves of constant products of different points are obtained
viewpoints that differ vertically and horizontally

To understand vertically it is important to have more
information and be an outstanding person such as
a billionaire or a minister or a champion or a scientist

But horizontally same secret data can really
be thought out by yourself without slightest hints
possibly spending more time

3 kB