Author Topic: Problem with CLEAR (Read 5361 times)

bartok · « **on:** June 23, 2021, 07:44:20 am »

PROBLEM WITH CLEAR

The goal is to implement the possibility, at the end of the program, to restart it from the beginning if the user want to do that, without going SYSTEM end run the program one more time.

Below, there is an extract of the program.

At line 1, a DO LOOP cycle starts and it ends at the end of the main code, at line 227. In lines 222 to 225, an other DO LOOP cycle waits a key press from user that has to be "s" or "n" in order exit this DO LOOP cycle. If it is "n", IF command in line 226 EXIT DO started in line 1, and program goes SYSTEM. IF it is "s", the program loops and goes to line 1.

It works.

But, when the program restarts, I have to clear all variables and arrays. Activating CLEAR command in line 2, the program not even starts! Everywhere I put the command CLEAR, no way the program works. In the help, I sawn that CLEAR has some problems with REDIM. But don't have found solution even moving away DATA.

Code: QB64: [Select]

DO
    '    CLEAR
    CLS
    OPTION BASE 1
    _TITLE "Calcolo dell'idrogramma di piena di progetto tramite il metodo SCS-CN"
 
    TempiRitorno:
    DATA "Definito dall'utente",2,5,10,20,50,100,200,500,1000
    DATA 1,0.82,1.24,1.46,1.69,2.04,2.34,2.70,3.22,3.64
    CoefficientiIdrogrammaUnitarioMockus: 'dati dell'idrogramma unitario di Mockus
    DATA 0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1,1.1,1.2,1.3,1.4,1.5,1.6,1.7,1.8,1.9,2,2.1,2.2,2.3,2.4,2.5,2.6,2.7,2.8,2.9,3,3.1,3.2,3.3,3.4,3.5,3.6,3.7,3.8,3.9,4,4.1,4.2,4.3,4.4,4.5,4.6,4.7,4.8,4.9,5: 't/ta
    DATA 0.03,0.1,0.19,0.31,0.47,0.66,0.82,0.93,0.99,1,0.99,0.93,0.86,0.78,0.68,0.56,0.46,0.39,0.33,0.28,0.244,0.207,0.177,0.147,0.127,0.107,0.092,0.077,0.066,0.055,0.048,0.04,0.035,0.029,0.025,0.021,0.018,0.015,0.013,0.011,0.009,0.008,0.007,0.006,0.006,0.005,0.004,0.003,0.001,0: ' t/tp
    CoefficientiDiscretizzazioneTemporale:
    DATA 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,18,20,22,24,26,28,30,32: 'N volte tc!.
    DATA 0.1,0.2,0.3,0.2,0.3,0.3,0.3,0.3,0.5,0.5,0.5,0.5,0.5,0.5,0.5,0.5,1,1,1,1,1,1,1,1: 'discretizzazione dei coeff. di Mockus.
 
    TYPE mockus
        tSUta AS SINGLE
        qSUqp AS SINGLE
    END TYPE
    TYPE CoefficientiDiscretizzazioneTemporale
        N AS INTEGER
        d AS SINGLE
        tSUta AS SINGLE
    END TYPE
    TYPE TempiRitorno
        T AS STRING
        k AS SINGLE
    END TYPE
    TYPE matrice1
        mdt AS SINGLE '[ore] conta la progessione delle ore fino al raggiungimento di "d".
        h1 AS SINGLE '[mm] DisegnaValore h della curva di possibilità climatica.
        i1 AS SINGLE '[mm/ora] intensità di pioggia.
        i2 AS SINGLE '[mm/ora] intensità di pioggia secondo lo ietogramma Chicago o costante.
        DH AS SINGLE '[mm] pioggia in ogni istante temporale dt.
        H2 AS SINGLE '[mm] pioggia cumulata ad ogni istante temporale.
        he AS SINGLE '[mm] piggia efficace cumulata ad ogni istante temporale.
        Dhe AS SINGLE '[mm] pioggia efficace ad ogni istante temporale.
        tSUta AS SINGLE
        qSUqp AS SINGLE
        tmSUta AS SINGLE '[-].
        qmSUqp AS SINGLE '[-] il DisegnaValore di qm/qp corrispondente a tm/ta e' = al DisegnaValore di q/qp che corrisponde a t/ta=tm/ta.
        qm AS SINGLE '[mc/s].
    END TYPE
    TYPE idrogramma
        i AS INTEGER
        ore AS SINGLE
        portata AS SINGLE
    END TYPE
    TYPE composizione
        grafico AS LONG
        composizione AS LONG
    END TYPE
 
    CONST R& = _RGB32(255, 0, 0)
    CONST G& = _RGB32(0, 255, 0)
    CONST B& = _RGB32(0, 0, 255)
    CONST bianco& = _RGB32(255, 255, 255)
    CONST giallo& = _RGB32(255, 255, 0)
    CONST grigio& = _RGB32(127, 127, 127)
    CONST azzurro& = _RGB32(0, 255, 255)
    CONST pastello& = _RGB32(183, 150, 139)
    CONST viola& = _RGB32(255, 0, 255)
    CONST trasparente& = _RGB32(0, 0)
    CONST LarghezzaColonna% = 8
 
    DIM SHARED idrogrammi1a24(2, 24, 50, 1) AS idrogramma
    DIM SHARED MassimiIdrogrammi1a24(2, 24, 1) AS idrogramma
    DIM SHARED FinePioggiaIdrogrammi1a24(2, 24, 1) AS idrogramma ' per ogniidrogrammi1a24( trova il momento di Durata della pioggia.
    DIM SHARED i%, n%, z%, ieto%, VisualizzaIeto%
    DIM SHARED ore!(3), portata!(3) 'ore e portate di picco dell'idrogramma di progetto e scelto (entrambi interpolati).
    DIM SHARED tipo% '1:idrogrammi1a24( di progetto. 2: a ascelta. Entrambi interpolati.
    DIM SHARED MassimiAssolutiIeto(2) AS idrogramma
    DIM SHARED IdroMaxIeto%(2) 'memorizza l'idrogramma con la portata di picco massima (che per lo ietogramma chicago è sempre l'ultimo), in modo da definire l'idrogramma di progetto quando la soglia di progetto e' troppo bassa.
    DIM SHARED FinePioggiaIdrogrammi1e2(2) AS idrogramma 'serve a memorizzare l'ora e la portata in cui termina la pioggia.
    DIM SHARED PassiFinePioggia1a24%(2, 24)
    DIM SHARED L%, H%
    DIM SHARED CoefficientiDiscretizzazioneTemporale(24) AS CoefficientiDiscretizzazioneTemporale
    DIM SHARED TempiRitorno(10) AS TempiRitorno
    DIM SHARED T$
    DIM SHARED KeyPress$
 
    REDIM SHARED IdroPixel1(1) AS idrogramma
    REDIM SHARED IdroPixel2(1) AS idrogramma
    REDIM SHARED idrogramma1(1) AS idrogramma 'idrogramma di progetto.
    REDIM SHARED idrogramma2(1) AS idrogramma 'idrogramma a scelta.
 
    DIM FineColonna%(8)
    DIM esci$
    DIM esci%(2)
    DIM schermo&
    DIM ComplessivoIeto1e2(2) AS composizione
    DIM idrogramma1e2(2) AS composizione
    DIM graficoCOPIA&
    DIM quadro&
    DIM unitari&
    DIM MatriciIeto1e2(2, 24)
    DIM mockus(50) AS mockus
    DIM dt!(2, 24)
    DIM matrice1(2, 24, 50, 1) AS matrice1
    DIM matrice2!(2, 24, 50, 50)
    DIM MinimiMatriciQuadrante1(2, 24, 1) AS idrogramma 'riferito all'idrogramma
    DIM MinimiMatriciQuadrante2(2, 24, 1) AS idrogramma 'riferito all'idrogramma unitario
    DIM MassimiQuadrante2(2, 24, 1) AS idrogramma 'riferito all'idrogramma unitario
    DIM test%
    DIM CoeffPerditeIniziali!
    DIM S2! '[mm] contenuto idrico massimodel terreno.
    DIM Ia! '[mm] perdite iniziali.
    DIM tc! '[ore] tempo di corrivazione
    DIM ta! '[ore] tempo di picco.
    DIM qp! '[mc/s] portata al colmo dell'idrogramma unitario.
    DIM k! '[-] coeff. della curva di possibilità climatica tado dal sito della Regione.
    DIM a1! '[mm/d^n] coeff. della curva di possibilità climatica.
    DIM n1! '[-] coeff. della curva di possibilità climatica.
    DIM A2! '[mq] superficie bacino idrografico.
    DIM L! '[m] lunghezza asta principale.
    DIM HmaxL! '[m] punto più alto dell'astra principale.
    DIM HminL! '[m] punto più basso dell'asta principale.
    DIM s1! '[-] pendenza media del bacino non espressa in percentuale ma come 0,x.
    DIM CNII! '[-] Intestazioneto.
    DIM CNIII '[-] discende da CNII.
    DIM tl! '[ore] tempo di ritardo.
 
    RESTORE TempiRitorno
    FOR i% = 1 TO 20
        IF i% <= 10 THEN READ TempiRitorno(i%).T
        IF i% > 10 THEN READ TempiRitorno(i% - 10).k
    NEXT i%
    RESTORE CoefficientiIdrogrammaUnitarioMockus
    FOR i% = 1 TO 100
        IF i% <= 50 THEN READ mockus(i%).tSUta
        IF i% > 50 THEN READ mockus(i% - 50).qSUqp
    NEXT i%
    L% = _DESKTOPWIDTH - 20: H% = L% \ 1.62 'imposta la larghezza dello SCREEN in modo che L%xH% sia un rettangolo aureo.
    FOR ieto% = 1 TO 2
        ComplessivoIeto1e2(ieto%).grafico = _NEWIMAGE(L% - (L% \ 5), H%, 32)
        ComplessivoIeto1e2(ieto%).composizione = _NEWIMAGE(L%, H%, 32)
        idrogramma1e2(ieto%).grafico = _NEWIMAGE(L% - (L% \ 4), H%, 32)
        idrogramma1e2(ieto%).composizione = _NEWIMAGE(L%, H%, 32)
        FOR z% = 1 TO 24
            MatriciIeto1e2(ieto%, z%) = _NEWIMAGE(L%, H%, 32)
        NEXT z%
    NEXT ieto%
    quadro& = _NEWIMAGE(L% \ 2, H% \ 2, 32)
    unitari& = _NEWIMAGE(L%, H%, 32)
    schermo& = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT, 32)
    esci$ = "I dati forniti non determinano pioggia efficace o questa Š tale da comportare portate trascurabili."
    SCREEN schermo&
    _SCREENMOVE 0, 0
    PRINT "Questo programma serve a calcolare l'idrogramma di progetto (e relativa portata di picco) per"
    PRINT "un  dato  tempo  di  ritorno,  utilizzando  l'idrogramma  unitario  adimensionale di Mockus e"
    PRINT "ietrogrammi tipo "; CHR$(34); "Chicago"; CHR$(34); " o "; CHR$(34); "costanti"; CHR$(34); "."
    PRINT
    PRINT "Di seguito si dovranno inserire i valori della curva di possibilit… climatica "; CHR$(34); "h = Ktúaúd^n"; CHR$(34); "."
    PRINT "Se  si dispone  dei valori  del Centro  Funzionale, digitare il valore "; CHR$(34); "Kt"; CHR$(34); " relativo al tempo"
    PRINT "di ritorno "; CHR$(34); "T"; CHR$(34); " d'interesse, con i relativi valori "; CHR$(34); "a"; CHR$(34); " e "; CHR$(34); "n"; CHR$(34); "."
    PRINT "Se invece si ha una  propria curva di possibilit… climatica, quando verr… chiesto di inserire"
    PRINT CHR$(34); "Kt"; CHR$(34); ", digitare "; CHR$(34); "INVIO"; CHR$(34); ", o "; CHR$(34); "1"; CHR$(34); "."
    PRINT "In tal caso "; CHR$(34); "Kt"; CHR$(34); " sar… considerato pari a "; CHR$(34); "1"; CHR$(34); " e "; CHR$(34); "T"; CHR$(34); " come "; CHR$(34); "definito dall'utente"; CHR$(34); "."
    PRINT
    PRINT "- Kt [-] (INVIO per 1)                                           = "
    PRINT "- a [mm/d^n]                                                     = "
    PRINT "- n [-] (0ö1)                                                    = "
    PRINT "- Area del bacino idrografico [mý]                               = "
    PRINT "- Lunghezza dell'asta principale del bacino idrografico [m]      = "
    PRINT "- Altitudine s.l.m. del punto pi— alto dell'asta principale [m]  = "
    PRINT "- Altitudine s.l.m. del punto pi— basso dell'asta principale [m] = "
    PRINT "- Pendenza media del bacino idrografico [%] (1ö100)              = "
    PRINT "- CN(II) [-] (1ö100)                                             = "
    PRINT "- Coefficiente delle perdite inziali [-] (0ö0.2 - INVIO per 0.1) = "
    CALL InserimentoDati(k!, a1!, n1, A2!, L!, HmaxL!, HminL!, s1!, CNII!, CoeffPerditeIniziali!)
    _AUTODISPLAY
    LOCATE PosizioneCursore% + 10, 1
    PRINT "- Visualizzare i risultati utilizzando lo ietogramma Chicago [1] o costante [2]?"
    PRINT
    DO
        _LIMIT 50
        KeyPress$ = INKEY$
    LOOP UNTIL KeyPress$ = "1" OR KeyPress$ = "2"
    VisualizzaIeto% = VAL(KeyPress$)
    CNIII! = (23 * CNII!) / (10 + 0.13 * CNII!)
    tl! = 0.342 * ((L! / 1000) ^ 0.8 / s1! ^ 0.5) * (1000 / CNIII! - 9) ^ 0.7 'formula di Mockus.
    S2! = 25.4 * (1000 / CNIII! - 10)
    Ia! = CoeffPerditeIniziali! * S2! 'coeff.=0.03-0.2. 'perdite iniziali
    tc! = tl! / 0.6
    ta! = tl! / 0.9
    qp! = 0.208 * ((A2! / 1000000) / ta!)
    RESTORE CoefficientiDiscretizzazioneTemporale
    FOR i% = 1 TO 48
        IF i% <= 24 THEN READ CoefficientiDiscretizzazioneTemporale(i%).N: CoefficientiDiscretizzazioneTemporale(i%).d = CoefficientiDiscretizzazioneTemporale(i%).N * tc!
        IF i% > 24 THEN READ CoefficientiDiscretizzazioneTemporale(i% - 24).tSUta
    NEXT i%
 
    'FOR ieto% = 1 TO 2
    '    FOR z% = 1 TO 24
    '        GOSUB CalcolaMatriciIeto1e2
    '        IF esci%(ieto%) = 0 THEN GOSUB DisegnaMatriciIeto1e2
    '    NEXT z%
    '    IF esci%(ieto%) = 0 THEN GOSUB DisegnaComplessivoIeto1e2
    'NEXT ieto%
    '_DEST schermo&
    'SELECT CASE esci%(VisualizzaIeto%)
    '    CASE IS = 0
    '        CLS
    '        GOSUB DisegnaUnitari
    '        GOSUB VisualizzaComplessivo
    '        SLEEP
    '        CALL CalcolaIdrogramma(MassimiIdrogrammi1a24(VisualizzaIeto%, 24, 1).ore, idrogrammi1a24(VisualizzaIeto%, 24, 50, 1).ore, MassimiAssolutiIeto(VisualizzaIeto%).ore, MassimiAssolutiIeto(VisualizzaIeto%).portata, ComplessivoIeto1e2(VisualizzaIeto%).grafico, ComplessivoIeto1e2(VisualizzaIeto%).composizione, graficoCOPIA&)
    '        SLEEP
    '        GOSUB DisegnaIdrogramma
    '        GOSUB VisualizzaIdrogramma
    '        SLEEP
    '        GOSUB VisualizzaUnitari
    '        GOSUB VisualizzaMatrici
    '    GOSUB Risultati
    '    CASE IS = 1
    '        PRINT esci$
    'END SELECT
    GOSUB freeimage
    PRINT
    PRINT "- Riavviare il programma? [S/N]"
    DO
        _LIMIT 50
        KeyPress$ = LCASE$(INKEY$)
    LOOP UNTIL KeyPress$ = "s" OR KeyPress$ = "n"
    IF KeyPress$ = "n" THEN EXIT DO
LOOP
SYSTEM
'---------------------------------------------------------------------------------------------------------------------------------------------------
freeimage:
FOR ieto% = 1 TO 2
    _FREEIMAGE ComplessivoIeto1e2(ieto%).grafico
    _FREEIMAGE ComplessivoIeto1e2(ieto%).composizione
    _FREEIMAGE idrogramma1e2(ieto%).grafico
    _FREEIMAGE idrogramma1e2(ieto%).composizione
    FOR z% = 1 TO 24
        _FREEIMAGE MatriciIeto1e2(ieto%, z%)
    NEXT z%
    '    IF esci%(ieto%) = 0 THEN _FREEIMAGE graficoCOPIA&
NEXT ieto%
_FREEIMAGE unitari&
_FREEIMAGE quadro&
RETURN
 
 
'-----------------------------------------------------------------------------------------------------------------------------------------------------------
SUB InserimentoDati (k!, a1!, n1, A2!, L!, HmaxL!, HminL!, s1!, CNII!, CoeffPerditeIniziali!)
 
    SHARED PosizioneCursore%
 
    DIM inputs$(10)
    DIM richiesta%
    DIM test%(10)
    DIM debug%
    DIM carattere$
    DIM punti%
    DIM T!
    DIM cursore%
    DIM esci%
 
    PosizioneCursore% = CSRLIN - 10
    richiesta% = 1
    T! = TIMER
    DO
        _LIMIT 30
        KeyPress$ = INKEY$
        IF TIMER > T! + 0.5 THEN
            cursore% = NOT cursore%
            T! = TIMER
        END IF
        FOR i% = 1 TO 10
            LOCATE PosizioneCursore% - 1 + i%, 68: PRINT inputs$(i%) + SPACE$(30)
        NEXT i%
        LOCATE PosizioneCursore% - 1 + richiesta%, 68 + LEN(inputs$(richiesta%))
        IF debug% = 1 THEN EXIT SUB
        IF esci% = 1 THEN EXIT DO
        IF cursore% THEN PRINT "_"
        SELECT CASE KeyPress$
            CASE CHR$(44), CHR$(46) ',e.
                punti% = 0
                IF KeyPress$ = CHR$(44) THEN KeyPress$ = CHR$(46)
                FOR n% = 1 TO LEN(inputs$(richiesta%))
                    carattere$ = MID$(inputs$(richiesta%), n%, 1)
                    IF carattere$ = CHR$(46) THEN punti% = 1
                NEXT n%
                IF punti% = 0 THEN inputs$(richiesta%) = inputs$(richiesta%) + KeyPress$
            CASE CHR$(48) TO CHR$(57) '0-9
                inputs$(richiesta%) = inputs$(richiesta%) + KeyPress$
            CASE CHR$(8) 'del
                IF LEN(inputs$(richiesta%)) > 0 THEN inputs$(richiesta%) = LEFT$(inputs$(richiesta%), LEN(inputs$(richiesta%)) - 1)
            CASE CHR$(0) + "H" 'su
                GOSUB Valutavalore
                SELECT CASE test%(richiesta%)
                    CASE IS = 0
                        inputs$(richiesta%) = ""
                    CASE IS = 1
                        IF richiesta% = 1 THEN
                            EXIT SELECT
                        ELSEIF richiesta <= 10 THEN
                            richiesta% = richiesta% - 1
                        END IF
                END SELECT
            CASE CHR$(13), CHR$(0) + "P" 'invio
                IF debug% = 1 THEN EXIT SELECT
                GOSUB Valutavalore
                IF richiesta% <> 10 THEN
                    IF KeyPress$ = CHR$(0) + "P" THEN KeyPress$ = CHR$(13)
                END IF
                IF richiesta% <> 1 THEN
                    IF LEN(inputs$(richiesta%)) = 0 THEN test%(richiesta%) = 0
                END IF
                SELECT CASE test%(richiesta%)
                    CASE IS = 0
                        inputs$(richiesta%) = ""
                    CASE IS = 1
                        IF richiesta% = 10 THEN
                            IF KeyPress$ = CHR$(0) + "P" THEN
                                EXIT SELECT
                            ELSE
                                esci% = 1
                            END IF
                        ELSE
                            richiesta% = richiesta% + 1
                        END IF
                END SELECT
        END SELECT
    LOOP
    k! = VAL(inputs$(1)): a1! = VAL(inputs$(2)): n1! = VAL(inputs$(3)): A2! = VAL(inputs$(4)): L! = VAL(inputs$(5)): HmaxL! = VAL(inputs$(6)): HminL! = VAL(inputs$(7)): s1! = VAL(inputs$(8)): CNII! = VAL(inputs$(9)): CoeffPerditeIniziali! = VAL(inputs$(10))
    EXIT SUB
    '-----------------------------------------------------------------------------------------------------------------------------------------------------------
    Valutavalore:
    test%(richiesta%) = 0 ' se 0 rimane nella richiesta in corso, se 1, cambia.
 
    SELECT CASE richiesta%
        CASE 1
            IF inputs$(richiesta%) = "123" THEN 'avvia debug
                debug% = 1
                'test:
                'k! = 2.34: a1! = 1: n1! = 0.45596: A2! = 0: L! = 3300: HmaxL! = 1981: HminL! = 1062: s1! = 41.5: CNII! = 70: CoeffPerditeIniziali! = 0.1
                'Cillian:
                k! = 2.34: a1! = 14.6653: n1! = 0.45596: A2! = 2641902: L! = 3300: HmaxL! = 1981: HminL! = 1062: s1! = 41.5: CNII! = 70: CoeffPerditeIniziali! = 0.1
                'pialong:
                'k! = 2.34:'a1! = 17.097811:'n1! = 0.497753:'A2! = 2509318:'L! = 2919:'HmaxL! = 1654:'HminL! = 388:'s1! = 0.663:'CNII! = 66:CoeffPerditeIniziali!=0.1
                GOSUB TrovaT
                RETURN
            END IF
            IF LEN(inputs$(richiesta%)) = 0 THEN
                IF KeyPress$ = CHR$(13) THEN inputs$(richiesta%) = "1"
            END IF
            GOSUB TrovaT
            IF KeyPress$ = CHR$(0) + "P" THEN
                IF LEN(inputs$(richiesta%)) = 0 THEN test%(richiesta%) = 0
            END IF
        CASE 2, 4, 5, 6, 7
            test%(richiesta%) = 1
        CASE 3
            IF VAL(inputs$(richiesta%)) <= 1 THEN
                test%(richiesta%) = 1
            ELSE
                test%(richiesta%) = 0
            END IF
        CASE 8, 9
            IF VAL(inputs$(richiesta%)) >= 1 THEN
                IF VAL(inputs$(richiesta%)) <= 100 THEN test%(richiesta%) = 1
            ELSEIF inputs$(richiesta%) = "" THEN test%(richiesta%) = 1
            ELSE
                test%(richiesta%) = 0
            END IF
        CASE IS = 10
            IF LEN(inputs$(richiesta%)) = 0 THEN
                IF KeyPress$ = CHR$(13) THEN inputs$(richiesta%) = "0.1"
                test%(richiesta%) = 1
                EXIT SELECT
            END IF
            IF VAL(inputs$(richiesta%)) >= 0 THEN
                IF VAL(inputs$(richiesta%)) <= 0.2 THEN
                    IF KeyPress$ = CHR$(0) + "P" THEN
                        test%(richiesta%) = 1
                    ELSE
                        test%(richiesta%) = 1
                    END IF
                ELSE
                    test%(richiesta%) = 0
                END IF
            END IF
    END SELECT
    RETURN
    '-----------------------------------------------------------------------------------------------------------------------------------------------------------
    TrovaT:
    i% = 1
    '    IF debug% <> 1 THEN k! = VAL(inputs$(1))
    FOR i% = 1 TO 10
        IF VAL(inputs$(1)) = TempiRitorno(i%).k THEN
            IF i% = 1 THEN
                T$ = TempiRitorno(i%).T
                test%(richiesta%) = 1
            ELSE
                T$ = TempiRitorno(i%).T + " anni"
                test%(richiesta%) = 1
            END IF
            EXIT FOR
        ELSE
            test%(richiesta%) = 0
        END IF
    NEXT i%
    RETURN
END SUB
 

SpriggsySpriggs · « **Reply #1 on:** June 23, 2021, 09:14:32 am »

I seem to recall there being an issue with CLEAR causing it to free screen handles? Do you recall, @FellippeHeitor ?

FellippeHeitor · « **Reply #2 on:** June 23, 2021, 09:50:02 am »

That got fixed in the dev builds. This seems like something else. I'll have a closer look later.

SpriggsySpriggs · « **Reply #3 on:** June 23, 2021, 10:12:59 am »

@bartok

Can you provide some test data? I don't understand the language and don't know what it expects as input. Also, I don't think you need your freeimage subroutine since CLEAR already frees all valid images.

bartok · « **Reply #4 on:** June 23, 2021, 11:38:07 am »

Quote from: SpriggsySpriggs on June 23, 2021, 10:12:59 am

@bartok

[...] Also, I don't think you need your freeimage subroutine since CLEAR already frees all valid images.

I posted a question about that some time ago, just asking why Terry Ritchie's tutorials insisted in _FREEIMAGE importance at the end of the main code, if a simple CLEAR command, should clear all.

It was responded to me something like this: imagines access the video memory and CLEAR doesn't free these memory handles.

Quote from: SpriggsySpriggs on June 23, 2021, 10:12:59 am

@bartok

Can you provide some test data? I don't understand the language and don't know what it expects as input. [...]

Below, the code you have asked for. Reduncing it at the minimum in order to make it clearer, I have found the problem, but it is a mystery!

Enabling command CLEAR in line 2, the program doesn't work and crashes. I works ONLY disabling "RESTORE group 1"...

Changing the text in DATA "Definito dall'utente" with a random number, it still not works.

But besides changing:

TYPE TempiRitorno
T AS STRING
k AS SINGLE
END TYPE

with

TYPE TempiRitorno
T AS SINGLE
k AS SINGLE
END TYPE

It works.

So, it seems that CLEAR has some problem with TYPE defining STRING or mixed kind of variables.

Code: QB64: [Select]

DO
    CLEAR
    CLS
    OPTION BASE 1
 
 
    TempiRitorno:
    DATA "Definito dall'utente",2,5,10,20,50,100,200,500,1000
    DATA 1,0.82,1.24,1.46,1.69,2.04,2.34,2.70,3.22,3.64
    CoefficientiIdrogrammaUnitarioMockus: 'dati dell'idrogramma unitario di Mockus
    DATA 0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1,1.1,1.2,1.3,1.4,1.5,1.6,1.7,1.8,1.9,2,2.1,2.2,2.3,2.4,2.5,2.6,2.7,2.8,2.9,3,3.1,3.2,3.3,3.4,3.5,3.6,3.7,3.8,3.9,4,4.1,4.2,4.3,4.4,4.5,4.6,4.7,4.8,4.9,5: 't/ta
    DATA 0.03,0.1,0.19,0.31,0.47,0.66,0.82,0.93,0.99,1,0.99,0.93,0.86,0.78,0.68,0.56,0.46,0.39,0.33,0.28,0.244,0.207,0.177,0.147,0.127,0.107,0.092,0.077,0.066,0.055,0.048,0.04,0.035,0.029,0.025,0.021,0.018,0.015,0.013,0.011,0.009,0.008,0.007,0.006,0.006,0.005,0.004,0.003,0.001,0: ' t/tp
 
    TYPE mockus
        tSUta AS SINGLE
        qSUqp AS SINGLE
    END TYPE
    TYPE TempiRitorno
        T AS STRING
        k AS SINGLE
    END TYPE
    DIM SHARED i%, n%, z%, ieto%, VisualizzaIeto%
    DIM SHARED TempiRitorno(10) AS TempiRitorno
    DIM mockus(50) AS mockus
 
    ' 'RESTORE group 1:
    RESTORE TempiRitorno
    FOR i% = 1 TO 20
        IF i% <= 10 THEN READ TempiRitorno(i%).T
        IF i% > 10 THEN READ TempiRitorno(i% - 10).k
    NEXT i%
 
    ' 'RESTORE group 2:
    RESTORE CoefficientiIdrogrammaUnitarioMockus
    FOR i% = 1 TO 100
        IF i% <= 50 THEN READ mockus(i%).tSUta
        IF i% > 50 THEN READ mockus(i% - 50).qSUqp
    NEXT i%
 
 
    '[...]
    PRINT
    PRINT "- Restart program? [Y/N]"
    DO
        _LIMIT 50
        KeyPress$ = LCASE$(INKEY$)
    LOOP UNTIL KeyPress$ = "y" OR KeyPress$ = "n"
    IF KeyPress$ = "n" THEN EXIT DO
LOOP
END

bplus · « **Reply #5 on:** June 23, 2021, 02:53:29 pm »

Seems to me that Type, Const, Shared statements should all be outside of loop.

To restart with everything cleared do that at start of a rerun loop (instead of a Run statement) set everything to 0.

Erase, arrays started with Dim and ReDim dynamic arrays started with Redim.

George McGinn · « **Reply #6 on:** June 24, 2021, 12:15:24 am »

Can you nest RUN statements?

What I mean is can you in program A, execute a RUN for program A?

A RUN clears memory of the calling program. The only question is can you do a recursive RUN to the calling program.

bartok · « **Reply #7 on:** June 24, 2021, 02:25:18 am »

Quote from: bplus on June 23, 2021, 02:53:29 pm

Seems to me that Type, Const, Shared statements should all be outside of loop.

It not works:

Code: QB64: [Select]

CLS
OPTION BASE 1
 
 
TempiRitorno:
DATA "Definito dall'utente",2,5,10,20,50,100,200,500,1000
DATA 1,0.82,1.24,1.46,1.69,2.04,2.34,2.70,3.22,3.64
CoefficientiIdrogrammaUnitarioMockus: 'dati dell'idrogramma unitario di Mockus
DATA 0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1,1.1,1.2,1.3,1.4,1.5,1.6,1.7,1.8,1.9,2,2.1,2.2,2.3,2.4,2.5,2.6,2.7,2.8,2.9,3,3.1,3.2,3.3,3.4,3.5,3.6,3.7,3.8,3.9,4,4.1,4.2,4.3,4.4,4.5,4.6,4.7,4.8,4.9,5: 't/ta
DATA 0.03,0.1,0.19,0.31,0.47,0.66,0.82,0.93,0.99,1,0.99,0.93,0.86,0.78,0.68,0.56,0.46,0.39,0.33,0.28,0.244,0.207,0.177,0.147,0.127,0.107,0.092,0.077,0.066,0.055,0.048,0.04,0.035,0.029,0.025,0.021,0.018,0.015,0.013,0.011,0.009,0.008,0.007,0.006,0.006,0.005,0.004,0.003,0.001,0: ' t/tp
 
TYPE mockus
    tSUta AS SINGLE
    qSUqp AS SINGLE
END TYPE
TYPE TempiRitorno
    T AS STRING
    k AS SINGLE
END TYPE
DIM SHARED i%, n%, z%, ieto%, VisualizzaIeto%
DIM SHARED TempiRitorno(10) AS TempiRitorno
DIM mockus(50) AS mockus
 
DO
    CLEAR
 
    ' 'RESTORE group 1:
    RESTORE TempiRitorno
    FOR i% = 1 TO 20
        IF i% <= 10 THEN READ TempiRitorno(i%).T
        IF i% > 10 THEN READ TempiRitorno(i% - 10).k
    NEXT i%
 
    ' 'RESTORE group 2:
    RESTORE CoefficientiIdrogrammaUnitarioMockus
    FOR i% = 1 TO 100
        IF i% <= 50 THEN READ mockus(i%).tSUta
        IF i% > 50 THEN READ mockus(i% - 50).qSUqp
    NEXT i%
 
 
    '[...]
    PRINT
    PRINT "- Restart program? [Y/N]"
    DO
        _LIMIT 50
        KeyPress$ = LCASE$(INKEY$)
    LOOP UNTIL KeyPress$ = "y" OR KeyPress$ = "n"
    IF KeyPress$ = "n" THEN EXIT DO
LOOP
END
 

However, in this way I have solved:

Code: QB64: [Select]

DO
    CLEAR
 
    CLS
    OPTION BASE 1
 
 
    TempiRitorno:
    DATA 0,2,5,10,20,50,100,200,500,1000: '------------------------------------------------------>removed text end changed with "0".
    DATA 1,0.82,1.24,1.46,1.69,2.04,2.34,2.70,3.22,3.64
    CoefficientiIdrogrammaUnitarioMockus: 'dati dell'idrogramma unitario di Mockus
    DATA 0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1,1.1,1.2,1.3,1.4,1.5,1.6,1.7,1.8,1.9,2,2.1,2.2,2.3,2.4,2.5,2.6,2.7,2.8,2.9,3,3.1,3.2,3.3,3.4,3.5,3.6,3.7,3.8,3.9,4,4.1,4.2,4.3,4.4,4.5,4.6,4.7,4.8,4.9,5: 't/ta
    DATA 0.03,0.1,0.19,0.31,0.47,0.66,0.82,0.93,0.99,1,0.99,0.93,0.86,0.78,0.68,0.56,0.46,0.39,0.33,0.28,0.244,0.207,0.177,0.147,0.127,0.107,0.092,0.077,0.066,0.055,0.048,0.04,0.035,0.029,0.025,0.021,0.018,0.015,0.013,0.011,0.009,0.008,0.007,0.006,0.006,0.005,0.004,0.003,0.001,0: ' t/tp
 
    TYPE mockus
        tSUta AS SINGLE
        qSUqp AS SINGLE
    END TYPE
    TYPE TempiRitorno
        T AS SINGLE '-------------------------------------------------------------------------->changed STRING to SINGLE
        k AS SINGLE
    END TYPE
    DIM SHARED i%, n%, z%, ieto%, VisualizzaIeto%
    DIM SHARED TempiRitorno(10) AS TempiRitorno
    DIM mockus(50) AS mockus
 
 
    ' 'RESTORE group 1:
    RESTORE TempiRitorno
    FOR i% = 1 TO 20
        IF i% <= 10 THEN READ TempiRitorno(i%).T
        IF i% > 10 THEN READ TempiRitorno(i% - 10).k
    NEXT i%
 
    ' 'RESTORE group 2:
    RESTORE CoefficientiIdrogrammaUnitarioMockus
    FOR i% = 1 TO 100
        IF i% <= 50 THEN READ mockus(i%).tSUta
        IF i% > 50 THEN READ mockus(i% - 50).qSUqp
    NEXT i%
 
 
    '[...]
    PRINT
    PRINT "- Restart program? [Y/N]"
    DO
        _LIMIT 50
        KeyPress$ = LCASE$(INKEY$)
    LOOP UNTIL KeyPress$ = "y" OR KeyPress$ = "n"
    IF KeyPress$ = "n" THEN EXIT DO
LOOP
END
 

I suppose there is a bug in CLEAR command:
with

TYPE TempiRitorno
T AS STRING
k AS SINGLE
END TYPE

program crashes. Same thing with:

TYPE TempiRitorno
T AS STRING
k AS STRING
END TYPE

It works only with:

TYPE TempiRitorno
T AS SINGLE
k AS SINGLE
END TYPE

bplus · « **Reply #8 on:** June 24, 2021, 07:04:39 am »

Quote

It not works:

I was suggesting a work around CLEAR, clear the things manually without CLEAR.

Code: QB64: [Select]

CLS
OPTION BASE 1
 
 
TempiRitorno:
DATA "Definito dall'utente",2,5,10,20,50,100,200,500,1000
DATA 1,0.82,1.24,1.46,1.69,2.04,2.34,2.70,3.22,3.64
CoefficientiIdrogrammaUnitarioMockus: 'dati dell'idrogramma unitario di Mockus
DATA 0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1,1.1,1.2,1.3,1.4,1.5,1.6,1.7,1.8,1.9,2,2.1,2.2,2.3,2.4,2.5,2.6,2.7,2.8,2.9,3,3.1,3.2,3.3,3.4,3.5,3.6,3.7,3.8,3.9,4,4.1,4.2,4.3,4.4,4.5,4.6,4.7,4.8,4.9,5: 't/ta
DATA 0.03,0.1,0.19,0.31,0.47,0.66,0.82,0.93,0.99,1,0.99,0.93,0.86,0.78,0.68,0.56,0.46,0.39,0.33,0.28,0.244,0.207,0.177,0.147,0.127,0.107,0.092,0.077,0.066,0.055,0.048,0.04,0.035,0.029,0.025,0.021,0.018,0.015,0.013,0.011,0.009,0.008,0.007,0.006,0.006,0.005,0.004,0.003,0.001,0: ' t/tp
 
TYPE mockus
    tSUta AS SINGLE
    qSUqp AS SINGLE
END TYPE
TYPE TempiRitorno
    T AS STRING
    k AS SINGLE
END TYPE
DIM SHARED i%, n%, z%, ieto%, VisualizzaIeto%
DIM SHARED TempiRitorno(10) AS TempiRitorno
DIM mockus(50) AS mockus
 
DO
    ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''CLEAR
 
    ' 'RESTORE group 1:
    RESTORE TempiRitorno
    FOR i% = 1 TO 20
        IF i% <= 10 THEN READ TempiRitorno(i%).T
        IF i% > 10 THEN READ TempiRitorno(i% - 10).k
    NEXT i%
 
    ' 'RESTORE group 2:
    RESTORE CoefficientiIdrogrammaUnitarioMockus
    FOR i% = 1 TO 100
        IF i% <= 50 THEN READ mockus(i%).tSUta
        IF i% > 50 THEN READ mockus(i% - 50).qSUqp
    NEXT i%
 
 
    '[...]
    PRINT
    PRINT "- Restart program? [Y/N]"
    DO
        _LIMIT 50
        KeyPress$ = LCASE$(INKEY$)
    LOOP UNTIL KeyPress$ = "y" OR KeyPress$ = "n"
    IF KeyPress$ = "n" THEN EXIT DO
LOOP
END
 
 

Seems to work fine for me since main code isn't doing anything but load arrays.

SMcNeill · « **Reply #9 on:** June 24, 2021, 08:55:51 am »

Here, I've simplified the issue so everyone can see what's going on here a little better:

Code: QB64: [Select]

Data "Hello World",1
Type test_type
    x As String
    y As Single
End Type
Dim test As test_type
Clear
Read x$, y
Print x$, y
Sleep
Read test.x '<<< The issue is in this line here.  CLEAR and UDT don't seem to play nicely together.
Print "Hello Crash"
Sleep
 

CLEAR and User Defined Types simply aren't playing nice together with other.

An even simpler demo:

Code: QB64: [Select]

Type test_type: x As String: End Type: Dim test As test_type
Clear
x$ = "Hello World": Print x$: Sleep
test.x = x$
Print "Hello Crash", x$: Sleep
 

Apparently, the way it seems to exist to me, at the moment, if you're going to use CLEAR, you don't want to make use of UDTs in your program.

Personally, I tend to *always* to avoid the CLEAR and RUN statements, as I've always found them to be buggy and unreliable at best. Simply having a GOSUB to initialize all variables when they're first defined seems to be the best way to me.

bplus · « **Reply #10 on:** June 24, 2021, 03:42:26 pm »

Quote

Personally, I tend to *always* to avoid the CLEAR and RUN statements, as I've always found them to be buggy and unreliable at best. Simply having a GOSUB to initialize all variables when they're first defined seems to be the best way to me.

+1 yes!

George McGinn · « **Reply #11 on:** June 24, 2021, 03:48:50 pm »

I do too (I never use CLEAR, and I will use pipecom or SHELL instead of RUN).

I thought because RUN wipes out memory and that the fact that the calling program never existed, it was an idea.

Quote from: bplus on June 24, 2021, 03:42:26 pm

+1 yes!

bartok · « **Reply #12 on:** June 25, 2021, 04:49:19 am »

The problem I have found about CLEAR, at the end was very simple to be fixed. I needed to define T AS STRING, but I solved defining T AS SINGLE (and even INTEGER is working) and then converting it in string with _LTRIM and STR$. But, when the code starts to be long and complicated, like the mine with 12 subroutines and almost 2000 lines, it becomes difficult to distinguish if the problem is about something wrong somewhere in the code, or a bug. Generally, 999 every 1000 times the problem is something wrong in the code, so one doesn't think about a bug and finishes to spend much time in searching an error. Finally, one can suppose a bug, but even in this case, it is impossible to know that the problem is in something apparently separate: how one can suppose that there is a conflict between CLEAR and defining a string in TYPE?

Even when I wrote the first post, I was not thinking about a bug in CLEAR, and I was convinced that there was someting wrong in the code, or maybe a wrong use of CLEAR. I found the bug only cutting the first example in order to make it more understandable for you. And, as you say that CLEAR is buggy, maybe there are other bug in it.

I think that it will be nice if CLEAR will be fixed, because I think that it is not a marginal command, as RUN, but a very important one: it is common that a program has to restart itself without exiting and rerun it, so it is important to have a simple and well working command that clear all variables without the necessity to create specific routines to do it.

FellippeHeitor · « **Reply #13 on:** June 25, 2021, 08:01:54 am »

We've had a few corner cases like this one since the introduction of variable-width strings in types. Do you get the same problem with CLEAR if you declare your element as a fixed string element? For example:

Code: QB64: [Select]

    T AS STRING * 256

Cobalt · « **Reply #14 on:** June 25, 2021, 12:12:55 pm »

Quote from: SMcNeill on June 24, 2021, 08:55:51 am

Here, I've simplified the issue so everyone can see what's going on here a little better:

Code: QB64: [Select]
Data "Hello World",1
Type test_type
x As String
y As Single
End Type
Dim test As test_type
Clear
Read x$, y
Print x$, y
Sleep
Read test.x '<<< The issue is in this line here. CLEAR and UDT don't seem to play nicely together.
Print "Hello Crash"
Sleep

CLEAR and User Defined Types simply aren't playing nice together with other.

An even simpler demo:

Code: QB64: [Select]
Type test_type: x As String: End Type: Dim test As test_type
Clear
x$ = "Hello World": Print x$: Sleep
test.x = x$
Print "Hello Crash", x$: Sleep

Apparently, the way it seems to exist to me, at the moment, if you're going to use CLEAR, you don't want to make use of UDTs in your program.

Personally, I tend to *always* to avoid the CLEAR and RUN statements, as I've always found them to be buggy and unreliable at best. Simply having a GOSUB to initialize all variables when they're first defined seems to be the best way to me.

must be a variable length thing, cause using defined length does not crash.

though CLEAR seems to wipe the UDT out, as test.x becomes a single value variable no longer a string. why there is no error when trying to apply a string to numerical variable is odd. cause that is where the crash is, trying to apply a string to numerical.

@FellippeHeitor doesn't crash at least with a fix length string value.

News:

Author Topic: Problem with CLEAR (Read 5361 times)

bartok

Problem with CLEAR

SpriggsySpriggs

Re: Problem with CLEAR

FellippeHeitor

Re: Problem with CLEAR

SpriggsySpriggs

Re: Problem with CLEAR

bartok

Re: Problem with CLEAR

bplus

Re: Problem with CLEAR

George McGinn

Re: Problem with CLEAR

bartok

Re: Problem with CLEAR

bplus

Re: Problem with CLEAR

SMcNeill

Re: Problem with CLEAR

bplus

Re: Problem with CLEAR

George McGinn

Re: Problem with CLEAR

bartok

Re: Problem with CLEAR

FellippeHeitor

Re: Problem with CLEAR

Cobalt

Re: Problem with CLEAR