Match Three

[SMcNeill]

So I've finally rounded up a little free time and have decided to play around with the little "one key input" Halloween contest that's currently going on.  What I've decided to shoot for is a simple little strategy game of a match-3 style.

Code: QB64: [Select]

1. Dim Shared WS, GridSize
2. ReDim Shared Grid(0, 0) As _Byte
3.  
4. GridSize = 30
5. MakeGrid
6. DisplayGrid
7.  
8.  
9. Sleep
10.  
11. Sub DisplayGrid
12.     For x = 1 To GridSize: For y = 1 To GridSize
13.         Locate y, x: Print _Trim$(Str$(Grid(x, y)));
14.     Next y, x
15.     AutoScale
16. End Sub
17.  
18. Sub MakeGrid
19.     If GridSize Mod 3 <> 0 Then Error 5: End
20.     If WS <> 0 Then _FreeImage WS
21.  
22.     WS = _NewImage(GridSize * 8, GridSize * 8 + 16, 32)
23.     Screen WS
24.     _Font 8 'this creates a 30x32 screen
25.     ReDim Grid(1 To GridSize, 1 To GridSize) As _Byte
26.  
27.     count = 3
28.     For x = 1 To GridSize: For y = 1 To GridSize
29.         count = (count + 1) Mod 3 + 1
30.         Grid(x, y) = count 'Assign values of 1 to 3 equally amongst the grid
31.     Next y, x
32.     For x = 1 To GridSize: For y = 1 To GridSize
33.         xswap = Int(Rnd * GridSize) + 1: yswap = Int(Rnd * GridSize) + 1
34.         Swap Grid(xswap, yswap), Grid(x, y) 'Shuffle the grid
35.     Next y, x
36. End Sub
37.  
38. Sub AutoScale
39.     Static DisplayScreen
40.     If DisplayScreen = 0 Then
41.         DW = _DesktopWidth
42.         DH = _DesktopHeight
43.         Scale = (DH - 80) / 640
44.         DisplayScreen = _NewImage(640 * Scale, 640 * Scale, 32)
45.         Screen DisplayScreen
46.         _ScreenMove (DW - _Width(DisplayScreen)) \ 2, 0
47.         _Source WS: _Dest WS
48.     End If
49.     _PutImage , WS, DisplayScreen
50.     _Display
51. End Sub

Now, all this is doing at the moment is tossing a bunch of numbers up on the screen for us, with values of 1, 2, or 3.  The goal here would be to clear the screen of all numbers, making matches from the bottom up as you go.  Simple enough game play, but one which many people end up failing to do properly. All you need to do to fail is to get stuck with something like 1, 3, 2, 2, 1, 3 for the bottom numbers of the last six columns, and you've lost.  It's impossible to make another match-3 with those 6 numbers!  There's a few hiding behind those that you need to access, so you didn't clear the rest of the puzzle properly to get a win!  :(

Of course, at this point, there's no actual game here -- just a way to toss the numbers up on the screen.  You can't match them or eliminate them in and way, shape, or form so far.  :P

All I'm curious about at this point is how the AutoScale works out for everyone.  This should make a rather small screen, then scale over to fit any desktop out there -- and it shouldn't cover your Window's Taskbar, leaving a little room open at the bottom of the screen.  Can folks test this little snippet out for me and let me know how things work with the scaling department for you guys? I don't know of a simple way to get Taskbar height that's cross compatible for all OSes, so I'm just eyeballing it with my display and hoping it doesn't cover anything. 

The goal, if scaling works properly, is to substitute numbers for images of candy, and then it'll become a match-3 candy puzzle!  (Expandable to Match-4, 5, 6, ect, if I want to add harder levels as a player progresses.)  I just need to find a good candy spritesheet somewhere, which shouldn't be too hard to come up with with all the Candy Crush type games out there, and then I can turn this little concept into a Halloween-themed game!  (And come Christmas, I can swap candies for reindeer, snowmen, presents, and snowflakes!)

[bplus]

OK here's what it looks like on my screen, Title with desktop dimensions:

[SMcNeill]

Your QB64 IDE is hiding the taskbar, but from the size and all, it looks like it's properly sizing and positioning itself on your screen.  👍

[Pete]

Too hard for me. I lost 10 times in a row. Barely pressed a key and it indicated game over... Press any key to end, I believe it said. Can you dumb it down a bit for us non-farm professionals? :D

Hey Steve, looks the same on mine as on Mark's. Yes, I can see my Windows task bar at the bottom, and the title bar, of the app, at the top. My only concern is the numbers appear blurry with that font, size, and the close approximation of characters.

Pete

[bplus]

Your QB64 IDE is hiding the taskbar, but from the size and all, it looks like it's properly sizing and positioning itself on your screen.  👍

I have my task bar on the left side (You can see half), there is so much more width than height on my laptop I save every pixel of height I can for QB64 programs!

But the sizing does seem to work OK, so far ;-))

[Dav]

The Autoscale works well here.  Looks great.  Doesn't hide taskbar, and i can see title bar.

- Dav

[Pete]

Steve does know we mean this Halloween, right???

Pete

[Richard]

@SMcNeill

This is what it looks like on my display (native resolution 3200 x 1800)




 


 [ You are not allowed to view this attachment ]  






Can you make a    Match One    version for me?

[Dav]

Here's my screenshot.  The autoscale works well on my 1366x768 laptop.

- Dav

  [ You are not allowed to view this attachment ]  

[SMcNeill]

Thanks guys.  Seems like it's scaling properly for everyone.  Now I just need some little candy icons and the input loop, and I can turn it into a game with just a few hours work.  Scaling has been bugging the crap out of me lately, mainly because I hurt my back again and have been doing a lot more stuff on the 4k ultra-high def laptop where I can lounge in my recliner, than I have been on my PC with the less comfortable office chair associated with it. 

Having to upscale/downscale/resize everything was turning into a real PITA, so I have a feeling that little AutoScale snippet is going to end up in a lot of my stuff for the next couple of months.  It's a pleasure to see that it's properly sizing things on various displays properly, without any issues. 

Many thanks for testing and posting screenshots, one and all.  😘

[SMcNeill]

A very simple first version of this little One Click Match program:

Code: QB64: [Select]

1. Dim Shared WS, GridSize, Choice, Matches, Center, Guess$, Guess, DisplayScreen
2. ReDim Shared Grid(0, 0) As _Byte
3. Choice = 1
4.  
5. Declare Library "th"
6.     Function taskbar_height& ()
7. End Declare
8. Randomize Timer
9.  
10. GridSize = 8: Matches = 3
11.  
12. renewgrid = -1
13. Do
14.     If renewgrid Then MakeGrid: renewgrid = 0
15.     DisplayGrid
16.     UserInput
17.     _Limit 2
18.     Choice = (Choice + 1) Mod GridSize
19.     If Choice = 0 Then Choice = GridSize
20. Loop Until checkwin
21. Screen 0: _FreeImage WS
22. WS = _NewImage(240, 240, 32)
23. Screen WS
24. _Font 8
25.  
26. Cls
27. Print "YOU ARE A BIG WEENER!! YAAAYYY!!"
28. _FreeImage DisplayScreen
29. DisplayScreen = 0
30. AutoScale
31.  
32. _KeyClear
33. Sleep
34. System
35.  
36.  
37. Function checkwin
38.     For x = 1 To GridSize
39.         For y = 1 To GridSize
40.             If Grid(x, y) <> 0 Then Exit Function
41.     Next y, x
42.     checkwin = -1
43. End Function
44.  
45. Sub UserInput
46.     C = Choice - 1
47.     If C = 0 Then C = GridSize
48.     k = _KeyHit
49.     Select Case k
50.         Case 27
51.             Screen 0: _FreeImage WS
52.             WS = _NewImage(240, 240, 32)
53.             Screen WS
54.             _Font 8
55.  
56.             Cls
57.             Print "YOU ARE A BIG LOSER!! HAHAHAHA!!"
58.             _FreeImage DisplayScreen
59.             DisplayScreen = 0
60.             AutoScale
61.             _KeyClear
62.             Sleep
63.             System
64.  
65.  
66.         Case 32
67.             For y = GridSize To 1 Step -1
68.                 If Grid(C, y) <> 0 Then Exit For
69.             Next
70.             If y <> 0 Then
71.                 '             If Grid(C, y) <> 0 Then
72.                 If Grid(C, y) = Guess Or Guess = 0 Then
73.                     Guess = Grid(C, y)
74.                     Guess$ = Guess$ + _Trim$(Str$(Guess))
75.                     Grid(C, y) = 0
76.                     If Len(Guess$) = Matches Then
77.                         Guess$ = ""
78.                         Guess = 0
79.                     End If
80.                     DisplayGrid
81.                 End If
82.                 '        End If
83.             End If
84.     End Select
85.     _KeyClear
86. End Sub
87.  
88.  
89. Sub DisplayGrid
90.     Cls
91.     For x = 1 To GridSize: For y = 1 To GridSize
92.         If Grid(x, y) Then Locate y, x: Print _Trim$(Str$(Grid(x, y)));
93.     Next y, x
94.     Locate y, Choice: Print "^";
95.     Center = 640 - _PrintWidth(String$(Matches, " ")) / 2
96.     Line (0, GridSize * 8 + 8)-Step(639, 16), -1, BF
97.     PW = _PrintWidth(String$(Matches, " "))
98.     Line ((GridSize * 8 - PW) \ 2, GridSize * 8 + 8)-Step(PW, 8), &HFF000000, BF
99.     _PrintString ((GridSize * 8 - PW) \ 2, GridSize * 8 + 8), Guess$
100.     AutoScale
101. End Sub
102.  
103. Sub MakeGrid
104.  
105.     If WS <> 0 Then Screen 0: _FreeImage WS
106.  
107.     WS = _NewImage(GridSize * 8, GridSize * 8 + 16, 32)
108.     Screen WS
109.     _Font 8 'this creates a 30x32 screen
110.     ReDim Grid(1 To GridSize, 1 To GridSize) As _Byte
111.  
112.     count = -1: value = -1
113.     For x = 1 To GridSize: For y = 1 To GridSize
114.         count = (count + 1) Mod Matches
115.         If count = 0 Then value = (value + 1) Mod Matches
116.             Grid(y, x) = value + 1
117.     Next y, x
118.     If count <> Matches - 1 Then
119.         For i = count To 0 Step -1
120.             Grid(GridSize - i, GridSize) = 0
121.         Next
122.     End If
123.  
124.  
125.     For x = 1 To GridSize: For y = 1 To GridSize
126.         xswap = Int(Rnd * GridSize) + 1: yswap = Int(Rnd * GridSize) + 1
127.         If Grid(x, y) <> 0 And Grid(xswap, yswap) <> 0 Then Swap Grid(xswap, yswap), Grid(x, y) 'Shuffle the grid
128.     Next y, x
129.     Guess$ = ""
130.     Guess = 0
131. End Sub
132.  
133. Sub AutoScale
134.     If DisplayScreen = 0 Then
135.         DW = _DesktopWidth
136.         DH = _DesktopHeight
137.  
138.         Scale = (DH - taskbar_height) / 640
139.         DisplayScreen = _NewImage(640 * Scale, 640 * Scale, 32)
140.         Screen DisplayScreen
141.         ScreenMove (DW - _Width(DisplayScreen)) \ 2, 0
142.         _Source WS: _Dest WS
143.     End If
144.     _PutImage , WS, DisplayScreen
145.     _Display
146. End Sub
147.  
148. Sub ScreenMove (x, y)
149.     $If BORDERDEC = UNDEFINED Then
150.         $Let BORDERDEC = TRUE
151.         Declare Library
152.             Function glutGet& (ByVal what&)
153.         End Declare
154.     $End If
155.     BorderWidth = glutGet(506)
156.     TitleBarHeight = glutGet(507)
157.     _ScreenMove x - BorderWidth, y - BorderWidth - TitleBarHeight
158. End Sub
159.  

There's a few internal variables which you guys can mess around with to affect difficulty and numbers of matches required:

 GridSize = 8: Matches = 3

Gridsize changes the size of our grid, Matches changes the number that an user has to meet for a match.

Surprisingly, I find the game to be harder than it first appears, at least for myself.  If I'm not careful, I end up boxing myself in and not being able to form a proper match to clear the values from the board, ending up with me getting stuck and having to forfeit the game.  :(


Still to come (if I find time between now and Halloween -- this has always been a crazy busy time here on the farm) is a substitution of candy sprites instead of numbers, a level system which gets progressively harder (level one might be gridsize 8, match 3.  level two would be gridsize 12, match 3.  level three might be gridsize 12, match 4.  level four might be gridsize 8, match 4...  And so on until the user barfs at the attempt to match an almost impossible level and quits.), and once we have levels, I can install a highscore system.

The basic gameplay is there for a one-button game (with a second button emergency exit with the ESC key, but does that *really* count towards gameplay??  IF necessary, I can swap the exit condition to something rather simple such as simply letting the selector pass the screen three times without choosing a number to remove, but personally I like the "QUICK, QUIT" use of the ESC key.  :P

Anywho, the hard part is done here with the mechanics.  Everything from this point forward is just bells and whistles. 

I *did* manage to create a little game before Halloween after all.  LOL!   ;D

[bplus]

Doesn't work for people (like me) who have their taskbar along the side of their screen, scale = 0 so errors out when scale is applied to resize or create screen.

[SMcNeill]

Doesn't work for people (like me) who have their taskbar along the side of their screen, scale = 0 so errors out when scale is applied to resize or create screen.

Evil sidebar!  I'll need to put an exemption in there for crazy machines with set-ups like that.  😤

[bplus]

This fixed it for me, interesting game, I am "A BIG WEENER!! YAAAYYY!!" thanks for that LOL

Code: QB64: [Select]

1. Sub AutoScale
2.     If DisplayScreen = 0 Then
3.         DW = _DesktopWidth
4.         DH = _DesktopHeight ' usuallly the le
5.  
6.         If DH = taskbar_height Then
7.             If DH < DW Then scale = DH / 640 Else scale = DW / 640
8.         Else
9.             scale = (DH - taskbar_height) / 640
10.         End If
11.         'Cls
12.         'Print DH, scale, taskbar_height ' <<<<<<<<<<<<<< taskbar_height is DH !!!
13.         'End
14.  
15.  
16.  
17.  
18.         DisplayScreen = _NewImage(640 * scale, 640 * scale, 32) '<<<<<<<<<<<<<<<<< error
19.         Screen DisplayScreen
20.         ScreenMove (DW - _Width(DisplayScreen)) \ 2, 0
21.         _Source WS: _Dest WS
22.     End If
23.     _PutImage , WS, DisplayScreen
24.     _Display
25. End Sub
26.  

[Pete]

Quit playing games and vote! That one VA candidate is a real...


      /***\
***         ***  (ASCII Hat).

Sorry, I had to hack your Kobayashi Maru app. It turns out me and Kirk have that much in common; so now, "I'm a BIG WINNER!"

Pete 😉