Author Topic: I'm stumped by this error (Read 4623 times)

Jaze · « **on:** September 06, 2021, 04:33:48 pm »

I'm writing a puzzle game. You start with a phrase spelled with different letters than the ones actually in the phrase. You continue along until you have the original phrase. The letters appear in one color if you've changed it and another color for the original code. I got it working so the first letter you choose to switch displays properly. But every time you try to change another letter, the lines of the phrase are printed out twice. The second printed line is in a different color. I'm at wits end. Any help would be much appreciated.

Code: QB64: [Select]

ON ERROR GOTO crap
GOTO beginning
crap:
PRINT "Error, Line number"
PRINT ERR, _ERRORLINE
END
beginning:
WIDTH 80, 50
_FULLSCREEN
CONST TRUE = 1
CONST FALSE = 0
CONST numberOfLines = 15
 
DIM SHARED leftArrow$: leftArrow$ = CHR$(0) + "K"
DIM SHARED rightArrow$: rightArrow$ = CHR$(0) + "M"
DIM SHARED translationMatrix$(1 TO 26, 1 TO 2): FOR cl = 1 TO 26: translationMatrix$(cl, 1) = "": translationMatrix$(cl, 2) = "": NEXT cl
DIM SHARED codedPhrase$: codedPhrase$ = ""
DIM SHARED answerPhrase$: answerPhrase$ = ""
DIM SHARED highlightedLetter: highlightedLetter = 0
DIM SHARED attemptedLetters$(1 TO 26, 1 TO 2): FOR cl = 1 TO 26: attemptedLetters$(cl, 1) = CHR$(cl + 64): attemptedLetters$(cl, 2) = "-": NEXT cl
DIM SHARED workingLines$(1 TO numberOfLines)
DIM SHARED initiallyCodedLines$(1 TO numberOfLines)
DIM SHARED newLines$(1 TO numberOfLines)
DIM SHARED answerLines$(1 TO numberOfLines)
DIM SHARED leftPositions(1 TO numberOfLines) AS INTEGER
FOR cl = 1 TO numberOfLines
    workingLines$(cl) = ""
    initiallyCodedLines$(cl) = ""
    newLines$(cl) = ""
    answerLines$(cl) = ""
    leftPositions(cl) = 0
NEXT cl
 
CALL Main
SUB Main
    'first, pick a phrase
    randomPhrase = INT(RND * FileStatus) + 1
    OPEN "Phrases.txt" FOR INPUT AS #1
    FOR x = 1 TO randomPhrase
        LINE INPUT #1, answerPhrase$
    NEXT x
    CLOSE #1
 
    'second, create a code
    usedAlphabet$ = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    FOR allLetters = 1 TO 26
        translationMatrix$(allLetters, 1) = CHR$(allLetters + 64)
        newRndLet:
        randomLetter = INT(RND * LEN(usedAlphabet$)) + 1
        translationMatrix$(allLetters, 2) = MID$(usedAlphabet$, randomLetter, 1)
        IF translationMatrix$(allLetters, 1) = translationMatrix$(allLetters, 2) THEN GOTO newRndLet
        usedAlphabet$ = MID$(usedAlphabet$, 1, randomLetter - 1) + MID$(usedAlphabet$, randomLetter + 1, LEN(usedAlphabet$))
    NEXT allLetters
 
    'third: put the phrase in code
    PRINT "answerPhrase$ = " + answerPhrase$: PRINT
    FOR letter = 1 TO LEN(answerPhrase$)
        answerLetter$ = MID$(answerPhrase$, letter, 1)
        upAnsLet$ = UCASE$(answerLetter$)
        answerLetterNumber = ASC(upAnsLet$) - 64
        IF ASC(upAnsLet$) >= 65 AND ASC(upAnsLet$) <= 90 THEN
            upCodeLet$ = translationMatrix$(ASC(upAnsLet$) - 64, 2)
            IF ASC(answerLetter$) >= 65 AND ASC(answerLetter$) <= 90 THEN
                codedLetter$ = upCodeLet$
            ELSE
                codedLetter$ = LCASE$(upCodeLet$)
            END IF
        ELSE
            codedLetter$ = answerLetter$
        END IF
        codedPhrase$ = codedPhrase$ + codedLetter$
    NEXT letter
 
    'next on the list is to center the phrases
    shrinkCode$ = codedPhrase$
    shrinkAns$ = answerPhrase$
    IF LEN(codedPhrase$) >= 60 THEN
        numLine = 0
        DO
            numLine = numLine + 1
            checkHere = 60
            DO
                checkHere = checkHere - 1
                findSpace$ = MID$(codedPhrase$, checkHere, 1)
            LOOP UNTIL findSpace$ = " "
            workingLines$(numLine) = MID$(shrinkCode$, 1, checkHere)
            initiallyCodedLines$(numLine) = MID$(shrinkCode$, 1, checkHere)
            leftPositions(numLine) = Center(MID$(shrinkCode$, 1, checkHere))
            answerLines$(numLine) = MID$(shrinkAns$, 1, checkHere)
            shrinkCode$ = MID$(shrinkCode$, checkHere + 1, LEN(shrinkCode$))
            shrinkAns$ = MID$(shrinkAns$, checkHere + 1, LEN(shrinkAns$))
        LOOP UNTIL numLine = 15 OR shrinkCode$ = ""
    ELSE
        workingLines$(1) = codedPhrase$
        initiallyCodedLines$(1) = codedPhrase$
        answerLines$(1) = answerPhrase$
        leftPositions(1) = Center(codedPhrase$)
    END IF
    cs = 1
    '    DO WHILE leftPositions(cs) <> 0
    '        LOCATE , leftPositions(cs): PRINT answerLines$(cs)
    '        cs = cs + 1
    '    LOOP
    PRINT
    '    gg = 1
    '    DO WHILE leftPositions(gg) <> 0
    '        LOCATE , leftPositions(gg): PRINT workingLines$(gg)
    '        gg = gg + 1
    '    LOOP
    '    a$ = P$
 
    'now to display and build the interface
    highlightedLetter = 1
    CALL DisplayScreen
    '    d$ = P$
    plsWt = FALSE
    DO
        '        FOR cv = 1 TO numberOfLines: newLines$(cv) = "": NEXT cv
        getCmd$ = INKEY$
        getCmd$ = UCASE$(getCmd$)
        SELECT CASE getCmd$
            CASE leftArrow$
                IF highlightedLetter > 1 THEN
                    highlightedLetter = highlightedLetter - 1
                ELSE
                    highlightedLetter = 26
                END IF
                plsWt = TRUE
            CASE rightArrow$
                IF highlightedLetter < 26 THEN
                    highlightedLetter = highlightedLetter + 1
                ELSE
                    highlightedLetter = 1
                END IF
                plsWt = TRUE
            CASE CHR$(13)
                FOR cl = 1 TO 26
                    attemptedLetters$(cl, 1) = CHR$(cl + 64)
                    attemptedLetters$(cl, 2) = "-"
                NEXT cl
                FOR x = 1 TO numberOfLines
                    workingLines$(x) = initiallyCodedLines$(x)
                NEXT x
            CASE CHR$(27)
                END
            CASE "A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z"
                plsWt = TRUE
                attemptedLetters$(highlightedLetter, 2) = getCmd$
                numLines = 1
                DO WHILE workingLines$(numLines) <> ""
                    FOR let1 = 1 TO LEN(workingLines$(numLines))
                        currentLetter$ = MID$(workingLines$(numLines), let1, 1)
                        '                        LOCATE 1, 1: PRINT "currentLetter$: " + currentLetter$: g$ = P$
                        IF CHR$(highlightedLetter + 64) = UCASE$(currentLetter$) THEN
                            replacementLetter$ = getCmd$
                            letCase = ASC(MID$(workingLines$(numLines), let1, 1))
                            IF letCase >= 97 AND letCase <= 122 THEN replacementLetter$ = LCASE$(replacementLetter$)
                            newLines$(numLines) = newLines$(numLines) + replacementLetter$
                        ELSE
                            newLines$(numLines) = newLines$(numLines) + currentLetter$
                        END IF
                        '                        PRINT "**************************************************************************************************"
                        '                        PRINT "newLines$(numLines) = " + newLines$(numLines): k$ = P$
                    NEXT let1
                    numLines = numLines + 1
                LOOP
        END SELECT
        IF plsWt = TRUE THEN
            plsWt = FALSE
            f = 1
            DO WHILE newLines$(f) <> ""
                workingLines$(f) = newLines$(f)
                f = f + 1
            LOOP
            CALL DisplayScreen
        END IF
    LOOP UNTIL SolvedIt = TRUE
END SUB
 
FUNCTION SolvedIt
    rtn = TRUE
    FOR checkTheLine = 1 TO numberOfLines
        IF workingLines$(checkTheLine) <> answerLines$(checkTheLine) THEN rtn = FALSE
    NEXT checkTheLine
    SolvedIt = rtn
END FUNCTION
 
 
SUB DisplayScreen
    COLOR 11, 1: CLS
    LOCATE 1, 1: PRINT answerPhrase$
    'print out the quote
    numLines = 1
    DO WHILE leftPositions(numLines) <> 0
        'LOCATE 48, 1: PRINT "leftPositions(numLines) = " + S$(leftPositions(numLines)) + " ": c$ = P$
        LOCATE 11 + numLines, leftPositions(numLines)
        '        PRINT "numLines: " + S$(numLines) + "    workingLine$(numlines), LEN = " + workingLines$(numLines) + ",   " + S$(LEN(workinglines(numLines)))
        '        PRINT "initiallyCodedLines$(" + S$(numLines) + "): = " + initiallyCodedLines$(numLines)
        '        PRINT "answerLines$(numLines)" + answerLines$(numLines)
        '        f$ = P$
        FOR o = 1 TO LEN(workingLines$(numLines))
            wlc$ = MID$(workingLines$(numLines), o, 1)
            icl$ = MID$(initiallyCodedLines$(numLines), o, 1)
            al$ = MID$(answerLines$(numLines), o, 1)
            IF ASC(UCASE$(wlc$)) - 64 = highlightedLetter THEN 'if the letter is highlighted print 11 on 0
                COLOR 10, 0
            ELSEIF wlc$ = al$ THEN 'the letter is correct
                COLOR 14, 1
            ELSEIF wlc$ <> icl$ THEN 'the letter has been changed or not changed back to its original code
                COLOR 15, 1
            ELSE
                COLOR 10, 1
            END IF
            PRINT wlc$; ': f$ = P$
        NEXT o
        numLines = numLines + 1
    LOOP
    'print out the selectable letters
    spaces = 2
    FOR b = 1 TO 26
        IF b = highlightedLetter THEN
            COLOR 10, 0
        ELSE
            COLOR 14, 1
        END IF
        LOCATE 40, spaces: PRINT attemptedLetters$(b, 1)
        IF b = highlightedLetter THEN
            COLOR 10, 0
        ELSE
            COLOR 12, 1
        END IF
        LOCATE 42, spaces: PRINT attemptedLetters$(b, 2)
        spaces = spaces + 3
    NEXT b
END SUB
 
 
FUNCTION FileStatus
    IF _FILEEXISTS("Phrases.txt") = 0 THEN
        OPEN "Phrases.txt" FOR OUTPUT AS #1
        PRINT #1, "Tomorrow, and tomorrow, and tomorrow, Creeps in this petty pace from day to day, To the last syllable of recorded time; And all our yesterdays have lighted fools The way to dusty death. Out, out, brief candle! Life's but a walking shadow, a poor player, That struts and frets his hour upon the stage, And then is heard no more. It is a tale Told by an idiot, full of sound and fury, Signifying nothing."
        PRINT #1, "To be, or not to be: that is the question: Whether 'tis nobler in the mind to suffer The slings and arrows of outrageous fortune, Or to take arms against a sea of troubles, And by opposing end them? To die: to sleep; No more; and by a sleep to say we end The heart-ache and the thousand natural shocks That flesh is heir to, 'tis a consummation Devoutly to be wish'd. To die, to sleep; To sleep: perchance to dream: ay, there's the rub; For in that sleep of death what dreams may come When we have shuffled off this mortal coil, Must give us pause"
        PRINT #1, "If someone is able to show me that what I think or do is not right, I will happily change. For I seek the truth, by which no oe ever was truly harmed. Harmed is the person who continues in his self-deception and ignorance."
        PRINT #1, "Funny lines: Before you marry a person, you should first make them use a computer with slow internet to see who they really are. -- Someone asked me, if I were stranded on a desert island what book would I bring... " + CHR$(34) + "How to Build a Boat." + CHR$(34)
        PRINT #1, "Funny lines: I finally realized that people are prisoners of their own phones... that's why it's called a " + CHR$(34) + "cell" + CHR$(34) + " phone. -- Be decisive. Right or wrong, make a decision. The road is paved with flat squirrels who couldn't make a decision."
        PRINT #1, "Funny lines: If at first you don't succeed, then skydiving definitely isn't for you. -- My cell phone is acting up. I keep pressing the Home button but every time I look around, I'm still at work."
        PRINT #1, "Pangrams: Pack my box with five dozen liquor jugs. -- The quick brown fox jumps over the lazy dog. -- My girl wove six dozen plaid jackets before she quit."
        PRINT #1, "EOF"
        CLOSE #1
        numberOfPhrases = 7
    ELSE
        OPEN "Phrases.txt" FOR INPUT AS #1
        numberOfPhrases = 0
        DO
            numberOfPhrases = numberOfPhrases + 1
            LINE INPUT #1, lineCounting$
        LOOP UNTIL INSTR(lineCounting$, "EOF") <> 0
        numberOfPhrases = numberOfPhrases - 1
        CLOSE #1
    END IF
    FileStatus = numberOfPhrases
END FUNCTION
 
FUNCTION Center (text$)
    Center = INT((80 - LEN(text$)) / 2)
END FUNCTION
 
FUNCTION S$ (number)
    S$ = LTRIM$(STR$(number))
END FUNCTION
 
FUNCTION P$
    pause$ = INPUT$(1)
    IF pause$ = CHR$(27) THEN END
    P$ = pause$
END FUNCTION

doppler · « **Reply #1 on:** September 06, 2021, 04:45:55 pm »

Someone is likely to swoop in with an answer. Before that happens try out your problem using the debugger version of qb64. It is stable enough to help you with your problem.

https://www.qb64.org/forum/index.php?topic=4119.0

FellippeHeitor spent an ungodly amount of time making it work. Having an answer is nice. But figuring it out with the proper tools go'es further than just an answer.
Trust me it's easier to use once you get the hang of it.

Jaze · « **Reply #2 on:** September 06, 2021, 05:09:39 pm »

I hate to sound like a Newbie but how exactly do you start debug mode?

doppler · « **Reply #3 on:** September 06, 2021, 05:29:09 pm »

Download the code from the link. I also suggest reading the whole message post, to get an idea what to do.
extract it to a new directory. Say. "qb64-debug" it's independant so you don't want to destroy your working qb64 directory.
Start the new version. Load your problem code. Add: "$debug" to the top line of your code.
Hit F7 to get it all going.

At this point follow the Function prompts. ie: set a break point, step your code. add watch variable points.

You could step through all your code and watch the output display. Once you determine your problem point set a breakpoint there. So when you just hit F5 to start it will stop before your problem area. Then you can step. Watch output and variables. It should become obvious where your problem is. Stepping in your head, you can miss it. Stepping your code is slower than full out running. And mistakes can be seen.

TRUST ME IT GOING TO BE FUN.

Jaze · « **Reply #4 on:** September 06, 2021, 05:41:20 pm »

I just found another error on line 84. codedPhrase$ should have been shrinkCode$ -- I didn't notice because it worked as I intended.

doppler · « **Reply #5 on:** September 06, 2021, 05:46:24 pm »

Quote from: Jaze on September 06, 2021, 05:41:20 pm

worked as I intended.

Ah, the old it did what I said error.
10 Bang head against wall : goto 10

Honestly try using the debugger version too.

bplus · « **Reply #6 on:** September 06, 2021, 06:36:33 pm »

Never mind I am still trying to figure out how this is supposed to work, so
1. high light letter
2. press the letter you think it should be
3. prest-o change - o two lines appear after the first change ;(

bplus · « **Reply #7 on:** September 06, 2021, 08:32:24 pm »

These replacement blocks will get you closer:

Code: QB64: [Select]

            Case "A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z"
                plsWt = TRUE
                attemptedLetters$(highlightedLetter, 2) = getCmd$
                numLines = 1
                Do While workingLines$(numLines) <> ""
                    For let1 = 1 To Len(workingLines$(numLines))
                        currentLetter$ = Mid$(workingLines$(numLines), let1, 1)
                        '                        LOCATE 1, 1: PRINT "currentLetter$: " + currentLetter$: g$ = P$
                        If Chr$(highlightedLetter + 64) = UCase$(currentLetter$) Then
                            replacementLetter$ = getCmd$
                            letCase = Asc(Mid$(workingLines$(numLines), let1, 1))
                            If letCase >= 97 And letCase <= 122 Then replacementLetter$ = LCase$(replacementLetter$)
                            Mid$(workingLines$(numLines), let1, 1) = replacementLetter$  '<<< here you were building longer and longer lines
                        Else
                            Mid$(workingLines$(numLines), let1, 1) = currentLetter$  '<<< here you were building longer and longer lines
                        End If
                        '                        PRINT "**************************************************************************************************"
                        '                        PRINT "newLines$(numLines) = " + newLines$(numLines): k$ = P$
                    Next let1
                    numLines = numLines + 1
                Loop
        End Select
        DisplayScreen
        _Limit 60
        'If plsWt = TRUE Then
        '    plsWt = FALSE
        '    f = 1
        '    Do While newLines$(f) <> ""
        '        workingLines$(f) = newLines$(f)
        '        f = f + 1
        '    Loop
        '    Call DisplayScreen
        'End If
 

but you have a logic problem eg, if you replace all the s with l and then need to replace all the l with s, you will never get 2nd word, lines, right.

bplus · « **Reply #8 on:** September 06, 2021, 08:56:33 pm »

BTW your code worked the first time with a letter change because newLines$() were completely blank so the first change of letters replaced newLines$()... oh hey that means there may be another way to fix this... be right back.

bplus · « **Reply #9 on:** September 06, 2021, 09:02:35 pm »

Yep! this works too at line 150 add this line (to your original code):

Code: QB64: [Select]

Erase newLines$ 
 

that way newLines$() starts empty at each rebuild.

Jaze · « **Reply #10 on:** September 07, 2021, 12:29:49 am »

thanks

bplus · « **Reply #11 on:** September 07, 2021, 05:45:06 am »

Quote

but you have a logic problem eg, if you replace all the s with l and then need to replace all the l with s, you will never get 2nd word, lines, right.

I have figured out how to handle this logic problem of replacements.

You have 3 sets of lines:
1. The original Answer set
2, that gets coded into a Coded Set
3. and a Working set than transitions from the Coded set to the Answer set and yes, as you have, the Coded set is solved when the Working set matches the Answer set.
Note: forget about another NewLines set that's just more fiddle.

I suggest when you set up the Coded Set you also set up the Working set with all "*" where there are letters in the Answer set. BTW, this is how we do it with Hangman.

Now for displaying the Puzzle in transition from Coded to Answer (NOT like Hangman) where the Working set still has a * show the Coded letter in the Coded Color (I suggest a better contrast between Coded say Blue to Answer say Red) and where there is a letter in the Answer set show that letter with the Answer color. So in fixing the Display sub find the letter AND color to print one letter at a time. If the Working set still shows a * display the Coded set letter and color, where it is not a * show the Working set letter in the Working set color.

So how to change a Coded character to the replacement letter in the Working set?
1. Find where the coded letter is in the Coded set, column x

Code: QB64: [Select]

lastX = 1 'before Loop
While x <> 0
x = INSTR(lastX, Coded$(lineNum), ChangeLetter$)

2. Use MID$ sub to change that letter only in the Working set;

Code: QB64: [Select]

MID$(Working$(lineNum), x, 1) = ReplacementLetter$
Wend
 

that replaces the * with the letters plus you can easily change letters you have replaced already to different ones.

bplus · « **Reply #12 on:** September 07, 2021, 06:03:19 am »

As far as setup goes, lay out the Answer set centered as you like then line for line, letter for letter, build the Working set with "*" where there is a letter and the other characters or blanks where they are.

bplus · « **Reply #13 on:** September 07, 2021, 06:12:27 am »

Quote

So how to change a Coded character to the replacement letter in the Working set?
1. Find where the coded letter is in the Coded set, column x

Code: QB64: [Select]
lastX = 1 'before Loop
WHILE x <> 0
x = INSTR(lastX, Coded$(lineNum), ChangeLetter$)
2. Use MID$ sub to change that letter only in the Working set;
Code: QB64: [Select]
MID$(Working$(lineNum), x, 1) = ReplacementLetter$
WEND

that replaces the * with the letters plus you can easily change letters you have replaced already to different ones.

Forgot to update lastX should be:

Code: QB64: [Select]

lastX = 1 'before Loop
WHILE lastX <> 0
  x = INSTR(lastX, Coded$(lineNum), ChangeLetter$)
  ' 2. Use MID$ sub to change that letter only in the Working set;
  if x <> 0 MID$(Working$(lineNum), x, 1) = ReplacementLetter$ 
  lastX = x
WEND
 

Jaze · « **Reply #14 on:** September 07, 2021, 02:00:45 pm »

I finally was able to work around the errors. Thank you all. Now I am going to add a menu with options to add a new phrase to Phrases.txt or load a saved game. Those SUBs are easy enough. Thanks again

News:

Author Topic: I'm stumped by this error (Read 4623 times)

Jaze

I'm stumped by this error

doppler

Re: I'm stumped by this error

Jaze

Re: I'm stumped by this error

doppler

Re: I'm stumped by this error

Jaze

Re: I'm stumped by this error

doppler

Re: I'm stumped by this error

bplus

Re: I'm stumped by this error

bplus

Re: I'm stumped by this error

bplus

Re: I'm stumped by this error

bplus

Re: I'm stumped by this error

Jaze

Re: I'm stumped by this error

bplus

Re: I'm stumped by this error

bplus

Re: I'm stumped by this error

bplus

Re: I'm stumped by this error

Jaze

Re: I'm stumped by this error