One Key Input

[SMcNeill]

For the Halloween Challenge that @bplus and @johnno56 have been talking about recently, one of the rules is to set up a program so that it only works with a single key being used.  For many folks, this could be a rather difficult thing to add into a game (How the heck do we get alphabetic responses with just the space bar??), so I thought I'd whip up a really simple little demo for one way to do this:

Code: QB64: [Select]

1. $Color:0
2. Selection$ = "<Will be accepted after two seconds inactivity>": terminate = Timer: t = Timer
3.  
4. Do
5.     Cls
6.     k = _KeyDown(32)
7.     DisplayKeys Selection
8.     If t = 0 Then
9.         If k Then t = Timer: Selection = (Selection + 1) Mod 26
10.     Else
11.         If Timer > t + 2 Then
12.             Selection$ = Chr$(65 + Selection)
13.             t = 0
14.         Else
15.             If k Then t = Timer: Selection = (Selection + 1) Mod 26
16.             Selection$ = "<Will be accepted after two seconds inactivity>"
17.         End If
18.     End If
19.     If t <> 0 Then terminate = Timer
20.     Locate 5, 1: Print "SELECTED: "; Selection$; Chr$(13); "TERMINATION IN: "; _Ceil(terminate - Timer) + 5
21.     _Display
22.     _Limit 5
23. Loop Until Timer > terminate + 5 '5 seconds of zero activity after a selection will terminate the program completely.
24.  
25. Sub DisplayKeys (Selection)
26.     Color Red
27.     Locate Selection \ 13 + 1, (Selection Mod 13) * 3 + 2: Print "[ ]"
28.     Color BrightWhite
29.     For j = 0 To 1
30.         For i = 0 To 12
31.             Locate j + 1, (i + 1) * 3: Print Chr$(65 + 13 * j + i)
32.     Next i, j
33. End Sub

My whole little demo here comes in at around 30 lines of code or so, so something like this should be easy enough to implement in just about any sort of program someone would need it in.  The only real change might be a need to alter the termination part of the program (in this case it's just 5 seconds of total inactivity) to whatever suits your program needs instead.  (For example, hangman might terminate after the player either wins or dies...)

Usage...  Just press the SPACEBAR.  If you can't figure it out after that, I've did something wrong!   It's just a simple 1-key input routine!  :P

[bplus]

Yeah I suppose that would work and easier to understand than what I am using; it could all fit on one line too.
Just keep punching the spacebar until you're on your choice and then wait. Each punch might add to timer I imagine.
Oh verification would not be needed, just allot of spacebar punching.

Do suggest a different highlight color than dark red for that background, I couldn't even see it in semi cloudy afternoon here in Ohio.

Well, I guess I will rewrite this method into one function and install and test.

[SMcNeill]

You can also hold down the spacebar to autoscroll, without having to beat the key to death.  The limit 5 will max increment 5 characters per second, so you should be able to choose the letter you desire within 5 seconds or so.

I imagine something like this would work real nice and easy for a Hangman-like game.

[bplus]

I imagine something like this would work real nice and easy for a Hangman-like game.

Yeah, it would work pretty nice for Game I have for challenge, here is Function I came up with:

Code: QB64: [Select]

1. _Title "One Key System modified by bplus" ' b+ mod 2021-10-04
2. ' 2021-10-04 Steve One Key System   https://www.qb64.org/forum/index.php?topic=4255.msg136324#msg136324
3. ' 2021-10-04 bplus mod to a single Function for returning user input
4. Color 11, 0: Cls 'get black background
5. Do
6.     Print: Print "Select letter using spacebar to scroll to it: ";
7.     c$ = choice$(24, 25, " 1234ABCDEFGHIKKLMNOPQRSTUVWXYZ")
8.     here: If c$ <> " " Then Print c$ Else c$ = choice$(24, 25, " 1234ABCDEFGHIKKLMNOPQRSTUVWXYZ"): GoTo here:
9. Loop Until c$ = "Q"
10.  
11. Function choice$ (row, col, selection$)
12.     fg~& = _DefaultColor: bg~& = _BackgroundColor: place& = 0
13.     saveRow = CsrLin: saveCol = Pos(0): t = Timer
14.     GoSub show
15.     Do
16.         k$ = InKey$
17.         If k$ = Chr$(27) Then System ' emergency exit
18.         GoSub show:
19.         If k$ = " " Then
20.             t = Timer: place = (place + 1) Mod Len(selection$)
21.         Else ' watch out for midnight!
22.             If Timer - t > 4 Then choice$ = Mid$(selection$, place + 1, 1): Locate saveRow, saveCol: Exit Function
23.         End If
24.         _Limit 7 'so can hold down spacebar, nice
25.     Loop
26.     show:
27.     Locate row, col
28.     For i = 1 To Len(selection$)
29.         If i = place + 1 Then Color bg~&, fg~& Else Color fg~&, bg~&
30.         Locate row, col - 1 + i: Print Mid$(selection$, i, 1);
31.     Next
32.     Color fg~&, bg~&
33.     Return
34. End Function
35.  

I am leaving a space at the start of selections to signal the app that the user left to find Pete in the Submarine.

[johnno56]

Cool... One slight problem... Keyboard buffer may be a thing... Holding Space to scroll; Release... and the 'selector' keeps moving for a short time... I do not know the QB64 commands well enough to fix that... Moo Ha Ha....

[bplus]

Cool... One slight problem... Keyboard buffer may be a thing... Holding Space to scroll; Release... and the 'selector' keeps moving for a short time... I do not know the QB64 commands well enough to fix that... Moo Ha Ha....

You could employ _KeyClear which clears keyboard buffer but I like trying to play shuffle board with the Spacebar, man it's a b when the you go slightly past the letter you want!

[SMcNeill]

Cool... One slight problem... Keyboard buffer may be a thing... Holding Space to scroll; Release... and the 'selector' keeps moving for a short time... I do not know the QB64 commands well enough to fix that... Moo Ha Ha....

No keyboard buffer.  You’re not bothering to check if a series of keys were pressed.  All we need to know is if a _KEYDOWN even is occurring or not.

[TempodiBasic]

Well
I find fine your different proposals to get input using a line/table of the choices available (set of characters).
I have build this binary selection method that you can evaluate here
https://www.qb64.org/forum/index.php?topic=4257.msg136345#msg136345

[bplus]

I have Steve's idea evolved to this in my code, free for anyone who wants to use in challenge and needs letters or menu choices by number up to 10 digits.

Code: QB64: [Select]

1. _Title "One Key - Best so far Choice$" ' b+ 2021-10-09
2. ' Best in my opinion One Key Control as date above
3.  
4.  
5. 'setup for Choice$ function
6. Dim Shared KeyTimer, place ' preserve values between choice$ calls
7. KeyTimer = Timer ' <<<<<<<<< init outside main choice calling loop
8. Do
9.     Cls
10.  
11.     '
12.     ' Here we can run all the backgound graphics we want with no pauses waiting for input
13.     '
14.  
15.     Print "Use this One Key tool to Input your name or something using only spacebar!"
16.     Print "Select by spacing until highlite is over your choice letter or menu #."
17.     Print "Use Menu #1 at end of letters to signal the end of you input, like enter."
18.     Print "Use Menu #2 to actually insert a space in the text!"
19.     Print "Use escape to quit"
20.     Print
21.     Print "Progress: "; text$
22.     '''' KeyTimer = Timer ' <<<<<<<<<<<<<<<<<<<<<<<<<<<< no not just before calling choice, start outside loop
23.     c$ = choice$(10, 5, " A B C D E F G H I J K L M N O P Q R S T U V W X Y Z 1 2 ")
24.     If c$ <> "" And c$ <> " " And c$ <> "1" And c$ <> "2" Then text$ = text$ + c$
25.     If c$ = "1" Then
26.         Print "User input "; text$; ", resetting for another go."
27.         KeyTimer = Timer 'reset for another go round
28.         text$ = ""
29.         _Delay 3
30.     End If
31.     If c$ = "2" Then text$ = text$ + " "
32.     _Limit 30
33. Loop Until _KeyDown(27)
34.  
35. Function choice$ (row, col, selection$) ' One Key User Input System with tiny little setup
36.     ' setup  for best results space out selections$ for one letter at a time choice
37.     ' dim shared KeyTimer in main, set KeyTimer like KeyTimer = timer outside main loop with Choice$
38.     Dim As _Unsigned Long fg, bg
39.     Dim As Integer saveRow, saveCol, i
40.     Dim k$
41.     fg~& = _DefaultColor: bg~& = _BackgroundColor
42.     saveRow = CsrLin: saveCol = Pos(0)
43.     If _KeyDown(27) Then System ' emergency exit
44.     GoSub show:
45.     k$ = InKey$
46.     If k$ = " " Then KeyTimer = Timer: place = (place + 1) Mod Len(selection$)
47.     If Timer - KeyTimer >= 4 Then choice$ = Mid$(selection$, place + 1, 1): place = 0
48.     Locate saveRow, saveCol: Exit Function
49.  
50.     show:
51.     Locate row, col
52.     For i = 1 To Len(selection$)
53.         If i = place + 1 Then Color bg~&, fg~& Else Color fg~&, bg~&
54.         Locate row, col - 1 + i: Print Mid$(selection$, i, 1);
55.     Next
56.     '_Display  now the main loop handles since this is no longer a loop
57.     Color fg~&, bg~&
58.     Return
59. End Function

This does not cover the midnight problem with timer, who's up that late anymore? :)

[Cobalt]

Why does this sound like some kind of Atari wana-be challenge? Hell they only gave you that one damn button.

Does mouse movement count? hover the mouse over something and use the 'one' button to activate that option.

[bplus]

Why does this sound like some kind of Atari wana-be challenge? Hell they only gave you that one damn button.

Does mouse movement count? hover the mouse over something and use the 'one' button to activate that option.

@Cobalt

Yes it does come from a Competition and discussion here at this forum and a Halloween Challenge for this forum that extends the specification for extra credit a Halloween Theme and/or screen 0 text, Console would count too I should think.
https://www.qb64.org/forum/index.php?topic=4245.msg136193#msg136193

Using the mouse positioning has already been ruled out, Steve brought it up maybe in the above link.
https://www.qb64.org/forum/index.php?topic=4245.msg136415#msg136415

Pete, Dav and I so far have posted code taking up the challenge. Pete stayed in Screen 0 (extra credit) and converted old code to Halloween Theme in link above, I think, Yes Here:
https://www.qb64.org/forum/index.php?topic=4245.msg136564#msg136564

Dav has a One key Halloween Game and has hinted at a bundle of them (graphics mode).
Dav's Jack Stack: https://www.qb64.org/forum/index.php?topic=4258.msg136358#msg136358

I am running a graphics version for Halloween and another Screen 0 variation on the Crypt-o-Gram Game in Text Mode: https://www.qb64.org/forum/index.php?topic=4258.msg136358#msg136358

[Cobalt]

Well really haven't felt like programing lately, but I will give this a shot. Probably don't have the time but who knows.

[TempodiBasic]

One Key Challange
I have understood that the input system allowed was only Keyboard. No mouse No joystick.

about snippets posted here, they are very remarkable.
All 3 codes use the method
wait input, do while input, stop more than X time = finished
so you count time of waiting only at moment that input stops,
moreover until timeout, you can restart the choice procedure to change your selection.

I think that I'll turn my binary search including this time using method that is fastest to choose for all the humans (it lets remember me the Hall of Fame panel of cabinet videogames),
the previous one is good for other goals (just think when you play a videogame that let you choose the starting level from a panel).

Thanks for talking and sharing

PS
@SMcNeill
Steve , I know you are professional and expert.... why do you post an Old BASIC style snippet? With all those CHR$?
It is great but so poor flexible and poor reusable! How many code Should I change to show the alphabet in QWERTY order at the place of natural order?  :P