Subroutines to draw axes automatically scaled.

[bartok]

As extract from the program that I posted, I post here a sequence of subroutine that I think it can be usefull in order to draw axes.

N1!, N2!: they are examples of maximum values in abscissa and ordinate.
N3!, N4!: example of pair of values to put in the graph.

The program has these features:
- the origin of the axes is 40 pixels in X and Y direction from the lower left corner, these distances are named dx! and dy!.
- the axes are drawn in this way, speaking for example about Y axe: it starts at dy! distance from the loer border, it goes at dy! distance beyond N2! and it is spaced by dy! from the upper border. to do it the process is iterative.

Generally, the subroutine ScalaOrigine is CALLed by DisegnaAssi, but in more rare cases ScalaOrigine may be CALLed alone and
scala~% = 0 AND origine~% = 1.
It may happen when we have to work on images already created and scaled and it is necessary only to restore the origin of the axes.

Code: QB64: [Select]

1. OPTION BASE 1
2.  
3. CONST R& = _RGB32(255, 0, 0)
4. CONST G& = _RGB32(0, 255, 0)
5. CONST B& = _RGB32(0, 0, 255)
6. CONST W& = _RGB32(255, 255, 255)
7. CONST YE& = _RGB32(255, 255, 0)
8.  
9. DIM schermo&
10. DIM N1!, N2!, N3!, N4!
11.  
12. schermo& = _NEWIMAGE(800, 600, 32)
13. SCREEN schermo&
14.  
15. N1! = 113.4
16. N2! = 34.44
17. N3! = 43
18. N4! = 22.2
19.  
20. CALL DisegnaAssi("X", "Y", N1!, N2!, schermo&, YE&, W&, B&, G&)
21. CALL DisegnaValore(N1!, N2!, R&, YE&, G&)
22. CALL DisegnaValore(N3!, N4!, R&, YE&, G&)
23.  
24. '--------------------------------------------------------------------------------------------------------------------------------------------------
25. SUB ScalaOrigine (scala~%, origine~%, X!, Y!, immagine&)
26.  
27.     SHARED dx%, dy%
28.     SHARED dx!, dy!
29.  
30.     DIM fattoreX!, fattoreY!
31.  
32.     fattoreX! = 1
33.     fattoreY! = 1
34.     IF scala~% = 0 AND origine~% = 1 THEN GOSUB origine
35.     IF scala~% = 1 AND origine~% = 1 THEN
36.         DO
37.             GOSUB scala
38.             GOSUB origine
39.             IF Y! * fattoreY! >= dy! + Y! + dy! + dy! THEN
40.                 IF X! * fattoreX! >= dx! + X! + dx! + dx! THEN
41.                     EXIT DO
42.                 ELSE
43.                     fattoreX! = fattoreX! + 0.01
44.                 END IF
45.             ELSE
46.                 fattoreY! = fattoreY! + 0.01
47.             END IF
48.         LOOP
49.     END IF
50.     EXIT SUB
51.     '--------------------------------------------------------------------------------------------------------------------------------------------------
52.     scala:
53.  
54.     WINDOW
55.     WINDOW (0, 0)-(X! * fattoreX!, Y! * fattoreY!)
56.     RETURN
57.     '--------------------------------------------------------------------------------------------------------------------------------------------------
58.     origine:
59.  
60.     dx% = 39
61.     dx! = PMAP(dx%, 2)
62.     dy% = _HEIGHT(immagine&) - 1 - dx%
63.     dy! = PMAP(dy%, 3)
64.     RETURN
65. END SUB
66. '--------------------------------------------------------------------------------------------------------------------------------------------------
67. '--------------------------------------------------------------------------------------------------------------------------------------------------
68. SUB DisegnaAssi (X$, Y$, X!, Y!, immagine&, ColoreCartiglio&, ColoreAssi&, ColoreTacca&, ColoreNumeri&)
69.  
70.     SHARED dx%, dy%
71.     SHARED dx!, dy!
72.  
73.     DIM x%, y%
74.     DIM taccaX!, taccaY!
75.  
76.     _DEST immagine&: CLS
77.     SELECT CASE X!
78.         CASE IS >= 12
79.             taccaX! = X! \ 6
80.         CASE IS <= 1
81.             taccaX! = 0.25
82.         CASE ELSE
83.             taccaX! = 0.5
84.     END SELECT
85.     SELECT CASE Y!
86.         CASE IS >= 12
87.             taccaY! = Y! \ 6
88.         CASE IS <= 1
89.             taccaY! = 0.25
90.         CASE ELSE
91.             taccaY! = 0.5
92.     END SELECT
93.     WINDOW
94.     LINE (0, 0)-(_WIDTH(immagine&) - 1, _HEIGHT(immagine&) - 1), ColoreCartiglio&, B
95.     CALL ScalaOrigine(1, 1, X!, Y!, immagine&)
96.     LINE (dx!, dy! + Y! + dy!)-(dx!, dy!), ColoreAssi&: LINE -(dx! + X! + dx!, dy!), ColoreAssi&
97.     PSET (dx!, dy! + Y! + dy!), ColoreAssi&: DRAW "F20": PSET (dx!, dy! + Y! + dy!), ColoreAssi&: DRAW "G20"
98.     PSET (dx! + X! + dx!, dy!), ColoreAssi&: DRAW "G20": PSET (dx! + X! + dx!, dy!), ColoreAssi&: DRAW "H20"
99.     COLOR ColoreNumeri&
100.     _PRINTSTRING (PMAP(dx! + X! + dx!, 0), dy%), X$
101.     _PRINTSTRING (dx%, PMAP(dy! + Y! + dy!, 1) - dx% \ 2), Y$
102.     _PRINTSTRING (dx% \ 4, dy% - 7), "0"
103.     i% = 1
104.     WHILE i% * taccaX! <= X!
105.         LINE (dx! + i% * taccaX!, PMAP(dy% + 5, 3))-(dx! + i% * taccaX!, PMAP(dy% - 5, 3)), ColoreTacca&
106.         x% = PMAP(dx! + i% * taccaX!, 0)
107.         _PRINTSTRING (x% - 3 * LEN(_TRIM$(STR$(i% * taccaX!))), _HEIGHT(immagine&) - 1 - dx% + 5), _TRIM$(STR$(i% * taccaX!))
108.         i% = i% + 1
109.     WEND
110.     i% = 1
111.     WHILE i% * taccaY! <= Y!
112.         LINE (PMAP(dx% - 5, 2), dy! + i% * taccaY!)-(PMAP(dx% + 5, 2), dy! + i% * taccaY!), ColoreTacca&
113.         y% = PMAP(dy! + i% * taccaY!, 1)
114.         _PRINTSTRING (dx% \ 4, y% - 7), _TRIM$(STR$(i% * taccaY!))
115.         i% = i% + 1
116.     WEND
117. END SUB
118. '--------------------------------------------------------------------------------------------------------------------------------------------------
119. '--------------------------------------------------------------------------------------------------------------------------------------------------
120. SUB DisegnaValore (X!, Y!, ColoreLinea&, ColorePunto&, ColoreTesto&)
121.  
122.     SHARED dx%, dy%
123.     SHARED dx!, dy!
124.  
125.     DIM x%, y%
126.  
127.     CIRCLE (dx! + X!, dy! + Y!), PMAP(3, 2), ColorePunto&
128.     PAINT (dx! + X! + PMAP(0.5, 2), dy! + Y! + PMAP(0.5, 2)), ColorePunto&
129.     LINE (dx!, dy! + Y!)-(dx! + X!, dy! + Y!), ColoreLinea&, , 65520
130.     LINE -(dx! + X!, dy!), ColoreLinea&, , 65520
131.     x% = PMAP(dx! + X!, 0)
132.     y% = PMAP(dy! + Y!, 1)
133.     COLOR ColoreTesto&
134.     _PRINTSTRING (x% + 4, y% - 16), "(" + _TRIM$(STR$(Arrotonda!(X!))) + ";" + _TRIM$(STR$(Arrotonda!(Y!))) + ")"
135. END SUB
136. '--------------------------------------------------------------------------------------------------------------------------------------------------
137. '--------------------------------------------------------------------------------------------------------------------------------------------------
138. FUNCTION Arrotonda! (num!)
139.  
140.     Arrotonda! = _ROUND(num! * 100) / 100
141. END FUNCTION
142.