SHELL (taskkill)

[krovit]

A weak point of QB64 I think is the shell to run DOS commands.
Some work, others don't... it takes a bit of luck.

For example CMD /C TASKKILL /F /IM... it never seems.

To work Tips?

Thank you!

[SpriggsySpriggs]

I think CMD /C is already part of our shell string on the back end. Try it without CMD /C

[krovit]

Thank you, SpriggsySpriggs
but not even so it works.

[zaadstra]

I think CMD /C is already part of our shell string on the back end. Try it without CMD /C

When did this change?  I don't knpw better than this has to be added for 'difficult' commands.  Indeed a bit trial and error.

For example CMD /C TASKKILL /F /IM... it never seems.

Is it possible the command won't execute because it is missing elevated rights (administrator)?

[krovit]

Hello, Zaadstda

Frankly the behavior seems random... can't find constant logic in the behavior... maybe it's me who's wrong. For sure you have to abound with CHR$(34) in code composition.

The problem of Administrator rights exists and depends, of course, by windows (which likes to complicate things).

The problem sometimes, but not always, is solved by running the EXE file as an administrator.

It would be nice to find a reliable system that works to give these rights of administrator within the BAS code.

Things can improve if you launch a BAT file from the inside of the code. The exact same institutions launched with SHELL do not work! But I would not want to be a slave to the presence of the batch file.

[krovit]

However, several problems remain...

This works

Code: QB64: [Select]

1. shell "ren c:\"+ chr$(34)+ "example.txt" + chr$(34) + " " + chr$(34) + "example.txt_" + chr$(34)
2.  

This NOT works

Code: QB64: [Select]

1. shell "ren "+ chr$(34)+ "c:\example.txt" + chr$(34) + " " + chr$(34) + "c:\example.txt_" + chr$(34)
2.  

This NOT works

Code: QB64: [Select]

1. file1$ = "example.txt"
2. file2$ = file1$+"_"
3.  
4. shell "ren "+ chr$(34)+ file1$ + chr$(34) + " " + chr$(34) + file2$ + chr$(34)
5.  

This NOT works

Code: QB64: [Select]

1. file1$ = "example.txt"
2. file2$ = file1$+"_"
3.  
4. shell "ren "+ chr$(34)+ "c:\example.txt" + chr$(34) + " " + chr$(34) + "c:\example.txt_" + chr$(34)
5.  

This works

Code: QB64: [Select]

1. file1$ = "example.txt"
2. file2$ = file1$+"_"
3.  
4. shell "ren C:\"+ chr$(34)+ file1$ + chr$(34) + " " + chr$(34) + file2$ + chr$(34)

In practice it seems (it seems!) that the file name should NOT contain the path.
The full path to the file MUST be put together with the dos command.
The path can be assigned to a variable, and this can be added to the DOS command, but it can NOT be inside the file name...


Taskkill, instead, it seems to ignore all this...

To the DOS command "Copy", instead, everything is fine... and works with any combination...

But not always always... :(

[SpriggsySpriggs]

You could also just use http://www.qb64.org/wiki/NAME

[krovit]

Thanks for reminding me: NAME I knew (but I had forgotten!); soon I will need.

However the problem on DOS command remains. Maybe it's just mine but something is not convincing (see examples).
Every now and then it happens that if he can't do without it and then you have to invent something.

For TASKKILL (what now interests me most) I'll have to resort to a batch file.

[SpriggsySpriggs]

What is your intention with taskkill (other than the obvious; killing a task). Are you writing up a program that needs to be able to stop any process by name? Or is this for stopping a particular process on certain intervals or events?

[krovit]

I use win 7 (but on win 10 it's the same thing).

One of the goals is also to terminate processes that start on their own under certain conditions.
At this time I need to kill a particular program.

For taskkil, more than other dos commands, you need administrator rights.

Getting the rights is a problem!

For taskkill, it seems, it is not enough even to run the EXE file in administrator mode.
And to BAT file, by its nature, cannot be assigned administrator rights for execute.

So you don't get anything: neither with BAS code, nor with the EXE, nor with the BAT file.

From the command line, in a CMD window opened in administrator mode, everything works perfectly !!

But now... I think I'll amaze you!

Sometimes... only a few very rare times... for example this morning when I tried again (the PC had not been turned off) the first time - ONLY THE FIRST TIME - the EXE file, without administrator rights, terminated the program !!!

Then, nothing more. Instead, the execution is planted and does not execute the END command.

Virus? no, there are none; mystery? yes, it is Maybe ghosts...

I'm losing hope...

Code: QB64: [Select]

1. SHELL "C:\Windows\System32\notepad.exe"
2. SLEEP
3. SHELL "taskkill /IM " + CHR$(34) + "notepad.*" + CHR$(34)
4. END
5.  

[Petr]

I tried your broken example with the REN command for dos. I proceeded as follows: instead of calling SHELL directly from QB64, I assigned the entire Dos command to a string variable, pasted it into the clipboard with the _CLIPBOARD $ command, and pasted the string into a .BAT file in a text editor, and added the PAUSE command at the end (same as SLEEP in QB64) (to find out why it doesn't work). The syntax was bad. The REN command did not want the REN format "path / file" "path / file" but REN path / file file. In addition, quotation marks are not required for the dos system.

Otherwise, terminating processes using TASKKILL is not a problem if I get the process ID with the TASKLIST command, which I need to terminate with the TASKKILL / PID [process ID] / T command.


Automatically kill notepad after two seconds:

Code: QB64: [Select]

1. SHELL _DONTWAIT "C:\Windows\System32\notepad.exe"
2. _DELAY 2
3. SHELL "taskkill /IM " + CHR$(34) + "notepad.*" + CHR$(34)
4. END
5.  

[SpriggsySpriggs]

@krovit I had to redo this code to make it look better. It used to look a little ugly. It was written prior to v1.5 but now it is up to v1.5 syntax. It works in 64 bit and should work in 32 as well.

Replace "untitled" with the filename of a program. exe extension is already assumed. The code right now will kill a program called "untitled.exe". You can also kill a program by PID if you have that available to you.

Code: QB64: [Select]

1. Option _Explicit
2. '$Console:Only
3.  
4. Type PROCESSENTRY32
5.     As _Unsigned Long dwSize, cntUsage, th32ProcessID
6.     $If 64BIT Then
7.         As String * 4 padding
8.     $End If
9.     As _Unsigned _Offset th32DefaultHeapID
10.     As _Unsigned Long th32ModuleID, cntThreads, th32ParentProcessID
11.     As Long pcPriClassbase
12.     As _Unsigned Long dwFlags
13.     As String * 260 szExeFile
14. End Type
15.  
16. 'Flags
17. Const TH32CS_INHERIT = &H80000000
18. Const TH32CS_SNAPHEAPLIST = &H00000001
19. Const TH32CS_SNAPMODULE = &H00000008
20. Const TH32CS_SNAPMODULE32 = &H00000010
21. Const TH32CS_SNAPPROCESS = &H00000002
22. Const TH32CS_SNAPTHREAD = &H00000004
23. Const TH32CS_SNAPALL = TH32CS_SNAPHEAPLIST Or TH32CS_SNAPMODULE Or TH32CS_SNAPPROCESS Or TH32CS_SNAPTHREAD
24.  
25. Const PROCESS_TERMINATE = &H0001
26.  
27. Declare Dynamic Library "Kernel32"
28.     Function CreateToolhelp32Snapshot& (ByVal dwFlags As _Unsigned Long, Byval th32ProcessID As _Unsigned Long)
29.     Function Process32First& (ByVal hSnapshot As _Offset, Byval lppe As _Offset)
30.     Function Process32Next& (ByVal hSnapshot As _Offset, Byval lppe As _Offset)
31.     Function OpenProcess%& (ByVal dwDesiredAccess As _Unsigned Long, Byval bInheritHandle As Long, Byval dwProcessId As _Unsigned Long)
32.     Function TerminateProcess& (ByVal hProcess As _Offset, Byval uExitCode As _Unsigned Long)
33.     Sub CloseHandle (ByVal hObject As _Offset)
34. End Declare
35.  
36. 'NOTE: Processes do NOT close gracefully with this option. It's just to kill something immediately.
37.  
38. 'Print KillProcessByName("untitled") 'Doesn't kill gracefully. Think twice before using.
39. 'Print KillProcessByPID(5660) 'Doesn't kill gracefully. Think twice before using.
40.  
41. Function KillProcessByName& (processname As String)
42.     Dim As Long snap
43.     snap = CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0)
44.     Dim As PROCESSENTRY32 pEntry
45.     pEntry.dwSize = Len(pEntry)
46.     Dim As Long hRes
47.     hRes = Process32First(snap, _Offset(pEntry))
48.     While hRes
49.         If Mid$(pEntry.szExeFile, 1, Len(processname + ".exe")) = processname + ".exe" Then
50.             pEntry.szExeFile = ""
51.             Dim As _Offset hProcess
52.             hProcess = OpenProcess(PROCESS_TERMINATE, 0, pEntry.th32ProcessID)
53.             If hProcess <> 0 Then
54.                 Dim As Long terminate
55.                 terminate = TerminateProcess(hProcess, 0)
56.                 CloseHandle hProcess
57.                 If terminate Then KillProcessByName = terminate
58.             End If
59.         End If
60.         hRes = Process32Next(snap, _Offset(pEntry))
61.     Wend
62.     CloseHandle snap
63. End Function
64.  
65. Sub KillProcessByName (processname As String)
66.     Dim As Long a
67.     a = KillProcessByName(processname)
68. End Sub
69.  
70. Function KillProcessByPID& (PID As _Unsigned Long)
71.     Dim As _Offset hProcess
72.     hProcess = OpenProcess(PROCESS_TERMINATE, 0, PID)
73.     If hProcess <> 0 Then
74.         Dim As Long terminate
75.         terminate = TerminateProcess(hProcess, 0)
76.         CloseHandle hProcess
77.         If terminate Then KillProcessByPID = terminate
78.     End If
79. End Function
80.  
81. Sub KillProcessByPID (PID As _Unsigned Long)
82.     Dim As Long a
83.     a = KillProcessByPID(PID)
84. End Sub

[zaadstra]

However, several problems remain...


In practice it seems (it seems!) that the file name should NOT contain the path.
The full path to the file MUST be put together with the dos command.
The path can be assigned to a variable, and this can be added to the DOS command, but it can NOT be inside the file name...


Taskkill, instead, it seems to ignore all this...

To the DOS command "Copy", instead, everything is fine... and works with any combination...

But not always always... :(

Next to all other solutions in this thread. 

If in doubt that a command is working,  try it in a CMD window (DOS box).  You not only can see error messages, but most commands show a good help /? function:

Code: Text: [Select]

1. R:\>ren r:\a.txt r:\b.txt
2. The syntax of the command is incorrect.
3.  
4. R:\>ren /?
5. Renames a file or files.
6.  
7. RENAME [drive:][path]filename1 filename2.
8. REN [drive:][path]filename1 filename2.
9.  
10. Note that you cannot specify a new drive or path for your destination file.
11.  
12. R:\>

[krovit]

Code: QB64: [Select]

1. SHELL _DONTWAIT "C:\Windows\System32\notepad.exe"
2. _DELAY 2
3. SHELL "taskkill /IM " + CHR$(34) + "notepad.*" + CHR$(34)
4. END
5.  

Thank you Petr and Zaadstra...

I tried the DOS command syntax in every way (obviously starting from the right one) but none worked.

Petr's code on my pc does not work in any way.
At this point I begin to believe that there is something on my PC with windows 7 (but also with 10) that is not good

Maybe a customization maybe something else that makes these commands ineffective.

[krovit]

Thank you SpriggsySpriggs...

The code works perfectly even on my machines!

I wonders because all these lines of code are needed for a simple taskkill.

Of course I wonder where you found all those references !